etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # zsh-refcard-tag documentation: {{{
  15 #   You may notice strange looking comments in this file.
  16 #   These are there for a purpose. grml's zsh-refcard can now be
  17 #   automatically generated from the contents of the actual configuration
  18 #   file. However, we need a little extra information on which comments
  19 #   and what lines of code to take into account (and for what purpose).
  20 #
  21 # Here is what they mean:
  22 #
  23 # List of tags (comment types) used:
  24 #   #a#     Next line contains an important alias, that should
  25 #           be included in the grml-zsh-refcard.
  26 #           (placement tag: @@INSERT-aliases@@)
  27 #   #f#     Next line contains the beginning of an important function.
  28 #           (placement tag: @@INSERT-functions@@)
  29 #   #v#     Next line contains an important variable.
  30 #           (placement tag: @@INSERT-variables@@)
  31 #   #k#     Next line contains an important keybinding.
  32 #           (placement tag: @@INSERT-keybindings@@)
  33 #   #d#     Hashed directories list generation:
  34 #               start   denotes the start of a list of 'hash -d'
  35 #                       definitions.
  36 #               end     denotes its end.
  37 #           (placement tag: @@INSERT-hasheddirs@@)
  38 #   #A#     Abbreviation expansion list generation:
  39 #               start   denotes the beginning of abbreviations.
  40 #               end     denotes their end.
  41 #           Lines within this section that end in '#d .*' provide
  42 #           extra documentation to be included in the refcard.
  43 #           (placement tag: @@INSERT-abbrev@@)
  44 #   #m#     This tag allows you to manually generate refcard entries
  45 #           for code lines that are hard/impossible to parse.
  46 #               Example:
  47 #                   #m# k ESC-h Call the run-help function
  48 #               That would add a refcard entry in the keybindings table
  49 #               for 'ESC-h' with the given comment.
  50 #           So the syntax is: #m# <section> <argument> <comment>
  51 #   #o#     This tag lets you insert entries to the 'other' hash.
  52 #           Generally, this should not be used. It is there for
  53 #           things that cannot be done easily in another way.
  54 #           (placement tag: @@INSERT-other-foobar@@)
  55 #
  56 #   All of these tags (except for m and o) take two arguments, the first
  57 #   within the tag, the other after the tag:
  58 #
  59 #   #<tag><section># <comment>
  60 #
  61 #   Where <section> is really just a number, which are defined by the
  62 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  63 #   instead of names is, that for the reader, the tag should not differ
  64 #   much from a regular comment. For zsh, it is a regular comment indeed.
  65 #   The numbers have got the following meanings:
  66 #         0 -> "default"
  67 #         1 -> "system"
  68 #         2 -> "user"
  69 #         3 -> "debian"
  70 #         4 -> "search"
  71 #         5 -> "shortcuts"
  72 #         6 -> "services"
  73 #
  74 #   So, the following will add an entry to the 'functions' table in the
  75 #   'system' section, with a (hopefully) descriptive comment:
  76 #       #f1# Edit an alias via zle
  77 #       edalias() {
  78 #
  79 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  80 #   that can be found in 'grml-zsh-refcard.tex.in'.
  81 #   If the section number is omitted, the 'default' section is assumed.
  82 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  83 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  84 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  85 #}}}
  86
  87 # zsh profiling {{{
  88 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  89 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
  90     zmodload zsh/zprof
  91 fi
  92 # }}}
  93
  94 # load .zshrc.pre to give the user the chance to overwrite the defaults
  95 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
  96
  97 # {{{ check for version/system
  98 # check for versions (compatibility reasons)
  99 is4(){
 100     [[ $ZSH_VERSION == <4->* ]] && return 0
 101     return 1
 102 }
 103
 104 is41(){
 105     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 106     return 1
 107 }
 108
 109 is42(){
 110     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 111     return 1
 112 }
 113
 114 is425(){
 115     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 116     return 1
 117 }
 118
 119 is43(){
 120     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 121     return 1
 122 }
 123
 124 #f1# Checks whether or not you're running grml
 125 isgrml(){
 126     [[ -f /etc/grml_version ]] && return 0
 127     return 1
 128 }
 129
 130 #f1# Checks whether or not you're running a grml cd
 131 isgrmlcd(){
 132     [[ -f /etc/grml_cd ]] && return 0
 133     return 1
 134 }
 135
 136 if isgrml ; then
 137 #f1# Checks whether or not you're running grml-small
 138     isgrmlsmall() {
 139         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 140     }
 141 else
 142     isgrmlsmall() { return 1 }
 143 fi
 144
 145 isdarwin(){
 146     [[ $OSTYPE == darwin* ]] && return 0
 147     return 1
 148 }
 149
 150 #f1# are we running within an utf environment?
 151 isutfenv() {
 152     case "$LANG $CHARSET $LANGUAGE" in
 153         *utf*) return 0 ;;
 154         *UTF*) return 0 ;;
 155         *)     return 1 ;;
 156     esac
 157 }
 158
 159 # check for user, if not running as root set $SUDO to sudo
 160 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 161
 162 # change directory to home on first invocation of zsh
 163 # important for rungetty -> autologin
 164 # Thanks go to Bart Schaefer!
 165 isgrml && checkhome() {
 166     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 167         export ALREADY_DID_CD_HOME=$HOME
 168         cd
 169     fi
 170 }
 171
 172 # check for zsh v3.1.7+
 173
 174 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 175      || ${ZSH_VERSION} == 3.<2->.<->*    \
 176      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 177
 178     printf '-!-\n'
 179     printf '-!- In this configuration we try to make use of features, that only\n'
 180     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 181     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 182     printf '-!- advanced features in all supported versions.\n'
 183     printf '-!-\n'
 184     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 185     printf '-!-\n'
 186     printf '-!- While this *may* work, it might as well fail.\n'
 187     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 188     printf '-!-\n'
 189     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 190     printf '-!- If it does today, you'\''ve been lucky.\n'
 191     printf '-!-\n'
 192     printf '-!- Ye been warned!\n'
 193     printf '-!-\n'
 194
 195     function zstyle() { : }
 196 fi
 197
 198 # autoload wrapper - use this one instead of autoload directly
 199 # We need to define this function as early as this, because autoloading
 200 # 'is-at-least()' needs it.
 201 function zrcautoload() {
 202     setopt local_options extended_glob
 203     local fdir ffile
 204     local -i ffound
 205
 206     ffile=${1}
 207     (( found = 0 ))
 208     for fdir in ${fpath} ; do
 209         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 210     done
 211
 212     (( ffound == 0 )) && return 1
 213     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 214         autoload -U ${ffile} || return 1
 215     else
 216         autoload ${ffile} || return 1
 217     fi
 218     return 0
 219 }
 220
 221 # Load is-at-least() for more precise version checks
 222 # Note that this test will *always* fail, if the is-at-least
 223 # function could not be marked for autoloading.
 224 zrcautoload is-at-least || is-at-least() { return 1 }
 225
 226 # }}}
 227
 228 # setting some default values {{{
 229
 230 NOCOR=${NOCOR:-0}
 231 NOMENU=${NOMENU:-0}
 232 NOPRECMD=${NOPRECMD:-0}
 233 BATTERY=${BATTERY:-0}
 234 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 235 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 236
 237 if isgrmlcd ; then
 238     GRML_WARN_SKEL=${GRML_WARN_SKEL:-0}
 239 else
 240     GRML_WARN_SKEL=${GRML_WARN_SKEL:-1}
 241 fi
 242
 243 if (( GRML_WARN_SKEL != 0 )) ; then
 244
 245 function grml_warn_skel_main() {
 246     printf '
 247 Dear user,
 248
 249 You updated grml'\''s zshrc which brings a major change.
 250 The configuration is kept only in one file, being the global zshrc.
 251 In the past, the configuration was split in two files, with the
 252 second file being the .zshrc file from /etc/skel.
 253
 254 If you have a .zshrc file in your home directory that originally
 255 came from the skel directory, please remove it. This is also the case
 256 if you followed earlier instructions from the grml-zsh-refcard or
 257 from <http://grml.org/console/> on non-grml systems.
 258
 259 Please see the current grml-zsh-refcard (available at
 260 <http://grml.org/zsh/>) for updated installation information. In short,
 261 you don'\''t want a .zshrc.global file. Install the global zshrc to
 262 ~/.zshrc and be done.
 263
 264 If you need changes to the configuration, use ~/.zshrc.pre and
 265 ~/.zshrc.local.
 266
 267 '
 268 }
 269
 270 function grml_warn_skel_remove() {
 271     printf 'To remove this warning execute '\''grml_do_not_warn_skel'\''.\n\n'
 272 }
 273
 274 function grml_do_not_warn_skel() {
 275     printf '# Do not warn about old skel dot-files anymore\n' >>! ~/.zshrc.pre
 276     printf 'GRML_WARN_SKEL=0\n' >>! ~/.zshrc.pre
 277 }
 278
 279 # let's try to guess how the user uses us.
 280 if is-at-least 4.3.7 ; then
 281     # funcsourcetrace requires at least version 4.3.7 of zsh.
 282     GRML_SRC_FILE="${${funcsourcetrace[1]}%:*}"
 283
 284     grml_warn_skel_main
 285     case ${GRML_SRC_FILE} in
 286         (${HOME}/.zshrc.global)
 287             grml_warn_skel_remove
 288             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc.global'\''.\n'
 289             printf 'Nowadays you just copy the global zshrc to '\''~/.zshrc'\'' to use\n'
 290             printf 'it on a non-grml-system.\n'
 291             ;;
 292         (${HOME}/.zshrc)
 293             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc'\''.\n'
 294             printf 'We'\''ll disable this warning automatically for later sessions.\n'
 295             grml_do_not_warn_skel
 296             ;;
 297         (*)
 298             grml_do_not_warn_skel
 299             ;;
 300     esac
 301 else
 302     grml_warn_skel_main
 303     grml_warn_skel_remove
 304 fi
 305
 306 unfunction grml_warn_skel_remove grml_warn_skel_main
 307
 308 fi # GRML_WARN_SKEL
 309
 310 # }}}
 311
 312 # utility functions {{{
 313 # this function checks if a command exists and returns either true
 314 # or false. This avoids using 'which' and 'whence', which will
 315 # avoid problems with aliases for which on certain weird systems. :-)
 316 check_com() {
 317     local -i comonly
 318
 319     if [[ ${1} == '-c' ]] ; then
 320         (( comonly = 1 ))
 321         shift
 322     else
 323         (( comonly = 0 ))
 324     fi
 325
 326     if (( ${#argv} != 1 )) ; then
 327         printf 'usage: check_com [-c] <command>\n' >&2
 328         return 1
 329     fi
 330
 331     if (( comonly > 0 )) ; then
 332         [[ -n ${commands[$1]}  ]] && return 0
 333         return 1
 334     fi
 335
 336     if   [[ -n ${commands[$1]}    ]] \
 337       || [[ -n ${functions[$1]}   ]] \
 338       || [[ -n ${aliases[$1]}     ]] \
 339       || [[ -n ${reswords[(r)$1]} ]] ; then
 340
 341         return 0
 342     fi
 343
 344     return 1
 345 }
 346
 347 # creates an alias and precedes the command with
 348 # sudo if $EUID is not zero.
 349 salias() {
 350     local only=0 ; local multi=0
 351     while [[ ${1} == -* ]] ; do
 352         case ${1} in
 353             (-o) only=1 ;;
 354             (-a) multi=1 ;;
 355             (--) shift ; break ;;
 356             (-h)
 357                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 358                 printf '  -h      shows this help text.\n'
 359                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 360                 printf '          be careful using this option.\n'
 361                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 362                 return 0
 363                 ;;
 364             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 365         esac
 366         shift
 367     done
 368
 369     if (( ${#argv} > 1 )) ; then
 370         printf 'Too many arguments %s\n' "${#argv}"
 371         return 1
 372     fi
 373
 374     key="${1%%\=*}" ;  val="${1#*\=}"
 375     if (( EUID == 0 )) && (( only == 0 )); then
 376         alias -- "${key}=${val}"
 377     elif (( EUID > 0 )) ; then
 378         (( multi > 0 )) && val="${val// ; / ; sudo }"
 379         alias -- "${key}=sudo ${val}"
 380     fi
 381
 382     return 0
 383 }
 384
 385 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 386 # usage: uprint foo
 387 #   Where foo is the *name* of the parameter you want printed.
 388 #   Note that foo is no typo; $foo would be wrong here!
 389 if ! is42 ; then
 390     uprint () {
 391         local -a u
 392         local w
 393         local parameter=${1}
 394
 395         if [[ -z ${parameter} ]] ; then
 396             printf 'usage: uprint <parameter>\n'
 397             return 1
 398         fi
 399
 400         for w in ${(P)parameter} ; do
 401             [[ -z ${(M)u:#${w}} ]] && u=( ${u} ${w} )
 402         done
 403
 404         builtin print -l ${u}
 405     }
 406 fi
 407
 408 # Check if we can read given files and source those we can.
 409 xsource() {
 410     if (( ${#argv} < 1 )) ; then
 411         printf 'usage: xsource FILE(s)...\n' >&2
 412         return 1
 413     fi
 414
 415     while (( ${#argv} > 0 )) ; do
 416         [[ -r ${1} ]] && source ${1}
 417         shift
 418     done
 419     return 0
 420 }
 421
 422 # Check if we can read a given file and 'cat(1)' it.
 423 xcat() {
 424     if (( ${#argv} != 1 )) ; then
 425         printf 'usage: xcat FILE\n' >&2
 426         return 1
 427     fi
 428
 429     [[ -r ${1} ]] && cat ${1}
 430     return 0
 431 }
 432
 433 # Remove these functions again, they are of use only in these
 434 # setup files. This should be called at the end of .zshrc.
 435 xunfunction() {
 436     local -a funcs
 437     funcs=(salias xcat xsource xunfunction zrcautoload)
 438
 439     for func in $funcs ; do
 440         [[ -n ${functions[$func]} ]] \
 441             && unfunction $func
 442     done
 443     return 0
 444 }
 445
 446 #}}}
 447
 448 # locale setup {{{
 449 if [[ -z "$LANG" ]] ; then
 450    xsource "/etc/default/locale"
 451 fi
 452
 453 export LANG=${LANG:-en_US.iso885915}
 454 for var in LC_ALL LC_MESSAGES ; do
 455     [[ -n ${(P)var} ]] && export $var
 456 done
 457
 458 xsource "/etc/sysconfig/keyboard"
 459
 460 TZ=$(xcat /etc/timezone)
 461 # }}}
 462
 463 # check for potentially old files in 'completion.d' {{{
 464 setopt extendedglob
 465 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 466 if (( ${#xof} > 0 )) ; then
 467     printf '\n -!- INFORMATION\n\n'
 468     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 469     printf ' -!- /etc/zsh/completion.d/.\n\n'
 470     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 471     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 472     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 473     printf ' -!- named _* to that directory.\n\n'
 474     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 475     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 476     printf ' -!- starting with an underscore are marked for automatic loading\n'
 477     printf ' -!- by default (so that is quite convenient).\n\n'
 478     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 479     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 480     printf ' -!- Delete the files for example via running:\n\n'
 481     printf "      rm ${xof}\n\n"
 482     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 483     printf ' -!- resolve the situation manually.\n\n'
 484     BROKEN_COMPLETION_DIR=1
 485 fi
 486 unset xof
 487 # }}}
 488
 489 # {{{ set some variables
 490 if check_com -c vim ; then
 491 #v#
 492     export EDITOR=${EDITOR:-vim}
 493 else
 494     export EDITOR=${EDITOR:-vi}
 495 fi
 496
 497 #v#
 498 export PAGER=${PAGER:-less}
 499
 500 #v#
 501 export MAIL=${MAIL:-/var/mail/$USER}
 502
 503 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 504 export SHELL='/bin/zsh'
 505
 506 # color setup for ls:
 507 check_com -c dircolors && eval $(dircolors -b)
 508 # color setup for ls on OS X:
 509 isdarwin && export CLICOLOR=1
 510
 511 # do MacPorts setup on darwin
 512 if isdarwin && [[ -d /opt/local ]]; then
 513     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 514     # zshenv.
 515     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 516     MANPATH="/opt/local/share/man:$MANPATH"
 517 fi
 518 # do Fink setup on darwin
 519 isdarwin && xsource /sw/bin/init.sh
 520
 521 # completion functions go to /etc/zsh/completion.d
 522 # function files may be put into /etc/zsh/functions.d, from where they
 523 # will be automatically autoloaded.
 524 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 525     print 'Warning: not setting completion directories because broken files have been found.' >&2
 526 else
 527     [[ -d /etc/zsh/completion.d ]] && fpath=( $fpath /etc/zsh/completion.d )
 528     if [[ -d /etc/zsh/functions.d ]] ; then
 529         fdir='/etc/zsh/functions.d'
 530         fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 531         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 532             zrcautoload ${func:t}
 533         done
 534         unset fdir
 535     fi
 536 fi
 537
 538 # automatically remove duplicates from these arrays
 539 typeset -U path cdpath fpath manpath
 540 # }}}
 541
 542 # {{{ keybindings
 543 if [[ "$TERM" != emacs ]] ; then
 544     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 545     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 546     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 547     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 548     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 549     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 550     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 551     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 552     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 553     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 554     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 555     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 556     # ncurses stuff:
 557     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 558     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 559     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 560     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 561     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 562     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 563     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 564     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 565 fi
 566
 567 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 568 # use emacs style per default:
 569 bindkey -e
 570 # use vi style:
 571 # bindkey -v
 572
 573 #if [[ "$TERM" == screen ]] ; then
 574 bindkey '\e[1~' beginning-of-line       # home
 575 bindkey '\e[4~' end-of-line             # end
 576 bindkey '\e[A'  up-line-or-search       # cursor up
 577 bindkey '\e[B'  down-line-or-search     # <ESC>-
 578
 579 bindkey '^xp'   history-beginning-search-backward
 580 bindkey '^xP'   history-beginning-search-forward
 581 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 582 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 583 # if terminal type is set to 'rxvt':
 584 bindkey '\e[7~' beginning-of-line       # home
 585 bindkey '\e[8~' end-of-line             # end
 586 #fi
 587
 588 # insert unicode character
 589 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 590 # See for example http://unicode.org/charts/ for unicode characters code
 591 zrcautoload insert-unicode-char
 592 zle -N insert-unicode-char
 593 #k# Insert Unicode character
 594 bindkey '^Xi' insert-unicode-char
 595
 596 # just type 'cd ...' to get 'cd ../..'
 597 #  rationalise-dot() {
 598 #  if [[ $LBUFFER == *.. ]] ; then
 599 #    LBUFFER+=/..
 600 #  else
 601 #    LBUFFER+=.
 602 #  fi
 603 #  }
 604 #  zle -N rationalise-dot
 605 #  bindkey . rationalise-dot
 606
 607 #  bindkey '\eq' push-line-or-edit
 608
 609 ## toggle the ,. abbreviation feature on/off
 610 # NOABBREVIATION: default abbreviation-state
 611 #                 0 - enabled (default)
 612 #                 1 - disabled
 613 NOABBREVIATION=${NOABBREVIATION:-0}
 614
 615 grml_toggle_abbrev() {
 616     if (( ${NOABBREVIATION} > 0 )) ; then
 617         NOABBREVIATION=0
 618     else
 619         NOABBREVIATION=1
 620     fi
 621 }
 622
 623 zle -N grml_toggle_abbrev
 624 bindkey '^xA' grml_toggle_abbrev
 625
 626 # }}}
 627
 628 # a generic accept-line wrapper {{{
 629
 630 # This widget can prevent unwanted autocorrections from command-name
 631 # to _command-name, rehash automatically on enter and call any number
 632 # of builtin and user-defined widgets in different contexts.
 633 #
 634 # For a broader description, see:
 635 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 636 #
 637 # The code is imported from the file 'zsh/functions/accept-line' from
 638 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 639 # distributed under the same terms as zsh itself.
 640
 641 # A newly added command will may not be found or will cause false
 642 # correction attempts, if you got auto-correction set. By setting the
 643 # following style, we force accept-line() to rehash, if it cannot
 644 # find the first word on the command line in the $command[] hash.
 645 zstyle ':acceptline:*' rehash true
 646
 647 function Accept-Line() {
 648     setopt localoptions noksharrays
 649     local -a subs
 650     local -xi aldone
 651     local sub
 652
 653     zstyle -a ":acceptline:${alcontext}" actions subs
 654
 655     (( ${#subs} < 1 )) && return 0
 656
 657     (( aldone = 0 ))
 658     for sub in ${subs} ; do
 659         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 660         zle ${sub}
 661
 662         (( aldone > 0 )) && break
 663     done
 664 }
 665
 666 function Accept-Line-getdefault() {
 667     local default_action
 668
 669     zstyle -s ":acceptline:${alcontext}" default_action default_action
 670     case ${default_action} in
 671         ((accept-line|))
 672             printf ".accept-line"
 673             ;;
 674         (*)
 675             printf ${default_action}
 676             ;;
 677     esac
 678 }
 679
 680 function accept-line() {
 681     setopt localoptions noksharrays
 682     local -a cmdline
 683     local -x alcontext
 684     local buf com fname format msg default_action
 685
 686     alcontext='default'
 687     buf="${BUFFER}"
 688     cmdline=(${(z)BUFFER})
 689     com="${cmdline[1]}"
 690     fname="_${com}"
 691
 692     zstyle -t ":acceptline:${alcontext}" rehash \
 693         && [[ -z ${commands[$com]} ]]           \
 694         && rehash
 695
 696     if    [[ -n ${reswords[(r)$com]} ]] \
 697        || [[ -n ${aliases[$com]}     ]] \
 698        || [[ -n ${functions[$com]}   ]] \
 699        || [[ -n ${builtins[$com]}    ]] \
 700        || [[ -n ${commands[$com]}    ]] ; then
 701
 702         # there is something sensible to execute, just do it.
 703         alcontext='normal'
 704         zle Accept-Line
 705
 706         default_action=$(Accept-Line-getdefault)
 707         zstyle -T ":acceptline:${alcontext}" call_default \
 708             && zle ${default_action}
 709         return
 710     fi
 711
 712     if    [[ -o correct              ]] \
 713        || [[ -o correctall           ]] \
 714        && [[ -n ${functions[$fname]} ]] ; then
 715
 716         # nothing there to execute but there is a function called
 717         # _command_name; a completion widget. Makes no sense to
 718         # call it on the commandline, but the correct{,all} options
 719         # will ask for it nevertheless, so warn the user.
 720         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 721             # Okay, we warned the user before, he called us again,
 722             # so have it his way.
 723             alcontext='force'
 724             zle Accept-Line
 725
 726             default_action=$(Accept-Line-getdefault)
 727             zstyle -T ":acceptline:${alcontext}" call_default \
 728                 && zle ${default_action}
 729             return
 730         fi
 731
 732         # prepare warning message for the user, configurable via zstyle.
 733         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 734
 735         if [[ -z ${msg} ]] ; then
 736             msg="%c will not execute and completion %f exists."
 737         fi
 738
 739         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 740
 741         zle -M -- "${msg}"
 742         return
 743     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 744         # If we are here, the commandline contains something that is not
 745         # executable, which is neither subject to _command_name correction
 746         # and is not empty. might be a variable assignment
 747         alcontext='misc'
 748         zle Accept-Line
 749
 750         default_action=$(Accept-Line-getdefault)
 751         zstyle -T ":acceptline:${alcontext}" call_default \
 752             && zle ${default_action}
 753         return
 754     fi
 755
 756     # If we got this far, the commandline only contains whitespace, or is empty.
 757     alcontext='empty'
 758     zle Accept-Line
 759
 760     default_action=$(Accept-Line-getdefault)
 761     zstyle -T ":acceptline:${alcontext}" call_default \
 762         && zle ${default_action}
 763 }
 764
 765 zle -N accept-line
 766 zle -N Accept-Line
 767
 768 # }}}
 769
 770 # power completion - abbreviation expansion {{{
 771 # power completion / abbreviation expansion / buffer expansion
 772 # see http://zshwiki.org/home/examples/zleiab for details
 773 # less risky than the global aliases but powerful as well
 774 # just type the abbreviation key and afterwards ',.' to expand it
 775 declare -A abk
 776 setopt extendedglob
 777 setopt interactivecomments
 778 abk=(
 779 # key  # value                (#d additional doc string)
 780 #A# start
 781     '...' '../..'
 782     '....' '../../..'
 783     'BG' '& exit'
 784     'C' '| wc -l'
 785     'G' '|& grep --color=auto'
 786     'H' '| head'
 787     'Hl' ' --help |& less -r'      #d (Display help in pager)
 788     'L' '| less'
 789     'LL' '|& less -r'
 790     'M' '| most'
 791     'N' '&>/dev/null'              #d (No Output)
 792     'R' '| tr A-z N-za-m'          #d (ROT13)
 793     'SL' '| sort | less'
 794     'S' '| sort -u'
 795     'T' '| tail'
 796     'V' '|& vim -'
 797 #A# end
 798     'co' "./configure && make && sudo make install"
 799 )
 800
 801 globalias() {
 802     local MATCH
 803
 804     if (( NOABBREVIATION > 0 )) ; then
 805         LBUFFER="${LBUFFER},."
 806         return 0
 807     fi
 808
 809     matched_chars='[.-|_a-zA-Z0-9]#'
 810     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 811     LBUFFER+=${abk[$MATCH]:-$MATCH}
 812 }
 813
 814 zle -N globalias
 815 bindkey ",." globalias
 816 # }}}
 817
 818 # {{{ autoloading
 819 zrcautoload zmv    # who needs mmv or rename?
 820 zrcautoload history-search-end
 821
 822 # we don't want to quote/espace URLs on our own...
 823 # if autoload -U url-quote-magic ; then
 824 #    zle -N self-insert url-quote-magic
 825 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 826 # else
 827 #    print 'Notice: no url-quote-magic available :('
 828 # fi
 829 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 830
 831 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 832 alias run-help >&/dev/null && unalias run-help
 833 zrcautoload run-help # use via 'esc-h'
 834
 835 # completion system
 836 if zrcautoload compinit && compinit 2>/dev/null ; then
 837     compinit 2>/dev/null || print 'Notice: no compinit available :('
 838 else
 839     print 'Notice: no compinit available :('
 840     function zstyle { }
 841     function compdef { }
 842 fi
 843
 844 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 845
 846 is4 && \
 847 for mod in complist deltochar mathfunc ; do
 848     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 849 done
 850
 851 # autoload zsh modules when they are referenced
 852 if is4 ; then
 853     tmpargs=(
 854         a   stat
 855         a   zpty
 856         ap  mapfile
 857     )
 858
 859     while (( ${#tmpargs} > 0 )) ; do
 860         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 861         shift 2 tmpargs
 862     done
 863     unset tmpargs
 864 fi
 865
 866 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 867     #k# Insert files
 868     bindkey "^Xf" insert-files # C-x-f
 869 fi
 870
 871 bindkey ' '   magic-space    # also do history expansion on space
 872 #k# Trigger menu-complete
 873 bindkey '\ei' menu-complete  # menu completion via esc-i
 874
 875 # press esc-e for editing command line in $EDITOR or $VISUAL
 876 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 877     #k# Edit the current line in \kbd{\$EDITOR}
 878     bindkey '\ee' edit-command-line
 879 fi
 880
 881 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 882     #k# menu selection: pick item but stay in the menu
 883     bindkey -M menuselect '\e^M' accept-and-menu-complete
 884
 885     # accept a completion and try to complete again by using menu
 886     # completion; very useful with completing directories
 887     # by using 'undo' one's got a simple file browser
 888     bindkey -M menuselect '^o' accept-and-infer-next-history
 889 fi
 890
 891 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 892 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 893 zle -N _bkdate
 894
 895 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 896 bindkey '^Ed' _bkdate
 897
 898 # press esc-m for inserting last typed word again (thanks to caphuso!)
 899 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 900 zle -N insert-last-typed-word;
 901
 902 #k# Insert last typed word
 903 bindkey "\em" insert-last-typed-word
 904
 905 #k# Shortcut for \kbd{fg<enter>}
 906 bindkey -s '^z' "fg\n"
 907
 908 # run command line as user root via sudo:
 909 sudo-command-line() {
 910     [[ -z $BUFFER ]] && zle up-history
 911     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 912 }
 913 zle -N sudo-command-line
 914
 915 #k# Put the current command line into a \kbd{sudo} call
 916 bindkey "^Os" sudo-command-line
 917
 918 ### jump behind the first word on the cmdline.
 919 ### useful to add options.
 920 function jump_after_first_word() {
 921     local words
 922     words=(${(z)BUFFER})
 923
 924     if (( ${#words} <= 1 )) ; then
 925         CURSOR=${#BUFFER}
 926     else
 927         CURSOR=${#${words[1]}}
 928     fi
 929 }
 930 zle -N jump_after_first_word
 931
 932 bindkey '^x1' jump_after_first_word
 933
 934 # }}}
 935
 936 # {{{ set some important options
 937 # Please update these tags, if you change the umask settings below.
 938 #o# r_umask     002
 939 #o# r_umaskstr  rwxrwxr-x
 940 #o# umask       022
 941 #o# umaskstr    rwxr-xr-x
 942 (( EUID != 0 )) && umask 002 || umask 022
 943
 944 # history:
 945 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 946 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 947 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 948 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 949                             # list duplicates an older one, the older command is removed from the list
 950 setopt histignorespace      # remove command lines from the history list when
 951                             # the first character on the line is a space
 952 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 953                             # and the command is the name of a directory, perform the cd command to that directory
 954 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 955                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 956                             # -> searches for word not in compressed files
 957                             # don't forget to quote '^', '~' and '#'!
 958 setopt longlistjobs         # display PID when suspending processes as well
 959 setopt notify               # report the status of backgrounds jobs immediately
 960 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 961                             # the entire command path is hashed first.
 962 setopt completeinword       # not just at the end
 963 setopt nohup                # and don't kill them, either
 964 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 965 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 966 setopt nobeep               # avoid "beep"ing
 967 setopt pushd_ignore_dups    # don't push the same dir twice.
 968
 969 MAILCHECK=30       # mailchecks
 970 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 971 watch=(notme root) # watch for everyone but me and root
 972
 973 # only slash should be considered as a word separator:
 974 slash-backward-kill-word() {
 975     local WORDCHARS="${WORDCHARS:s@/@}"
 976     # zle backward-word
 977     zle backward-kill-word
 978 }
 979 zle -N slash-backward-kill-word
 980
 981 #k# Kill everything in a word up to its last \kbd{/}
 982 bindkey '\ev' slash-backward-kill-word
 983
 984 # }}}
 985
 986 # {{{ history
 987
 988 ZSHDIR=$HOME/.zsh
 989
 990 #v#
 991 HISTFILE=$HOME/.zsh_history
 992 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
 993 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
 994
 995 # }}}
 996
 997 # dirstack handling {{{
 998
 999 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1000 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1001
1002 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1003     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1004     # "cd -" won't work after login by just setting $OLDPWD, so
1005     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
1006 fi
1007
1008 chpwd() {
1009     if is42 ; then
1010         builtin print -l ${(u)dirstack} >! ${DIRSTACKFILE}
1011     else
1012         uprint dirstack >! ${DIRSTACKFILE}
1013     fi
1014 }
1015
1016 # }}}
1017
1018 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1019 if [[ $BATTERY -gt 0 ]] ; then
1020     if ! check_com -c acpi ; then
1021         BATTERY=0
1022     fi
1023 fi
1024
1025 battery() {
1026 if [[ $BATTERY -gt 0 ]] ; then
1027     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]##Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1028     if [[ -z "$PERCENT" ]] ; then
1029         PERCENT='acpi not present'
1030     else
1031         if [[ "$PERCENT" -lt 20 ]] ; then
1032             PERCENT="warning: ${PERCENT}%%"
1033         else
1034             PERCENT="${PERCENT}%%"
1035         fi
1036     fi
1037 fi
1038 }
1039 # }}}
1040
1041 # set colors for use in prompts {{{
1042 if zrcautoload colors && colors 2>/dev/null ; then
1043     BLUE="%{${fg[blue]}%}"
1044     RED="%{${fg_bold[red]}%}"
1045     GREEN="%{${fg[green]}%}"
1046     CYAN="%{${fg[cyan]}%}"
1047     MAGENTA="%{${fg[magenta]}%}"
1048     YELLOW="%{${fg[yellow]}%}"
1049     WHITE="%{${fg[white]}%}"
1050     NO_COLOUR="%{${reset_color}%}"
1051 else
1052     BLUE=$'%{\e[1;34m%}'
1053     RED=$'%{\e[1;31m%}'
1054     GREEN=$'%{\e[1;32m%}'
1055     CYAN=$'%{\e[1;36m%}'
1056     WHITE=$'%{\e[1;37m%}'
1057     MAGENTA=$'%{\e[1;35m%}'
1058     YELLOW=$'%{\e[1;33m%}'
1059     NO_COLOUR=$'%{\e[0m%}'
1060 fi
1061
1062 # }}}
1063
1064 # gather version control information for inclusion in a prompt {{{
1065
1066 if ! is41 ; then
1067     # Be quiet about version problems in grml's zshrc as the user cannot disable
1068     # loading vcs_info() as it is *in* the zshrc - as you can see. :-)
1069     # Just unset most probable variables and disable vcs_info altogether.
1070     local -i i
1071     for i in {0..9} ; do
1072         unset VCS_INFO_message_${i}_
1073     done
1074     zstyle ':vcs_info:*' enable false
1075 fi
1076
1077 # The following code is imported from the file 'zsh/functions/vcs_info'
1078 # from <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>,
1079 # which distributed under the same terms as zsh itself.
1080
1081 # we will be using two variables, so let the code know now.
1082 zstyle ':vcs_info:*' max-exports 2
1083
1084 # vcs_info() documentation:
1085 #{{{
1086 # REQUIREMENTS:
1087 #{{{
1088 #     This functionality requires zsh version >= 4.1.*.
1089 #}}}
1090 #
1091 # LOADING:
1092 #{{{
1093 # To load vcs_info(), copy this file to your $fpath[] and do:
1094 #   % autoload -Uz vcs_info && vcs_info
1095 #
1096 # To work, vcs_info() needs 'setopt prompt_subst' in your setup.
1097 #}}}
1098 #
1099 # QUICKSTART:
1100 #{{{
1101 # To get vcs_info() working quickly (including colors), you can do the
1102 # following (assuming, you loaded vcs_info() properly - see above):
1103 #
1104 # % RED=$'%{\e[31m%}'
1105 # % GR=$'%{\e[32m%}'
1106 # % MA=$'%{\e[35m%}'
1107 # % YE=$'%{\e[33m%}'
1108 # % NC=$'%{\e[0m%}'
1109 #
1110 # % zstyle ':vcs_info:*' actionformats \
1111 #       "${MA}(${NC}%s${MA})${YE}-${MA}[${GR}%b${YE}|${RED}%a${MA}]${NC} "
1112 #
1113 # % zstyle ':vcs_info:*' formats       \
1114 #       "${MA}(${NC}%s${MA})${Y}-${MA}[${GR}%b${MA}]${NC}%} "
1115 #
1116 # % zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YE}%r"
1117 #
1118 # % precmd () { vcs_info }
1119 # % PS1='${MA}[${GR}%n${MA}] ${MA}(${RED}%!${MA}) ${YE}%3~ ${VCS_INFO_message_0_}${NC}%# '
1120 #
1121 # Obviously, the las two lines are there for demonstration: You need to
1122 # call vcs_info() from your precmd() function (see 'SPECIAL FUNCTIONS' in
1123 # 'man zshmisc'). Once that is done you need a *single* quoted
1124 # '${VCS_INFO_message_0_}' in your prompt.
1125 #
1126 # Now call the 'vcs_info_printsys' utility from the command line:
1127 #
1128 # % vcs_info_printsys
1129 # # list of supported version control backends:
1130 # # disabled systems are prefixed by a hash sign (#)
1131 # git
1132 # hg
1133 # bzr
1134 # darcs
1135 # svk
1136 # mtn
1137 # svn
1138 # cvs
1139 # cdv
1140 # tla
1141 # # flavours (cannot be used in the disable style; they
1142 # # are disabled with their master [git-svn -> git]):
1143 # git-p4
1144 # git-svn
1145 #
1146 # Ten version control backends as you can see. You may not want all
1147 # of these. Because there is no point in running the code to detect
1148 # systems you do not use. ever. So, there is a way to disable some
1149 # backends altogether:
1150 #
1151 # % zstyle ':vcs_info:*' disable bzr cdv darcs mtn svk tla
1152 #
1153 # If you rerun 'vcs_info_printsys' now, you will see the backends listed
1154 # in the 'disable' style marked as diabled by a hash sign. That means the
1155 # detection of these systems is skipped *completely*. No wasted time there.
1156 #
1157 # For more control, read the reference below.
1158 #}}}
1159 #
1160 # CONFIGURATION:
1161 #{{{
1162 # The vcs_info() feature can be configured via zstyle.
1163 #
1164 # First, the context in which we are working:
1165 #       :vcs_info:<vcs-string>:<user-context>
1166 #
1167 # ...where <vcs-string> is one of:
1168 #   - git, git-svn, git-p4, hg, darcs, bzr, cdv, mtn, svn, cvs, svk or tla.
1169 #
1170 # ...and <user-context> is a freely configurable string, assignable by the
1171 # user as the first argument to vcs_info() (see its description below).
1172 #
1173 # There is are three special values for <vcs-string>: The first is named
1174 # 'init', that is in effect as long as there was no decision what vcs
1175 # backend to use. The second is 'preinit; it is used *before* vcs_info()
1176 # is run, when initializing the data exporting variables. The third
1177 # special value is 'formats' and is used by the 'vcs_info_lastmsg' for
1178 # looking up its styles.
1179 #
1180 # There are two pre-defined values for <user-context>:
1181 #   default  - the one used if none is specified
1182 #   command  - used by vcs_info_lastmsg to lookup its styles.
1183 #
1184 # You may *not* use 'print_systems_' as a user-context string, because it
1185 # is used internally.
1186 #
1187 # You can of course use ':vcs_info:*' to match all VCSs in all
1188 # user-contexts at once.
1189 #
1190 # Another special context is 'formats', which is used by the
1191 # vcs_info_lastmsg() utility function (see below).
1192 #
1193 #
1194 # This is a description of all styles, that are looked up:
1195 #   formats             - A list of formats, used when actionformats is not
1196 #                         used (which is most of the time).
1197 #   actionformats       - A list of formats, used if a there is a special
1198 #                         action going on in your current repository;
1199 #                         (like an interactive rebase or a merge conflict)
1200 #   branchformat        - Some backends replace %b in the formats and
1201 #                         actionformats styles above, not only by a branch
1202 #                         name but also by a revision number. This style
1203 #                         let's you modify how that string should look like.
1204 #   nvcsformats         - These "formats" are exported, when we didn't detect
1205 #                         a version control system for the current directory.
1206 #                         This is useful, if you want vcs_info() to completely
1207 #                         take over the generation of your prompt.
1208 #                         You would do something like
1209 #                           PS1='${VCS_INFO_message_0_}'
1210 #                         to accomplish that.
1211 #   max-exports         - Defines the maximum number if VCS_INFO_message_*_
1212 #                         variables vcs_info() will export.
1213 #   enable              - Checked in the 'init' context. If set to false,
1214 #                         vcs_info() will do nothing.
1215 #   disable             - Provide a list of systems, you don't want
1216 #                         the vcs_info() to check for repositories
1217 #                         (checked in the 'init' context, too).
1218 #   disable-patterns    - A list of patterns that are checked against $PWD.
1219 #                         If the pattern matches, vcs_info will be disabled.
1220 #                         Say, ~/.zsh is a directory under version control,
1221 #                         in which you do not want vcs_info to be active, do:
1222 #                         zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh+(|/*)"
1223 #   use-simple          - If there are two different ways of gathering
1224 #                         information, you can select the simpler one
1225 #                         by setting this style to true; the default
1226 #                         is to use the not-that-simple code, which is
1227 #                         potentially a lot slower but might be more
1228 #                         accurate in all possible cases.
1229 #   use-prompt-escapes  - determines if we assume that the assembled
1230 #                         string from vcs_info() includes prompt escapes.
1231 #                         (Used by vcs_info_lastmsg().
1232 #
1233 # The use-simple style is only available for the bzr backend.
1234 #
1235 # The default values for these in all contexts are:
1236 #   formats             " (%s)-[%b|%a]-"
1237 #   actionformats       " (%s)-[%b]-"
1238 #   branchformat        "%b:%r" (for bzr, svn and svk)
1239 #   nvcsformats         ""
1240 #   max-exports         2
1241 #   enable              true
1242 #   disable             (empty list)
1243 #   disable-patterns    (empty list)
1244 #   use-simple          false
1245 #   use-prompt-escapes  true
1246 #
1247 #
1248 # In normal formats and actionformats, the following replacements
1249 # are done:
1250 #   %s  - The vcs in use (git, hg, svn etc.)
1251 #   %b  - Information about the current branch.
1252 #   %a  - An identifier, that describes the action.
1253 #         Only makes sense in actionformats.
1254 #   %R  - base directory of the repository.
1255 #   %r  - repository name
1256 #         If %R is '/foo/bar/repoXY', %r is 'repoXY'.
1257 #   %S  - subdirectory within a repository. if $PWD is
1258 #         '/foo/bar/reposXY/beer/tasty', %S is 'beer/tasty'.
1259 #
1260 #
1261 # In branchformat these replacements are done:
1262 #   %b  - the branch name
1263 #   %r  - the current revision number
1264 #
1265 # Not all vcs backends have to support all replacements.
1266 # nvcsformat does not perform *any* replacements. It is just a string.
1267 #}}}
1268 #
1269 # ODDITIES:
1270 #{{{
1271 # If you want to use the %b (bold off) prompt expansion in 'formats', which
1272 # expands %b itself, use %%b. That will cause the vcs_info() expansion to
1273 # replace %%b with %b. So zsh's prompt expansion mechanism can handle it.
1274 # Similarly, to hand down %b from branchformat, use %%%%b. Sorry for this
1275 # inconvenience, but it cannot be easily avoided. Luckily we do not clash
1276 # with a lot of prompt expansions and this only needs to be done for those.
1277 # See 'man zshmisc' for details about EXPANSION OF PROMPT SEQUENCES.
1278 #}}}
1279 #
1280 # FUNCTION DESCRIPTIONS (public API):
1281 #{{{
1282 #   vcs_info()
1283 #       The main function, that runs all backends and assembles
1284 #       all data into ${VCS_INFO_message_*_}. This is the function
1285 #       you want to call from precmd() if you want to include
1286 #       up-to-date information in your prompt (see VARIABLE
1287 #       DESCRIPTION below).
1288 #
1289 #   vcs_info_printsys()
1290 #       Prints a list of all supported version control systems.
1291 #       Useful to find out possible contexts (and which of them are enabled)
1292 #       or values for the 'disable' style.
1293 #
1294 #   vcs_info_lastmsg()
1295 #       Outputs the last ${VCS_INFO_message_*_} value. Takes into account
1296 #       the value of the use-prompt-escapes style in ':vcs_info:formats'.
1297 #       It also only prints max-exports values.
1298 #
1299 # All functions named VCS_INFO_* are for internal use only.
1300 #}}}
1301 #
1302 # VARIABLE DESCRIPTION:
1303 #{{{
1304 #   ${VCS_INFO_message_N_}    (Note the trailing underscore)
1305 #       Where 'N' is an integer, eg: VCS_INFO_message_0_
1306 #       These variables are the storage for the informational message the
1307 #       last vcs_info() call has assembled. These are strongly connected
1308 #       to the formats, actionformats and nvcsformats styles described
1309 #       above. Those styles are lists. the first member of that list gets
1310 #       expanded into ${VCS_INFO_message_0_}, the second into
1311 #       ${VCS_INFO_message_1_} and the Nth into ${VCS_INFO_message_N-1_}.
1312 #       These parameters are exported into the environment.
1313 #       (See the max-exports style above.)
1314 #}}}
1315 #
1316 # EXAMPLES:
1317 #{{{
1318 #   Don't use vcs_info at all (even though it's in your prompt):
1319 #   % zstyle ':vcs_info:*' enable false
1320 #
1321 #   Disable the backends for bzr and svk:
1322 #   % zstyle ':vcs_info:*' disable bzr svk
1323 #
1324 #   Provide a special formats for git:
1325 #   % zstyle ':vcs_info:git:*' formats       ' GIT, BABY! [%b]'
1326 #   % zstyle ':vcs_info:git:*' actionformats ' GIT ACTION! [%b|%a]'
1327 #
1328 #   Use the quicker bzr backend (if you do, please report if it does
1329 #   the-right-thing[tm] - thanks):
1330 #   % zstyle ':vcs_info:bzr:*' use-simple true
1331 #
1332 #   Display the revision number in yellow for bzr and svn:
1333 #   % zstyle ':vcs_info:(svn|bzr):*' branchformat '%b%{'${fg[yellow]}'%}:%r'
1334 #
1335 # If you want colors, make sure you enclose the color codes in %{...%},
1336 # if you want to use the string provided by vcs_info() in prompts.
1337 #
1338 # Here is how to print the vcs infomation as a command:
1339 #   % alias vcsi='vcs_info command; vcs_info_lastmsg'
1340 #
1341 #   This way, you can even define different formats for output via
1342 #   vcs_info_lastmsg() in the ':vcs_info:command:*' namespace.
1343 #}}}
1344 #}}}
1345 # utilities
1346 VCS_INFO_adjust () { #{{{
1347     [[ -n ${vcs_comm[overwrite_name]} ]] && vcs=${vcs_comm[overwrite_name]}
1348     return 0
1349 }
1350 # }}}
1351 VCS_INFO_check_com () { #{{{
1352     (( ${+commands[$1]} )) && [[ -x ${commands[$1]} ]] && return 0
1353     return 1
1354 }
1355 # }}}
1356 VCS_INFO_formats () { # {{{
1357     setopt localoptions noksharrays
1358     local action=$1 branch=$2 base=$3
1359     local msg
1360     local -i i
1361
1362     if [[ -n ${action} ]] ; then
1363         zstyle -a ":vcs_info:${vcs}:${usercontext}" actionformats msgs
1364         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b|%a]-'
1365     else
1366         zstyle -a ":vcs_info:${vcs}:${usercontext}" formats msgs
1367         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b]-'
1368     fi
1369
1370     (( ${#msgs} > maxexports )) && msgs[$(( maxexports + 1 )),-1]=()
1371     for i in {1..${#msgs}} ; do
1372         zformat -f msg ${msgs[$i]}                      \
1373                         a:${action}                     \
1374                         b:${branch}                     \
1375                         r:${base:t}                     \
1376                         s:${vcs}                        \
1377                         R:${base}                       \
1378                         S:"$(VCS_INFO_reposub ${base})"
1379         msgs[$i]=${msg}
1380     done
1381     return 0
1382 }
1383 # }}}
1384 VCS_INFO_maxexports () { #{{{
1385     zstyle -s ":vcs_info:${vcs}:${usercontext}" "max-exports" maxexports || maxexports=2
1386     if [[ ${maxexports} != <-> ]] || (( maxexports < 1 )); then
1387         printf 'vcs_info(): expecting numeric arg >= 1 for max-exports (got %s).\n' ${maxexports}
1388         printf 'Defaulting to 2.\n'
1389         maxexports=2
1390     fi
1391 }
1392 # }}}
1393 VCS_INFO_nvcsformats () { #{{{
1394     setopt localoptions noksharrays
1395     local c v
1396
1397     if [[ $1 == 'preinit' ]] ; then
1398         c=default
1399         v=preinit
1400     fi
1401     zstyle -a ":vcs_info:${v:-$vcs}:${c:-$usercontext}" nvcsformats msgs
1402     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1403 }
1404 # }}}
1405 VCS_INFO_realpath () { #{{{
1406     # a portable 'readlink -f'
1407     # forcing a subshell, to ensure chpwd() is not removed
1408     # from the calling shell (if VCS_INFO_realpath() is called
1409     # manually).
1410     (
1411         (( ${+functions[chpwd]} )) && unfunction chpwd
1412         setopt chaselinks
1413         cd $1 2>/dev/null && pwd
1414     )
1415 }
1416 # }}}
1417 VCS_INFO_reposub () { #{{{
1418     setopt localoptions extendedglob
1419     local base=${1%%/##}
1420
1421     [[ ${PWD} == ${base}/* ]] || {
1422         printf '.'
1423         return 1
1424     }
1425     printf '%s' ${PWD#$base/}
1426     return 0
1427 }
1428 # }}}
1429 VCS_INFO_set () { #{{{
1430     setopt localoptions noksharrays
1431     local -i i j
1432
1433     if [[ $1 == '--clear' ]] ; then
1434         for i in {0..9} ; do
1435             unset VCS_INFO_message_${i}_
1436         done
1437     fi
1438     if [[ $1 == '--nvcs' ]] ; then
1439         [[ $2 == 'preinit' ]] && (( maxexports == 0 )) && (( maxexports = 1 ))
1440         for i in {0..$((maxexports - 1))} ; do
1441             typeset -gx VCS_INFO_message_${i}_=
1442         done
1443         VCS_INFO_nvcsformats $2
1444     fi
1445
1446     (( ${#msgs} - 1 < 0 )) && return 0
1447     for i in {0..$(( ${#msgs} - 1 ))} ; do
1448         (( j = i + 1 ))
1449         typeset -gx VCS_INFO_message_${i}_=${msgs[$j]}
1450     done
1451     return 0
1452 }
1453 # }}}
1454 # information gathering
1455 VCS_INFO_bzr_get_data () { # {{{
1456     setopt localoptions noksharrays
1457     local bzrbase bzrbr
1458     local -a bzrinfo
1459
1460     if zstyle -t ":vcs_info:${vcs}:${usercontext}" "use-simple" ; then
1461         bzrbase=${vcs_comm[basedir]}
1462         bzrinfo[2]=${bzrbase:t}
1463         if [[ -f ${bzrbase}/.bzr/branch/last-revision ]] ; then
1464             bzrinfo[1]=$(< ${bzrbase}/.bzr/branch/last-revision)
1465             bzrinfo[1]=${${bzrinfo[1]}%% *}
1466         fi
1467     else
1468         bzrbase=${${(M)${(f)"$( bzr info )"}:# ##branch\ root:*}/*: ##/}
1469         bzrinfo=( ${${${(M)${(f)"$( bzr version-info )"}:#(#s)(revno|branch-nick)*}/*: /}/*\//} )
1470         bzrbase="$(VCS_INFO_realpath ${bzrbase})"
1471     fi
1472
1473     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat bzrbr || bzrbr="%b:%r"
1474     zformat -f bzrbr "${bzrbr}" "b:${bzrinfo[2]}" "r:${bzrinfo[1]}"
1475     VCS_INFO_formats '' "${bzrbr}" "${bzrbase}"
1476     return 0
1477 }
1478 # }}}
1479 VCS_INFO_cdv_get_data () { # {{{
1480     local cdvbase
1481
1482     cdvbase=${vcs_comm[basedir]}
1483     VCS_INFO_formats '' "${cdvbase:t}" "${cdvbase}"
1484     return 0
1485 }
1486 # }}}
1487 VCS_INFO_cvs_get_data () { # {{{
1488     local cvsbranch cvsbase basename
1489
1490     cvsbase="."
1491     while [[ -d "${cvsbase}/../CVS" ]]; do
1492         cvsbase="${cvsbase}/.."
1493     done
1494     cvsbase="$(VCS_INFO_realpath ${cvsbase})"
1495     cvsbranch=$(< ./CVS/Repository)
1496     basename=${cvsbase:t}
1497     cvsbranch=${cvsbranch##${basename}/}
1498     [[ -z ${cvsbranch} ]] && cvsbranch=${basename}
1499     VCS_INFO_formats '' "${cvsbranch}" "${cvsbase}"
1500     return 0
1501 }
1502 # }}}
1503 VCS_INFO_darcs_get_data () { # {{{
1504     local darcsbase
1505
1506     darcsbase=${vcs_comm[basedir]}
1507     VCS_INFO_formats '' "${darcsbase:t}" "${darcsbase}"
1508     return 0
1509 }
1510 # }}}
1511 VCS_INFO_git_getaction () { #{{{
1512     local gitaction='' gitdir=$1
1513     local tmp
1514
1515     for tmp in "${gitdir}/rebase-apply" \
1516                "${gitdir}/rebase"       \
1517                "${gitdir}/../.dotest" ; do
1518         if [[ -d ${tmp} ]] ; then
1519             if   [[ -f "${tmp}/rebasing" ]] ; then
1520                 gitaction="rebase"
1521             elif [[ -f "${tmp}/applying" ]] ; then
1522                 gitaction="am"
1523             else
1524                 gitaction="am/rebase"
1525             fi
1526             printf '%s' ${gitaction}
1527             return 0
1528         fi
1529     done
1530
1531     for tmp in "${gitdir}/rebase-merge/interactive" \
1532                "${gitdir}/.dotest-merge/interactive" ; do
1533         if [[ -f "${tmp}" ]] ; then
1534             printf '%s' "rebase-i"
1535             return 0
1536         fi
1537     done
1538
1539     for tmp in "${gitdir}/rebase-merge" \
1540                "${gitdir}/.dotest-merge" ; do
1541         if [[ -d "${tmp}" ]] ; then
1542             printf '%s' "rebase-m"
1543             return 0
1544         fi
1545     done
1546
1547     if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1548         printf '%s' "merge"
1549         return 0
1550     fi
1551
1552     if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
1553         printf '%s' "bisect"
1554         return 0
1555     fi
1556     return 1
1557 }
1558 # }}}
1559 VCS_INFO_git_getbranch () { #{{{
1560     local gitbranch gitdir=$1
1561     local gitsymref='git symbolic-ref HEAD'
1562
1563     if    [[ -d "${gitdir}/rebase-apply" ]] \
1564        || [[ -d "${gitdir}/rebase" ]]       \
1565        || [[ -d "${gitdir}/../.dotest" ]]   \
1566        || [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1567         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1568         [[ -z ${gitbranch} ]] && [[ -r ${gitdir}/rebase-apply/head-name ]] \
1569             && gitbranch="$(< ${gitdir}/rebase-apply/head-name)"
1570
1571     elif   [[ -f "${gitdir}/rebase-merge/interactive" ]] \
1572         || [[ -d "${gitdir}/rebase-merge" ]] ; then
1573         gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
1574
1575     elif   [[ -f "${gitdir}/.dotest-merge/interactive" ]] \
1576         || [[ -d "${gitdir}/.dotest-merge" ]] ; then
1577         gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
1578
1579     else
1580         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1581
1582         if [[ $? -ne 0 ]] ; then
1583             gitbranch="$(git describe --exact-match HEAD 2>/dev/null)"
1584
1585             if [[ $? -ne 0 ]] ; then
1586                 gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
1587             fi
1588         fi
1589     fi
1590
1591     printf '%s' "${gitbranch##refs/heads/}"
1592     return 0
1593 }
1594 # }}}
1595 VCS_INFO_git_get_data () { # {{{
1596     setopt localoptions extendedglob
1597     local gitdir gitbase gitbranch gitaction
1598
1599     gitdir=${vcs_comm[gitdir]}
1600     gitbranch="$(VCS_INFO_git_getbranch ${gitdir})"
1601
1602     if [[ -z ${gitdir} ]] || [[ -z ${gitbranch} ]] ; then
1603         return 1
1604     fi
1605
1606     VCS_INFO_adjust
1607     gitaction="$(VCS_INFO_git_getaction ${gitdir})"
1608     gitbase=${PWD%/${$( git rev-parse --show-prefix )%/##}}
1609     VCS_INFO_formats "${gitaction}" "${gitbranch}" "${gitbase}"
1610     return 0
1611 }
1612 # }}}
1613 VCS_INFO_hg_get_data () { # {{{
1614     local hgbranch hgbase
1615
1616     hgbase=${vcs_comm[basedir]}
1617     hgbranch=$(< ${hgbase}/.hg/branch)
1618     VCS_INFO_formats '' "${hgbranch}" "${hgbase}"
1619     return 0
1620 }
1621 # }}}
1622 VCS_INFO_mtn_get_data () { # {{{
1623     local mtnbranch mtnbase
1624
1625     mtnbase=${vcs_comm[basedir]}
1626     mtnbranch=${${(M)${(f)"$( mtn status )"}:#(#s)Current branch:*}/*: /}
1627     VCS_INFO_formats '' "${mtnbranch}" "${mtnbase}"
1628     return 0
1629 }
1630 # }}}
1631 VCS_INFO_svk_get_data () { # {{{
1632     local svkbranch svkbase
1633
1634     svkbase=${vcs_comm[basedir]}
1635     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svkbranch || svkbranch="%b:%r"
1636     zformat -f svkbranch "${svkbranch}" "b:${vcs_comm[branch]}" "r:${vcs_comm[revision]}"
1637     VCS_INFO_formats '' "${svkbranch}" "${svkbase}"
1638     return 0
1639 }
1640 # }}}
1641 VCS_INFO_svn_get_data () { # {{{
1642     setopt localoptions noksharrays
1643     local svnbase svnbranch
1644     local -a svninfo
1645
1646     svnbase="."
1647     while [[ -d "${svnbase}/../.svn" ]]; do
1648         svnbase="${svnbase}/.."
1649     done
1650     svnbase="$(VCS_INFO_realpath ${svnbase})"
1651     svninfo=( ${${${(M)${(f)"$( svn info )"}:#(#s)(URL|Revision)*}/*: /}/*\//} )
1652
1653     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svnbranch || svnbranch="%b:%r"
1654     zformat -f svnbranch "${svnbranch}" "b:${svninfo[1]}" "r:${svninfo[2]}"
1655     VCS_INFO_formats '' "${svnbranch}" "${svnbase}"
1656     return 0
1657 }
1658 # }}}
1659 VCS_INFO_tla_get_data () { # {{{
1660     local tlabase tlabranch
1661
1662     tlabase="$(VCS_INFO_realpath ${vcs_comm[basedir]})"
1663     # tree-id gives us something like 'foo@example.com/demo--1.0--patch-4', so:
1664     tlabranch=${${"$( tla tree-id )"}/*\//}
1665     VCS_INFO_formats '' "${tlabranch}" "${tlabase}"
1666     return 0
1667 }
1668 # }}}
1669 # detection
1670 VCS_INFO_detect_by_dir() { #{{{
1671     local dirname=$1
1672     local basedir="." realbasedir
1673
1674     realbasedir="$(VCS_INFO_realpath ${basedir})"
1675     while [[ ${realbasedir} != '/' ]]; do
1676         if [[ -n ${vcs_comm[detect_need_file]} ]] ; then
1677             [[ -d ${basedir}/${dirname} ]] && \
1678             [[ -f ${basedir}/${dirname}/${vcs_comm[detect_need_file]} ]] && \
1679                 break
1680         else
1681             [[ -d ${basedir}/${dirname} ]] && break
1682         fi
1683
1684         basedir=${basedir}/..
1685         realbasedir="$(VCS_INFO_realpath ${basedir})"
1686     done
1687
1688     [[ ${realbasedir} == "/" ]] && return 1
1689     vcs_comm[basedir]=${realbasedir}
1690     return 0
1691 }
1692 # }}}
1693 VCS_INFO_bzr_detect() { #{{{
1694     VCS_INFO_check_com bzr || return 1
1695     vcs_comm[detect_need_file]=branch/format
1696     VCS_INFO_detect_by_dir '.bzr'
1697     return $?
1698 }
1699 # }}}
1700 VCS_INFO_cdv_detect() { #{{{
1701     VCS_INFO_check_com cdv || return 1
1702     vcs_comm[detect_need_file]=format
1703     VCS_INFO_detect_by_dir '.cdv'
1704     return $?
1705 }
1706 # }}}
1707 VCS_INFO_cvs_detect() { #{{{
1708     VCS_INFO_check_com svn || return 1
1709     [[ -d "./CVS" ]] && [[ -r "./CVS/Repository" ]] && return 0
1710     return 1
1711 }
1712 # }}}
1713 VCS_INFO_darcs_detect() { #{{{
1714     VCS_INFO_check_com darcs || return 1
1715     vcs_comm[detect_need_file]=format
1716     VCS_INFO_detect_by_dir '_darcs'
1717     return $?
1718 }
1719 # }}}
1720 VCS_INFO_git_detect() { #{{{
1721     if VCS_INFO_check_com git && git rev-parse --is-inside-work-tree &> /dev/null ; then
1722         vcs_comm[gitdir]="$(git rev-parse --git-dir 2> /dev/null)" || return 1
1723         if   [[ -d ${vcs_comm[gitdir]}/svn ]]             ; then vcs_comm[overwrite_name]='git-svn'
1724         elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]] ; then vcs_comm[overwrite_name]='git-p4' ; fi
1725         return 0
1726     fi
1727     return 1
1728 }
1729 # }}}
1730 VCS_INFO_hg_detect() { #{{{
1731     VCS_INFO_check_com hg || return 1
1732     vcs_comm[detect_need_file]=branch
1733     VCS_INFO_detect_by_dir '.hg'
1734     return $?
1735 }
1736 # }}}
1737 VCS_INFO_mtn_detect() { #{{{
1738     VCS_INFO_check_com mtn || return 1
1739     vcs_comm[detect_need_file]=revision
1740     VCS_INFO_detect_by_dir '_MTN'
1741     return $?
1742 }
1743 # }}}
1744 VCS_INFO_svk_detect() { #{{{
1745     setopt localoptions noksharrays extendedglob
1746     local -a info
1747     local -i fhash
1748     fhash=0
1749
1750     VCS_INFO_check_com svk || return 1
1751     [[ -f ~/.svk/config ]] || return 1
1752
1753     # This detection function is a bit different from the others.
1754     # We need to read svk's config file to detect a svk repository
1755     # in the first place. Therefore, we'll just proceed and read
1756     # the other information, too. This is more then any of the
1757     # other detections do but this takes only one file open for
1758     # svk at most. VCS_INFO_svk_get_data() get simpler, too. :-)
1759     while IFS= read -r line ; do
1760         if [[ -n ${vcs_comm[basedir]} ]] ; then
1761             line=${line## ##}
1762             [[ ${line} == depotpath:* ]] && vcs_comm[branch]=${line##*/}
1763             [[ ${line} == revision:* ]] && vcs_comm[revision]=${line##*[[:space:]]##}
1764             [[ -n ${vcs_comm[branch]} ]] && [[ -n ${vcs_comm[revision]} ]] && break
1765             continue
1766         fi
1767         (( fhash > 0 )) && [[ ${line} == '  '[^[:space:]]*:* ]] && break
1768         [[ ${line} == '  hash:'* ]] && fhash=1 && continue
1769         (( fhash == 0 )) && continue
1770         [[ ${PWD}/ == ${${line## ##}%:*}/* ]] && vcs_comm[basedir]=${${line## ##}%:*}
1771     done < ~/.svk/config
1772
1773     [[ -n ${vcs_comm[basedir]} ]]  && \
1774     [[ -n ${vcs_comm[branch]} ]]   && \
1775     [[ -n ${vcs_comm[revision]} ]] && return 0
1776     return 1
1777 }
1778 # }}}
1779 VCS_INFO_svn_detect() { #{{{
1780     VCS_INFO_check_com svn || return 1
1781     [[ -d ".svn" ]] && return 0
1782     return 1
1783 }
1784 # }}}
1785 VCS_INFO_tla_detect() { #{{{
1786     VCS_INFO_check_com tla || return 1
1787     vcs_comm[basedir]="$(tla tree-root 2> /dev/null)" && return 0
1788     return 1
1789 }
1790 # }}}
1791 # public API
1792 vcs_info_printsys () { # {{{
1793     vcs_info print_systems_
1794 }
1795 # }}}
1796 vcs_info_lastmsg () { # {{{
1797     local -i i
1798
1799     VCS_INFO_maxexports
1800     for i in {0..$((maxexports - 1))} ; do
1801         printf '$VCS_INFO_message_%d_: "' $i
1802         if zstyle -T ':vcs_info:formats:command' use-prompt-escapes ; then
1803             print -nP ${(P)${:-VCS_INFO_message_${i}_}}
1804         else
1805             print -n ${(P)${:-VCS_INFO_message_${i}_}}
1806         fi
1807         printf '"\n'
1808     done
1809 }
1810 # }}}
1811 vcs_info () { # {{{
1812     local pat
1813     local -i found
1814     local -a VCSs disabled dps
1815     local -x vcs usercontext
1816     local -ix maxexports
1817     local -ax msgs
1818     local -Ax vcs_comm
1819
1820     vcs="init"
1821     VCSs=(git hg bzr darcs svk mtn svn cvs cdv tla)
1822     case $1 in
1823         (print_systems_)
1824             zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1825             print -l '# list of supported version control backends:' \
1826                      '# disabled systems are prefixed by a hash sign (#)'
1827             for vcs in ${VCSs} ; do
1828                 [[ -n ${(M)disabled:#${vcs}} ]] && printf '#'
1829                 printf '%s\n' ${vcs}
1830             done
1831             print -l '# flavours (cannot be used in the disable style; they' \
1832                      '# are disabled with their master [git-svn -> git]):'   \
1833                      git-{p4,svn}
1834             return 0
1835             ;;
1836         ('')
1837             [[ -z ${usercontext} ]] && usercontext=default
1838             ;;
1839         (*) [[ -z ${usercontext} ]] && usercontext=$1
1840             ;;
1841     esac
1842
1843     zstyle -T ":vcs_info:${vcs}:${usercontext}" "enable" || {
1844         [[ -n ${VCS_INFO_message_0_} ]] && VCS_INFO_set --clear
1845         return 0
1846     }
1847     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1848
1849     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable-patterns" dps
1850     for pat in ${dps} ; do
1851         if [[ ${PWD} == ${~pat} ]] ; then
1852             [[ -n ${vcs_info_msg_0_} ]] && VCS_INFO_set --clear
1853             return 0
1854         fi
1855     done
1856
1857     VCS_INFO_maxexports
1858
1859     (( found = 0 ))
1860     for vcs in ${VCSs} ; do
1861         [[ -n ${(M)disabled:#${vcs}} ]] && continue
1862         vcs_comm=()
1863         VCS_INFO_${vcs}_detect && (( found = 1 )) && break
1864     done
1865
1866     (( found == 0 )) && {
1867         VCS_INFO_set --nvcs
1868         return 0
1869     }
1870
1871     VCS_INFO_${vcs}_get_data || {
1872         VCS_INFO_set --nvcs
1873         return 1
1874     }
1875
1876     VCS_INFO_set
1877     return 0
1878 }
1879
1880 VCS_INFO_set --nvcs preinit
1881 # }}}
1882
1883 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1884 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1885 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1886 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1887 #       to $vcs_info_msg_N_ as soon as we use the included version.
1888 if [[ "$TERM" == dumb ]] ; then
1889     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1890     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1891 else
1892     # these are the same, just with a lot of colours:
1893     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1894                                        "zsh: %r"
1895     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1896                                        "zsh: %r"
1897     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1898 fi
1899
1900 # }}}
1901
1902 # {{{ set prompt
1903 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1904     promptinit # people should be able to use their favourite prompt
1905 else
1906     print 'Notice: no promptinit available :('
1907 fi
1908
1909 setopt prompt_subst
1910
1911 # make sure to use right prompt only when not running a command
1912 is41 && setopt transient_rprompt
1913
1914 # TODO: revise all these NO* variables and especially their documentation
1915 #       in zsh-help() below.
1916 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1917     [[ $NOPRECMD -gt 0 ]] && return 0
1918     # update VCS information
1919     vcs_info
1920
1921     if [[ $TERM == screen* ]] ; then
1922         if [[ -n ${VCS_INFO_message_1_} ]] ; then
1923             print -nP "\ek${VCS_INFO_message_1_}\e\\"
1924         else
1925             print -nP "\ekzsh\e\\"
1926         fi
1927     fi
1928     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1929     if [[ $DONTSETRPROMPT -eq 0 ]] ; then
1930         if [[ $BATTERY -gt 0 ]] ; then
1931             # update battery (dropped into $PERCENT) information
1932             battery
1933             RPROMPT="%(?..:() ${PERCENT}"
1934         else
1935             RPROMPT="%(?..:() "
1936         fi
1937     fi
1938     # adjust title of xterm
1939     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1940     [[ ${NOTITLE} -gt 0 ]] && return 0
1941     case $TERM in
1942         (xterm*|rxvt*)
1943             print -Pn "\e]0;%n@%m: %~\a"
1944             ;;
1945     esac
1946 }
1947
1948 # preexec() => a function running before every command
1949 is4 && [[ $NOPRECMD -eq 0 ]] && \
1950 preexec () {
1951     [[ $NOPRECMD -gt 0 ]] && return 0
1952 # set hostname if not running on host with name 'grml'
1953     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1954        NAME="@$HOSTNAME"
1955     fi
1956 # get the name of the program currently running and hostname of local machine
1957 # set screen window title if running in a screen
1958     if [[ "$TERM" == screen* ]] ; then
1959         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1960         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1961         echo -ne "\ek$CMD\e\\"
1962     fi
1963 # adjust title of xterm
1964     [[ ${NOTITLE} -gt 0 ]] && return 0
1965     case $TERM in
1966         (xterm*|rxvt)
1967             print -Pn "\e]0;%n@%m: $1\a"
1968             ;;
1969     esac
1970 }
1971
1972 EXITCODE="%(?..%?%1v )"
1973 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
1974 PS3='?# '         # selection prompt used within a select loop.
1975 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1976
1977 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1978 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1979     debian_chroot=$(cat /etc/debian_chroot)
1980 fi
1981
1982 # don't use colors on dumb terminals (like emacs):
1983 if [[ "$TERM" == dumb ]] ; then
1984     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
1985 else
1986     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
1987     # set variable identifying the chroot you work in (used in the prompt below)
1988     if [[ $GRMLPROMPT -gt 0 ]] ; then
1989         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1990 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
1991     else
1992         # This assembles the primary prompt string
1993         if (( EUID != 0 )); then
1994             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
1995         else
1996             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
1997         fi
1998     fi
1999 fi
2000
2001 # if we are inside a grml-chroot set a specific prompt theme
2002 if [[ -n "$GRML_CHROOT" ]] ; then
2003     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
2004 fi
2005 # }}}
2006
2007 # {{{ 'hash' some often used directories
2008 #d# start
2009 hash -d deb=/var/cache/apt/archives
2010 hash -d doc=/usr/share/doc
2011 hash -d linux=/lib/modules/$(command uname -r)/build/
2012 hash -d log=/var/log
2013 hash -d slog=/var/log/syslog
2014 hash -d src=/usr/src
2015 hash -d templ=/usr/share/doc/grml-templates
2016 hash -d tt=/usr/share/doc/texttools-doc
2017 hash -d www=/var/www
2018 #d# end
2019 # }}}
2020
2021 # {{{ some aliases
2022 if check_com -c screen ; then
2023     if [[ $UID -eq 0 ]] ; then
2024         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
2025     elif [[ -r $HOME/.screenrc ]] ; then
2026         alias screen="${commands[screen]} -c $HOME/.screenrc"
2027     else
2028         [[ -r /etc/grml/screenrc_grml ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2029     fi
2030 fi
2031
2032 # do we have GNU ls with color-support?
2033 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
2034     #a1# execute \kbd{@a@}:\quad ls with colors
2035     alias ls='ls -b -CF --color=auto'
2036     #a1# execute \kbd{@a@}:\quad list all files, with colors
2037     alias la='ls -la --color=auto'
2038     #a1# long colored list, without dotfiles (@a@)
2039     alias ll='ls -l --color=auto'
2040     #a1# long colored list, human readable sizes (@a@)
2041     alias lh='ls -hAl --color=auto'
2042     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2043     alias l='ls -lF --color=auto'
2044 else
2045     alias ls='ls -b -CF'
2046     alias la='ls -la'
2047     alias ll='ls -l'
2048     alias lh='ls -hAl'
2049     alias l='ls -lF'
2050 fi
2051
2052 alias mdstat='cat /proc/mdstat'
2053 alias ...='cd ../../'
2054
2055 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2056 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2057     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2058 fi
2059
2060 alias cp='nocorrect cp'         # no spelling correction on cp
2061 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
2062 alias mv='nocorrect mv'         # no spelling correction on mv
2063 alias rm='nocorrect rm'         # no spelling correction on rm
2064
2065 #a1# Execute \kbd{rmdir}
2066 alias rd='rmdir'
2067 #a1# Execute \kbd{rmdir}
2068 alias md='mkdir'
2069
2070 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2071 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2072 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2073
2074 # make sure it is not assigned yet
2075 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
2076
2077 utf2iso() {
2078     if isutfenv ; then
2079         for ENV in $(env | command grep -i '.utf') ; do
2080             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2081         done
2082     fi
2083 }
2084
2085 # make sure it is not assigned yet
2086 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
2087 iso2utf() {
2088     if ! isutfenv ; then
2089         for ENV in $(env | command grep -i '\.iso') ; do
2090             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2091         done
2092     fi
2093 }
2094
2095 # set up software synthesizer via speakup
2096 swspeak() {
2097     if [ -x /usr/sbin/swspeak-setup ] ; then
2098        setopt singlelinezle
2099        unsetopt prompt_cr
2100        export PS1="%m%# "
2101        /usr/sbin/swspeak-setup $@
2102      else # old version:
2103         aumix -w 90 -v 90 -p 90 -m 90
2104         if ! [[ -r /dev/softsynth ]] ; then
2105             flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
2106             return 1
2107         else
2108            setopt singlelinezle
2109            unsetopt prompt_cr
2110            export PS1="%m%# "
2111             nice -n -20 speechd-up
2112             sleep 2
2113             flite -o play -t "Finished setting up software synthesizer"
2114         fi
2115      fi
2116 }
2117
2118 # I like clean prompt, so provide simple way to get that
2119 check_com 0 || alias 0='return 0'
2120
2121 # for really lazy people like mika:
2122 check_com S &>/dev/null || alias S='screen'
2123 check_com s &>/dev/null || alias s='ssh'
2124
2125 # get top 10 shell commands:
2126 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
2127
2128 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
2129 if check_com -c truecrypt ; then
2130     if isutfenv ; then
2131         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
2132     else
2133         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
2134     fi
2135 fi
2136
2137 #f1# Hints for the use of zsh on grml
2138 zsh-help() {
2139     print "$bg[white]$fg[black]
2140 zsh-help - hints for use of zsh on grml
2141 =======================================$reset_color"
2142
2143     print '
2144 Main configuration of zsh happens in /etc/zsh/zshrc.
2145 That file is part of the package grml-etc-core, if you want to
2146 use them on a non-grml-system just get the tar.gz from
2147 http://deb.grml.org/ or (preferably) get it from the git repository:
2148
2149   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2150
2151 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2152 The file is still there, but it is empty for backwards compatibility.
2153
2154 For your own changes use these two files:
2155     $HOME/.zshrc.pre
2156     $HOME/.zshrc.local
2157
2158 The former is sourced very early in our zshrc, the latter is sourced
2159 very lately.
2160
2161 System wide configuration without touching configuration files of grml
2162 can take place in /etc/zsh/zshrc.local.
2163
2164 Normally, the root user (EUID == 0) does not get the whole grml setup.
2165 If you want to force the whole setup for that user, too, set
2166 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
2167
2168 For information regarding zsh start at http://grml.org/zsh/
2169
2170 Take a look at grml'\''s zsh refcard:
2171 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2172
2173 Check out the main zsh refcard:
2174 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2175
2176 And of course visit the zsh-lovers:
2177 % man zsh-lovers
2178
2179 You can adjust some options through environment variables when
2180 invoking zsh without having to edit configuration files.
2181 Basically meant for bash users who are not used to the power of
2182 the zsh yet. :)
2183
2184   "NOCOR=1    zsh" => deactivate automatic correction
2185   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
2186   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2187   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2188                       preexec() and precmd() completely
2189   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2190
2191 A value greater than 0 is enables a feature; a value equal to zero
2192 disables it. If you like one or the other of these settings, you can
2193 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2194 zshrc.'
2195
2196     print "
2197 $bg[white]$fg[black]
2198 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2199 Enjoy your grml system with the zsh!$reset_color"
2200 }
2201
2202 # debian stuff
2203 if [[ -r /etc/debian_version ]] ; then
2204     #a3# Execute \kbd{apt-cache search}
2205     alias acs='apt-cache search'
2206     #a3# Execute \kbd{apt-cache show}
2207     alias acsh='apt-cache show'
2208     #a3# Execute \kbd{apt-cache policy}
2209     alias acp='apt-cache policy'
2210     #a3# Execute \kbd{apt-get dist-upgrade}
2211     salias adg="apt-get dist-upgrade"
2212     #a3# Execute \kbd{apt-get install}
2213     salias agi="apt-get install"
2214     #a3# Execute \kbd{aptitude install}
2215     salias ati="aptitude install"
2216     #a3# Execute \kbd{apt-get upgrade}
2217     salias ag="apt-get upgrade"
2218     #a3# Execute \kbd{apt-get update}
2219     salias au="apt-get update"
2220     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2221     salias -a up="aptitude update ; aptitude safe-upgrade"
2222     #a3# Execute \kbd{dpkg-buildpackage}
2223     alias dbp='dpkg-buildpackage'
2224     #a3# Execute \kbd{grep-excuses}
2225     alias ge='grep-excuses'
2226
2227     # debian upgrade
2228     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
2229     upgrade() {
2230         if [[ -z "$1" ]] ; then
2231             $SUDO apt-get update
2232             $SUDO apt-get -u upgrade
2233         else
2234             ssh $1 $SUDO apt-get update
2235             # ask before the upgrade
2236             local dummy
2237             ssh $1 $SUDO apt-get --no-act upgrade
2238             echo -n 'Process the upgrade?'
2239             read -q dummy
2240             if [[ $dummy == "y" ]] ; then
2241                 ssh $1 $SUDO apt-get -u upgrade --yes
2242             fi
2243         fi
2244     }
2245
2246     # get a root shell as normal user in live-cd mode:
2247     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2248        alias su="sudo su"
2249      fi
2250
2251     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2252     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2253     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2254     alias tlog="tail -f /var/log/syslog"    # follow the syslog
2255 fi
2256
2257 # sort installed Debian-packages by size
2258 if check_com -c grep-status ; then
2259     #a3# List installed Debian-packages sorted by size
2260     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
2261 fi
2262
2263 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2264 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
2265     if check_com -c wodim ; then
2266         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
2267 See #377109 in the BTS of Debian for more details.
2268
2269 Please use the wodim binary instead' ; return 1"
2270     fi
2271 fi
2272
2273 # get_tw_cli has been renamed into get_3ware
2274 if check_com -c get_3ware ; then
2275     get_tw_cli() {
2276         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
2277         get_3ware
2278     }
2279 fi
2280
2281 # I hate lacking backward compatibility, so provide an alternative therefore
2282 if ! check_com -c apache2-ssl-certificate ; then
2283
2284     apache2-ssl-certificate() {
2285
2286     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
2287     print 'You might want to take a look at Debian the package ssl-cert as well.'
2288     print 'To generate a certificate for use with apache2 follow the instructions:'
2289
2290     echo '
2291
2292 export RANDFILE=/dev/random
2293 mkdir /etc/apache2/ssl/
2294 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
2295 chmod 600 /etc/apache2/ssl/apache.pem
2296
2297 Run "grml-tips ssl-certificate" if you need further instructions.
2298 '
2299     }
2300 fi
2301 # }}}
2302
2303 # {{{ Use hard limits, except for a smaller stack and no core dumps
2304 unlimit
2305 is425 && limit stack 8192
2306 isgrmlcd && limit core 0 # important for a live-cd-system
2307 limit -s
2308 # }}}
2309
2310 # {{{ completion system
2311
2312 # called later (via is4 && grmlcomp)
2313 # note: use 'zstyle' for getting current settings
2314 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
2315 grmlcomp() {
2316     # TODO: This could use some additional information
2317
2318     # allow one error for every three characters typed in approximate completer
2319     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
2320
2321     # don't complete backup files as executables
2322     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
2323
2324     # start menu completion only if it could find no unambiguous initial string
2325     zstyle ':completion:*:correct:*'       insert-unambiguous true
2326     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
2327     zstyle ':completion:*:correct:*'       original true
2328
2329     # activate color-completion
2330     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
2331
2332     # format on completion
2333     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
2334
2335     # complete 'cd -<tab>' with menu
2336     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
2337
2338     # insert all expansions for expand completer
2339     zstyle ':completion:*:expand:*'        tag-order all-expansions
2340     zstyle ':completion:*:history-words'   list false
2341
2342     # activate menu
2343     zstyle ':completion:*:history-words'   menu yes
2344
2345     # ignore duplicate entries
2346     zstyle ':completion:*:history-words'   remove-all-dups yes
2347     zstyle ':completion:*:history-words'   stop yes
2348
2349     # match uppercase from lowercase
2350     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
2351
2352     # separate matches into groups
2353     zstyle ':completion:*:matches'         group 'yes'
2354     zstyle ':completion:*'                 group-name ''
2355
2356     if [[ "$NOMENU" -eq 0 ]] ; then
2357         # if there are more than 5 options allow selecting from a menu
2358         zstyle ':completion:*'               menu select=5
2359     else
2360         # don't use any menus at all
2361         setopt no_auto_menu
2362     fi
2363
2364     zstyle ':completion:*:messages'        format '%d'
2365     zstyle ':completion:*:options'         auto-description '%d'
2366
2367     # describe options in full
2368     zstyle ':completion:*:options'         description 'yes'
2369
2370     # on processes completion complete all user processes
2371     zstyle ':completion:*:processes'       command 'ps -au$USER'
2372
2373     # offer indexes before parameters in subscripts
2374     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
2375
2376     # provide verbose completion information
2377     zstyle ':completion:*'                 verbose true
2378
2379     # recent (as of Dec 2007) zsh versions are able to provide descriptions
2380     # for commands (read: 1st word in the line) that it will list for the user
2381     # to choose from. The following disables that, because it's not exactly fast.
2382     zstyle ':completion:*:-command-:*:'    verbose false
2383
2384     # set format for warnings
2385     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
2386
2387     # define files to ignore for zcompile
2388     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
2389     zstyle ':completion:correct:'          prompt 'correct to: %e'
2390
2391     # Ignore completion functions for commands you don't have:
2392     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
2393
2394     # Provide more processes in completion of programs like killall:
2395     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
2396
2397     # complete manual by their section
2398     zstyle ':completion:*:manuals'    separate-sections true
2399     zstyle ':completion:*:manuals.*'  insert-sections   true
2400     zstyle ':completion:*:man:*'      menu yes select
2401
2402     # provide .. as a completion
2403     zstyle ':completion:*' special-dirs ..
2404
2405     # run rehash on completion so new installed program are found automatically:
2406     _force_rehash() {
2407         (( CURRENT == 1 )) && rehash
2408         return 1
2409     }
2410
2411     ## correction
2412     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2413     if [[ "$NOCOR" -gt 0 ]] ; then
2414         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2415         setopt nocorrect
2416     else
2417         # try to be smart about when to use what completer...
2418         setopt correct
2419         zstyle -e ':completion:*' completer '
2420             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2421                 _last_try="$HISTNO$BUFFER$CURSOR"
2422                 reply=(_complete _match _ignored _prefix _files)
2423             else
2424                 if [[ $words[1] == (rm|mv) ]] ; then
2425                     reply=(_complete _files)
2426                 else
2427                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2428                 fi
2429             fi'
2430     fi
2431
2432     # command for process lists, the local web server details and host completion
2433     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2434
2435     # caching
2436     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2437                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2438
2439     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
2440     if is42 ; then
2441         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2442         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2443     else
2444         _ssh_hosts=()
2445         _etc_hosts=()
2446     fi
2447     hosts=(
2448         $(hostname)
2449         "$_ssh_hosts[@]"
2450         "$_etc_hosts[@]"
2451         grml.org
2452         localhost
2453     )
2454     zstyle ':completion:*:hosts' hosts $hosts
2455     # TODO: so, why is this here?
2456     #  zstyle '*' hosts $hosts
2457
2458     # use generic completion system for programs not yet defined; (_gnu_generic works
2459     # with commands that provide a --help option with "standard" gnu-like output.)
2460     compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
2461
2462     # see upgrade function in this file
2463     compdef _hosts upgrade
2464 }
2465 # }}}
2466
2467 # {{{ grmlstuff
2468 grmlstuff() {
2469 # people should use 'grml-x'!
2470     startx() {
2471         if [[ -e /etc/X11/xorg.conf ]] ; then
2472             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
2473         else
2474             echo "Please use the script \"grml-x\" for starting the X Window System
2475 because there does not exist /etc/X11/xorg.conf yet.
2476 If you want to use startx anyway please call \"/usr/bin/startx\"."
2477             return -1
2478         fi
2479     }
2480
2481     xinit() {
2482         if [[ -e /etc/X11/xorg.conf ]] ; then
2483             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
2484         else
2485             echo "Please use the script \"grml-x\" for starting the X Window System.
2486 because there does not exist /etc/X11/xorg.conf yet.
2487 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
2488             return -1
2489         fi
2490     }
2491
2492     if check_com -c 915resolution ; then
2493         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
2494     fi
2495
2496     #a1# Output version of running grml
2497     alias grml-version='cat /etc/grml_version'
2498
2499     if check_com -c rebuildfstab ; then
2500         #a1# Rebuild /etc/fstab
2501         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2502     fi
2503
2504     if check_com -c grml-debootstrap ; then
2505         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
2506     fi
2507 }
2508 # }}}
2509
2510 # {{{ now run the functions
2511 isgrml && checkhome
2512 is4    && isgrml    && grmlstuff
2513 is4    && grmlcomp
2514 # }}}
2515
2516 # {{{ keephack
2517 is4 && xsource "/etc/zsh/keephack"
2518 # }}}
2519
2520 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
2521 # You use it as follows:
2522 # $ NTREF=/reference/file
2523 # $ ls -l *(e:nt:)
2524 # This lists all the files in the current directory newer than the reference file.
2525 # You can also specify the reference file inline; note quotes:
2526 # $ ls -l *(e:'nt ~/.zshenv':)
2527 is4 && nt() {
2528     if [[ -n $1 ]] ; then
2529         local NTREF=${~1}
2530     fi
2531     [[ $REPLY -nt $NTREF ]]
2532 }
2533 # }}}
2534
2535 # shell functions {{{
2536
2537 #f1# Provide csh compatibility
2538 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
2539
2540 #f1# Reload an autoloadable function
2541 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2542
2543 #f1# Reload zsh setup
2544 reload() {
2545     if [[ "$#*" -eq 0 ]] ; then
2546         [[ -r ~/.zshrc ]] && . ~/.zshrc
2547     else
2548         local fn
2549         for fn in "$@"; do
2550             unfunction $fn
2551             autoload -U $fn
2552         done
2553     fi
2554 }
2555 compdef _functions reload freload
2556
2557 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2558 sll() {
2559     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2560     for i in "$@" ; do
2561         file=$i
2562         while [[ -h "$file" ]] ; do
2563             ls -l $file
2564             file=$(readlink "$file")
2565         done
2566     done
2567 }
2568
2569 # fast manual access
2570 if check_com qma ; then
2571     #f1# View the zsh manual
2572     manzsh()  { qma zshall "$1" }
2573     compdef _man qma
2574 else
2575     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
2576 fi
2577
2578 if check_com -c $PAGER ; then
2579     #f1# View Debian's changelog of a given package
2580     dchange() {
2581         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
2582             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
2583         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2584             $PAGER /usr/share/doc/${1}/changelog.gz
2585         else
2586             if check_com -c aptitude ; then
2587                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2588                 if isgrml ; then
2589                     aptitude -t unstable changelog ${1}
2590                 else
2591                     aptitude changelog ${1}
2592                 fi
2593             else
2594                 echo "No changelog for package $1 found, sorry."
2595                 return 1
2596             fi
2597         fi
2598     }
2599     _dchange() { _files -W /usr/share/doc -/ }
2600     compdef _dchange dchange
2601
2602     #f1# View Debian's NEWS of a given package
2603     dnews() {
2604         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
2605             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
2606         else
2607             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
2608                 $PAGER /usr/share/doc/${1}/NEWS.gz
2609             else
2610                 echo "No NEWS file for package $1 found, sorry."
2611                 return 1
2612             fi
2613         fi
2614     }
2615     _dnews() { _files -W /usr/share/doc -/ }
2616     compdef _dnews dnews
2617
2618     #f1# View upstream's changelog of a given package
2619     uchange() {
2620         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2621             $PAGER /usr/share/doc/${1}/changelog.gz
2622         else
2623             echo "No changelog for package $1 found, sorry."
2624             return 1
2625         fi
2626     }
2627     _uchange() { _files -W /usr/share/doc -/ }
2628     compdef _uchange uchange
2629 fi
2630
2631 # zsh profiling
2632 profile() {
2633     ZSH_PROFILE_RC=1 $SHELL "$@"
2634 }
2635
2636 #f1# Edit an alias via zle
2637 edalias() {
2638     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2639 }
2640 compdef _aliases edalias
2641
2642 #f1# Edit a function via zle
2643 edfunc() {
2644     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
2645 }
2646 compdef _functions edfunc
2647
2648 # use it e.g. via 'Restart apache2'
2649 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2650 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2651 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2652 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2653 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2654 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2655     __start_stop() {
2656         local action_="${1:l}"  # e.g Start/Stop/Restart
2657         local service_="$2"
2658         local param_="$3"
2659
2660         local service_target_="$(readlink /etc/init.d/$service_)"
2661         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2662             # runit
2663             case "${action_}" in
2664                 start) if [[ ! -e /etc/service/$service_ ]]; then
2665                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2666                        else
2667                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2668                        fi ;;
2669                 # there is no reload in runits sysv emulation
2670                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2671                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2672             esac
2673         else
2674             # sysvinit
2675             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2676         fi
2677     }
2678
2679     for i in Start Restart Stop Force-Reload Reload ; do
2680         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2681     done
2682 fi
2683
2684 #f1# Provides useful information on globbing
2685 H-Glob() {
2686     echo -e "
2687     /      directories
2688     .      plain files
2689     @      symbolic links
2690     =      sockets
2691     p      named pipes (FIFOs)
2692     *      executable plain files (0100)
2693     %      device files (character or block special)
2694     %b     block special files
2695     %c     character special files
2696     r      owner-readable files (0400)
2697     w      owner-writable files (0200)
2698     x      owner-executable files (0100)
2699     A      group-readable files (0040)
2700     I      group-writable files (0020)
2701     E      group-executable files (0010)
2702     R      world-readable files (0004)
2703     W      world-writable files (0002)
2704     X      world-executable files (0001)
2705     s      setuid files (04000)
2706     S      setgid files (02000)
2707     t      files with the sticky bit (01000)
2708
2709   print *(m-1)          # Files modified up to a day ago
2710   print *(a1)           # Files accessed a day ago
2711   print *(@)            # Just symlinks
2712   print *(Lk+50)        # Files bigger than 50 kilobytes
2713   print *(Lk-50)        # Files smaller than 50 kilobytes
2714   print **/*.c          # All *.c files recursively starting in \$PWD
2715   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2716   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2717   print *~*.*           # All Files that do not contain a dot
2718   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2719   print -l *(.c|.h)     # Lists *.c and *.h
2720   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2721   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2722 }
2723 alias help-zshglob=H-Glob
2724
2725 check_com -c qma && alias ?='qma zshall'
2726
2727 # grep for running process, like: 'any vim'
2728 any() {
2729     if [[ -z "$1" ]] ; then
2730         echo "any - grep for process(es) by keyword" >&2
2731         echo "Usage: any <keyword>" >&2 ; return 1
2732     else
2733         local STRING=$1
2734         local LENGTH=$(expr length $STRING)
2735         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
2736         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
2737         ps xauwww| grep "[$FIRSCHAR]$REST"
2738     fi
2739 }
2740
2741 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2742 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2743 [[ -r /proc/1/maps ]] && \
2744 deswap() {
2745     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2746     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2747     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2748 }
2749
2750 # print hex value of a number
2751 hex() {
2752     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2753 }
2754
2755 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2756 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2757 peval() {
2758     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2759     perl -e "print eval($CALC),\"\n\";"
2760 }
2761 functions peval &>/dev/null && alias calc=peval
2762
2763 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
2764 # certain circumstances, so work around it, no matter which environment we have
2765 brltty() {
2766     if [[ -z "$DISPLAY" ]] ; then
2767         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
2768         command brltty "$@"
2769     else
2770         command brltty "$@"
2771     fi
2772 }
2773
2774 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2775 aoeu() {
2776     echo -n 'Switching to us keyboard layout: '
2777     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2778     echo 'Done'
2779 }
2780 asdf() {
2781     echo -n 'Switching to dvorak keyboard layout: '
2782     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2783     echo 'Done'
2784 }
2785 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2786 uiae() {
2787     echo -n 'Switching to us keyboard layout: '
2788     setxkbmap us && echo 'Done' || echo 'Failed'
2789 }
2790
2791 # set up an ipv6 tunnel
2792 ipv6-tunnel() {
2793     case $1 in
2794         start)
2795             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2796                 print 'ipv6 tunnel already set up, nothing to be done.'
2797                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2798             else
2799                 [[ -n "$PUBLIC_IP" ]] || \
2800                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2801                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2802
2803                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
2804                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
2805                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
2806                 ifconfig sit0 tunnel ::192.88.99.1 up
2807                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
2808             fi
2809             ;;
2810         status)
2811             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2812                 print 'ipv6 tunnel available' ; return 0
2813             else
2814                 print 'ipv6 tunnel not available' ; return 1
2815             fi
2816             ;;
2817         stop)
2818             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2819                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
2820                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
2821             else
2822                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
2823             fi
2824             ;;
2825         *)
2826             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
2827             ;;
2828     esac
2829 }
2830
2831 # run dhclient for wireless device
2832 iwclient() {
2833     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
2834 }
2835
2836 # spawn a minimally set up ksh - useful if you want to umount /usr/.
2837 minimal-shell() {
2838     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
2839 }
2840
2841 # make a backup of a file
2842 bk() {
2843     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2844 }
2845
2846 #f1# grep for patterns in grml's zsh setup
2847 zg() {
2848 #{{{
2849     LANG=C perl -e '
2850
2851 sub usage {
2852     print "usage: zg -[anr] <pattern>\n";
2853     print " Search for patterns in grml'\''s zshrc.\n";
2854     print " zg takes no or exactly one option plus a non empty pattern.\n\n";
2855     print "   options:\n";
2856     print "     --  no options (use if your pattern starts in with a dash.\n";
2857     print "     -a  search for the pattern in all code regions\n";
2858     print "     -n  search for the pattern in non-root code only\n";
2859     print "     -r  search in code for everyone (also root) only\n\n";
2860     print "   The default is -a for non-root users and -r for root.\n\n";
2861     print " If you installed the zshrc to a non-default locations (ie *NOT*\n";
2862     print " in /etc/zsh/zshrc) do: export GRML_ZSHRC=\$HOME/.zshrc\n";
2863     print " ...in case you copied the file to that location.\n\n";
2864     exit 1;
2865 }
2866
2867 if ($ENV{GRML_ZSHRC} ne "") {
2868     $RC = $ENV{GRML_ZSHRC};
2869 } else {
2870     $RC = "/etc/zsh/zshrc";
2871 }
2872
2873 usage if ($#ARGV < 0 || $#ARGV > 1);
2874 if ($> == 0) { $mode = "allonly"; }
2875 else { $mode = "all"; }
2876
2877 $opt = $ARGV[0];
2878 if ($opt eq "--")     { shift; }
2879 elsif ($opt eq "-a")  { $mode = "all"; shift; }
2880 elsif ($opt eq "-n")  { $mode = "nonroot"; shift; }
2881 elsif ($opt eq "-r" ) { $mode = "allonly"; shift; }
2882 elsif ($opt =~ m/^-/ || $#ARGV > 0) { usage(); }
2883
2884 $pattern = $ARGV[0];
2885 usage() if ($pattern eq "");
2886
2887 open FH, "<$RC" or die "zg: Could not open $RC: $!\n";
2888 while ($line = <FH>) {
2889     chomp $line;
2890     if ($line =~ m/^#:grep:marker:for:mika:/) { $markerfound = 1; next; }
2891     next if ($mode eq "nonroot" && markerfound == 0);
2892     break if ($mode eq "allonly" && markerfound == 1);
2893     print $line, "\n" if ($line =~ /$pattern/);
2894 }
2895 close FH;
2896 exit 0;
2897
2898     ' -- "$@"
2899 #}}}
2900     return $?
2901 }
2902
2903 # }}}
2904
2905 # {{{ make sure our environment is clean regarding colors
2906 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2907 # }}}
2908
2909 # source another config file if present {{{
2910 xsource "/etc/zsh/zshrc.local"
2911 # }}}
2912
2913 # "persistent history" {{{
2914 # just write important commands you always need to ~/.important_commands
2915 if [[ -r ~/.important_commands ]] ; then
2916     fc -R ~/.important_commands
2917 fi
2918 # }}}
2919
2920 #:grep:marker:for:mika: :-)
2921 ### non-root (EUID != 0) code below
2922 ###
2923
2924 (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) && return 0
2925
2926 # variables {{{
2927
2928 # set terminal property (used e.g. by msgid-chooser)
2929 export COLORTERM="yes"
2930
2931 # set default browser
2932 if [[ -z "$BROWSER" ]] ; then
2933     if [[ -n "$DISPLAY" ]] ; then
2934         #v# If X11 is running
2935         check_com -c firefox && export BROWSER=firefox
2936     else
2937         #v# If no X11 is running
2938         check_com -c w3m && export BROWSER=w3m
2939     fi
2940 fi
2941
2942 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
2943 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
2944 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
2945
2946 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
2947 #v# [for non-root only]
2948 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
2949 # }}}
2950
2951 # aliases {{{
2952
2953 # Xterm resizing-fu.
2954 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
2955 alias hide='echo -en "\033]50;nil2\007"'
2956 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
2957 alias small='echo -en "\033]50;6x10\007"'
2958 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
2959 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
2960 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
2961 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
2962 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
2963 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
2964
2965 # general
2966 #a2# Execute \kbd{du -sch}
2967 alias da='du -sch'
2968 #a2# Execute \kbd{jobs -l}
2969 alias j='jobs -l'
2970
2971 # compile stuff
2972 #a2# Execute \kbd{./configure}
2973 alias CO="./configure"
2974 #a2# Execute \kbd{./configure --help}
2975 alias CH="./configure --help"
2976
2977 # http://conkeror.mozdev.org/
2978 # TODO: I think this should be removed, as conkeror is not a simple extension anymore
2979 #a2# Run a keyboard driven firefox
2980 alias conkeror='firefox -chrome chrome://conkeror/content'
2981
2982 # arch/tla stuff
2983 if check_com -c tla ; then
2984     #a2# Execute \kbd{tla what-changed --diffs | less}
2985     alias tdi='tla what-changed --diffs | less'
2986     #a2# Execute \kbd{tla-buildpackage}
2987     alias tbp='tla-buildpackage'
2988     #a2# Execute \kbd{tla archive-mirror}
2989     alias tmi='tla archive-mirror'
2990     #a2# Execute \kbd{tla commit}
2991     alias tco='tla commit'
2992     #a2# Execute \kbd{tla star-merge}
2993     alias tme='tla star-merge'
2994 fi
2995
2996 # listing stuff
2997 #a2# Execute \kbd{ls -lSrah}
2998 alias dir="ls -lSrah"
2999 #a2# Only show dot-directories
3000 alias lad='ls -d .*(/)'                # only show dot-directories
3001 #a2# Only show dot-files
3002 alias lsa='ls -a .*(.)'                # only show dot-files
3003 #a2# Only files with setgid/setuid/sticky flag
3004 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
3005 #a2# Only show 1st ten symlinks
3006 alias lsl='ls -l *(@[1,10])'           # only symlinks
3007 #a2# Display only executables
3008 alias lsx='ls -l *(*[1,10])'           # only executables
3009 #a2# Display world-{readable,writable,executable} files
3010 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
3011 #a2# Display the ten biggest files
3012 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
3013 #a2# Only show directories
3014 alias lsd='ls -d *(/)'                 # only show directories
3015 #a2# Only show empty directories
3016 alias lse='ls -d *(/^F)'               # only show empty directories
3017 #a2# Display the ten newest files
3018 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
3019 #a2# Display the ten oldest files
3020 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
3021 #a2# Display the ten smallest files
3022 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
3023
3024 # chmod
3025 #a2# Execute \kbd{chmod 600}
3026 alias rw-='chmod 600'
3027 #a2# Execute \kbd{chmod 700}
3028 alias rwx='chmod 700'
3029 #m# a2 r-{}- Execute \kbd{chmod 644}
3030 alias r--='chmod 644'
3031 #a2# Execute \kbd{chmod 755}
3032 alias r-x='chmod 755'
3033
3034 # some useful aliases
3035 #a2# Execute \kbd{mkdir -o}
3036 alias md='mkdir -p'
3037
3038 check_com -c ipython && alias ips='ipython -p sh'
3039
3040 # console stuff
3041 #a2# Execute \kbd{mplayer -vo fbdev}
3042 alias cmplayer='mplayer -vo fbdev'
3043 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
3044 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
3045 #a2# Execute \kbd{links2 -driver fb}
3046 alias fblinks='links2 -driver fb'
3047
3048 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3049 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3050 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3051
3052 # simple webserver
3053 check_com -c python && alias http="python -m SimpleHTTPServer"
3054
3055 # Use 'g' instead of 'git':
3056 check_com g || alias g='git'
3057
3058 # use colors when browsing man pages, but only if not using LESS_TERMCAP_* from /etc/zsh/zshenv:
3059 if [[ -z "$LESS_TERMCAP_md" ]] ; then
3060     [[ -d ~/.terminfo/ ]] && alias man='TERMINFO=~/.terminfo/ LESS=C TERM=mostlike PAGER=less man'
3061 fi
3062
3063 # check whether Debian's package management (dpkg) is running
3064 if check_com salias ; then
3065     #a2# Check whether a dpkg instance is currently running
3066     salias check_dpkg_running="dpkg_running"
3067 fi
3068
3069 # work around non utf8 capable software in utf environment via $LANG and luit
3070 if check_com isutfenv && check_com luit ; then
3071     if check_com -c mrxvt ; then
3072         isutfenv && [[ -n "$LANG" ]] && \
3073             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3074     fi
3075
3076     if check_com -c aterm ; then
3077         isutfenv && [[ -n "$LANG" ]] && \
3078             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3079     fi
3080
3081     if check_com -c centericq ; then
3082         isutfenv && [[ -n "$LANG" ]] && \
3083             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3084     fi
3085 fi
3086 # }}}
3087
3088 # useful functions {{{
3089
3090 # searching
3091 #f4# Search for newspostings from authors
3092 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
3093 #f4# Search Debian Bug Tracking System
3094 debbug()  {
3095     setopt localoptions extendedglob
3096     if [[ $# -eq 1 ]]; then
3097         case "$1" in
3098             ([0-9]##)
3099             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
3100             ;;
3101             (*@*)
3102             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
3103             ;;
3104             (*)
3105             ${=BROWSER} "http://bugs.debian.org/$*"
3106             ;;
3107         esac
3108     else
3109         print "$0 needs one argument"
3110         return 1
3111     fi
3112 }
3113 #f4# Search Debian Bug Tracking System in mbox format
3114 debbugm() { bts show --mbox $1 } # provide bugnummer as "$1"
3115 #f4# Search DMOZ
3116 dmoz()    { ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_} }
3117 #f4# Search German   Wiktionary
3118 dwicti()  { ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_} }
3119 #f4# Search English  Wiktionary
3120 ewicti()  { ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_} }
3121 #f4# Search Google Groups
3122 ggogle()  { ${=BROWSER} "http://groups.google.com/groups?q=$*" }
3123 #f4# Search Google
3124 google()  { ${=BROWSER} "http://www.google.com/search?&num=100&q=$*" }
3125 #f4# Search Google Groups for MsgID
3126 mggogle() { ${=BROWSER} "http://groups.google.com/groups?selm=$*" }
3127 #f4# Search Netcraft
3128 netcraft(){ ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1" }
3129 #f4# Use German Wikipedia's full text search
3130 swiki()   { ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1} }
3131 #f4# search \kbd{dict.leo.org}
3132 oleo()    { ${=BROWSER} "http://dict.leo.org/?search=$*" }
3133 #f4# Search German   Wikipedia
3134 wikide()  { ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}" }
3135 #f4# Search English  Wikipedia
3136 wikien()  { ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}" }
3137 #f4# Search official debs
3138 wodeb()   { ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all" }
3139
3140 #m# f4 gex() Exact search via Google
3141 check_com google && gex () { google "\"[ $1]\" $*" } # exact search at google
3142
3143 # misc
3144 #f5# Backup \kbd{file {\rm to} file\_timestamp}
3145 bk()      { cp -b ${1} ${1}_`date --iso-8601=m` }
3146 #f5# Copied diff
3147 cdiff()   { diff -crd "$*" | egrep -v "^Only in |^Binary files " }
3148 #f5# cd to directoy and list files
3149 cl()      { cd $1 && ls -a }        # cd && ls
3150 #f5# Cvs add
3151 cvsa()    { cvs add $* && cvs com -m 'initial checkin' $* }
3152 #f5# Cvs diff
3153 cvsd()    { cvs diff -N $* |& $PAGER }
3154 #f5# Cvs log
3155 cvsl()    { cvs log $* |& $PAGER }
3156 #f5# Cvs update
3157 cvsq()    { cvs -nq update }
3158 #f5# Rcs2log
3159 cvsr()    { rcs2log $* | $PAGER }
3160 #f5# Cvs status
3161 cvss()    { cvs status -v $* }
3162 #f5# Disassemble source files using gcc and as
3163 disassemble(){ gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null }
3164 #f5# Firefox remote control - open given URL
3165 fir()     { firefox -a firefox -remote "openURL($1)" }
3166 #f5# Create Directoy and \kbd{cd} to it
3167 mcd()     { mkdir -p "$@"; cd "$@" } # mkdir && cd
3168 #f5# Unified diff to timestamped outputfile
3169 mdiff()   { diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1" }
3170 #f5# Memory overview
3171 memusage(){ ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc }
3172 #f5# Show contents of tar file
3173 shtar()   { gunzip -c $1 | tar -tf - -- | $PAGER }
3174 #f5# Show contents of tgz file
3175 shtgz()   { tar -ztf $1 | $PAGER }
3176 #f5# Show contents of zip file
3177 shzip()   { unzip -l $1 | $PAGER }
3178 #f5# Greps signature from file
3179 sig()     { agrep -d '^-- $' "$*" ~/.Signature }
3180 #f5# Unified diff
3181 udiff()   { diff -urd $* | egrep -v "^Only in |^Binary files " }
3182 #f5# (Mis)use \kbd{vim} as \kbd{less}
3183 viless()  { vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}" }
3184
3185 # download video from youtube
3186 ytdl() {
3187     if ! [[ -n "$2" ]] ; then
3188         print "Usage: ydtl http://youtube.com/watch?v=.... outputfile.flv">&2
3189         return 1
3190     else
3191         wget -O${2} "http://youtube.com/get_video?"${${${"$(wget -o/dev/null -O- "${1}" | grep -e watch_fullscreen)"}##*watch_fullscreen\?}%%\&fs=*}
3192     fi
3193 }
3194
3195 # Function Usage: uopen $URL/$file
3196 #f5# Download a file and display it locally
3197 uopen() {
3198     if ! [[ -n "$1" ]] ; then
3199         print "Usage: uopen \$URL/\$file">&2
3200         return 1
3201     else
3202         FILE=$1
3203         MIME=$(curl --head $FILE | grep Content-Type | cut -d ' ' -f 2 | cut -d\; -f 1)
3204         MIME=${MIME%$'\r'}
3205         curl $FILE | see ${MIME}:-
3206     fi
3207 }
3208
3209 # Function Usage: doc packagename
3210 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
3211 doc() { cd /usr/share/doc/$1 && ls }
3212 _doc() { _files -W /usr/share/doc -/ }
3213 check_com compdef && compdef _doc doc
3214
3215 #f5# Make screenshot
3216 sshot() {
3217     [[ ! -d ~/shots  ]] && mkdir ~/shots
3218     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
3219     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
3220 }
3221
3222 # list images only
3223 limg() {
3224     local -a images
3225     images=( *.{jpg,gif,png}(.N) )
3226
3227     if [[ $#images -eq 0 ]] ; then
3228         print "No image files found"
3229     else
3230         ls "$@" "$images[@]"
3231     fi
3232 }
3233
3234 #f5# Create PDF file from source code
3235 makereadable() {
3236     output=$1
3237     shift
3238     a2ps --medium A4dj -E -o $output $*
3239     ps2pdf $output
3240 }
3241
3242 # zsh with perl-regex - use it e.g. via:
3243 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
3244 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
3245 regcheck() {
3246     zmodload -i zsh/pcre
3247     pcre_compile $1 && \
3248     pcre_match $2 && echo "regex matches" || echo "regex does not match"
3249 }
3250
3251 #f5# List files which have been modified within the last {\it n} days
3252 new() { print -l *(m-$1) }
3253
3254 #f5# Grep in history
3255 greph() { history 0 | grep $1 }
3256 # use colors when GNU grep with color-support
3257 #a2# Execute \kbd{grep -{}-color=auto}
3258 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
3259 #a2# Execute \kbd{grep -i -{}-color=auto}
3260 alias GREP='grep -i --color=auto'
3261
3262 # one blank line between each line
3263 if [[ -r ~/.terminfo/m/mostlike ]] ; then
3264     #f5# Watch manpages in a stretched style
3265     man2() { PAGER='dash -c "sed G | /usr/bin/less"' TERM=mostlike /usr/bin/man "$@" ; }
3266 fi
3267
3268 # d():Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
3269 # note: option AUTO_PUSHD has to be set
3270 #f5# Jump between directories
3271 d() {
3272     emulate -L zsh
3273     autoload -U colors
3274     local color=$fg_bold[blue]
3275     integer i=0
3276     dirs -p | while read dir; do
3277         local num="${$(printf "%-4d " $i)/ /.}"
3278         printf " %s  $color%s$reset_color\n" $num $dir
3279         (( i++ ))
3280     done
3281     integer dir=-1
3282     read -r 'dir?Jump to directory: ' || return
3283     (( dir == -1 )) && return
3284     if (( dir < 0 || dir >= i )); then
3285         echo d: no such directory stack entry: $dir
3286         return 1
3287     fi
3288     cd ~$dir
3289 }
3290
3291 # usage example: 'lcheck strcpy'
3292 #f5# Find out which libs define a symbol
3293 lcheck() {
3294     if [[ -n "$1" ]] ; then
3295         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
3296     else
3297         echo "Usage: lcheck <function>" >&2
3298     fi
3299 }
3300
3301 #f5# Clean up directory - remove well known tempfiles
3302 purge() {
3303     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
3304     NBFILES=${#FILES}
3305     if [[ $NBFILES > 0 ]] ; then
3306         print $FILES
3307         local ans
3308         echo -n "Remove these files? [y/n] "
3309         read -q ans
3310         if [[ $ans == "y" ]] ; then
3311             rm ${FILES}
3312             echo ">> $PWD purged, $NBFILES files removed"
3313         else
3314             echo "Ok. .. than not.."
3315         fi
3316     fi
3317 }
3318
3319 # Translate DE<=>EN
3320 # 'translate' looks up fot a word in a file with language-to-language
3321 # translations (field separator should be " : "). A typical wordlist looks
3322 # like at follows:
3323 #  | english-word : german-transmission
3324 # It's also only possible to translate english to german but not reciprocal.
3325 # Use the following oneliner to turn back the sort order:
3326 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3327 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3328 #f5# Translates a word
3329 trans() {
3330     case "$1" in
3331         -[dD]*)
3332             translate -l de-en $2
3333             ;;
3334         -[eE]*)
3335             translate -l en-de $2
3336             ;;
3337         *)
3338             echo "Usage: $0 { -D | -E }"
3339             echo "         -D == German to English"
3340             echo "         -E == English to German"
3341     esac
3342 }
3343
3344 #f5# List all occurrences of programm in current PATH
3345 plap() {
3346     if [[ $# = 0 ]] ; then
3347         echo "Usage:    $0 program"
3348         echo "Example:  $0 zsh"
3349         echo "Lists all occurrences of program in the current PATH."
3350     else
3351         ls -l ${^path}/*$1*(*N)
3352     fi
3353 }
3354
3355 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
3356 #f5# Select items for specific command(s) from history
3357 selhist() {
3358     emulate -L zsh
3359     local TAB=$'\t';
3360     (( $# < 1 )) && {
3361         echo "Usage: $0 command"
3362         return 1
3363     };
3364     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
3365     print -l $cmd | less -F
3366     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
3367     local answer
3368     read answer
3369     print -z "${cmd[$answer]#*$TAB}"
3370 }
3371
3372 # Use vim to convert plaintext to HTML
3373 #f5# Transform files to html with highlighting
3374 2html() { vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null }
3375
3376 # Usage: simple-extract <file>
3377 #f5# Smart archive extractor
3378 simple-extract () {
3379     if [[ -f $1 ]] ; then
3380         case $1 in
3381             *.tar.bz2)  bzip2 -v -d $1      ;;
3382             *.tar.gz)   tar -xvzf $1        ;;
3383             *.rar)      unrar $1            ;;
3384             *.deb)      ar -x $1            ;;
3385             *.bz2)      bzip2 -d $1         ;;
3386             *.lzh)      lha x $1            ;;
3387             *.gz)       gunzip -d $1        ;;
3388             *.tar)      tar -xvf $1         ;;
3389             *.tgz)      gunzip -d $1        ;;
3390             *.tbz2)     tar -jxvf $1        ;;
3391             *.zip)      unzip $1            ;;
3392             *.Z)        uncompress $1       ;;
3393             *)          echo "'$1' Error. Please go away" ;;
3394         esac
3395     else
3396         echo "'$1' is not a valid file"
3397     fi
3398 }
3399
3400 # Usage: smartcompress <file> (<type>)
3401 #f5# Smart archive creator
3402 smartcompress() {
3403     if [[ -n $2 ]] ; then
3404         case $2 in
3405             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
3406             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
3407             tar.Z)          tar -Zcvf$1.$2 $1 ;;
3408             tar)            tar -cvf$1.$2  $1 ;;
3409             gz | gzip)      gzip           $1 ;;
3410             bz2 | bzip2)    bzip2          $1 ;;
3411             *)
3412                 echo "Error: $2 is not a valid compression type"
3413                 ;;
3414         esac
3415     else
3416         smartcompress $1 tar.gz
3417     fi
3418 }
3419
3420 # Usage: show-archive <archive>
3421 #f5# List an archive's content
3422 show-archive() {
3423     if [[ -f $1 ]] ; then
3424         case $1 in
3425             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
3426             *.tar)         tar -tf $1 ;;
3427             *.tgz)         tar -ztf $1 ;;
3428             *.zip)         unzip -l $1 ;;
3429             *.bz2)         bzless $1 ;;
3430             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
3431             *)             echo "'$1' Error. Please go away" ;;
3432         esac
3433     else
3434         echo "'$1' is not a valid archive"
3435     fi
3436 }
3437
3438 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
3439 #f5# Use \kbd{vim} as your manpage reader
3440 vman() { man $* | col -b | view -c 'set ft=man nomod nolist' - }
3441
3442 # function readme() { $PAGER -- (#ia3)readme* }
3443 #f5# View all README-like files in current directory in pager
3444 readme() {
3445     local files
3446     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
3447     if (($#files)) ; then
3448         $PAGER $files
3449     else
3450         print 'No README files.'
3451     fi
3452 }
3453
3454 # function ansi-colors()
3455 #f5# Display ANSI colors
3456 ansi-colors() {
3457     typeset esc="\033[" line1 line2
3458     echo " _ _ _40 _ _ _41_ _ _ _42 _ _ 43_ _ _ 44_ _ _45 _ _ _ 46_ _ _ 47_ _ _ 49_ _"
3459     for fore in 30 31 32 33 34 35 36 37; do
3460         line1="$fore "
3461         line2="   "
3462         for back in 40 41 42 43 44 45 46 47 49; do
3463             line1="${line1}${esc}${back};${fore}m Normal ${esc}0m"
3464             line2="${line2}${esc}${back};${fore};1m Bold   ${esc}0m"
3465         done
3466         echo -e "$line1\n$line2"
3467     done
3468 }
3469
3470 # suidfind() { ls -latg $path | grep '^...s' }
3471 #f5# Find all files in \$PATH with setuid bit set
3472 suidfind() { ls -latg $path/*(sN) }
3473
3474 # See above but this is /better/ ... anywise ..
3475 findsuid() {
3476     print 'Output will be written to ~/suid_* ...'
3477     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
3478     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
3479     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
3480     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
3481     print 'Finished'
3482 }
3483
3484 #f5# Reload given functions
3485 refunc() {
3486     for func in $argv ; do
3487         unfunction $func
3488         autoload $func
3489     done
3490 }
3491
3492 # a small check to see which DIR is located on which server/partition.
3493 # stolen and modified from Sven's zshrc.forall
3494 #f5# Report diskusage of a directory
3495 dirspace() {
3496     if [[ -n "$1" ]] ; then
3497         for dir in $* ; do
3498             if [[ -d "$dir" ]] ; then
3499                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3500             else
3501                 echo "warning: $dir does not exist" >&2
3502             fi
3503         done
3504     else
3505         for dir in $path; do
3506             if [[ -d "$dir" ]] ; then
3507                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3508             else
3509                 echo "warning: $dir does not exist" >&2
3510             fi
3511         done
3512     fi
3513 }
3514
3515 # % slow_print `cat /etc/passwd`
3516 #f5# Slowly print out parameters
3517 slow_print() {
3518     for argument in "${@}" ; do
3519         for ((i = 1; i <= ${#1} ;i++)) ; do
3520             print -n "${argument[i]}"
3521             sleep 0.08
3522         done
3523         print -n " "
3524     done
3525     print ""
3526 }
3527
3528 #f5# Show some status info
3529 status() {
3530     print ""
3531     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
3532     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
3533     print "Term..: $TTY ($TERM), ${BAUD:+$BAUD bauds, }$COLUMNS x $LINES cars"
3534     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
3535     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
3536     print "Uptime:$(uptime)"
3537     print ""
3538 }
3539
3540 # Rip an audio CD
3541 #f5# Rip an audio CD
3542 audiorip() {
3543     mkdir -p ~/ripps
3544     cd ~/ripps
3545     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
3546     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
3547     echo " * Would you like to burn the cd now? (yes/no)"
3548     read input
3549     if [[ "$input" = "yes" ]] ; then
3550         echo " ! Burning Audio CD"
3551         audioburn
3552         echo " * done."
3553     else
3554         echo " ! Invalid response."
3555     fi
3556 }
3557
3558 # and burn it
3559 #f5# Burn an audio CD (in combination with audiorip)
3560 audioburn() {
3561     cd ~/ripps
3562     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
3563     echo " * Should I remove the temporary files? (yes/no)"
3564     read input
3565     if [[ "$input" = "yes" ]] ; then
3566         echo " ! Removing Temporary Files."
3567         cd ~
3568         rm -rf ~/ripps
3569         echo " * done."
3570     else
3571         echo " ! Invalid response."
3572     fi
3573 }
3574
3575 #f5# Make an audio CD from all mp3 files
3576 mkaudiocd() {
3577     # TODO: do the renaming more zshish, possibly with zmv()
3578     cd ~/ripps
3579     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
3580     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
3581     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
3582     normalize -m *.wav
3583     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
3584 }
3585
3586 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
3587 mkiso() {
3588     echo " * Volume name "
3589     read volume
3590     echo " * ISO Name (ie. tmp.iso)"
3591     read iso
3592     echo " * Directory or File"
3593     read files
3594     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
3595 }
3596
3597 #f5# Simple thumbnails generator
3598 genthumbs() {
3599     rm -rf thumb-* index.html
3600     echo "
3601 <html>
3602   <head>
3603     <title>Images</title>
3604   </head>
3605   <body>" > index.html
3606     for f in *.(gif|jpeg|jpg|png) ; do
3607         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
3608         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
3609     done
3610     echo "
3611   </body>
3612 </html>" >> index.html
3613 }
3614
3615 #f5# Set all ulimit parameters to \kbd{unlimited}
3616 allulimit() {
3617     ulimit -c unlimited
3618     ulimit -d unlimited
3619     ulimit -f unlimited
3620     ulimit -l unlimited
3621     ulimit -n unlimited
3622     ulimit -s unlimited
3623     ulimit -t unlimited
3624 }
3625
3626 # ogg2mp3 with bitrate of 192
3627 ogg2mp3_192() {
3628     oggdec -o - ${1} | lame -b 192 - ${1:r}.mp3
3629 }
3630
3631 #f5# RFC 2396 URL encoding in Z-Shell
3632 urlencode() {
3633     setopt localoptions extendedglob
3634     input=( ${(s::)1} )
3635     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%${(l:2::0:)$(([##16]#match))}}
3636 }
3637
3638 #f5# Install x-lite (VoIP software)
3639 getxlite() {
3640     setopt local_options
3641     setopt errreturn
3642     [[ -d ~/tmp ]] || mkdir ~/tmp
3643     cd ~/tmp
3644
3645     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
3646     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
3647         unp X-Lite_Install.tar.gz && echo done || echo failed
3648     else
3649         echo "Error while downloading." ; return 1
3650     fi
3651
3652     if [[ -x xten-xlite/xtensoftphone ]] ; then
3653         echo "Execute xten-xlite/xtensoftphone to start xlite."
3654     fi
3655 }
3656
3657 #f5# Install skype
3658 getskype() {
3659     setopt local_options
3660     setopt errreturn
3661     echo "Downloading debian package of skype."
3662     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
3663     wget http://www.skype.com/go/getskype-linux-deb
3664     $SUDO dpkg -i skype*.deb && echo "skype installed."
3665 }
3666
3667 #f5# Install beta-version of skype
3668 getskypebeta() {
3669     setopt local_options
3670     setopt errreturn
3671     echo "Downloading debian package of skype (beta version)."
3672     wget http://www.skype.com/go/getskype-linux-beta-deb
3673     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
3674 }
3675
3676 #f5# Install gizmo (VoIP software)
3677 getgizmo() {
3678     setopt local_options
3679     setopt errreturn
3680     echo "libgtk2.0-0, gconf2, libstdc++6, libasound2 and zlib1g have to be available. Installing."
3681     $SUDO apt-get update
3682     $SUDO apt-get install libgtk2.0-0 gconf2 libstdc++6 libasound2 zlib1g
3683     wget "$(lynx --dump http://gizmo5.com/pc/download/linux/ | awk '/libstdc\+\+6.*\.deb/ {print $2}')"
3684     $SUDO dpkg -i gizmo-project*.deb && echo "gizmo installed."
3685 }
3686
3687 #f5# Get and run AIR (Automated Image and Restore)
3688 getair() {
3689     setopt local_options
3690     setopt errreturn
3691     [[ -w . ]] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
3692     local VER='1.2.8'
3693     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
3694     tar zxf air-$VER.tar.gz
3695     cd air-$VER
3696     INTERACTIVE=no $SUDO ./install-air-1.2.8
3697     [[ -x /usr/local/bin/air ]] && [[ -n "$DISPLAY" ]] && $SUDO air
3698 }
3699
3700 #f5# Get specific git commitdiff
3701 git-get-diff() {
3702     if [[ -z $GITTREE ]] ; then
3703         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3704     fi
3705     if ! [[ -z $1 ]] ; then
3706         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
3707     else
3708         echo "Usage: git-get-diff <commit>"
3709     fi
3710 }
3711
3712 #f5# Get specific git commit
3713 git-get-commit() {
3714     if [[ -z $GITTREE ]] ; then
3715         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3716     fi
3717     if ! [[ -z $1 ]] ; then
3718         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
3719     else
3720         echo "Usage: git-get-commit <commit>"
3721     fi
3722 }
3723
3724 #f5# Get specific git diff
3725 git-get-plaindiff () {
3726     if [[ -z $GITTREE ]] ; then
3727        GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3728     fi
3729     if [[ -z $1 ]] ; then
3730        echo 'Usage: git-get-plaindiff '
3731     else
3732        echo -n "Downloading $1.diff ... "
3733        # avoid "generating ..." stuff from kernel.org server:
3734        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O /dev/null
3735        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff \
3736             && echo done || echo failed
3737     fi
3738 }
3739
3740
3741 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
3742 #f5# Log 'make install' output
3743 mmake() {
3744     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
3745     make -n install > ~/.errorlogs/${PWD##*/}-makelog
3746 }
3747
3748 #f5# Indent source code
3749 smart-indent() {
3750     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs $*
3751 }
3752
3753 # highlight important stuff in diff output, usage example: hg diff | hidiff
3754 #m# a2 hidiff \kbd{histring} oneliner for diffs
3755 check_com -c histring && \
3756     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
3757
3758 # rename pictures based on information found in exif headers
3759 #f5# Rename pictures based on information found in exif headers
3760 exirename() {
3761     if [[ $# -lt 1 ]] ; then
3762         echo 'Usage: jpgrename $FILES' >& 2
3763         return 1
3764     else
3765         echo -n 'Checking for jhead with version newer than 1.9: '
3766         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
3767         if [[ $jhead_version > '1.9' ]]; then
3768             echo 'success - now running jhead.'
3769             jhead -n%Y-%m-%d_%Hh%M_%f $*
3770         else
3771             echo 'failed - exiting.'
3772         fi
3773     fi
3774 }
3775
3776 # open file in vim and jump to line
3777 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
3778 j2v() {
3779     local -a params
3780     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
3781     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
3782     vim ${params}
3783 }
3784
3785 # get_ic() - queries imap servers for capabilities; real simple. no imaps
3786 ic_get() {
3787     local port
3788     if [[ ! -z $1 ]] ; then
3789         port=${2:-143}
3790         print "querying imap server on $1:${port}...\n";
3791         print "a1 capability\na2 logout\n" | nc $1 ${port}
3792     else
3793         print "usage:\n  $0 <imap-server> [port]"
3794     fi
3795 }
3796
3797 # creates a Maildir/ with its {new,cur,tmp} subdirs
3798 mkmaildir() {
3799     local root subdir
3800     root=${MAILDIR_ROOT:-${HOME}/Mail}
3801     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
3802     subdir=${1}
3803     mkdir -p ${root}/${subdir}/{cur,new,tmp}
3804 }
3805
3806 #f5# Change the xterm title from within GNU-screen
3807 xtrename() {
3808     if [[ ${1} != "-f" ]] ; then
3809         if [[ -z ${DISPLAY} ]] ; then
3810             printf 'xtrename only makes sense in X11.\n'
3811             return 1
3812         fi
3813     else
3814         shift
3815     fi
3816     if [[ -z ${1} ]] ; then
3817         printf 'usage: xtrename [-f] "title for xterm"\n'
3818         printf '  renames the title of xterm from _within_ screen.\n'
3819         printf '  also works without screen.\n'
3820         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3821         return 0
3822     fi
3823     print -n "\eP\e]0;${1}\C-G\e\\"
3824     return 0
3825 }
3826
3827 # hl() highlighted less
3828 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
3829 if check_com -c highlight ; then
3830     function hl() {
3831         local theme lang
3832         theme=${HL_THEME:-""}
3833         case ${1} in
3834             (-l|--list)
3835                 ( printf 'available languages (syntax parameter):\n\n' ;
3836                     highlight --list-langs ; ) | less -SMr
3837                 ;;
3838             (-t|--themes)
3839                 ( printf 'available themes (style parameter):\n\n' ;
3840                     highlight --list-themes ; ) | less -SMr
3841                 ;;
3842             (-h|--help)
3843                 printf 'usage: hl <syntax[:theme]> <file>\n'
3844                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
3845                 printf '  Example: hl c main.c\n'
3846                 ;;
3847             (*)
3848                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
3849                     printf 'usage: hl <syntax[:theme]> <file>\n'
3850                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
3851                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
3852                     return 1
3853                 fi
3854                 lang=${1%:*}
3855                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
3856                 if [[ -n ${theme} ]] ; then
3857                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
3858                 else
3859                     highlight --ansi --syntax ${lang} ${2} | less -SMr
3860                 fi
3861                 ;;
3862         esac
3863         return 0
3864     }
3865     # ... and a proper completion for hl()
3866     # needs 'highlight' as well, so it fits fine in here.
3867     function _hl_genarg()  {
3868         local expl
3869         if [[ -prefix 1 *: ]] ; then
3870             local themes
3871             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
3872             compset -P 1 '*:'
3873             _wanted -C list themes expl theme compadd ${themes}
3874         else
3875             local langs
3876             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
3877             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
3878         fi
3879     }
3880     function _hl_complete() {
3881         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
3882     }
3883     compdef _hl_complete hl
3884 fi
3885
3886 # Create small urls via http://tinyurl.com using wget(1).
3887 function zurl() {
3888     [[ -z ${1} ]] && { print "USAGE: zurl <URL>" ; return 1 }
3889
3890     local PN url tiny grabber search result preview
3891     PN=${0}
3892     url=${1}
3893 #   Check existence of given URL with the help of ping(1).
3894 #   N.B. ping(1) only works without an eventual given protocol.
3895     ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
3896         read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
3897
3898     if (( $? == 0 )) ; then
3899 #           Prepend 'http://' to given URL where necessary for later output.
3900             [[ ${url} != http(s|)://* ]] && url='http://'${url}
3901             tiny='http://tinyurl.com/create.php?url='
3902             if check_com -c wget ; then
3903                 grabber='wget -O- -o/dev/null'
3904             else
3905                 print "wget is not available, but mandatory for ${PN}. Aborting."
3906             fi
3907 #           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
3908             search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
3909             result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
3910 #           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
3911             preview='http://preview.'${result#http://}
3912
3913             printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
3914             printf '%s\t%s\n\n' 'Given URL:' ${url}
3915             printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
3916     else
3917         return 1
3918     fi
3919 }
3920
3921 #f2# Print a specific line of file(s).
3922 linenr () {
3923 # {{{
3924     if [ $# -lt 2 ] ; then
3925        print "Usage: linenr <number>[,<number>] <file>" ; return 1
3926     elif [ $# -eq 2 ] ; then
3927          local number=$1
3928          local file=$2
3929          command ed -s $file <<< "${number}n"
3930     else
3931          local number=$1
3932          shift
3933          for file in "$@" ; do
3934              if [ ! -d $file ] ; then
3935                 echo "${file}:"
3936                 command ed -s $file <<< "${number}n" 2> /dev/null
3937              else
3938                 continue
3939              fi
3940          done | less
3941     fi
3942 # }}}
3943 }
3944
3945 #f2# Find history events by search pattern and list them by date.
3946 whatwhen()  {
3947 # {{{
3948     local usage help ident format_l format_s first_char remain first last
3949     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3950     help='Use' \`'whatwhen -h'\'' for further explanations.'
3951     ident=${(l,${#${:-Usage: }},, ,)}
3952     format_l="${ident}%s\t\t\t%s\n"
3953     format_s="${format_l//(\\t)##/\\t}"
3954     # Make the first char of the word to search for case
3955     # insensitive; e.g. [aA]
3956     first_char=[${(L)1[1]}${(U)1[1]}]
3957     remain=${1[2,-1]}
3958     # Default search range is `-100'.
3959     first=${2:-\-100}
3960     # Optional, just used for `<first> <last>' given.
3961     last=$3
3962     case $1 in
3963         ("")
3964             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3965             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3966         ;;
3967         (-h)
3968             printf '%s\n\n' ${usage}
3969             print 'OPTIONS:'
3970             printf $format_l '-h' 'show help text'
3971             print '\f'
3972             print 'SEARCH RANGE:'
3973             printf $format_l "'0'" 'the whole history,'
3974             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3975             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3976             printf '\n%s\n' 'EXAMPLES:'
3977             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3978             printf $format_l 'whatwhen zsh -250'
3979             printf $format_l 'whatwhen foo 1 99'
3980         ;;
3981         (\?)
3982             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3983         ;;
3984         (*)
3985             # -l list results on stout rather than invoking $EDITOR.
3986             # -i Print dates as in YYYY-MM-DD.
3987             # -m Search for a - quoted - pattern within the history.
3988             fc -li -m "*${first_char}${remain}*" $first $last
3989         ;;
3990     esac
3991 # }}}
3992 }
3993
3994 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
3995 fluxkey-change() {
3996     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
3997     if ! [[ -r "$FLUXKEYS" ]] ; then
3998         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
3999         return 1
4000     else
4001         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
4002             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
4003             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
4004         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
4005             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
4006             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
4007         else
4008             echo 'Sorry, do not know what to do.'
4009             return 1
4010         fi
4011     fi
4012 }
4013
4014 # retrieve weather information on the console
4015 # Usage example: 'weather LOWG'
4016 weather() {
4017     [[ -n "$1" ]] || {
4018         print 'Usage: weather <station_id>' >&2
4019         print 'List of stations: http://en.wikipedia.org/wiki/List_of_airports_by_ICAO_code'>&2
4020         return 1
4021     }
4022
4023     local PLACE="${1:u}"
4024     local FILE="$HOME/.weather/$PLACE"
4025     local LOG="$HOME/.weather/log"
4026
4027     [[ -d $HOME/.weather ]] || {
4028         print -n "Creating $HOME/.weather: "
4029         mkdir $HOME/.weather
4030         print 'done'
4031     }
4032
4033     print "Retrieving information for ${PLACE}:"
4034     print
4035     wget -T 10 --no-verbose --output-file=$LOG --output-document=$FILE --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
4036
4037     if [[ $? -eq 0 ]] ; then
4038         if [[ -n "$VERBOSE" ]] ; then
4039             cat $FILE
4040         else
4041             DATE=$(grep 'UTC' $FILE | sed 's#.* /##')
4042             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' $FILE| tr -d '(')
4043             echo "date: $DATE"
4044             echo "temp:  $TEMPERATURE"
4045         fi
4046     else
4047         print "There was an error retrieving the weather information for $PLACE" >&2
4048         cat $LOG
4049         return 1
4050     fi
4051 }
4052 # }}}
4053
4054 # mercurial related stuff {{{
4055 if check_com -c hg ; then
4056     # gnu like diff for mercurial
4057     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
4058     #f5# GNU like diff for mercurial
4059     hgdi() {
4060         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
4061     }
4062
4063     # build debian package
4064     #a2# Alias for \kbd{hg-buildpackage}
4065     alias hbp='hg-buildpackage'
4066
4067     # execute commands on the versioned patch-queue from the current repos
4068     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
4069
4070     # diffstat for specific version of a mercurial repository
4071     #   hgstat      => display diffstat between last revision and tip
4072     #   hgstat 1234 => display diffstat between revision 1234 and tip
4073     #f5# Diffstat for specific version of a mercurial repos
4074     hgstat() {
4075         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
4076     }
4077
4078     #f5# Get current mercurial tip via hg itself
4079     gethgclone() {
4080         setopt local_options
4081         setopt errreturn
4082         if [[ -f mercurial-tree/.hg ]] ; then
4083             cd mercurial-tree
4084             echo "Running hg pull for retreiving latest version..."
4085             hg pull
4086             echo "Finished update. Building mercurial"
4087             make local
4088             echo "Setting \$PATH to $PWD:\$PATH..."
4089             export PATH="$PWD:$PATH"
4090         else
4091             echo "Downloading mercurial via hg"
4092             hg clone http://selenic.com/repo/hg mercurial-tree
4093             cd mercurial-tree
4094             echo "Building mercurial"
4095             make local
4096             echo "Setting \$PATH to $PWD:\$PATH..."
4097             export PATH="$PWD:$PATH"
4098             echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4099             # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
4100             # export PYTHONPATH=${HOME}/lib/python
4101         fi
4102     }
4103
4104 fi # end of check whether we have the 'hg'-executable
4105
4106 # get current mercurial snapshot
4107 #f5# Get current mercurial snapshot
4108 gethgsnap() {
4109     setopt local_options
4110     setopt errreturn
4111     if [[ -f mercurial-snapshot.tar.gz ]] ; then
4112          echo "mercurial-snapshot.tar.gz exists already, skipping download."
4113     else
4114         echo "Downloading mercurial snapshot"
4115         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
4116     fi
4117     echo "Unpacking mercurial-snapshot.tar.gz"
4118     tar zxf mercurial-snapshot.tar.gz
4119     cd mercurial-snapshot/
4120     echo "Installing required build-dependencies"
4121     $SUDO apt-get update
4122     $SUDO apt-get install python2.4-dev
4123     echo "Building mercurial"
4124     make local
4125     echo "Setting \$PATH to $PWD:\$PATH..."
4126     export PATH="$PWD:$PATH"
4127     echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4128 }
4129 # }}}
4130
4131 # some useful commands often hard to remember - let's grep for them {{{
4132 # actually use our zg() function now. :)
4133
4134 # Work around ion/xterm resize bug.
4135 #if [[ "$SHLVL" -eq 1 ]]; then
4136 #       if check_com -c resize ; then
4137 #               eval `resize </dev/null`
4138 #       fi
4139 #fi
4140
4141 # enable jackd:
4142 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
4143 # now play audio file:
4144 #  alsaplayer -o jack foobar.mp3
4145
4146 # send files via netcat
4147 # on sending side:
4148 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
4149 #  send dir* $HOST
4150 #  alias receive='nc -vlp 51330 | tar xzvp'
4151
4152 # debian stuff:
4153 # dh_make -e foo@localhost -f $1
4154 # dpkg-buildpackage -rfakeroot
4155 # lintian *.deb
4156 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
4157 # dpkg-scansources . | gzip > Sources.gz
4158 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
4159
4160 # other stuff:
4161 # convert -geometry 200x200 -interlace LINE -verbose
4162 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
4163 # ps -ao user,pcpu,start,command
4164 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
4165 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
4166 # nc -vz $1 1-1024   # portscan via netcat
4167 # wget --mirror --no-parent --convert-links
4168 # pal -d `date +%d`
4169 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
4170 #
4171 # modify console cursor
4172 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
4173 # print $'\e[?96;0;64c'
4174 # }}}
4175
4176 # grml-small cleanups {{{
4177
4178 # The following is used to remove zsh-config-items that do not work
4179 # in grml-small by default.
4180 # If you do not want these adjustments (for whatever reason), set
4181 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
4182 # sources if it is there).
4183
4184 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
4185
4186     unset abk[V]
4187     unalias    'V'      &> /dev/null
4188     unfunction vman     &> /dev/null
4189     unfunction vimpm    &> /dev/null
4190     unfunction vimhelp  &> /dev/null
4191     unfunction viless   &> /dev/null
4192     unfunction 2html    &> /dev/null
4193
4194     # manpages are not in grmlsmall
4195     unfunction manzsh   &> /dev/null
4196     unalias    man2     &> /dev/null
4197     unalias    man      &> /dev/null
4198     unfunction man2     &> /dev/null
4199
4200 fi
4201
4202 #}}}
4203
4204 # finally source a local zshrc {{{
4205
4206 # this allows us to stay in sync with grml's zshrc and put own
4207 # modifications in ~/.zshrc.local
4208
4209 xsource "${HOME}/.zshrc.local"
4210
4211 # }}}
4212
4213 ## genrefcard.pl settings {{{
4214
4215 ### doc strings for external functions from files
4216 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
4217
4218 ### example: split functions-search 8,16,24,32
4219 #@# split functions-search 8
4220
4221 ## }}}
4222
4223 ## END OF FILE #################################################################
4224 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4