etc/zsh/zshrc

   1 # Filename:      zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 # Latest change: Wed Aug 06 23:50:53 CEST 2008 [mika]
   7 ################################################################################
   8 # This file is sourced only for interactive shells. It
   9 # should contain commands to set up aliases, functions,
  10 # options, key bindings, etc.
  11 #
  12 # Global Order: zshenv, zprofile, zshrc, zlogin
  13 ################################################################################
  14
  15 # zsh-refcard-tag documentation: {{{
  16 #   You may notice strange looking comments in the zshrc (and ~/.zshrc as
  17 #   well). These are there for a purpose. grml's zsh-refcard can now be
  18 #   automatically generated from the contents of the actual configuration
  19 #   files. However, we need a little extra information on which comments
  20 #   and what lines of code to take into account (and for what purpose).
  21 #
  22 # Here is what they mean:
  23 #
  24 # List of tags (comment types) used:
  25 #   #a#     Next line contains an important alias, that should
  26 #           be included in the grml-zsh-refcard.
  27 #           (placement tag: @@INSERT-aliases@@)
  28 #   #f#     Next line contains the beginning of an important function.
  29 #           (placement tag: @@INSERT-functions@@)
  30 #   #v#     Next line contains an important variable.
  31 #           (placement tag: @@INSERT-variables@@)
  32 #   #k#     Next line contains an important keybinding.
  33 #           (placement tag: @@INSERT-keybindings@@)
  34 #   #d#     Hashed directories list generation:
  35 #               start   denotes the start of a list of 'hash -d'
  36 #                       definitions.
  37 #               end     denotes its end.
  38 #           (placement tag: @@INSERT-hasheddirs@@)
  39 #   #A#     Abbreviation expansion list generation:
  40 #               start   denotes the beginning of abbreviations.
  41 #               end     denotes their end.
  42 #           Lines within this section that end in '#d .*' provide
  43 #           extra documentation to be included in the refcard.
  44 #           (placement tag: @@INSERT-abbrev@@)
  45 #   #m#     This tag allows you to manually generate refcard entries
  46 #           for code lines that are hard/impossible to parse.
  47 #               Example:
  48 #                   #m# k ESC-h Call the run-help function
  49 #               That would add a refcard entry in the keybindings table
  50 #               for 'ESC-h' with the given comment.
  51 #           So the syntax is: #m# <section> <argument> <comment>
  52 #   #o#     This tag lets you insert entries to the 'other' hash.
  53 #           Generally, this should not be used. It is there for
  54 #           things that cannot be done easily in another way.
  55 #           (placement tag: @@INSERT-other-foobar@@)
  56 #
  57 #   All of these tags (except for m and o) take two arguments, the first
  58 #   within the tag, the other after the tag:
  59 #
  60 #   #<tag><section># <comment>
  61 #
  62 #   Where <section> is really just a number, which are defined by the
  63 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  64 #   instead of names is, that for the reader, the tag should not differ
  65 #   much from a regular comment. For zsh, it is a regular comment indeed.
  66 #   The numbers have got the following meanings:
  67 #         0 -> "default"
  68 #         1 -> "system"
  69 #         2 -> "user"
  70 #         3 -> "debian"
  71 #         4 -> "search"
  72 #         5 -> "shortcuts"
  73 #         6 -> "services"
  74 #
  75 #   So, the following will add an entry to the 'functions' table in the
  76 #   'system' section, with a (hopefully) descriptive comment:
  77 #       #f1# Edit an alias via zle
  78 #       edalias() {
  79 #
  80 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  81 #   that can be found in 'grml-zsh-refcard.tex.in'.
  82 #   If the section number is omitted, the 'default' section is assumed.
  83 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  84 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  85 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  86 #}}}
  87
  88 # zsh profiling {{{
  89 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  90 if [[ -n $ZSH_PROFILE_RC ]] ; then
  91     zmodload zsh/zprof
  92 fi
  93 # }}}
  94
  95 # {{{ check for version/system
  96 # check for versions (compatibility reasons)
  97 is4(){
  98     [[ $ZSH_VERSION == <4->* ]] && return 0
  99     return 1
 100 }
 101
 102 is41(){
 103     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 104     return 1
 105 }
 106
 107 is42(){
 108     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 109     return 1
 110 }
 111
 112 is43(){
 113     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 114     return 1
 115 }
 116
 117 #f1# Checks whether or not you're running grml
 118 isgrml(){
 119     [[ -f /etc/grml_version ]] && return 0
 120     return 1
 121 }
 122
 123 #f1# Checks whether or not you're running a grml cd
 124 isgrmlcd(){
 125     [[ -f /etc/grml_cd ]] && return 0
 126     return 1
 127 }
 128
 129 if isgrml ; then
 130 #f1# Checks whether or not you're running grml-small
 131     isgrmlsmall() {
 132         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 133     }
 134 else
 135     isgrmlsmall() { return 1 }
 136 fi
 137
 138 #f1# are we running within an utf environment?
 139 isutfenv() {
 140     case "$LANG $CHARSET $LANGUAGE" in
 141         *utf*) return 0 ;;
 142         *UTF*) return 0 ;;
 143         *)     return 1 ;;
 144     esac
 145 }
 146
 147 # check for user, if not running as root set $SUDO to sudo
 148 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 149
 150 # change directory to home on first invocation of zsh
 151 # important for rungetty -> autologin
 152 # Thanks go to Bart Schaefer!
 153 isgrml && checkhome() {
 154     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 155         export ALREADY_DID_CD_HOME=$HOME
 156         cd
 157     fi
 158 }
 159
 160 # check for zsh v3.1.7+
 161
 162 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 163      || ${ZSH_VERSION} == 3.<2->.<->*    \
 164      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 165
 166     printf '-!-\n'
 167     printf '-!- In this configuration we try to make use of features, that only\n'
 168     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 169     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 170     printf '-!- advanced features in all supported versions.\n'
 171     printf '-!-\n'
 172     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 173     printf '-!-\n'
 174     printf '-!- While this *may* work, it might as well fail.\n'
 175     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 176     printf '-!-\n'
 177     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 178     printf '-!- If it does today, you'\''ve been lucky.\n'
 179     printf '-!-\n'
 180     printf '-!- Ye been warned!\n'
 181     printf '-!-\n'
 182
 183     function zstyle() { : }
 184 fi
 185
 186 # }}}
 187
 188 # utility functions {{{
 189 # this function checks if a command exists and returns either true
 190 # or false. This avoids using 'which' and 'whence', which will
 191 # avoid problems with aliases for which on certain weird systems. :-)
 192 check_com() {
 193     local -i comonly
 194
 195     if [[ ${1} == '-c' ]] ; then
 196         (( comonly = 1 ))
 197         shift
 198     else
 199         (( comonly = 0 ))
 200     fi
 201
 202     if (( ${#argv} != 1 )) ; then
 203         printf 'usage: check_com [-c] <command>\n' >&2
 204         return 1
 205     fi
 206
 207     if (( comonly > 0 )) ; then
 208         [[ -n ${commands[$1]}  ]] && return 0
 209         return 1
 210     fi
 211
 212     if   [[ -n ${commands[$1]}    ]] \
 213       || [[ -n ${functions[$1]}   ]] \
 214       || [[ -n ${aliases[$1]}     ]] \
 215       || [[ -n ${reswords[(r)$1]} ]] ; then
 216
 217         return 0
 218     fi
 219
 220     return 1
 221 }
 222
 223 # creates an alias and precedes the command with
 224 # sudo if $EUID is not zero.
 225 salias() {
 226     local only=0 ; local multi=0
 227     while [[ ${1} == -* ]] ; do
 228         case ${1} in
 229             (-o) only=1 ;;
 230             (-a) multi=1 ;;
 231             (--) shift ; break ;;
 232             (-h)
 233                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 234                 printf '  -h      shows this help text.\n'
 235                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 236                 printf '          be careful using this option.\n'
 237                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 238                 return 0
 239                 ;;
 240             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 241         esac
 242         shift
 243     done
 244
 245     if (( ${#argv} > 1 )) ; then
 246         printf 'Too many arguments %s\n' "${#argv}"
 247         return 1
 248     fi
 249
 250     key="${1%%\=*}" ;  val="${1#*\=}"
 251     if (( EUID == 0 )) && (( only == 0 )); then
 252         alias -- "${key}=${val}"
 253     elif (( EUID > 0 )) ; then
 254         (( multi > 0 )) && val="${val// ; / ; sudo }"
 255         alias -- "${key}=sudo ${val}"
 256     fi
 257
 258     return 0
 259 }
 260
 261 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 262 # usage: uprint foo
 263 #   Where foo is the *name* of the parameter you want printed.
 264 #   Note that foo is no typo; $foo would be wrong here!
 265 if ! is42 ; then
 266     uprint () {
 267         local -a u
 268         local w
 269         local parameter=${1}
 270
 271         if [[ -z ${parameter} ]] ; then
 272             printf 'usage: uprint <parameter>\n'
 273             return 1
 274         fi
 275
 276         for w in ${(P)parameter} ; do
 277             [[ -z ${(M)u:#${w}} ]] && u=( ${u} ${w} )
 278         done
 279
 280         builtin print -l ${u}
 281     }
 282 fi
 283
 284 # Check if we can read given files and source those we can.
 285 xsource() {
 286     if (( ${#argv} < 1 )) ; then
 287         printf 'usage: xsource FILE(s)...\n' >&2
 288         return 1
 289     fi
 290
 291     while (( ${#argv} > 0 )) ; do
 292         [[ -r ${1} ]] && source ${1}
 293         shift
 294     done
 295     return 0
 296 }
 297
 298 # Check if we can read a given file and 'cat(1)' it.
 299 xcat() {
 300     if (( ${#argv} != 1 )) ; then
 301         printf 'usage: xcat FILE\n' >&2
 302         return 1
 303     fi
 304
 305     [[ -r ${1} ]] && cat ${1}
 306     return 0
 307 }
 308
 309 # Remove these functions again, they are of use only in these
 310 # setup files. This should be called at the end of .zshrc.
 311 xunfunction() {
 312     local -a funcs
 313     funcs=(salias xcat xsource xunfunction zrcautoload)
 314
 315     for func in $funcs ; do
 316         [[ -n ${functions[$func]} ]] \
 317             && unfunction $func
 318     done
 319     return 0
 320 }
 321
 322 # autoload wrapper - use this one instead of autoload directly
 323 function zrcautoload() {
 324     setopt local_options extended_glob
 325     local fdir ffile
 326     local -i ffound
 327
 328     ffile=${1}
 329     (( found = 0 ))
 330     for fdir in ${fpath} ; do
 331         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 332     done
 333
 334     (( ffound == 0 )) && return 1
 335     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 336         autoload -U ${ffile} || return 1
 337     else
 338         autoload ${ffile} || return 1
 339     fi
 340     return 0
 341 }
 342
 343 #}}}
 344
 345 # Load is-at-least() for more precise version checks {{{
 346
 347 # Note that this test will *always* fail, if the is-at-least
 348 # function could not be marked for autoloading.
 349 zrcautoload is-at-least || is-at-least() { return 1 }
 350
 351 # }}}
 352
 353 # locale setup {{{
 354 if [[ -z "$LANG" ]] ; then
 355    xsource "/etc/default/locale"
 356 fi
 357
 358 export LANG=${LANG:-en_US.iso885915}
 359 for var in LC_ALL LC_MESSAGES ; do
 360     [[ -n ${(P)var} ]] && export $var
 361 done
 362
 363 xsource "/etc/sysconfig/keyboard"
 364
 365 TZ=$(xcat /etc/timezone)
 366 # }}}
 367
 368 # check for potentially old files in 'completion.d' {{{
 369 setopt extendedglob
 370 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 371 if (( ${#xof} > 0 )) ; then
 372     printf '\n -!- INFORMATION\n\n'
 373     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 374     printf ' -!- /etc/zsh/completion.d/.\n\n'
 375     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 376     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 377     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 378     printf ' -!- named _* to that directory.\n\n'
 379     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 380     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 381     printf ' -!- starting with an underscore are marked for automatic loading\n'
 382     printf ' -!- by default (so that is quite convenient).\n\n'
 383     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 384     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 385     printf ' -!- Delete the files for example via running:\n\n'
 386     printf "      rm ${xof}\n\n"
 387     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 388     printf ' -!- resolve the situation manually.\n\n'
 389     BROKEN_COMPLETION_DIR=1
 390 fi
 391 unset xof
 392 # }}}
 393
 394 # {{{ set some variables
 395 if check_com -c vim ; then
 396 #v#
 397     export EDITOR=${EDITOR:-vim}
 398 else
 399     export EDITOR=${EDITOR:-vi}
 400 fi
 401
 402 #v#
 403 export PAGER=${PAGER:-less}
 404
 405 #v#
 406 export MAIL=${MAIL:-/var/mail/$USER}
 407
 408 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 409 export SHELL='/bin/zsh'
 410
 411 # color setup for ls:
 412 check_com -c dircolors && eval $(dircolors -b)
 413
 414 # set width of man pages to 80 for more convenient reading
 415 # export MANWIDTH=${MANWIDTH:-80}
 416
 417 # Search path for the cd command
 418 #  cdpath=(.. ~)
 419
 420 # completion functions go to /etc/zsh/completion.d
 421 # function files may be put into /etc/zsh/functions.d, from where they
 422 # will be automatically autoloaded.
 423 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 424     print 'Warning: not setting completion directories because broken files have been found.' >&2
 425 else
 426     [[ -d /etc/zsh/completion.d ]] && fpath=( $fpath /etc/zsh/completion.d )
 427     if [[ -d /etc/zsh/functions.d ]] ; then
 428         fpath+=( /etc/zsh/functions.d )
 429         for func in /etc/zsh/functions.d/[^_]*[^~] ; do
 430             zrcautoload -U ${func:t}
 431         done
 432     fi
 433 fi
 434
 435 # automatically remove duplicates from these arrays
 436 typeset -U path cdpath fpath manpath
 437 # }}}
 438
 439 # {{{ keybindings
 440 if [[ "$TERM" != emacs ]] ; then
 441     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 442     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 443     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 444     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 445     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 446     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 447     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 448     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 449     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 450     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 451     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 452     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 453     # ncurses stuff:
 454     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 455     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 456     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 457     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 458     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 459     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 460     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 461     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 462 fi
 463
 464 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 465 # use emacs style per default:
 466 bindkey -e
 467 # use vi style:
 468 # bindkey -v
 469
 470 #if [[ "$TERM" == screen ]] ; then
 471 bindkey '\e[1~' beginning-of-line       # home
 472 bindkey '\e[4~' end-of-line             # end
 473 bindkey '\e[A'  up-line-or-search       # cursor up
 474 bindkey '\e[B'  down-line-or-search     # <ESC>-
 475
 476 bindkey '^xp'   history-beginning-search-backward
 477 bindkey '^xP'   history-beginning-search-forward
 478 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 479 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 480 # if terminal type is set to 'rxvt':
 481 bindkey '\e[7~' beginning-of-line       # home
 482 bindkey '\e[8~' end-of-line             # end
 483 #fi
 484
 485 # insert unicode character
 486 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 487 # See for example http://unicode.org/charts/ for unicode characters code
 488 zrcautoload insert-unicode-char
 489 zle -N insert-unicode-char
 490 #k# Insert Unicode character
 491 bindkey '^Xi' insert-unicode-char
 492
 493 # just type 'cd ...' to get 'cd ../..'
 494 #  rationalise-dot() {
 495 #  if [[ $LBUFFER == *.. ]] ; then
 496 #    LBUFFER+=/..
 497 #  else
 498 #    LBUFFER+=.
 499 #  fi
 500 #  }
 501 #  zle -N rationalise-dot
 502 #  bindkey . rationalise-dot
 503
 504 #  bindkey '\eq' push-line-or-edit
 505
 506 ## toggle the ,. abbreviation feature on/off
 507 # NOABBREVIATION: default abbreviation-state
 508 #                 0 - enabled (default)
 509 #                 1 - disabled
 510 NOABBREVIATION=${NOABBREVIATION:-0}
 511
 512 grml_toggle_abbrev() {
 513     if (( ${NOABBREVIATION} > 0 )) ; then
 514         NOABBREVIATION=0
 515     else
 516         NOABBREVIATION=1
 517     fi
 518 }
 519
 520 zle -N grml_toggle_abbrev
 521 bindkey '^xA' grml_toggle_abbrev
 522
 523 # }}}
 524
 525 # a generic accept-line wrapper {{{
 526
 527 # This widget can prevent unwanted autocorrections from command-name
 528 # to _command-name, rehash automatically on enter and call any number
 529 # of builtin and user-defined widgets in different contexts.
 530 #
 531 # For a broader description, see:
 532 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 533 #
 534 # The code is imported from the file 'zsh/functions/accept-line' from
 535 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 536 # distributed under the same terms as zsh itself.
 537
 538 # A newly added command will may not be found or will cause false
 539 # correction attempts, if you got auto-correction set. By setting the
 540 # following style, we force accept-line() to rehash, if it cannot
 541 # find the first word on the command line in the $command[] hash.
 542 zstyle ':acceptline:*' rehash true
 543
 544 function Accept-Line() {
 545     setopt localoptions noksharrays
 546     local -a subs
 547     local -xi aldone
 548     local sub
 549
 550     zstyle -a ":acceptline:${alcontext}" actions subs
 551
 552     (( ${#subs} < 1 )) && return 0
 553
 554     (( aldone = 0 ))
 555     for sub in ${subs} ; do
 556         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 557         zle ${sub}
 558
 559         (( aldone > 0 )) && break
 560     done
 561 }
 562
 563 function Accept-Line-getdefault() {
 564     local default_action
 565
 566     zstyle -s ":acceptline:${alcontext}" default_action default_action
 567     case ${default_action} in
 568         ((accept-line|))
 569             printf ".accept-line"
 570             ;;
 571         (*)
 572             printf ${default_action}
 573             ;;
 574     esac
 575 }
 576
 577 function accept-line() {
 578     setopt localoptions noksharrays
 579     local -a cmdline
 580     local -x alcontext
 581     local buf com fname format msg default_action
 582
 583     alcontext='default'
 584     buf="${BUFFER}"
 585     cmdline=(${(z)BUFFER})
 586     com="${cmdline[1]}"
 587     fname="_${com}"
 588
 589     zstyle -t ":acceptline:${alcontext}" rehash \
 590         && [[ -z ${commands[$com]} ]]           \
 591         && rehash
 592
 593     if    [[ -n ${reswords[(r)$com]} ]] \
 594        || [[ -n ${aliases[$com]}     ]] \
 595        || [[ -n ${functions[$com]}   ]] \
 596        || [[ -n ${builtins[$com]}    ]] \
 597        || [[ -n ${commands[$com]}    ]] ; then
 598
 599         # there is something sensible to execute, just do it.
 600         alcontext='normal'
 601         zle Accept-Line
 602
 603         default_action=$(Accept-Line-getdefault)
 604         zstyle -T ":acceptline:${alcontext}" call_default \
 605             && zle ${default_action}
 606         return
 607     fi
 608
 609     if    [[ -o correct              ]] \
 610        || [[ -o correctall           ]] \
 611        && [[ -n ${functions[$fname]} ]] ; then
 612
 613         # nothing there to execute but there is a function called
 614         # _command_name; a completion widget. Makes no sense to
 615         # call it on the commandline, but the correct{,all} options
 616         # will ask for it nevertheless, so warn the user.
 617         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 618             # Okay, we warned the user before, he called us again,
 619             # so have it his way.
 620             alcontext='force'
 621             zle Accept-Line
 622
 623             default_action=$(Accept-Line-getdefault)
 624             zstyle -T ":acceptline:${alcontext}" call_default \
 625                 && zle ${default_action}
 626             return
 627         fi
 628
 629         # prepare warning message for the user, configurable via zstyle.
 630         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 631
 632         if [[ -z ${msg} ]] ; then
 633             msg="%c will not execute and completion %f exists."
 634         fi
 635
 636         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 637
 638         zle -M -- "${msg}"
 639         return
 640     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 641         # If we are here, the commandline contains something that is not
 642         # executable, which is neither subject to _command_name correction
 643         # and is not empty. might be a variable assignment
 644         alcontext='misc'
 645         zle Accept-Line
 646
 647         default_action=$(Accept-Line-getdefault)
 648         zstyle -T ":acceptline:${alcontext}" call_default \
 649             && zle ${default_action}
 650         return
 651     fi
 652
 653     # If we got this far, the commandline only contains whitespace, or is empty.
 654     alcontext='empty'
 655     zle Accept-Line
 656
 657     default_action=$(Accept-Line-getdefault)
 658     zstyle -T ":acceptline:${alcontext}" call_default \
 659         && zle ${default_action}
 660 }
 661
 662 zle -N accept-line
 663 zle -N Accept-Line
 664
 665 # }}}
 666
 667 # power completion - abbreviation expansion {{{
 668 # power completion / abbreviation expansion / buffer expansion
 669 # see http://zshwiki.org/home/examples/zleiab for details
 670 # less risky than the global aliases but powerful as well
 671 # just type the abbreviation key and afterwards ',.' to expand it
 672 declare -A abk
 673 setopt extendedglob
 674 setopt interactivecomments
 675 abk=(
 676 # key  # value                (#d additional doc string)
 677 #A# start
 678     '...' '../..'
 679     '....' '../../..'
 680     'BG' '& exit'
 681     'C' '| wc -l'
 682     'G' '|& grep --color=auto'
 683     'H' '| head'
 684     'Hl' ' --help |& less -r'      #d (Display help in pager)
 685     'L' '| less'
 686     'LL' '|& less -r'
 687     'M' '| most'
 688     'N' '&>/dev/null'              #d (No Output)
 689     'R' '| tr A-z N-za-m'          #d (ROT13)
 690     'SL' '| sort | less'
 691     'S' '| sort -u'
 692     'T' '| tail'
 693     'V' '|& vim -'
 694 #A# end
 695     'hide' "echo -en '\033]50;nil2\007'"
 696     'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 697     'small' 'echo -en "\033]50;6x10\007"'
 698     'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 699     'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 700     'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 701     'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 702     'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 703     'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 704     'da' 'du -sch'
 705     'j' 'jobs -l'
 706     'u' 'translate -i'
 707     'co' "./configure && make && sudo make install"
 708     'CH' "./configure --help"
 709     'conkeror' 'firefox -chrome chrome://conkeror/content'
 710     'dir' 'ls -lSrah'
 711     'lad' $'ls -d .*(/)\n# only show dot-directories'
 712     'lsa' $'ls -a .*(.)\n# only show dot-files'
 713     'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
 714     'lsl' $'ls -l *(@[1,10])\n# only symlinks'
 715     'lsx' $'ls -l *(*[1,10])\n# only executables'
 716     'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
 717     'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
 718     'lsd' $'ls -d *(/)\n# only show directories'
 719     'lse' $'ls -d *(/^F)\n# only show empty directories'
 720     'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
 721     'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
 722     'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
 723     'rw-' 'chmod 600'
 724     '600' 'chmod u+rw-x,g-rwx,o-rwx'
 725     'rwx' 'chmod u+rwx'
 726     '700' 'chmod u+rwx,g-rwx,o-rwx'
 727     'r--' 'chmod u+r-wx,g-rwx,o-rwx'
 728     '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
 729     '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
 730     'md' 'mkdir -p '
 731     'cmplayer' 'mplayer -vo -fs -zoom fbdev'
 732     'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
 733     'fblinks' 'links2 -driver fb'
 734     'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 735     'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 736     'fori' 'for i ({..}) { }'
 737     'cx' 'chmod +x'
 738     'e'  'print -l'
 739     'se' 'setopt interactivecomments'
 740     'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
 741     'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
 742     'fb3' '=mplayer -vo fbdev -fs  -zoom 1>/dev/null -xy 3'
 743     'ci' 'centericq'
 744     'D'  'export DISPLAY=:0.0'
 745     'mp' 'mplayer -vo xv -fs -zoom'
 746 )
 747
 748 globalias() {
 749     local MATCH
 750
 751     if (( NOABBREVIATION > 0 )) ; then
 752         LBUFFER="${LBUFFER},."
 753         return 0
 754     fi
 755
 756     matched_chars='[.-|_a-zA-Z0-9]#'
 757     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 758     LBUFFER+=${abk[$MATCH]:-$MATCH}
 759 }
 760
 761 zle -N globalias
 762 bindkey ",." globalias
 763 # }}}
 764
 765 # {{{ autoloading
 766 zrcautoload zmv    # who needs mmv or rename?
 767 zrcautoload history-search-end
 768
 769 # we don't want to quote/espace URLs on our own...
 770 # if autoload -U url-quote-magic ; then
 771 #    zle -N self-insert url-quote-magic
 772 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 773 # else
 774 #    print 'Notice: no url-quote-magic available :('
 775 # fi
 776 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 777
 778 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 779 alias run-help >&/dev/null && unalias run-help
 780 zrcautoload run-help # use via 'esc-h'
 781
 782 # completion system
 783 if zrcautoload compinit && compinit 2>/dev/null ; then
 784     compinit 2>/dev/null || print 'Notice: no compinit available :('
 785 else
 786     print 'Notice: no compinit available :('
 787     function zstyle { }
 788     function compdef { }
 789 fi
 790
 791 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 792
 793 is4 && \
 794 for mod in complist deltochar mathfunc ; do
 795     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 796 done
 797
 798 # autoload zsh modules when they are referenced
 799 if is4 ; then
 800     tmpargs=(
 801         a   stat
 802         a   zpty
 803         ap  zprof
 804         ap  mapfile
 805     )
 806
 807     while (( ${#tmpargs} > 0 )) ; do
 808         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 809         shift 2 tmpargs
 810     done
 811     unset tmpargs
 812 fi
 813
 814 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 815     #k# Insert files
 816     bindkey "^Xf" insert-files # C-x-f
 817 fi
 818
 819 bindkey ' '   magic-space    # also do history expansion on space
 820 #k# Trigger menu-complete
 821 bindkey '\ei' menu-complete  # menu completion via esc-i
 822
 823 # press esc-e for editing command line in $EDITOR or $VISUAL
 824 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 825     #k# Edit the current line in \kbd{\$EDITOR}
 826     bindkey '\ee' edit-command-line
 827 fi
 828
 829 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 830     #k# menu selection: pick item but stay in the menu
 831     bindkey -M menuselect '\e^M' accept-and-menu-complete
 832
 833     # use the vi navigation keys (hjkl) besides cursor keys in menu completion
 834     #bindkey -M menuselect 'h' vi-backward-char        # left
 835     #bindkey -M menuselect 'k' vi-up-line-or-history   # up
 836     #bindkey -M menuselect 'l' vi-forward-char         # right
 837     #bindkey -M menuselect 'j' vi-down-line-or-history # bottom
 838
 839     # accept a completion and try to complete again by using menu
 840     # completion; very useful with completing directories
 841     # by using 'undo' one's got a simple file browser
 842     bindkey -M menuselect '^o' accept-and-infer-next-history
 843 fi
 844
 845 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 846 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 847 zle -N _bkdate
 848
 849 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 850 bindkey '^Ed' _bkdate
 851
 852 # press esc-m for inserting last typed word again (thanks to caphuso!)
 853 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 854 zle -N insert-last-typed-word;
 855
 856 #k# Insert last typed word
 857 bindkey "\em" insert-last-typed-word
 858
 859 # set command prediction from history, see 'man 1 zshcontrib'
 860 #  is4 && zrcautoload predict-on && \
 861 #  zle -N predict-on         && \
 862 #  zle -N predict-off        && \
 863 #  bindkey "^X^Z" predict-on && \
 864 #  bindkey "^Z" predict-off
 865
 866 #k# Shortcut for \kbd{fg<enter>}
 867 bindkey -s '^z' "fg\n"
 868
 869 # press ctrl-q to quote line:
 870 #  mquote () {
 871 #        zle beginning-of-line
 872 #        zle forward-word
 873 #        # RBUFFER="'$RBUFFER'"
 874 #        RBUFFER=${(q)RBUFFER}
 875 #        zle end-of-line
 876 #  }
 877 #  zle -N mquote && bindkey '^q' mquote
 878
 879 # run command line as user root via sudo:
 880 sudo-command-line() {
 881     [[ -z $BUFFER ]] && zle up-history
 882     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 883 }
 884 zle -N sudo-command-line
 885
 886 #k# Put the current command line into a \kbd{sudo} call
 887 bindkey "^Os" sudo-command-line
 888
 889 ### jump behind the first word on the cmdline.
 890 ### useful to add options.
 891 function jump_after_first_word() {
 892     local words
 893     words=(${(z)BUFFER})
 894
 895     if (( ${#words} <= 1 )) ; then
 896         CURSOR=${#BUFFER}
 897     else
 898         CURSOR=${#${words[1]}}
 899     fi
 900 }
 901 zle -N jump_after_first_word
 902
 903 bindkey '^x1' jump_after_first_word
 904
 905 # }}}
 906
 907 # {{{ set some important options
 908 # Please update these tags, if you change the umask settings below.
 909 #o# r_umask     002
 910 #o# r_umaskstr  rwxrwxr-x
 911 #o# umask       022
 912 #o# umaskstr    rwxr-xr-x
 913 (( EUID != 0 )) && umask 002 || umask 022
 914
 915 # history:
 916 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 917 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 918 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 919 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 920                             # list duplicates an older one, the older command is removed from the list
 921 setopt histignorespace      # remove command lines from the history list when
 922                             # the first character on the line is a space
 923 #  setopt histallowclobber    # add `|' to output redirections in the history
 924 #  setopt NO_clobber          # warning if file exists ('cat /dev/null > ~/.zshrc')
 925 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 926                             # and the command is the name of a directory, perform the cd command to that directory
 927 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 928                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 929                             # -> searches for word not in compressed files
 930                             # don't forget to quote '^', '~' and '#'!
 931 setopt longlistjobs         # display PID when suspending processes as well
 932 setopt notify               # report the status of backgrounds jobs immediately
 933 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 934                             # the entire command path is hashed first.
 935 setopt completeinword       # not just at the end
 936 # setopt nocheckjobs          # don't warn me about bg processes when exiting
 937 setopt nohup                # and don't kill them, either
 938 # setopt printexitvalue       # alert me if something failed
 939 # setopt dvorak               # with spelling correction, assume dvorak kb
 940 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 941 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 942 setopt nobeep               # avoid "beep"ing
 943 setopt pushd_ignore_dups    # don't push the same dir twice.
 944
 945 MAILCHECK=30       # mailchecks
 946 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 947 watch=(notme root) # watch for everyone but me and root
 948
 949 # define word separators (for stuff like backward-word, forward-word, backward-kill-word,..)
 950 #  WORDCHARS='*?_-.[]~=/&;!#$%^(){}<>' # the default
 951 #  WORDCHARS=.
 952 #  WORDCHARS='*?_[]~=&;!#$%^(){}'
 953 #  WORDCHARS='${WORDCHARS:s@/@}'
 954
 955 # only slash should be considered as a word separator:
 956 slash-backward-kill-word() {
 957     local WORDCHARS="${WORDCHARS:s@/@}"
 958     # zle backward-word
 959     zle backward-kill-word
 960 }
 961 zle -N slash-backward-kill-word
 962
 963 #k# Kill everything in a word up to its last \kbd{/}
 964 bindkey '\ev' slash-backward-kill-word
 965
 966 # }}}
 967
 968 # {{{ history
 969
 970 ZSHDIR=$HOME/.zsh
 971
 972 #v#
 973 HISTFILE=$HOME/.zsh_history
 974 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
 975 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
 976
 977 # }}}
 978
 979 # dirstack handling {{{
 980
 981 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
 982 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
 983
 984 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
 985     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
 986     # "cd -" won't work after login by just setting $OLDPWD, so
 987     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
 988 fi
 989
 990 chpwd() {
 991     if is42 ; then
 992         builtin print -l ${(u)dirstack} >! ${DIRSTACKFILE}
 993     else
 994         uprint dirstack >! ${DIRSTACKFILE}
 995     fi
 996 }
 997
 998 # }}}
 999
1000 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1001 if [[ -n "$BATTERY" ]] ; then
1002     if check_com -c acpi ; then
1003         PERCENT="${(C)${(s| |)$(acpi 2>/dev/null)}[4]}"
1004         [[ -z "$PERCENT" ]] && PERCENT='acpi not present'
1005
1006         if [[ "${PERCENT%%%}" -lt 20 ]] ; then
1007             PERCENT="warning: ${PERCENT}%"
1008         fi
1009     fi
1010 fi
1011 # }}}
1012
1013 # gather version control information for inclusion in a prompt {{{
1014
1015 # vcs_info() documentation: {{{
1016 #
1017 # The vcs_info () feature can be configured via zstyle:
1018 #   First, the context in which we are working:
1019 #       :vcs_info:<vcs-string>
1020 #   ...where <vcs-string> is one of: git, hg, bzr, svn or svk
1021 #
1022 #   You can of course use ':vcs_info:*' to match all VCSs at once.
1023 #
1024 # There is one special context named 'init', that is in effect as long
1025 # as there was no decision what vcs backend to use.
1026 #
1027 # There are currently two styles, that are looked up:
1028 #   promptformat        - Used in most circumstances.
1029 #   promptactionformat  - Used if a there is a special action going on;
1030 #                         (like an interactive rebase or a merge conflict)
1031 #   enable              - check in the 'init' context. If set to false,
1032 #                         vcs_info() will do nothing.
1033 #
1034 # The default values for these in all contexts are:
1035 #   promptformat        " (%s)-[%b|%a]-"
1036 #   promptactionformat  " (%s)-[%b]-"
1037 #   enable              true
1038 #
1039 # In these formats, the following replacements are done:
1040 #   %s  - The vcs in use (git, hg, svn etc.)
1041 #   %b  - Information about the current branch.
1042 #   %a  - An identifier, that describes the action.
1043 #         Only makes sense in promptactionformat.
1044 #   %R  - base directory of the repository.
1045 #   %r  - repository name
1046 #         If %R is '/foo/bar/repoXY', %r is 'repoXY'.
1047 #
1048 # Not all vcs backends may support all replacements
1049 #
1050 # If you want colors, make sure you enclose the color codes in %{...%}, because
1051 # the string provided by vcs_info() is commonly used for prompts.
1052 #
1053 #   Example: PROMPT='%(?..[%?]-)%3~%$(vcs_info)#'
1054 #
1055 # This *requires* 'setopt prompt_subst'.
1056 # }}}
1057 VCS_INFO_default_action_format=' (%s)-[%b|%a]-'
1058 VCS_INFO_default_format=' (%s)-[%b]-'
1059 VCS_INFO_realpath () { #{{{
1060     # replacing 'readlink -f', which is really not portable.
1061     (( ${+functions[chpwd]} )) && unfunction chpwd
1062     setopt chaselinks
1063     cd $1 2>/dev/null && pwd
1064 }
1065 # }}}
1066 VCS_INFO_git_getaction () { #{{{
1067     local gitaction='' gitdir=${1}
1068     local tmp
1069
1070     for tmp in "${gitdir}/rebase-apply" \
1071                "${gitdir}/rebase"       \
1072                "${gitdir}/../.dotest" ; do
1073         if [[ -d ${tmp} ]] ; then
1074             if   [[ -f "${tmp}/rebasing" ]] ; then
1075                 gitaction="rebase"
1076             elif [[ -f "${tmp}/applying" ]] ; then
1077                 gitaction="am"
1078             else
1079                 gitaction="am/rebase"
1080             fi
1081             print '%s' ${gitaction}
1082             return 0
1083         fi
1084     done
1085
1086     for tmp in "${gitdir}/rebase-merge/interactive" \
1087                "${gitdir}/.dotest-merge/interactive" ; do
1088         if [[ -f "${tmp}" ]] ; then
1089             printf '%s' "rebase-i"
1090             return 0
1091         fi
1092     done
1093
1094     for tmp in "${gitdir}/rebase-merge" \
1095                "${gitdir}/.dotest-merge" ; do
1096         if [[ -d "${tmp}" ]] ; then
1097             printf '%s' "rebase-m"
1098             return 0
1099         fi
1100     done
1101
1102     if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1103         printf '%s' "merge"
1104     else
1105         if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
1106             printf '%s' "bisect"
1107         fi
1108     fi
1109
1110     return 1
1111 }
1112 # }}}
1113 VCS_INFO_git_getbranch () { #{{{
1114     local gitbranch gitdir=${1}
1115     local gitsymref='git symbolic-ref HEAD'
1116
1117     if    [[ -d "${gitdir}/rebase-apply" ]] \
1118        || [[ -d "${gitdir}/rebase" ]]       \
1119        || [[ -d "${gitdir}/../.dotest" ]]   \
1120        || [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1121         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1122
1123     elif   [[ -f "${gitdir}/rebase-merge/interactive" ]] \
1124         || [[ -d "${gitdir}/rebase-merge" ]] ; then
1125         gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
1126
1127     elif   [[ -f "${gitdir}/.dotest-merge/interactive" ]] \
1128         || [[ -d "${gitdir}/.dotest-merge" ]] ; then
1129         gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
1130
1131     else
1132         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1133
1134         if [[ $? -ne 0 ]] ; then
1135             gitbranch="$(git describe --exact-match HEAD 2>/dev/null)"
1136
1137             if [[ $? -ne 0 ]] ; then
1138                 gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
1139             fi
1140         fi
1141     fi
1142
1143     printf '%s' "${gitbranch##refs/heads/}"
1144 }
1145 # }}}
1146 VCS_INFO_git_get_data () { # {{{
1147     setopt localoptions extendedglob
1148     local gitdir gitbase gitbranch gitaction msg
1149
1150     gitdir="$(git rev-parse --git-dir 2> /dev/null)"
1151
1152     if [[ $? -eq 0 ]] ; then
1153         gitbranch="$(VCS_INFO_git_getbranch ${gitdir})"
1154     fi
1155
1156     if [[ -z ${gitdir} ]] || [[ -z ${gitbranch} ]] ; then
1157         return
1158     fi
1159
1160     gitaction="$(VCS_INFO_git_getaction ${gitdir})"
1161     msg=$(VCS_INFO_format ${gitaction})
1162
1163     gitbase=${PWD%/${$(git rev-parse --show-prefix)%/##}}
1164
1165     zformat -f msg "${msg}" "a:${gitaction}" "b:${gitbranch}" "s:${vcs}" "r:${gitbase:t}" "R:${gitbase}"
1166     printf '%s' ${msg}
1167 }
1168 # }}}
1169 VCS_INFO_hg_get_data () { # {{{
1170     local msg hgbranch hgbase
1171
1172     hgbase=${1}
1173     hgbranch=$(< ${hgbase}/.hg/branch)
1174     msg=$(VCS_INFO_format)
1175     zformat -f msg "${msg}" "a:" "b:${hgbranch}" "s:${vcs}" "r:${hgbase:t}" "R:${hgbase}"
1176     printf '%s' ${msg}
1177 }
1178 # }}}
1179 VCS_INFO_svk_get_data () { # {{{
1180     local msg svkbranch svkbase
1181
1182     svkbase=${1}
1183     svkbranch=${svkbase##*
1184   }
1185     svkbase=${svkbase%%
1186   *}
1187
1188     msg=$(VCS_INFO_format)
1189     zformat -f msg "${msg}" "a:" "b:${svkbranch}" "s:${vcs}" "r:${svkbase:t}" "R:${svkbase}"
1190     printf '%s' ${msg}
1191 }
1192 # }}}
1193 VCS_INFO_svn_get_data () { # {{{
1194     local msg svnbranch svnbase
1195
1196     svnbase="."
1197     while [[ -d "${svnbase}/../.svn" ]]; do
1198         svnbase="${svnbase}/.."
1199     done
1200     svnbase=$(VCS_INFO_realpath ${svnbase})
1201     svnbranch=$(svn info "$base_dir" | awk '/^URL/ { sub(".*/","",$0); r=$0 } /^Revision/ { sub("[^0-9]*","",$0); print r":"$0 }')
1202
1203     msg=$(VCS_INFO_format)
1204     zformat -f msg "${msg}" "a:" "b:${svnbranch}" "s:${vcs}" "r:${svnbase:t}" "R:${svnbase}"
1205     printf '%s' ${msg}
1206 }
1207 # }}}
1208 VCS_INFO_bzr_get_data () { # {{{
1209     local msg bzrbranch bzrbase bzrrevno i j
1210
1211     bzrbase=$(bzr info | sed -rne 's, *branch root: ,,p')
1212     case ${bzrbase} in
1213         .) bzrbase=${PWD} ;;
1214     esac
1215
1216     bzr version-info | while read i j; do
1217         case "${i}" in
1218             revno:)
1219                 bzrrevno=${j} ;;
1220             branch-nick:)
1221                 bzrbranch=${j} ;;
1222         esac
1223     done
1224
1225     msg=$(VCS_INFO_format)
1226     zformat -f msg "${msg}" "a:" "b:${bzrbranch}:${bzrrevno}" "s:${vcs}" "r:${bzrbase:t}" "R:${bzrbase}"
1227     printf '%s' ${msg}
1228 }
1229 # }}}
1230 # VCS_INFO_*_detect () {{{
1231
1232 VCS_INFO_bzr_detect() {
1233     check_com -c bzr || return 1
1234     [[ -d ".bzr" ]] && return 0
1235     return 1
1236 }
1237
1238 VCS_INFO_git_detect() {
1239     check_com -c git && git rev-parse --is-inside-work-tree &> /dev/null && return 0
1240     return 1
1241 }
1242
1243 VCS_INFO_hg_detect() {
1244     local basedir="."
1245
1246     check_com -c hg || return 1
1247     while [[ ! -d ${basedir}/.hg ]]; do
1248         basedir=${basedir}/..
1249         [[ $(VCS_INFO_realpath ${basedir}) = "/" ]] && return 1
1250     done
1251
1252     printf '%s' $(VCS_INFO_realpath ${basedir})
1253     return 0
1254 }
1255
1256 VCS_INFO_svk_detect() {
1257     local output
1258
1259     check_com -c svk || return 1
1260     [[ -f ~/.svk/config ]] || return 1
1261
1262     output=$(awk '/: *$/ { sub(/^ */,"",$0); sub(/: *$/,"",$0); if (match("'${PWD}'", $0"(/|$)")) { print $0; d=1; } } /depotpath/ && d == 1 { sub(".*/","",$0); r=$0 } /revision/ && d == 1 { print r ":" $2; exit 1 }' ~/.svk/config) && return 1
1263
1264     printf '%s' ${output}
1265     return 0
1266 }
1267
1268 VCS_INFO_svn_detect() {
1269     check_com -c svn || return 1
1270     [[ -d ".svn" ]] && return 0
1271     return 1
1272 }
1273
1274 # }}}
1275 VCS_INFO_format () { # {{{
1276     local msg
1277
1278     if [[ -n ${1} ]] ; then
1279         zstyle -s ":vcs_info:${vcs}" promptactionformat msg
1280         [[ -z ${msg} ]] && msg=${VCS_INFO_default_action_format}
1281     else
1282         zstyle -s ":vcs_info:${vcs}" promptformat msg
1283         [[ -z ${msg} ]] && msg=${VCS_INFO_default_format}
1284     fi
1285     printf '%s' ${msg}
1286 }
1287 # }}}
1288 vcs_info () { # {{{
1289     local string output
1290     local -i found
1291     local -a VCSs
1292     local -x vcs
1293
1294     vcs="init"
1295     zstyle -T ":vcs_info:${vcs}" "enable" || return 0
1296
1297     VCSs=(git hg bzr svn svk)
1298
1299     (( found = 0 ))
1300     for vcs in ${VCSs} ; do
1301         output=$(VCS_INFO_${vcs}_detect) && (( found = 1 )) && break
1302     done
1303
1304     (( found == 0 )) && return 0
1305
1306     string=$(VCS_INFO_${vcs}_get_data ${output}) || return 1
1307     printf '%s' ${string}
1308     return 0
1309 }
1310 # }}}
1311
1312 # change vcs_info formats for the grml prompt
1313 zstyle ':vcs_info:*' promptactionformat \
1314 "%{${fg[magenta]}%}(%{${reset_color}%}%s%{${fg[magenta]}%})%{${fg[yellow]}%}-%{${fg[magenta]}%}[%{${fg[green]}%}%b%{${fg[yellow]}%}|%{${fg[red]}%}%a%{${fg[magenta]}%}]%{${reset_color}%} "
1315 zstyle ':vcs_info:*' promptformat \
1316 "%{${fg[magenta]}%}(%{${reset_color}%}%s%{${fg[magenta]}%})%{${fg[yellow]}%}-%{${fg[magenta]}%}[%{${fg[green]}%}%b%{${fg[magenta]}%}]%{${reset_color}%} "
1317
1318 # }}}
1319
1320 # {{{ set prompt
1321 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1322     promptinit # people should be able to use their favourite prompt
1323 else
1324     print 'Notice: no promptinit available :('
1325 fi
1326
1327
1328 # precmd() => a function which is executed just before each prompt
1329 # use 'NOPRECMD=1' to disable the precmd + preexec commands
1330
1331 # precmd () { setopt promptsubst; [[ -o interactive ]] && jobs -l;
1332
1333 # make sure to use right prompt only when not running a command
1334 is41 && setopt transient_rprompt
1335
1336 is4 && [[ -z $NOPRECMD ]] && precmd () {
1337     [[ -n $NOPRECMD ]] && return 0
1338     # allow manual overwriting of RPROMPT
1339     if [[ -n $RPROMPT ]] ; then
1340         [[ $TERM == screen* ]] && echo -n $'\ekzsh\e\\'
1341         # return 0
1342     fi
1343     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1344     if [[ -z $DONTSETRPROMPT ]] ; then
1345         if [[ -n $BATTERY ]] ; then
1346             RPROMPT="%(?..:()% ${PERCENT}${SCREENTITLE}"
1347             # RPROMPT="${PERCENT}${SCREENTITLE}"
1348         else
1349             RPROMPT="%(?..:()% ${SCREENTITLE}"
1350             # RPROMPT="${SCREENTITLE}"
1351         fi
1352     fi
1353     # adjust title of xterm
1354     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1355     case $TERM in
1356         (xterm*|rxvt)
1357             print -Pn "\e]0;%n@%m: %~\a"
1358             ;;
1359     esac
1360 }
1361
1362 # chpwd () => a function which is executed whenever the directory is changed
1363
1364 # preexec() => a function running before every command
1365 is4 && [[ -z $NOPRECMD ]] && \
1366 preexec () {
1367     [[ -n $NOPRECMD ]] && return 0
1368 # set hostname if not running on host with name 'grml'
1369     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1370        NAME="@$HOSTNAME"
1371     fi
1372 # get the name of the program currently running and hostname of local machine
1373 # set screen window title if running in a screen
1374     if [[ "$TERM" == screen* ]] ; then
1375         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1376         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1377         echo -ne "\ek$CMD\e\\"
1378     fi
1379 # set the screen title to "zsh" when sitting at the command prompt:
1380     if [[ "$TERM" == screen* ]] ; then
1381         SCREENTITLE=$'%{\ekzsh\e\\%}'
1382     else
1383         SCREENTITLE=''
1384     fi
1385 # adjust title of xterm
1386     case $TERM in
1387         (xterm*|rxvt)
1388             print -Pn "\e]0;%n@%m: $1\a"
1389             ;;
1390     esac
1391 }
1392
1393 # set colors
1394 if zrcautoload colors && colors 2>/dev/null ; then
1395     BLUE="%{${fg[blue]}%}"
1396     RED="%{${fg_bold[red]}%}"
1397     GREEN="%{${fg[green]}%}"
1398     CYAN="%{${fg[cyan]}%}"
1399     WHITE="%{${fg[white]}%}"
1400     NO_COLOUR="%{${reset_color}%}"
1401 else
1402     BLUE=$'%{\e[1;34m%}'
1403     RED=$'%{\e[1;31m%}'
1404     GREEN=$'%{\e[1;32m%}'
1405     CYAN=$'%{\e[1;36m%}'
1406     WHITE=$'%{\e[1;37m%}'
1407     NO_COLOUR=$'%{\e[0m%}'
1408 fi
1409
1410 EXITCODE="%(?..%?%1v )"
1411 PS2='`%_> '       # secondary prompt, printed when the shell needs more information to complete a command.
1412 PS3='?# '         # selection prompt used within a select loop.
1413 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1414
1415 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1416 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1417     debian_chroot=$(cat /etc/debian_chroot)
1418 fi
1419
1420 # don't use colors on dumb terminals (like emacs):
1421 if [[ "$TERM" == dumb ]] ; then
1422     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< %# "
1423 else
1424     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
1425     # set variable identifying the chroot you work in (used in the prompt below)
1426     if [[ -n $GRMLPROMPT ]] ; then
1427         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
1428 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
1429     else
1430         if (( EUID != 0 )); then
1431             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
1432         else
1433             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# " # primary prompt string
1434         fi
1435     fi
1436 fi
1437
1438 # if we are inside a grml-chroot set a specific prompt theme
1439 if [[ -n "$GRML_CHROOT" ]] ; then
1440     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
1441 fi
1442 # }}}
1443
1444 # {{{ 'hash' some often used directories
1445 #d# start
1446 hash -d deb=/var/cache/apt/archives
1447 hash -d doc=/usr/share/doc
1448 hash -d linux=/lib/modules/$(command uname -r)/build/
1449 hash -d log=/var/log
1450 hash -d slog=/var/log/syslog
1451 hash -d src=/usr/src
1452 hash -d templ=/usr/share/doc/grml-templates
1453 hash -d tt=/usr/share/doc/texttools-doc
1454 hash -d www=/var/www
1455 #d# end
1456 # }}}
1457
1458 # {{{ some aliases
1459 if [[ $UID -eq 0 ]] ; then
1460     [[ -r /etc/grml/screenrc ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc'
1461 elif [[ -r $HOME/.screenrc ]] ; then
1462     alias screen="/usr/bin/screen -c $HOME/.screenrc"
1463 else
1464     [[ -r /etc/grml/screenrc_grml ]] && alias screen='/usr/bin/screen -c /etc/grml/screenrc_grml'
1465 fi
1466
1467 # do we have GNU ls with color-support?
1468 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
1469     #a1# execute \kbd{@a@}:\quad ls with colors
1470     alias ls='ls -b -CF --color=auto'
1471     #a1# execute \kbd{@a@}:\quad list all files, with colors
1472     alias la='ls -la --color=auto'
1473     #a1# long colored list, without dotfiles (@a@)
1474     alias ll='ls -l --color=auto'
1475     #a1# long colored list, human readable sizes (@a@)
1476     alias lh='ls -hAl --color=auto'
1477     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
1478     alias l='ls -lF --color=auto'
1479 else
1480     alias ls='ls -b -CF'
1481     alias la='ls -la'
1482     alias ll='ls -l'
1483     alias lh='ls -hAl'
1484     alias l='ls -lF'
1485 fi
1486
1487 alias mdstat='cat /proc/mdstat'
1488 alias ...='cd ../../'
1489
1490 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
1491 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
1492     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
1493 fi
1494
1495 alias cp='nocorrect cp'         # no spelling correction on cp
1496 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
1497 alias mv='nocorrect mv'         # no spelling correction on mv
1498 alias rm='nocorrect rm'         # no spelling correction on rm
1499
1500 #a1# Execute \kbd{rmdir}
1501 alias rd='rmdir'
1502 #a1# Execute \kbd{rmdir}
1503 alias md='mkdir'
1504
1505 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
1506 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
1507 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
1508
1509 # make sure it is not assigned yet
1510 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
1511
1512 utf2iso() {
1513     if isutfenv ; then
1514         for ENV in $(env | command grep -i '.utf') ; do
1515             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
1516         done
1517     fi
1518 }
1519
1520 # make sure it is not assigned yet
1521 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
1522 iso2utf() {
1523     if ! isutfenv ; then
1524         for ENV in $(env | command grep -i '\.iso') ; do
1525             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
1526         done
1527     fi
1528 }
1529
1530 # set up software synthesizer via speakup
1531 swspeak() {
1532     aumix -w 90 -v 90 -p 90 -m 90
1533     if ! [[ -r /dev/softsynth ]] ; then
1534         flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
1535         return 1
1536     else
1537         setopt singlelinezle
1538         unsetopt prompt_cr
1539         export PS1="%m%# "
1540         nice -n -20 speechd-up
1541         sleep 2
1542         flite -o play -t "Finished setting up software synthesizer"
1543     fi
1544 }
1545
1546 # I like clean prompt, so provide simple way to get that
1547 check_com 0 || alias 0='return 0'
1548
1549 # for really lazy people like mika:
1550 check_com S &>/dev/null || alias S='screen'
1551 check_com s &>/dev/null || alias s='ssh'
1552
1553 # get top 10 shell commands:
1554 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
1555
1556 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
1557 if check_com -c truecrypt ; then
1558     if isutfenv ; then
1559         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
1560     else
1561         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
1562     fi
1563 fi
1564
1565 #f1# Hints for the use of zsh on grml
1566 zsh-help() {
1567     print "$bg[white]$fg[black]
1568 zsh-help - hints for use of zsh on grml
1569 =======================================$reset_color"
1570
1571     print '
1572 Main configuration of zsh happens in /etc/zsh/zshrc (global)
1573 and /etc/skel/.zshrc which is copied to $HOME/.zshrc once.
1574 The files are part of the package grml-etc-core, if you want to
1575 use them on a non-grml-system just get the tar.gz from
1576 http://deb.grml.org/ or get the files from the mercurial
1577 repository:
1578
1579   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/skel/.zshrc
1580   http://hg.grml.org/grml-etc-core/raw-file/tip/etc/zsh/zshrc
1581
1582 If you want to stay in sync with zsh configuration of grml
1583 run '\''ln -sf /etc/skel/.zshrc $HOME/.zshrc'\'' and configure
1584 your own stuff in $HOME/.zshrc.local. System wide configuration
1585 without touching configuration files of grml can take place
1586 in /etc/zsh/zshrc.local.
1587
1588 If you want to use the configuration of user grml also when
1589 running as user root just run '\''zshskel'\'' which will source
1590 the file /etc/skel/.zshrc.
1591
1592 For information regarding zsh start at http://grml.org/zsh/
1593
1594 Take a look at grml'\''s zsh refcard:
1595 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
1596
1597 Check out the main zsh refcard:
1598 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
1599
1600 And of course visit the zsh-lovers:
1601 % man zsh-lovers
1602
1603 You can adjust some options through environment variables when
1604 invoking zsh without having to edit configuration files.
1605 Basically meant for bash users who are not used to the power of
1606 the zsh yet. :)
1607
1608   "NOCOR=1    zsh" => deactivate automatic correction
1609   "NOMENU=1   zsh" => do not use menu completion (note: use strg-d for completion instead!)
1610   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
1611   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt'
1612
1613     print "
1614 $bg[white]$fg[black]
1615 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
1616 Enjoy your grml system with the zsh!$reset_color"
1617 }
1618
1619 # debian stuff
1620 if [[ -r /etc/debian_version ]] ; then
1621     #a3# Execute \kbd{apt-cache search}
1622     alias acs='apt-cache search'
1623     #a3# Execute \kbd{apt-cache show}
1624     alias acsh='apt-cache show'
1625     #a3# Execute \kbd{apt-cache policy}
1626     alias acp='apt-cache policy'
1627     #a3# Execute \kbd{apt-get dist-upgrade}
1628     salias adg="apt-get dist-upgrade"
1629     #a3# Execute \kbd{apt-get install}
1630     salias agi="apt-get install"
1631     #a3# Execute \kbd{aptitude install}
1632     salias ati="aptitude install"
1633     #a3# Execute \kbd{apt-get upgrade}
1634     salias ag="apt-get upgrade"
1635     #a3# Execute \kbd{apt-get update}
1636     salias au="apt-get update"
1637     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
1638     salias -a up="aptitude update ; aptitude safe-upgrade"
1639     #a3# Execute \kbd{dpkg-buildpackage}
1640     alias dbp='dpkg-buildpackage'
1641     #a3# Execute \kbd{grep-excuses}
1642     alias ge='grep-excuses'
1643
1644     # debian upgrade
1645     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
1646     upgrade() {
1647         if [[ -z "$1" ]] ; then
1648             $SUDO apt-get update
1649             $SUDO apt-get -u upgrade
1650         else
1651             ssh $1 $SUDO apt-get update
1652             # ask before the upgrade
1653             local dummy
1654             ssh $1 $SUDO apt-get --no-act upgrade
1655             echo -n 'Process the upgrade?'
1656             read -q dummy
1657             if [[ $dummy == "y" ]] ; then
1658                 ssh $1 $SUDO apt-get -u upgrade --yes
1659             fi
1660         fi
1661     }
1662
1663     # get a root shell as normal user in live-cd mode:
1664     if isgrmlcd && [[ $UID -ne 0 ]] ; then
1665        alias su="sudo su"
1666      fi
1667
1668     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
1669     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
1670     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
1671     alias tlog="tail -f /var/log/syslog"    # follow the syslog
1672     #a1# (Re)-source \kbd{/etc/skel/.zshrc}
1673     alias zshskel="source /etc/skel/.zshrc" # source skeleton zshrc
1674 fi
1675
1676 # sort installed Debian-packages by size
1677 if check_com -c grep-status ; then
1678     #a3# List installed Debian-packages sorted by size
1679     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
1680 fi
1681
1682 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
1683 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
1684     if check_com -c wodim ; then
1685         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
1686 See #377109 in the BTS of Debian for more details.
1687
1688 Please use the wodim binary instead' ; return 1"
1689     fi
1690 fi
1691
1692 # get_tw_cli has been renamed into get_3ware
1693 if check_com -c get_3ware ; then
1694     get_tw_cli() {
1695         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
1696         get_3ware
1697     }
1698 fi
1699
1700 # I hate lacking backward compatibility, so provide an alternative therefore
1701 if ! check_com -c apache2-ssl-certificate ; then
1702
1703     apache2-ssl-certificate() {
1704
1705     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
1706     print 'You might want to take a look at Debian the package ssl-cert as well.'
1707     print 'To generate a certificate for use with apache2 follow the instructions:'
1708
1709     echo '
1710
1711 export RANDFILE=/dev/random
1712 mkdir /etc/apache2/ssl/
1713 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
1714 chmod 600 /etc/apache2/ssl/apache.pem
1715
1716 Run "grml-tips ssl-certificate" if you need further instructions.
1717 '
1718     }
1719 fi
1720 # }}}
1721
1722 # {{{ Use hard limits, except for a smaller stack and no core dumps
1723 unlimit
1724 is4 && limit stack 8192
1725 isgrmlcd && limit core 0 # important for a live-cd-system
1726 limit -s
1727 # }}}
1728
1729 # {{{ completion system
1730
1731 # called later (via is4 && grmlcomp)
1732 # notice: use 'zstyle' for getting current settings
1733 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
1734 grmlcomp() {
1735     # TODO: This could use some additional information
1736
1737     # allow one error for every three characters typed in approximate completer
1738     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
1739
1740     # don't complete backup files as executables
1741     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
1742
1743     # start menu completion only if it could find no unambiguous initial string
1744     zstyle ':completion:*:correct:*'       insert-unambiguous true
1745     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
1746     zstyle ':completion:*:correct:*'       original true
1747
1748     # activate color-completion
1749     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
1750
1751     # format on completion
1752     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
1753
1754     # complete 'cd -<tab>' with menu
1755     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
1756
1757     # insert all expansions for expand completer
1758     zstyle ':completion:*:expand:*'        tag-order all-expansions
1759     zstyle ':completion:*:history-words'   list false
1760
1761     # activate menu
1762     zstyle ':completion:*:history-words'   menu yes
1763
1764     # ignore duplicate entries
1765     zstyle ':completion:*:history-words'   remove-all-dups yes
1766     zstyle ':completion:*:history-words'   stop yes
1767
1768     # match uppercase from lowercase
1769     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
1770
1771     # separate matches into groups
1772     zstyle ':completion:*:matches'         group 'yes'
1773     zstyle ':completion:*'                 group-name ''
1774
1775     if [[ -z "$NOMENU" ]] ; then
1776         # if there are more than 5 options allow selecting from a menu
1777         zstyle ':completion:*'               menu select=5
1778     else
1779         # don't use any menus at all
1780         setopt no_auto_menu
1781     fi
1782
1783     zstyle ':completion:*:messages'        format '%d'
1784     zstyle ':completion:*:options'         auto-description '%d'
1785
1786     # describe options in full
1787     zstyle ':completion:*:options'         description 'yes'
1788
1789     # on processes completion complete all user processes
1790     zstyle ':completion:*:processes'       command 'ps -au$USER'
1791
1792     # offer indexes before parameters in subscripts
1793     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
1794
1795     # provide verbose completion information
1796     zstyle ':completion:*'                 verbose true
1797
1798     # recent (as of Dec 2007) zsh versions are able to provide descriptions
1799     # for commands (read: 1st word in the line) that it will list for the user
1800     # to choose from. The following disables that, because it's not exactly fast.
1801     zstyle ':completion:*:-command-:*:'    verbose false
1802
1803     # set format for warnings
1804     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
1805
1806     # define files to ignore for zcompile
1807     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
1808     zstyle ':completion:correct:'          prompt 'correct to: %e'
1809
1810     # Ignore completion functions for commands you don't have:
1811     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
1812
1813     # Provide more processes in completion of programs like killall:
1814     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
1815
1816     # complete manual by their section
1817     zstyle ':completion:*:manuals'    separate-sections true
1818     zstyle ':completion:*:manuals.*'  insert-sections   true
1819     zstyle ':completion:*:man:*'      menu yes select
1820
1821     # run rehash on completion so new installed program are found automatically:
1822     _force_rehash() {
1823         (( CURRENT == 1 )) && rehash
1824         return 1
1825     }
1826
1827     ## correction
1828     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
1829     if [[ -n "$NOCOR" ]] ; then
1830         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
1831         setopt nocorrect
1832     else
1833         # try to be smart about when to use what completer...
1834         setopt correct
1835         zstyle -e ':completion:*' completer '
1836             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
1837                 _last_try="$HISTNO$BUFFER$CURSOR"
1838                 reply=(_complete _match _ignored _prefix _files)
1839             else
1840                 if [[ $words[1] == (rm|mv) ]] ; then
1841                     reply=(_complete _files)
1842                 else
1843                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
1844                 fi
1845             fi'
1846     fi
1847
1848     # zstyle ':completion:*' completer _complete _correct _approximate
1849     # zstyle ':completion:*' expand prefix suffix
1850
1851     # complete shell aliases
1852     # zstyle ':completion:*' completer _expand_alias _complete _approximate
1853
1854     # command for process lists, the local web server details and host completion
1855     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
1856
1857     # caching
1858     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
1859                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
1860
1861     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
1862     if is42 ; then
1863         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
1864         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
1865     else
1866         _ssh_hosts=()
1867         _etc_hosts=()
1868     fi
1869     hosts=(
1870         $(hostname)
1871         "$_ssh_hosts[@]"
1872         "$_etc_hosts[@]"
1873         grml.org
1874         localhost
1875     )
1876     zstyle ':completion:*:hosts' hosts $hosts
1877     #  zstyle '*' hosts $hosts
1878
1879     # specify your logins:
1880     # my_accounts=(
1881     #  {grml,grml1}@foo.invalid
1882     #  grml-devel@bar.invalid
1883     # )
1884     # other_accounts=(
1885     #  {fred,root}@foo.invalid
1886     #  vera@bar.invalid
1887     # )
1888     # zstyle ':completion:*:my-accounts' users-hosts $my_accounts
1889     # zstyle ':completion:*:other-accounts' users-hosts $other_accounts
1890
1891     # specify specific port/service settings:
1892     #  telnet_users_hosts_ports=(
1893     #    user1@host1:
1894     #    user2@host2:
1895     #    @mail-server:{smtp,pop3}
1896     #    @news-server:nntp
1897     #    @proxy-server:8000
1898     #  )
1899     # zstyle ':completion:*:*:telnet:*' users-hosts-ports $telnet_users_hosts_ports
1900
1901     # use generic completion system for programs not yet defined; (_gnu_generic works
1902     # with commands that provide a --help option with "standard" gnu-like output.)
1903     compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
1904
1905     # see upgrade function in this file
1906     compdef _hosts upgrade
1907 }
1908 # }}}
1909
1910 # {{{ grmlstuff
1911 grmlstuff() {
1912 # people should use 'grml-x'!
1913     startx() {
1914         if [[ -e /etc/X11/xorg.conf ]] ; then
1915             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
1916         else
1917             echo "Please use the script \"grml-x\" for starting the X Window System
1918 because there does not exist /etc/X11/xorg.conf yet.
1919 If you want to use startx anyway please call \"/usr/bin/startx\"."
1920             return -1
1921         fi
1922     }
1923
1924     xinit() {
1925         if [[ -e /etc/X11/xorg.conf ]] ; then
1926             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
1927         else
1928             echo "Please use the script \"grml-x\" for starting the X Window System.
1929 because there does not exist /etc/X11/xorg.conf yet.
1930 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
1931             return -1
1932         fi
1933     }
1934
1935     if check_com -c 915resolution ; then
1936         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
1937     fi
1938
1939     #a1# Output version of running grml
1940     alias grml-version='cat /etc/grml_version'
1941
1942     if check_com -c rebuildfstab ; then
1943         #a1# Rebuild /etc/fstab
1944         alias grml-rebuildfstab='rebuildfstab -v -r -config'
1945     fi
1946
1947     if check_com -c grml-debootstrap ; then
1948         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
1949     fi
1950 }
1951 # }}}
1952
1953 # {{{ now run the functions
1954 isgrml && checkhome
1955 is4    && isgrml    && grmlstuff
1956 is4    && grmlcomp
1957 # }}}
1958
1959 # {{{ keephack
1960 is4 && xsource "/etc/zsh/keephack"
1961 # }}}
1962
1963 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
1964 # You use it as follows:
1965 # $ NTREF=/reference/file
1966 # $ ls -l *(e:nt:)
1967 # This lists all the files in the current directory newer than the reference file.
1968 # You can also specify the reference file inline; note quotes:
1969 # $ ls -l *(e:'nt ~/.zshenv':)
1970 is4 && nt() {
1971     if [[ -n $1 ]] ; then
1972         local NTREF=${~1}
1973     fi
1974     [[ $REPLY -nt $NTREF ]]
1975 }
1976 # }}}
1977
1978 # shell functions {{{
1979
1980 #f1# Provide csh compatibility
1981 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
1982
1983 #f1# Reload an autoloadable function
1984 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
1985
1986 #f1# Reload zsh setup
1987 reload() {
1988     if [[ "$#*" -eq 0 ]] ; then
1989         [[ -r ~/.zshrc ]] && . ~/.zshrc
1990     else
1991         local fn
1992         for fn in "$@"; do
1993             unfunction $fn
1994             autoload -U $fn
1995         done
1996     fi
1997 }
1998 compdef _functions reload freload
1999
2000 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2001 sll() {
2002     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2003     for i in "$@" ; do
2004         file=$i
2005         while [[ -h "$file" ]] ; do
2006             ls -l $file
2007             file=$(readlink "$file")
2008         done
2009     done
2010 }
2011
2012 # fast manual access
2013 if check_com qma ; then
2014     #f1# View the zsh manual
2015     manzsh()  { qma zshall "$1" }
2016     compdef _man qma
2017 else
2018     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
2019     # manzsh()  { /usr/bin/man zshall |  most +/"$1" ; }
2020     # [[ -f ~/.terminfo/m/mostlike ]] && MYLESS='LESS=C TERMINFO=~/.terminfo TERM=mostlike less' || MYLESS='less'
2021     # manzsh()  { man zshall | $MYLESS -p $1 ; }
2022 fi
2023
2024 if check_com -c $PAGER ; then
2025     #f1# View Debian's changelog of a given package
2026     dchange() {
2027         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
2028             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
2029         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2030             $PAGER /usr/share/doc/${1}/changelog.gz
2031         else
2032             if check_com -c aptitude ; then
2033                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2034                 if isgrml ; then
2035                     aptitude -t unstable changelog ${1}
2036                 else
2037                     aptitude changelog ${1}
2038                 fi
2039             else
2040                 echo "No changelog for package $1 found, sorry."
2041                 return 1
2042             fi
2043         fi
2044     }
2045     _dchange() { _files -W /usr/share/doc -/ }
2046     compdef _dchange dchange
2047
2048     #f1# View Debian's NEWS of a given package
2049     dnews() {
2050         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
2051             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
2052         else
2053             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
2054                 $PAGER /usr/share/doc/${1}/NEWS.gz
2055             else
2056                 echo "No NEWS file for package $1 found, sorry."
2057                 return 1
2058             fi
2059         fi
2060     }
2061     _dnews() { _files -W /usr/share/doc -/ }
2062     compdef _dnews dnews
2063
2064     #f1# View upstream's changelog of a given package
2065     uchange() {
2066         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2067             $PAGER /usr/share/doc/${1}/changelog.gz
2068         else
2069             echo "No changelog for package $1 found, sorry."
2070             return 1
2071         fi
2072     }
2073     _uchange() { _files -W /usr/share/doc -/ }
2074     compdef _uchange uchange
2075 fi
2076
2077 # zsh profiling
2078 profile() {
2079     ZSH_PROFILE_RC=1 $SHELL "$@"
2080 }
2081
2082 #f1# Edit an alias via zle
2083 edalias() {
2084     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2085 }
2086 compdef _aliases edalias
2087
2088 #f1# Edit a function via zle
2089 edfunc() {
2090     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
2091 }
2092 compdef _functions edfunc
2093
2094 # use it e.g. via 'Restart apache2'
2095 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2096 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2097 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2098 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2099 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2100 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2101     __start_stop() {
2102         local action_="${1:l}"  # e.g Start/Stop/Restart
2103         local service_="$2"
2104         local param_="$3"
2105
2106         local service_target_="$(readlink /etc/init.d/$service_)"
2107         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2108             # runit
2109             case "${action_}" in
2110                 start) if [[ ! -e /etc/service/$service_ ]]; then
2111                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2112                        else
2113                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2114                        fi ;;
2115                 # there is no reload in runits sysv emulation
2116                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2117                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2118             esac
2119         else
2120             # sysvinit
2121             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2122         fi
2123     }
2124
2125     for i in Start Restart Stop Force-Reload Reload ; do
2126         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2127     done
2128 fi
2129
2130 #f1# Provides useful information on globbing
2131 H-Glob() {
2132     echo -e "
2133     /      directories
2134     .      plain files
2135     @      symbolic links
2136     =      sockets
2137     p      named pipes (FIFOs)
2138     *      executable plain files (0100)
2139     %      device files (character or block special)
2140     %b     block special files
2141     %c     character special files
2142     r      owner-readable files (0400)
2143     w      owner-writable files (0200)
2144     x      owner-executable files (0100)
2145     A      group-readable files (0040)
2146     I      group-writable files (0020)
2147     E      group-executable files (0010)
2148     R      world-readable files (0004)
2149     W      world-writable files (0002)
2150     X      world-executable files (0001)
2151     s      setuid files (04000)
2152     S      setgid files (02000)
2153     t      files with the sticky bit (01000)
2154
2155   print *(m-1)          # Files modified up to a day ago
2156   print *(a1)           # Files accessed a day ago
2157   print *(@)            # Just symlinks
2158   print *(Lk+50)        # Files bigger than 50 kilobytes
2159   print *(Lk-50)        # Files smaller than 50 kilobytes
2160   print **/*.c          # All *.c files recursively starting in \$PWD
2161   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2162   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2163   print *~*.*           # All Files that do not contain a dot
2164   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2165   print -l *(.c|.h)     # Lists *.c and *.h
2166   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2167   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2168 }
2169 alias help-zshglob=H-Glob
2170
2171 check_com -c qma && alias ?='qma zshall'
2172
2173 # grep for running process, like: 'any vim'
2174 any() {
2175     if [[ -z "$1" ]] ; then
2176         echo "any - grep for process(es) by keyword" >&2
2177         echo "Usage: any <keyword>" >&2 ; return 1
2178     else
2179         local STRING=$1
2180         local LENGTH=$(expr length $STRING)
2181         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
2182         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
2183         ps xauwww| grep "[$FIRSCHAR]$REST"
2184     fi
2185 }
2186
2187 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2188 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2189 [[ -r /proc/1/maps ]] && \
2190 deswap() {
2191     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2192     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2193     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2194 }
2195
2196 # print hex value of a number
2197 hex() {
2198     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2199 }
2200
2201 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2202 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2203 peval() {
2204     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2205     perl -e "print eval($CALC),\"\n\";"
2206 }
2207 functions peval &>/dev/null && alias calc=peval
2208
2209 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
2210 # certain circumstances, so work around it, no matter which environment we have
2211 brltty() {
2212     if [[ -z "$DISPLAY" ]] ; then
2213         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
2214         command brltty "$@"
2215     else
2216         command brltty "$@"
2217     fi
2218 }
2219
2220 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2221 aoeu() {
2222     echo -n 'Switching to us keyboard layout: '
2223     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2224     echo 'Done'
2225 }
2226 asdf() {
2227     echo -n 'Switching to dvorak keyboard layout: '
2228     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2229     echo 'Done'
2230 }
2231 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2232 uiae() {
2233     echo -n 'Switching to us keyboard layout: '
2234     setxkbmap us && echo 'Done' || echo 'Failed'
2235 }
2236
2237 # set up an ipv6 tunnel
2238 ipv6-tunnel() {
2239     case $1 in
2240         start)
2241             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2242                 print 'ipv6 tunnel already set up, nothing to be done.'
2243                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2244             else
2245                 [[ -n "$PUBLIC_IP" ]] || \
2246                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2247                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2248
2249                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
2250                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
2251                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
2252                 ifconfig sit0 tunnel ::192.88.99.1 up
2253                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
2254             fi
2255             ;;
2256         status)
2257             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2258                 print 'ipv6 tunnel available' ; return 0
2259             else
2260                 print 'ipv6 tunnel not available' ; return 1
2261             fi
2262             ;;
2263         stop)
2264             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2265                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
2266                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
2267             else
2268                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
2269             fi
2270             ;;
2271         *)
2272             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
2273             ;;
2274     esac
2275 }
2276
2277 # run dhclient for wireless device
2278 iwclient() {
2279     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
2280 }
2281
2282 # spawn a minimally set up ksh - useful if you want to umount /usr/.
2283 minimal-shell() {
2284     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
2285 }
2286
2287 # make a backup of a file
2288 bk() {
2289     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2290 }
2291
2292 # Switching shell safely and efficiently? http://www.zsh.org/mla/workers/2001/msg02410.html
2293 # bash() {
2294 #  NO_SWITCH="yes" command bash "$@"
2295 # }
2296 # restart () {
2297 #  exec $SHELL $SHELL_ARGS "$@"
2298 # }
2299
2300 # }}}
2301
2302 # log out? set timeout in seconds {{{
2303 # TMOUT=1800
2304 # do not log out in some specific terminals:
2305 #  if [[ "${TERM}" == ([Exa]term*|rxvt|dtterm|screen*) ]] ; then
2306 #    unset TMOUT
2307 #  fi
2308 # }}}
2309
2310 # {{{ make sure our environment is clean regarding colors
2311 for color in BLUE RED GREEN CYAN WHITE ; unset $color
2312 # }}}
2313
2314 # source another config file if present {{{
2315 xsource "/etc/zsh/zshrc.local"
2316 xsource "${HOME}/.zshenv"
2317 # }}}
2318
2319 # "persistent history" {{{
2320 # just write important commands you always need to ~/.important_commands
2321 if [[ -r ~/.important_commands ]] ; then
2322     fc -R ~/.important_commands
2323 fi
2324 # }}}
2325
2326 ## genrefcard.pl settings {{{
2327 ### example: split functions-search 8,16,24,32
2328 #@# split functions-search 8
2329 ## }}}
2330
2331 # add variable to be able to check whether the file has been read {{{
2332 ZSHRC_GLOBAL_HAS_BEEN_READ=1
2333 # }}}
2334
2335 ## END OF FILE #################################################################
2336 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4