etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # zsh-refcard-tag documentation: {{{
  15 #   You may notice strange looking comments in this file.
  16 #   These are there for a purpose. grml's zsh-refcard can now be
  17 #   automatically generated from the contents of the actual configuration
  18 #   file. However, we need a little extra information on which comments
  19 #   and what lines of code to take into account (and for what purpose).
  20 #
  21 # Here is what they mean:
  22 #
  23 # List of tags (comment types) used:
  24 #   #a#     Next line contains an important alias, that should
  25 #           be included in the grml-zsh-refcard.
  26 #           (placement tag: @@INSERT-aliases@@)
  27 #   #f#     Next line contains the beginning of an important function.
  28 #           (placement tag: @@INSERT-functions@@)
  29 #   #v#     Next line contains an important variable.
  30 #           (placement tag: @@INSERT-variables@@)
  31 #   #k#     Next line contains an important keybinding.
  32 #           (placement tag: @@INSERT-keybindings@@)
  33 #   #d#     Hashed directories list generation:
  34 #               start   denotes the start of a list of 'hash -d'
  35 #                       definitions.
  36 #               end     denotes its end.
  37 #           (placement tag: @@INSERT-hasheddirs@@)
  38 #   #A#     Abbreviation expansion list generation:
  39 #               start   denotes the beginning of abbreviations.
  40 #               end     denotes their end.
  41 #           Lines within this section that end in '#d .*' provide
  42 #           extra documentation to be included in the refcard.
  43 #           (placement tag: @@INSERT-abbrev@@)
  44 #   #m#     This tag allows you to manually generate refcard entries
  45 #           for code lines that are hard/impossible to parse.
  46 #               Example:
  47 #                   #m# k ESC-h Call the run-help function
  48 #               That would add a refcard entry in the keybindings table
  49 #               for 'ESC-h' with the given comment.
  50 #           So the syntax is: #m# <section> <argument> <comment>
  51 #   #o#     This tag lets you insert entries to the 'other' hash.
  52 #           Generally, this should not be used. It is there for
  53 #           things that cannot be done easily in another way.
  54 #           (placement tag: @@INSERT-other-foobar@@)
  55 #
  56 #   All of these tags (except for m and o) take two arguments, the first
  57 #   within the tag, the other after the tag:
  58 #
  59 #   #<tag><section># <comment>
  60 #
  61 #   Where <section> is really just a number, which are defined by the
  62 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  63 #   instead of names is, that for the reader, the tag should not differ
  64 #   much from a regular comment. For zsh, it is a regular comment indeed.
  65 #   The numbers have got the following meanings:
  66 #         0 -> "default"
  67 #         1 -> "system"
  68 #         2 -> "user"
  69 #         3 -> "debian"
  70 #         4 -> "search"
  71 #         5 -> "shortcuts"
  72 #         6 -> "services"
  73 #
  74 #   So, the following will add an entry to the 'functions' table in the
  75 #   'system' section, with a (hopefully) descriptive comment:
  76 #       #f1# Edit an alias via zle
  77 #       edalias() {
  78 #
  79 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  80 #   that can be found in 'grml-zsh-refcard.tex.in'.
  81 #   If the section number is omitted, the 'default' section is assumed.
  82 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  83 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  84 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  85 #}}}
  86
  87 # zsh profiling {{{
  88 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
  89 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
  90     zmodload zsh/zprof
  91 fi
  92 # }}}
  93
  94 # load .zshrc.pre to give the user the chance to overwrite the defaults
  95 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
  96
  97 # {{{ check for version/system
  98 # check for versions (compatibility reasons)
  99 is4(){
 100     [[ $ZSH_VERSION == <4->* ]] && return 0
 101     return 1
 102 }
 103
 104 is41(){
 105     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 106     return 1
 107 }
 108
 109 is42(){
 110     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 111     return 1
 112 }
 113
 114 is425(){
 115     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 116     return 1
 117 }
 118
 119 is43(){
 120     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 121     return 1
 122 }
 123
 124 #f1# Checks whether or not you're running grml
 125 isgrml(){
 126     [[ -f /etc/grml_version ]] && return 0
 127     return 1
 128 }
 129
 130 #f1# Checks whether or not you're running a grml cd
 131 isgrmlcd(){
 132     [[ -f /etc/grml_cd ]] && return 0
 133     return 1
 134 }
 135
 136 if isgrml ; then
 137 #f1# Checks whether or not you're running grml-small
 138     isgrmlsmall() {
 139         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 140     }
 141 else
 142     isgrmlsmall() { return 1 }
 143 fi
 144
 145 isdarwin(){
 146     [[ $OSTYPE == darwin* ]] && return 0
 147     return 1
 148 }
 149
 150 #f1# are we running within an utf environment?
 151 isutfenv() {
 152     case "$LANG $CHARSET $LANGUAGE" in
 153         *utf*) return 0 ;;
 154         *UTF*) return 0 ;;
 155         *)     return 1 ;;
 156     esac
 157 }
 158
 159 # check for user, if not running as root set $SUDO to sudo
 160 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 161
 162 # change directory to home on first invocation of zsh
 163 # important for rungetty -> autologin
 164 # Thanks go to Bart Schaefer!
 165 isgrml && checkhome() {
 166     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 167         export ALREADY_DID_CD_HOME=$HOME
 168         cd
 169     fi
 170 }
 171
 172 # check for zsh v3.1.7+
 173
 174 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 175      || ${ZSH_VERSION} == 3.<2->.<->*    \
 176      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 177
 178     printf '-!-\n'
 179     printf '-!- In this configuration we try to make use of features, that only\n'
 180     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 181     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 182     printf '-!- advanced features in all supported versions.\n'
 183     printf '-!-\n'
 184     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 185     printf '-!-\n'
 186     printf '-!- While this *may* work, it might as well fail.\n'
 187     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 188     printf '-!-\n'
 189     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 190     printf '-!- If it does today, you'\''ve been lucky.\n'
 191     printf '-!-\n'
 192     printf '-!- Ye been warned!\n'
 193     printf '-!-\n'
 194
 195     function zstyle() { : }
 196 fi
 197
 198 # autoload wrapper - use this one instead of autoload directly
 199 # We need to define this function as early as this, because autoloading
 200 # 'is-at-least()' needs it.
 201 function zrcautoload() {
 202     setopt local_options extended_glob
 203     local fdir ffile
 204     local -i ffound
 205
 206     ffile=${1}
 207     (( found = 0 ))
 208     for fdir in ${fpath} ; do
 209         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 210     done
 211
 212     (( ffound == 0 )) && return 1
 213     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 214         autoload -U ${ffile} || return 1
 215     else
 216         autoload ${ffile} || return 1
 217     fi
 218     return 0
 219 }
 220
 221 # Load is-at-least() for more precise version checks
 222 # Note that this test will *always* fail, if the is-at-least
 223 # function could not be marked for autoloading.
 224 zrcautoload is-at-least || is-at-least() { return 1 }
 225
 226 # }}}
 227
 228 # setting some default values {{{
 229
 230 NOCOR=${NOCOR:-0}
 231 NOMENU=${NOMENU:-0}
 232 NOPRECMD=${NOPRECMD:-0}
 233 BATTERY=${BATTERY:-0}
 234 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 235 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 236
 237 if isgrmlcd ; then
 238     GRML_WARN_SKEL=${GRML_WARN_SKEL:-0}
 239 else
 240     GRML_WARN_SKEL=${GRML_WARN_SKEL:-1}
 241 fi
 242
 243 if (( GRML_WARN_SKEL != 0 )) ; then
 244
 245 function grml_warn_skel_main() {
 246     printf '
 247 Dear user,
 248
 249 You updated grml'\''s zshrc which brings a major change.
 250 The configuration is kept only in one file, being the global zshrc.
 251 In the past, the configuration was split in two files, with the
 252 second file being the .zshrc file from /etc/skel.
 253
 254 If you have a .zshrc file in your home directory that originally
 255 came from the skel directory, please remove it. This is also the case
 256 if you followed earlier instructions from the grml-zsh-refcard or
 257 from <http://grml.org/console/> on non-grml systems.
 258
 259 Please see the current grml-zsh-refcard (available at
 260 <http://grml.org/zsh/>) for updated installation information. In short,
 261 you don'\''t want a .zshrc.global file. Install the global zshrc to
 262 ~/.zshrc and be done.
 263
 264 If you need changes to the configuration, use ~/.zshrc.pre and
 265 ~/.zshrc.local.
 266
 267 '
 268 }
 269
 270 function grml_warn_skel_remove() {
 271     printf 'To remove this warning execute '\''grml_do_not_warn_skel'\''.\n\n'
 272 }
 273
 274 function grml_do_not_warn_skel() {
 275     printf '# Do not warn about old skel dot-files anymore\n' >>! ~/.zshrc.pre
 276     printf 'GRML_WARN_SKEL=0\n' >>! ~/.zshrc.pre
 277 }
 278
 279 # let's try to guess how the user uses us.
 280 if is-at-least 4.3.7 ; then
 281     # funcsourcetrace requires at least version 4.3.7 of zsh.
 282     GRML_SRC_FILE="${${funcsourcetrace[1]}%:*}"
 283
 284     grml_warn_skel_main
 285     case ${GRML_SRC_FILE} in
 286         (${HOME}/.zshrc.global)
 287             grml_warn_skel_remove
 288             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc.global'\''.\n'
 289             printf 'Nowadays you just copy the global zshrc to '\''~/.zshrc'\'' to use\n'
 290             printf 'it on a non-grml-system.\n'
 291             ;;
 292         (${HOME}/.zshrc)
 293             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc'\''.\n'
 294             printf 'We'\''ll disable this warning automatically for later sessions.\n'
 295             grml_do_not_warn_skel
 296             ;;
 297         (*)
 298             grml_do_not_warn_skel
 299             ;;
 300     esac
 301 else
 302     grml_warn_skel_main
 303     grml_warn_skel_remove
 304 fi
 305
 306 unfunction grml_warn_skel_remove grml_warn_skel_main
 307
 308 fi # GRML_WARN_SKEL
 309
 310 # }}}
 311
 312 # utility functions {{{
 313 # this function checks if a command exists and returns either true
 314 # or false. This avoids using 'which' and 'whence', which will
 315 # avoid problems with aliases for which on certain weird systems. :-)
 316 check_com() {
 317     local -i comonly
 318
 319     if [[ ${1} == '-c' ]] ; then
 320         (( comonly = 1 ))
 321         shift
 322     else
 323         (( comonly = 0 ))
 324     fi
 325
 326     if (( ${#argv} != 1 )) ; then
 327         printf 'usage: check_com [-c] <command>\n' >&2
 328         return 1
 329     fi
 330
 331     if (( comonly > 0 )) ; then
 332         [[ -n ${commands[$1]}  ]] && return 0
 333         return 1
 334     fi
 335
 336     if   [[ -n ${commands[$1]}    ]] \
 337       || [[ -n ${functions[$1]}   ]] \
 338       || [[ -n ${aliases[$1]}     ]] \
 339       || [[ -n ${reswords[(r)$1]} ]] ; then
 340
 341         return 0
 342     fi
 343
 344     return 1
 345 }
 346
 347 # creates an alias and precedes the command with
 348 # sudo if $EUID is not zero.
 349 salias() {
 350     local only=0 ; local multi=0
 351     while [[ ${1} == -* ]] ; do
 352         case ${1} in
 353             (-o) only=1 ;;
 354             (-a) multi=1 ;;
 355             (--) shift ; break ;;
 356             (-h)
 357                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 358                 printf '  -h      shows this help text.\n'
 359                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 360                 printf '          be careful using this option.\n'
 361                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 362                 return 0
 363                 ;;
 364             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 365         esac
 366         shift
 367     done
 368
 369     if (( ${#argv} > 1 )) ; then
 370         printf 'Too many arguments %s\n' "${#argv}"
 371         return 1
 372     fi
 373
 374     key="${1%%\=*}" ;  val="${1#*\=}"
 375     if (( EUID == 0 )) && (( only == 0 )); then
 376         alias -- "${key}=${val}"
 377     elif (( EUID > 0 )) ; then
 378         (( multi > 0 )) && val="${val// ; / ; sudo }"
 379         alias -- "${key}=sudo ${val}"
 380     fi
 381
 382     return 0
 383 }
 384
 385 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 386 # usage: uprint foo
 387 #   Where foo is the *name* of the parameter you want printed.
 388 #   Note that foo is no typo; $foo would be wrong here!
 389 if ! is42 ; then
 390     uprint () {
 391         local -a u
 392         local w
 393         local parameter=${1}
 394
 395         if [[ -z ${parameter} ]] ; then
 396             printf 'usage: uprint <parameter>\n'
 397             return 1
 398         fi
 399
 400         for w in ${(P)parameter} ; do
 401             [[ -z ${(M)u:#${w}} ]] && u=( ${u} ${w} )
 402         done
 403
 404         builtin print -l ${u}
 405     }
 406 fi
 407
 408 # Check if we can read given files and source those we can.
 409 xsource() {
 410     if (( ${#argv} < 1 )) ; then
 411         printf 'usage: xsource FILE(s)...\n' >&2
 412         return 1
 413     fi
 414
 415     while (( ${#argv} > 0 )) ; do
 416         [[ -r ${1} ]] && source ${1}
 417         shift
 418     done
 419     return 0
 420 }
 421
 422 # Check if we can read a given file and 'cat(1)' it.
 423 xcat() {
 424     if (( ${#argv} != 1 )) ; then
 425         printf 'usage: xcat FILE\n' >&2
 426         return 1
 427     fi
 428
 429     [[ -r ${1} ]] && cat ${1}
 430     return 0
 431 }
 432
 433 # Remove these functions again, they are of use only in these
 434 # setup files. This should be called at the end of .zshrc.
 435 xunfunction() {
 436     local -a funcs
 437     funcs=(salias xcat xsource xunfunction zrcautoload)
 438
 439     for func in $funcs ; do
 440         [[ -n ${functions[$func]} ]] \
 441             && unfunction $func
 442     done
 443     return 0
 444 }
 445
 446 #}}}
 447
 448 # locale setup {{{
 449 if [[ -z "$LANG" ]] ; then
 450    xsource "/etc/default/locale"
 451 fi
 452
 453 export LANG=${LANG:-en_US.iso885915}
 454 for var in LC_ALL LC_MESSAGES ; do
 455     [[ -n ${(P)var} ]] && export $var
 456 done
 457
 458 xsource "/etc/sysconfig/keyboard"
 459
 460 TZ=$(xcat /etc/timezone)
 461 # }}}
 462
 463 # check for potentially old files in 'completion.d' {{{
 464 setopt extendedglob
 465 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 466 if (( ${#xof} > 0 )) ; then
 467     printf '\n -!- INFORMATION\n\n'
 468     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 469     printf ' -!- /etc/zsh/completion.d/.\n\n'
 470     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 471     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 472     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 473     printf ' -!- named _* to that directory.\n\n'
 474     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 475     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 476     printf ' -!- starting with an underscore are marked for automatic loading\n'
 477     printf ' -!- by default (so that is quite convenient).\n\n'
 478     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 479     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 480     printf ' -!- Delete the files for example via running:\n\n'
 481     printf "      rm ${xof}\n\n"
 482     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 483     printf ' -!- resolve the situation manually.\n\n'
 484     BROKEN_COMPLETION_DIR=1
 485 fi
 486 unset xof
 487 # }}}
 488
 489 # {{{ set some variables
 490 if check_com -c vim ; then
 491 #v#
 492     export EDITOR=${EDITOR:-vim}
 493 else
 494     export EDITOR=${EDITOR:-vi}
 495 fi
 496
 497 #v#
 498 export PAGER=${PAGER:-less}
 499
 500 #v#
 501 export MAIL=${MAIL:-/var/mail/$USER}
 502
 503 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 504 export SHELL='/bin/zsh'
 505
 506 # color setup for ls:
 507 check_com -c dircolors && eval $(dircolors -b)
 508 # color setup for ls on OS X:
 509 isdarwin && export CLICOLOR=1
 510
 511 # do MacPorts setup on darwin
 512 if isdarwin && [[ -d /opt/local ]]; then
 513     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 514     # zshenv.
 515     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 516     MANPATH="/opt/local/share/man:$MANPATH"
 517 fi
 518 # do Fink setup on darwin
 519 isdarwin && xsource /sw/bin/init.sh
 520
 521 # completion functions go to /etc/zsh/completion.d
 522 # function files may be put into /etc/zsh/functions.d, from where they
 523 # will be automatically autoloaded.
 524 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 525     print 'Warning: not setting completion directories because broken files have been found.' >&2
 526 else
 527     [[ -d /etc/zsh/completion.d ]] && fpath=( $fpath /etc/zsh/completion.d )
 528     if [[ -d /etc/zsh/functions.d ]] ; then
 529         fdir='/etc/zsh/functions.d'
 530         fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 531         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 532             zrcautoload ${func:t}
 533         done
 534         unset fdir
 535     fi
 536 fi
 537
 538 # automatically remove duplicates from these arrays
 539 typeset -U path cdpath fpath manpath
 540 # }}}
 541
 542 # {{{ keybindings
 543 if [[ "$TERM" != emacs ]] ; then
 544     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 545     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 546     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 547     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 548     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 549     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 550     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 551     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 552     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 553     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 554     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 555     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 556     # ncurses stuff:
 557     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 558     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 559     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 560     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 561     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 562     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 563     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 564     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 565 fi
 566
 567 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 568 # use emacs style per default:
 569 bindkey -e
 570 # use vi style:
 571 # bindkey -v
 572
 573 #if [[ "$TERM" == screen ]] ; then
 574 bindkey '\e[1~' beginning-of-line       # home
 575 bindkey '\e[4~' end-of-line             # end
 576 bindkey '\e[A'  up-line-or-search       # cursor up
 577 bindkey '\e[B'  down-line-or-search     # <ESC>-
 578
 579 bindkey '^xp'   history-beginning-search-backward
 580 bindkey '^xP'   history-beginning-search-forward
 581 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 582 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 583 # if terminal type is set to 'rxvt':
 584 bindkey '\e[7~' beginning-of-line       # home
 585 bindkey '\e[8~' end-of-line             # end
 586 #fi
 587
 588 # insert unicode character
 589 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 590 # See for example http://unicode.org/charts/ for unicode characters code
 591 zrcautoload insert-unicode-char
 592 zle -N insert-unicode-char
 593 #k# Insert Unicode character
 594 bindkey '^Xi' insert-unicode-char
 595
 596 # just type 'cd ...' to get 'cd ../..'
 597 #  rationalise-dot() {
 598 #  if [[ $LBUFFER == *.. ]] ; then
 599 #    LBUFFER+=/..
 600 #  else
 601 #    LBUFFER+=.
 602 #  fi
 603 #  }
 604 #  zle -N rationalise-dot
 605 #  bindkey . rationalise-dot
 606
 607 #  bindkey '\eq' push-line-or-edit
 608
 609 ## toggle the ,. abbreviation feature on/off
 610 # NOABBREVIATION: default abbreviation-state
 611 #                 0 - enabled (default)
 612 #                 1 - disabled
 613 NOABBREVIATION=${NOABBREVIATION:-0}
 614
 615 grml_toggle_abbrev() {
 616     if (( ${NOABBREVIATION} > 0 )) ; then
 617         NOABBREVIATION=0
 618     else
 619         NOABBREVIATION=1
 620     fi
 621 }
 622
 623 zle -N grml_toggle_abbrev
 624 bindkey '^xA' grml_toggle_abbrev
 625
 626 # }}}
 627
 628 # a generic accept-line wrapper {{{
 629
 630 # This widget can prevent unwanted autocorrections from command-name
 631 # to _command-name, rehash automatically on enter and call any number
 632 # of builtin and user-defined widgets in different contexts.
 633 #
 634 # For a broader description, see:
 635 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 636 #
 637 # The code is imported from the file 'zsh/functions/accept-line' from
 638 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 639 # distributed under the same terms as zsh itself.
 640
 641 # A newly added command will may not be found or will cause false
 642 # correction attempts, if you got auto-correction set. By setting the
 643 # following style, we force accept-line() to rehash, if it cannot
 644 # find the first word on the command line in the $command[] hash.
 645 zstyle ':acceptline:*' rehash true
 646
 647 function Accept-Line() {
 648     setopt localoptions noksharrays
 649     local -a subs
 650     local -xi aldone
 651     local sub
 652
 653     zstyle -a ":acceptline:${alcontext}" actions subs
 654
 655     (( ${#subs} < 1 )) && return 0
 656
 657     (( aldone = 0 ))
 658     for sub in ${subs} ; do
 659         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 660         zle ${sub}
 661
 662         (( aldone > 0 )) && break
 663     done
 664 }
 665
 666 function Accept-Line-getdefault() {
 667     local default_action
 668
 669     zstyle -s ":acceptline:${alcontext}" default_action default_action
 670     case ${default_action} in
 671         ((accept-line|))
 672             printf ".accept-line"
 673             ;;
 674         (*)
 675             printf ${default_action}
 676             ;;
 677     esac
 678 }
 679
 680 function accept-line() {
 681     setopt localoptions noksharrays
 682     local -a cmdline
 683     local -x alcontext
 684     local buf com fname format msg default_action
 685
 686     alcontext='default'
 687     buf="${BUFFER}"
 688     cmdline=(${(z)BUFFER})
 689     com="${cmdline[1]}"
 690     fname="_${com}"
 691
 692     zstyle -t ":acceptline:${alcontext}" rehash \
 693         && [[ -z ${commands[$com]} ]]           \
 694         && rehash
 695
 696     if    [[ -n ${reswords[(r)$com]} ]] \
 697        || [[ -n ${aliases[$com]}     ]] \
 698        || [[ -n ${functions[$com]}   ]] \
 699        || [[ -n ${builtins[$com]}    ]] \
 700        || [[ -n ${commands[$com]}    ]] ; then
 701
 702         # there is something sensible to execute, just do it.
 703         alcontext='normal'
 704         zle Accept-Line
 705
 706         default_action=$(Accept-Line-getdefault)
 707         zstyle -T ":acceptline:${alcontext}" call_default \
 708             && zle ${default_action}
 709         return
 710     fi
 711
 712     if    [[ -o correct              ]] \
 713        || [[ -o correctall           ]] \
 714        && [[ -n ${functions[$fname]} ]] ; then
 715
 716         # nothing there to execute but there is a function called
 717         # _command_name; a completion widget. Makes no sense to
 718         # call it on the commandline, but the correct{,all} options
 719         # will ask for it nevertheless, so warn the user.
 720         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 721             # Okay, we warned the user before, he called us again,
 722             # so have it his way.
 723             alcontext='force'
 724             zle Accept-Line
 725
 726             default_action=$(Accept-Line-getdefault)
 727             zstyle -T ":acceptline:${alcontext}" call_default \
 728                 && zle ${default_action}
 729             return
 730         fi
 731
 732         # prepare warning message for the user, configurable via zstyle.
 733         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 734
 735         if [[ -z ${msg} ]] ; then
 736             msg="%c will not execute and completion %f exists."
 737         fi
 738
 739         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 740
 741         zle -M -- "${msg}"
 742         return
 743     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 744         # If we are here, the commandline contains something that is not
 745         # executable, which is neither subject to _command_name correction
 746         # and is not empty. might be a variable assignment
 747         alcontext='misc'
 748         zle Accept-Line
 749
 750         default_action=$(Accept-Line-getdefault)
 751         zstyle -T ":acceptline:${alcontext}" call_default \
 752             && zle ${default_action}
 753         return
 754     fi
 755
 756     # If we got this far, the commandline only contains whitespace, or is empty.
 757     alcontext='empty'
 758     zle Accept-Line
 759
 760     default_action=$(Accept-Line-getdefault)
 761     zstyle -T ":acceptline:${alcontext}" call_default \
 762         && zle ${default_action}
 763 }
 764
 765 zle -N accept-line
 766 zle -N Accept-Line
 767
 768 # }}}
 769
 770 # power completion - abbreviation expansion {{{
 771 # power completion / abbreviation expansion / buffer expansion
 772 # see http://zshwiki.org/home/examples/zleiab for details
 773 # less risky than the global aliases but powerful as well
 774 # just type the abbreviation key and afterwards ',.' to expand it
 775 declare -A abk
 776 setopt extendedglob
 777 setopt interactivecomments
 778 abk=(
 779 # key  # value                (#d additional doc string)
 780 #A# start
 781     '...' '../..'
 782     '....' '../../..'
 783     'BG' '& exit'
 784     'C' '| wc -l'
 785     'G' '|& grep --color=auto'
 786     'H' '| head'
 787     'Hl' ' --help |& less -r'      #d (Display help in pager)
 788     'L' '| less'
 789     'LL' '|& less -r'
 790     'M' '| most'
 791     'N' '&>/dev/null'              #d (No Output)
 792     'R' '| tr A-z N-za-m'          #d (ROT13)
 793     'SL' '| sort | less'
 794     'S' '| sort -u'
 795     'T' '| tail'
 796     'V' '|& vim -'
 797 #A# end
 798     'hide' "echo -en '\033]50;nil2\007'"
 799     'tiny' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
 800     'small' 'echo -en "\033]50;6x10\007"'
 801     'medium' 'echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
 802     'default' 'echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
 803     'large' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
 804     'huge' 'echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
 805     'smartfont' 'echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
 806     'semifont' 'echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
 807     'da' 'du -sch'
 808     'j' 'jobs -l'
 809     'u' 'translate -i'
 810     'co' "./configure && make && sudo make install"
 811     'CH' "./configure --help"
 812     'conkeror' 'firefox -chrome chrome://conkeror/content'
 813     'dir' 'ls -lSrah'
 814     'lad' $'ls -d .*(/)\n# only show dot-directories'
 815     'lsa' $'ls -a .*(.)\n# only show dot-files'
 816     'lss' $'ls -l *(s,S,t)\n# only files with setgid/setuid/sticky flag'
 817     'lsl' $'ls -l *(@[1,10])\n# only symlinks'
 818     'lsx' $'ls -l *(*[1,10])\n# only executables'
 819     'lsw' $'ls -ld *(R,W,X.^ND/)\n# world-{readable,writable,executable} files'
 820     'lsbig' $'ls -flh *(.OL[1,10])\n# display the biggest files'
 821     'lsd' $'ls -d *(/)\n# only show directories'
 822     'lse' $'ls -d *(/^F)\n# only show empty directories'
 823     'lsnew' $'ls -rl *(D.om[1,10])\n# display the newest files'
 824     'lsold' $'ls -rtlh *(D.om[-11,-1])\n # display the oldest files'
 825     'lssmall' $'ls -Srl *(.oL[1,10])\n# display the smallest files'
 826     'rw-' 'chmod 600'
 827     '600' 'chmod u+rw-x,g-rwx,o-rwx'
 828     'rwx' 'chmod u+rwx'
 829     '700' 'chmod u+rwx,g-rwx,o-rwx'
 830     'r--' 'chmod u+r-wx,g-rwx,o-rwx'
 831     '644' $'chmod u+rw-x,g+r-wx,o+r-wx\n # 4=r,2=w,1=x'
 832     '755' 'chmod u+rwx,g+r-w+x,o+r-w+x'
 833     'md' 'mkdir -p '
 834     'cmplayer' 'mplayer -vo -fs -zoom fbdev'
 835     'fbmplayer' 'mplayer -vo -fs -zoom fbdev'
 836     'fblinks' 'links2 -driver fb'
 837     'insecssh' 'ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 838     'insecscp' 'scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
 839     'fori' 'for i ({..}) { }'
 840     'cx' 'chmod +x'
 841     'e'  'print -l'
 842     'se' 'setopt interactivecomments'
 843     'va' 'valac --vapidir=../vapi/ --pkg=gtk+-2.0 gtktest.vala'
 844     'fb2' '=mplayer -vo fbdev -fs -zoom 1>/dev/null -xy 2'
 845     'fb3' '=mplayer -vo fbdev -fs  -zoom 1>/dev/null -xy 3'
 846     'ci' 'centericq'
 847     'D'  'export DISPLAY=:0.0'
 848     'mp' 'mplayer -vo xv -fs -zoom'
 849 )
 850
 851 globalias() {
 852     local MATCH
 853
 854     if (( NOABBREVIATION > 0 )) ; then
 855         LBUFFER="${LBUFFER},."
 856         return 0
 857     fi
 858
 859     matched_chars='[.-|_a-zA-Z0-9]#'
 860     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 861     LBUFFER+=${abk[$MATCH]:-$MATCH}
 862 }
 863
 864 zle -N globalias
 865 bindkey ",." globalias
 866 # }}}
 867
 868 # {{{ autoloading
 869 zrcautoload zmv    # who needs mmv or rename?
 870 zrcautoload history-search-end
 871
 872 # we don't want to quote/espace URLs on our own...
 873 # if autoload -U url-quote-magic ; then
 874 #    zle -N self-insert url-quote-magic
 875 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 876 # else
 877 #    print 'Notice: no url-quote-magic available :('
 878 # fi
 879 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 880
 881 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 882 alias run-help >&/dev/null && unalias run-help
 883 zrcautoload run-help # use via 'esc-h'
 884
 885 # completion system
 886 if zrcautoload compinit && compinit 2>/dev/null ; then
 887     compinit 2>/dev/null || print 'Notice: no compinit available :('
 888 else
 889     print 'Notice: no compinit available :('
 890     function zstyle { }
 891     function compdef { }
 892 fi
 893
 894 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 895
 896 is4 && \
 897 for mod in complist deltochar mathfunc ; do
 898     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 899 done
 900
 901 # autoload zsh modules when they are referenced
 902 if is4 ; then
 903     tmpargs=(
 904         a   stat
 905         a   zpty
 906         ap  mapfile
 907     )
 908
 909     while (( ${#tmpargs} > 0 )) ; do
 910         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 911         shift 2 tmpargs
 912     done
 913     unset tmpargs
 914 fi
 915
 916 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 917     #k# Insert files
 918     bindkey "^Xf" insert-files # C-x-f
 919 fi
 920
 921 bindkey ' '   magic-space    # also do history expansion on space
 922 #k# Trigger menu-complete
 923 bindkey '\ei' menu-complete  # menu completion via esc-i
 924
 925 # press esc-e for editing command line in $EDITOR or $VISUAL
 926 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 927     #k# Edit the current line in \kbd{\$EDITOR}
 928     bindkey '\ee' edit-command-line
 929 fi
 930
 931 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 932     #k# menu selection: pick item but stay in the menu
 933     bindkey -M menuselect '\e^M' accept-and-menu-complete
 934
 935     # accept a completion and try to complete again by using menu
 936     # completion; very useful with completing directories
 937     # by using 'undo' one's got a simple file browser
 938     bindkey -M menuselect '^o' accept-and-infer-next-history
 939 fi
 940
 941 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 942 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 943 zle -N _bkdate
 944
 945 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 946 bindkey '^Ed' _bkdate
 947
 948 # press esc-m for inserting last typed word again (thanks to caphuso!)
 949 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 950 zle -N insert-last-typed-word;
 951
 952 #k# Insert last typed word
 953 bindkey "\em" insert-last-typed-word
 954
 955 #k# Shortcut for \kbd{fg<enter>}
 956 bindkey -s '^z' "fg\n"
 957
 958 # run command line as user root via sudo:
 959 sudo-command-line() {
 960     [[ -z $BUFFER ]] && zle up-history
 961     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 962 }
 963 zle -N sudo-command-line
 964
 965 #k# Put the current command line into a \kbd{sudo} call
 966 bindkey "^Os" sudo-command-line
 967
 968 ### jump behind the first word on the cmdline.
 969 ### useful to add options.
 970 function jump_after_first_word() {
 971     local words
 972     words=(${(z)BUFFER})
 973
 974     if (( ${#words} <= 1 )) ; then
 975         CURSOR=${#BUFFER}
 976     else
 977         CURSOR=${#${words[1]}}
 978     fi
 979 }
 980 zle -N jump_after_first_word
 981
 982 bindkey '^x1' jump_after_first_word
 983
 984 # }}}
 985
 986 # {{{ set some important options
 987 # Please update these tags, if you change the umask settings below.
 988 #o# r_umask     002
 989 #o# r_umaskstr  rwxrwxr-x
 990 #o# umask       022
 991 #o# umaskstr    rwxr-xr-x
 992 (( EUID != 0 )) && umask 002 || umask 022
 993
 994 # history:
 995 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 996 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 997 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 998 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 999                             # list duplicates an older one, the older command is removed from the list
1000 setopt histignorespace      # remove command lines from the history list when
1001                             # the first character on the line is a space
1002 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
1003                             # and the command is the name of a directory, perform the cd command to that directory
1004 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
1005                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
1006                             # -> searches for word not in compressed files
1007                             # don't forget to quote '^', '~' and '#'!
1008 setopt longlistjobs         # display PID when suspending processes as well
1009 setopt notify               # report the status of backgrounds jobs immediately
1010 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
1011                             # the entire command path is hashed first.
1012 setopt completeinword       # not just at the end
1013 setopt nohup                # and don't kill them, either
1014 setopt auto_pushd           # make cd push the old directory onto the directory stack.
1015 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
1016 setopt nobeep               # avoid "beep"ing
1017 setopt pushd_ignore_dups    # don't push the same dir twice.
1018
1019 MAILCHECK=30       # mailchecks
1020 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
1021 watch=(notme root) # watch for everyone but me and root
1022
1023 # only slash should be considered as a word separator:
1024 slash-backward-kill-word() {
1025     local WORDCHARS="${WORDCHARS:s@/@}"
1026     # zle backward-word
1027     zle backward-kill-word
1028 }
1029 zle -N slash-backward-kill-word
1030
1031 #k# Kill everything in a word up to its last \kbd{/}
1032 bindkey '\ev' slash-backward-kill-word
1033
1034 # }}}
1035
1036 # {{{ history
1037
1038 ZSHDIR=$HOME/.zsh
1039
1040 #v#
1041 HISTFILE=$HOME/.zsh_history
1042 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1043 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1044
1045 # }}}
1046
1047 # dirstack handling {{{
1048
1049 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1050 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1051
1052 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1053     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1054     # "cd -" won't work after login by just setting $OLDPWD, so
1055     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
1056 fi
1057
1058 chpwd() {
1059     if is42 ; then
1060         builtin print -l ${(u)dirstack} >! ${DIRSTACKFILE}
1061     else
1062         uprint dirstack >! ${DIRSTACKFILE}
1063     fi
1064 }
1065
1066 # }}}
1067
1068 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1069 if [[ $BATTERY -gt 0 ]] ; then
1070     if ! check_com -c acpi ; then
1071         BATTERY=0
1072     fi
1073 fi
1074
1075 battery() {
1076 if [[ $BATTERY -gt 0 ]] ; then
1077     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]##Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1078     if [[ -z "$PERCENT" ]] ; then
1079         PERCENT='acpi not present'
1080     else
1081         if [[ "$PERCENT" -lt 20 ]] ; then
1082             PERCENT="warning: ${PERCENT}%%"
1083         else
1084             PERCENT="${PERCENT}%%"
1085         fi
1086     fi
1087 fi
1088 }
1089 # }}}
1090
1091 # set colors for use in prompts {{{
1092 if zrcautoload colors && colors 2>/dev/null ; then
1093     BLUE="%{${fg[blue]}%}"
1094     RED="%{${fg_bold[red]}%}"
1095     GREEN="%{${fg[green]}%}"
1096     CYAN="%{${fg[cyan]}%}"
1097     MAGENTA="%{${fg[magenta]}%}"
1098     YELLOW="%{${fg[yellow]}%}"
1099     WHITE="%{${fg[white]}%}"
1100     NO_COLOUR="%{${reset_color}%}"
1101 else
1102     BLUE=$'%{\e[1;34m%}'
1103     RED=$'%{\e[1;31m%}'
1104     GREEN=$'%{\e[1;32m%}'
1105     CYAN=$'%{\e[1;36m%}'
1106     WHITE=$'%{\e[1;37m%}'
1107     MAGENTA=$'%{\e[1;35m%}'
1108     YELLOW=$'%{\e[1;33m%}'
1109     NO_COLOUR=$'%{\e[0m%}'
1110 fi
1111
1112 # }}}
1113
1114 # gather version control information for inclusion in a prompt {{{
1115
1116 if ! is41 ; then
1117     # Be quiet about version problems in grml's zshrc as the user cannot disable
1118     # loading vcs_info() as it is *in* the zshrc - as you can see. :-)
1119     # Just unset most probable variables and disable vcs_info altogether.
1120     local -i i
1121     for i in {0..9} ; do
1122         unset VCS_INFO_message_${i}_
1123     done
1124     zstyle ':vcs_info:*' enable false
1125 fi
1126
1127 # The following code is imported from the file 'zsh/functions/vcs_info'
1128 # from <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>,
1129 # which distributed under the same terms as zsh itself.
1130
1131 # we will be using two variables, so let the code know now.
1132 zstyle ':vcs_info:*' max-exports 2
1133
1134 # vcs_info() documentation:
1135 #{{{
1136 # REQUIREMENTS:
1137 #{{{
1138 #     This functionality requires zsh version >= 4.1.*.
1139 #}}}
1140 #
1141 # LOADING:
1142 #{{{
1143 # To load vcs_info(), copy this file to your $fpath[] and do:
1144 #   % autoload -Uz vcs_info && vcs_info
1145 #
1146 # To work, vcs_info() needs 'setopt prompt_subst' in your setup.
1147 #}}}
1148 #
1149 # QUICKSTART:
1150 #{{{
1151 # To get vcs_info() working quickly (including colors), you can do the
1152 # following (assuming, you loaded vcs_info() properly - see above):
1153 #
1154 # % RED=$'%{\e[31m%}'
1155 # % GR=$'%{\e[32m%}'
1156 # % MA=$'%{\e[35m%}'
1157 # % YE=$'%{\e[33m%}'
1158 # % NC=$'%{\e[0m%}'
1159 #
1160 # % zstyle ':vcs_info:*' actionformats \
1161 #       "${MA}(${NC}%s${MA})${YE}-${MA}[${GR}%b${YE}|${RED}%a${MA}]${NC} "
1162 #
1163 # % zstyle ':vcs_info:*' formats       \
1164 #       "${MA}(${NC}%s${MA})${Y}-${MA}[${GR}%b${MA}]${NC}%} "
1165 #
1166 # % zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YE}%r"
1167 #
1168 # % precmd () { vcs_info }
1169 # % PS1='${MA}[${GR}%n${MA}] ${MA}(${RED}%!${MA}) ${YE}%3~ ${VCS_INFO_message_0_}${NC}%# '
1170 #
1171 # Obviously, the las two lines are there for demonstration: You need to
1172 # call vcs_info() from your precmd() function (see 'SPECIAL FUNCTIONS' in
1173 # 'man zshmisc'). Once that is done you need a *single* quoted
1174 # '${VCS_INFO_message_0_}' in your prompt.
1175 #
1176 # Now call the 'vcs_info_printsys' utility from the command line:
1177 #
1178 # % vcs_info_printsys
1179 # # list of supported version control backends:
1180 # # disabled systems are prefixed by a hash sign (#)
1181 # git
1182 # hg
1183 # bzr
1184 # darcs
1185 # svk
1186 # mtn
1187 # svn
1188 # cvs
1189 # cdv
1190 # tla
1191 # # flavours (cannot be used in the disable style; they
1192 # # are disabled with their master [git-svn -> git]):
1193 # git-p4
1194 # git-svn
1195 #
1196 # Ten version control backends as you can see. You may not want all
1197 # of these. Because there is no point in running the code to detect
1198 # systems you do not use. ever. So, there is a way to disable some
1199 # backends altogether:
1200 #
1201 # % zstyle ':vcs_info:*' disable bzr cdv darcs mtn svk tla
1202 #
1203 # If you rerun 'vcs_info_printsys' now, you will see the backends listed
1204 # in the 'disable' style marked as diabled by a hash sign. That means the
1205 # detection of these systems is skipped *completely*. No wasted time there.
1206 #
1207 # For more control, read the reference below.
1208 #}}}
1209 #
1210 # CONFIGURATION:
1211 #{{{
1212 # The vcs_info() feature can be configured via zstyle.
1213 #
1214 # First, the context in which we are working:
1215 #       :vcs_info:<vcs-string>:<user-context>
1216 #
1217 # ...where <vcs-string> is one of:
1218 #   - git, git-svn, git-p4, hg, darcs, bzr, cdv, mtn, svn, cvs, svk or tla.
1219 #
1220 # ...and <user-context> is a freely configurable string, assignable by the
1221 # user as the first argument to vcs_info() (see its description below).
1222 #
1223 # There is are three special values for <vcs-string>: The first is named
1224 # 'init', that is in effect as long as there was no decision what vcs
1225 # backend to use. The second is 'preinit; it is used *before* vcs_info()
1226 # is run, when initializing the data exporting variables. The third
1227 # special value is 'formats' and is used by the 'vcs_info_lastmsg' for
1228 # looking up its styles.
1229 #
1230 # There are two pre-defined values for <user-context>:
1231 #   default  - the one used if none is specified
1232 #   command  - used by vcs_info_lastmsg to lookup its styles.
1233 #
1234 # You may *not* use 'print_systems_' as a user-context string, because it
1235 # is used internally.
1236 #
1237 # You can of course use ':vcs_info:*' to match all VCSs in all
1238 # user-contexts at once.
1239 #
1240 # Another special context is 'formats', which is used by the
1241 # vcs_info_lastmsg() utility function (see below).
1242 #
1243 #
1244 # This is a description of all styles, that are looked up:
1245 #   formats             - A list of formats, used when actionformats is not
1246 #                         used (which is most of the time).
1247 #   actionformats       - A list of formats, used if a there is a special
1248 #                         action going on in your current repository;
1249 #                         (like an interactive rebase or a merge conflict)
1250 #   branchformat        - Some backends replace %b in the formats and
1251 #                         actionformats styles above, not only by a branch
1252 #                         name but also by a revision number. This style
1253 #                         let's you modify how that string should look like.
1254 #   nvcsformats         - These "formats" are exported, when we didn't detect
1255 #                         a version control system for the current directory.
1256 #                         This is useful, if you want vcs_info() to completely
1257 #                         take over the generation of your prompt.
1258 #                         You would do something like
1259 #                           PS1='${VCS_INFO_message_0_}'
1260 #                         to accomplish that.
1261 #   max-exports         - Defines the maximum number if VCS_INFO_message_*_
1262 #                         variables vcs_info() will export.
1263 #   enable              - Checked in the 'init' context. If set to false,
1264 #                         vcs_info() will do nothing.
1265 #   disable             - Provide a list of systems, you don't want
1266 #                         the vcs_info() to check for repositories
1267 #                         (checked in the 'init' context, too).
1268 #   disable-patterns    - A list of patterns that are checked against $PWD.
1269 #                         If the pattern matches, vcs_info will be disabled.
1270 #                         Say, ~/.zsh is a directory under version control,
1271 #                         in which you do not want vcs_info to be active, do:
1272 #                         zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh+(|/*)"
1273 #   use-simple          - If there are two different ways of gathering
1274 #                         information, you can select the simpler one
1275 #                         by setting this style to true; the default
1276 #                         is to use the not-that-simple code, which is
1277 #                         potentially a lot slower but might be more
1278 #                         accurate in all possible cases.
1279 #   use-prompt-escapes  - determines if we assume that the assembled
1280 #                         string from vcs_info() includes prompt escapes.
1281 #                         (Used by vcs_info_lastmsg().
1282 #
1283 # The use-simple style is only available for the bzr backend.
1284 #
1285 # The default values for these in all contexts are:
1286 #   formats             " (%s)-[%b|%a]-"
1287 #   actionformats       " (%s)-[%b]-"
1288 #   branchformat        "%b:%r" (for bzr, svn and svk)
1289 #   nvcsformats         ""
1290 #   max-exports         2
1291 #   enable              true
1292 #   disable             (empty list)
1293 #   disable-patterns    (empty list)
1294 #   use-simple          false
1295 #   use-prompt-escapes  true
1296 #
1297 #
1298 # In normal formats and actionformats, the following replacements
1299 # are done:
1300 #   %s  - The vcs in use (git, hg, svn etc.)
1301 #   %b  - Information about the current branch.
1302 #   %a  - An identifier, that describes the action.
1303 #         Only makes sense in actionformats.
1304 #   %R  - base directory of the repository.
1305 #   %r  - repository name
1306 #         If %R is '/foo/bar/repoXY', %r is 'repoXY'.
1307 #   %S  - subdirectory within a repository. if $PWD is
1308 #         '/foo/bar/reposXY/beer/tasty', %S is 'beer/tasty'.
1309 #
1310 #
1311 # In branchformat these replacements are done:
1312 #   %b  - the branch name
1313 #   %r  - the current revision number
1314 #
1315 # Not all vcs backends have to support all replacements.
1316 # nvcsformat does not perform *any* replacements. It is just a string.
1317 #}}}
1318 #
1319 # ODDITIES:
1320 #{{{
1321 # If you want to use the %b (bold off) prompt expansion in 'formats', which
1322 # expands %b itself, use %%b. That will cause the vcs_info() expansion to
1323 # replace %%b with %b. So zsh's prompt expansion mechanism can handle it.
1324 # Similarly, to hand down %b from branchformat, use %%%%b. Sorry for this
1325 # inconvenience, but it cannot be easily avoided. Luckily we do not clash
1326 # with a lot of prompt expansions and this only needs to be done for those.
1327 # See 'man zshmisc' for details about EXPANSION OF PROMPT SEQUENCES.
1328 #}}}
1329 #
1330 # FUNCTION DESCRIPTIONS (public API):
1331 #{{{
1332 #   vcs_info()
1333 #       The main function, that runs all backends and assembles
1334 #       all data into ${VCS_INFO_message_*_}. This is the function
1335 #       you want to call from precmd() if you want to include
1336 #       up-to-date information in your prompt (see VARIABLE
1337 #       DESCRIPTION below).
1338 #
1339 #   vcs_info_printsys()
1340 #       Prints a list of all supported version control systems.
1341 #       Useful to find out possible contexts (and which of them are enabled)
1342 #       or values for the 'disable' style.
1343 #
1344 #   vcs_info_lastmsg()
1345 #       Outputs the last ${VCS_INFO_message_*_} value. Takes into account
1346 #       the value of the use-prompt-escapes style in ':vcs_info:formats'.
1347 #       It also only prints max-exports values.
1348 #
1349 # All functions named VCS_INFO_* are for internal use only.
1350 #}}}
1351 #
1352 # VARIABLE DESCRIPTION:
1353 #{{{
1354 #   ${VCS_INFO_message_N_}    (Note the trailing underscore)
1355 #       Where 'N' is an integer, eg: VCS_INFO_message_0_
1356 #       These variables are the storage for the informational message the
1357 #       last vcs_info() call has assembled. These are strongly connected
1358 #       to the formats, actionformats and nvcsformats styles described
1359 #       above. Those styles are lists. the first member of that list gets
1360 #       expanded into ${VCS_INFO_message_0_}, the second into
1361 #       ${VCS_INFO_message_1_} and the Nth into ${VCS_INFO_message_N-1_}.
1362 #       These parameters are exported into the environment.
1363 #       (See the max-exports style above.)
1364 #}}}
1365 #
1366 # EXAMPLES:
1367 #{{{
1368 #   Don't use vcs_info at all (even though it's in your prompt):
1369 #   % zstyle ':vcs_info:*' enable false
1370 #
1371 #   Disable the backends for bzr and svk:
1372 #   % zstyle ':vcs_info:*' disable bzr svk
1373 #
1374 #   Provide a special formats for git:
1375 #   % zstyle ':vcs_info:git:*' formats       ' GIT, BABY! [%b]'
1376 #   % zstyle ':vcs_info:git:*' actionformats ' GIT ACTION! [%b|%a]'
1377 #
1378 #   Use the quicker bzr backend (if you do, please report if it does
1379 #   the-right-thing[tm] - thanks):
1380 #   % zstyle ':vcs_info:bzr:*' use-simple true
1381 #
1382 #   Display the revision number in yellow for bzr and svn:
1383 #   % zstyle ':vcs_info:(svn|bzr):*' branchformat '%b%{'${fg[yellow]}'%}:%r'
1384 #
1385 # If you want colors, make sure you enclose the color codes in %{...%},
1386 # if you want to use the string provided by vcs_info() in prompts.
1387 #
1388 # Here is how to print the vcs infomation as a command:
1389 #   % alias vcsi='vcs_info command; vcs_info_lastmsg'
1390 #
1391 #   This way, you can even define different formats for output via
1392 #   vcs_info_lastmsg() in the ':vcs_info:command:*' namespace.
1393 #}}}
1394 #}}}
1395 # utilities
1396 VCS_INFO_adjust () { #{{{
1397     [[ -n ${vcs_comm[overwrite_name]} ]] && vcs=${vcs_comm[overwrite_name]}
1398     return 0
1399 }
1400 # }}}
1401 VCS_INFO_check_com () { #{{{
1402     (( ${+commands[$1]} )) && [[ -x ${commands[$1]} ]] && return 0
1403     return 1
1404 }
1405 # }}}
1406 VCS_INFO_formats () { # {{{
1407     setopt localoptions noksharrays
1408     local action=$1 branch=$2 base=$3
1409     local msg
1410     local -i i
1411
1412     if [[ -n ${action} ]] ; then
1413         zstyle -a ":vcs_info:${vcs}:${usercontext}" actionformats msgs
1414         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b|%a]-'
1415     else
1416         zstyle -a ":vcs_info:${vcs}:${usercontext}" formats msgs
1417         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b]-'
1418     fi
1419
1420     (( ${#msgs} > maxexports )) && msgs[$(( maxexports + 1 )),-1]=()
1421     for i in {1..${#msgs}} ; do
1422         zformat -f msg ${msgs[$i]}                      \
1423                         a:${action}                     \
1424                         b:${branch}                     \
1425                         r:${base:t}                     \
1426                         s:${vcs}                        \
1427                         R:${base}                       \
1428                         S:"$(VCS_INFO_reposub ${base})"
1429         msgs[$i]=${msg}
1430     done
1431     return 0
1432 }
1433 # }}}
1434 VCS_INFO_maxexports () { #{{{
1435     zstyle -s ":vcs_info:${vcs}:${usercontext}" "max-exports" maxexports || maxexports=2
1436     if [[ ${maxexports} != <-> ]] || (( maxexports < 1 )); then
1437         printf 'vcs_info(): expecting numeric arg >= 1 for max-exports (got %s).\n' ${maxexports}
1438         printf 'Defaulting to 2.\n'
1439         maxexports=2
1440     fi
1441 }
1442 # }}}
1443 VCS_INFO_nvcsformats () { #{{{
1444     setopt localoptions noksharrays
1445     local c v
1446
1447     if [[ $1 == 'preinit' ]] ; then
1448         c=default
1449         v=preinit
1450     fi
1451     zstyle -a ":vcs_info:${v:-$vcs}:${c:-$usercontext}" nvcsformats msgs
1452     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1453 }
1454 # }}}
1455 VCS_INFO_realpath () { #{{{
1456     # a portable 'readlink -f'
1457     # forcing a subshell, to ensure chpwd() is not removed
1458     # from the calling shell (if VCS_INFO_realpath() is called
1459     # manually).
1460     (
1461         (( ${+functions[chpwd]} )) && unfunction chpwd
1462         setopt chaselinks
1463         cd $1 2>/dev/null && pwd
1464     )
1465 }
1466 # }}}
1467 VCS_INFO_reposub () { #{{{
1468     setopt localoptions extendedglob
1469     local base=${1%%/##}
1470
1471     [[ ${PWD} == ${base}/* ]] || {
1472         printf '.'
1473         return 1
1474     }
1475     printf '%s' ${PWD#$base/}
1476     return 0
1477 }
1478 # }}}
1479 VCS_INFO_set () { #{{{
1480     setopt localoptions noksharrays
1481     local -i i j
1482
1483     if [[ $1 == '--clear' ]] ; then
1484         for i in {0..9} ; do
1485             unset VCS_INFO_message_${i}_
1486         done
1487     fi
1488     if [[ $1 == '--nvcs' ]] ; then
1489         [[ $2 == 'preinit' ]] && (( maxexports == 0 )) && (( maxexports = 1 ))
1490         for i in {0..$((maxexports - 1))} ; do
1491             typeset -gx VCS_INFO_message_${i}_=
1492         done
1493         VCS_INFO_nvcsformats $2
1494     fi
1495
1496     (( ${#msgs} - 1 < 0 )) && return 0
1497     for i in {0..$(( ${#msgs} - 1 ))} ; do
1498         (( j = i + 1 ))
1499         typeset -gx VCS_INFO_message_${i}_=${msgs[$j]}
1500     done
1501     return 0
1502 }
1503 # }}}
1504 # information gathering
1505 VCS_INFO_bzr_get_data () { # {{{
1506     setopt localoptions noksharrays
1507     local bzrbase bzrbr
1508     local -a bzrinfo
1509
1510     if zstyle -t ":vcs_info:${vcs}:${usercontext}" "use-simple" ; then
1511         bzrbase=${vcs_comm[basedir]}
1512         bzrinfo[2]=${bzrbase:t}
1513         if [[ -f ${bzrbase}/.bzr/branch/last-revision ]] ; then
1514             bzrinfo[1]=$(< ${bzrbase}/.bzr/branch/last-revision)
1515             bzrinfo[1]=${${bzrinfo[1]}%% *}
1516         fi
1517     else
1518         bzrbase=${${(M)${(f)"$( bzr info )"}:# ##branch\ root:*}/*: ##/}
1519         bzrinfo=( ${${${(M)${(f)"$( bzr version-info )"}:#(#s)(revno|branch-nick)*}/*: /}/*\//} )
1520         bzrbase="$(VCS_INFO_realpath ${bzrbase})"
1521     fi
1522
1523     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat bzrbr || bzrbr="%b:%r"
1524     zformat -f bzrbr "${bzrbr}" "b:${bzrinfo[2]}" "r:${bzrinfo[1]}"
1525     VCS_INFO_formats '' "${bzrbr}" "${bzrbase}"
1526     return 0
1527 }
1528 # }}}
1529 VCS_INFO_cdv_get_data () { # {{{
1530     local cdvbase
1531
1532     cdvbase=${vcs_comm[basedir]}
1533     VCS_INFO_formats '' "${cdvbase:t}" "${cdvbase}"
1534     return 0
1535 }
1536 # }}}
1537 VCS_INFO_cvs_get_data () { # {{{
1538     local cvsbranch cvsbase basename
1539
1540     cvsbase="."
1541     while [[ -d "${cvsbase}/../CVS" ]]; do
1542         cvsbase="${cvsbase}/.."
1543     done
1544     cvsbase="$(VCS_INFO_realpath ${cvsbase})"
1545     cvsbranch=$(< ./CVS/Repository)
1546     basename=${cvsbase:t}
1547     cvsbranch=${cvsbranch##${basename}/}
1548     [[ -z ${cvsbranch} ]] && cvsbranch=${basename}
1549     VCS_INFO_formats '' "${cvsbranch}" "${cvsbase}"
1550     return 0
1551 }
1552 # }}}
1553 VCS_INFO_darcs_get_data () { # {{{
1554     local darcsbase
1555
1556     darcsbase=${vcs_comm[basedir]}
1557     VCS_INFO_formats '' "${darcsbase:t}" "${darcsbase}"
1558     return 0
1559 }
1560 # }}}
1561 VCS_INFO_git_getaction () { #{{{
1562     local gitaction='' gitdir=$1
1563     local tmp
1564
1565     for tmp in "${gitdir}/rebase-apply" \
1566                "${gitdir}/rebase"       \
1567                "${gitdir}/../.dotest" ; do
1568         if [[ -d ${tmp} ]] ; then
1569             if   [[ -f "${tmp}/rebasing" ]] ; then
1570                 gitaction="rebase"
1571             elif [[ -f "${tmp}/applying" ]] ; then
1572                 gitaction="am"
1573             else
1574                 gitaction="am/rebase"
1575             fi
1576             printf '%s' ${gitaction}
1577             return 0
1578         fi
1579     done
1580
1581     for tmp in "${gitdir}/rebase-merge/interactive" \
1582                "${gitdir}/.dotest-merge/interactive" ; do
1583         if [[ -f "${tmp}" ]] ; then
1584             printf '%s' "rebase-i"
1585             return 0
1586         fi
1587     done
1588
1589     for tmp in "${gitdir}/rebase-merge" \
1590                "${gitdir}/.dotest-merge" ; do
1591         if [[ -d "${tmp}" ]] ; then
1592             printf '%s' "rebase-m"
1593             return 0
1594         fi
1595     done
1596
1597     if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1598         printf '%s' "merge"
1599         return 0
1600     fi
1601
1602     if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
1603         printf '%s' "bisect"
1604         return 0
1605     fi
1606     return 1
1607 }
1608 # }}}
1609 VCS_INFO_git_getbranch () { #{{{
1610     local gitbranch gitdir=$1
1611     local gitsymref='git symbolic-ref HEAD'
1612
1613     if    [[ -d "${gitdir}/rebase-apply" ]] \
1614        || [[ -d "${gitdir}/rebase" ]]       \
1615        || [[ -d "${gitdir}/../.dotest" ]]   \
1616        || [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1617         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1618         [[ -z ${gitbranch} ]] && [[ -r ${gitdir}/rebase-apply/head-name ]] \
1619             && gitbranch="$(< ${gitdir}/rebase-apply/head-name)"
1620
1621     elif   [[ -f "${gitdir}/rebase-merge/interactive" ]] \
1622         || [[ -d "${gitdir}/rebase-merge" ]] ; then
1623         gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
1624
1625     elif   [[ -f "${gitdir}/.dotest-merge/interactive" ]] \
1626         || [[ -d "${gitdir}/.dotest-merge" ]] ; then
1627         gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
1628
1629     else
1630         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1631
1632         if [[ $? -ne 0 ]] ; then
1633             gitbranch="$(git describe --exact-match HEAD 2>/dev/null)"
1634
1635             if [[ $? -ne 0 ]] ; then
1636                 gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
1637             fi
1638         fi
1639     fi
1640
1641     printf '%s' "${gitbranch##refs/heads/}"
1642     return 0
1643 }
1644 # }}}
1645 VCS_INFO_git_get_data () { # {{{
1646     setopt localoptions extendedglob
1647     local gitdir gitbase gitbranch gitaction
1648
1649     gitdir=${vcs_comm[gitdir]}
1650     gitbranch="$(VCS_INFO_git_getbranch ${gitdir})"
1651
1652     if [[ -z ${gitdir} ]] || [[ -z ${gitbranch} ]] ; then
1653         return 1
1654     fi
1655
1656     VCS_INFO_adjust
1657     gitaction="$(VCS_INFO_git_getaction ${gitdir})"
1658     gitbase=${PWD%/${$( git rev-parse --show-prefix )%/##}}
1659     VCS_INFO_formats "${gitaction}" "${gitbranch}" "${gitbase}"
1660     return 0
1661 }
1662 # }}}
1663 VCS_INFO_hg_get_data () { # {{{
1664     local hgbranch hgbase
1665
1666     hgbase=${vcs_comm[basedir]}
1667     hgbranch=$(< ${hgbase}/.hg/branch)
1668     VCS_INFO_formats '' "${hgbranch}" "${hgbase}"
1669     return 0
1670 }
1671 # }}}
1672 VCS_INFO_mtn_get_data () { # {{{
1673     local mtnbranch mtnbase
1674
1675     mtnbase=${vcs_comm[basedir]}
1676     mtnbranch=${${(M)${(f)"$( mtn status )"}:#(#s)Current branch:*}/*: /}
1677     VCS_INFO_formats '' "${mtnbranch}" "${mtnbase}"
1678     return 0
1679 }
1680 # }}}
1681 VCS_INFO_svk_get_data () { # {{{
1682     local svkbranch svkbase
1683
1684     svkbase=${vcs_comm[basedir]}
1685     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svkbranch || svkbranch="%b:%r"
1686     zformat -f svkbranch "${svkbranch}" "b:${vcs_comm[branch]}" "r:${vcs_comm[revision]}"
1687     VCS_INFO_formats '' "${svkbranch}" "${svkbase}"
1688     return 0
1689 }
1690 # }}}
1691 VCS_INFO_svn_get_data () { # {{{
1692     setopt localoptions noksharrays
1693     local svnbase svnbranch
1694     local -a svninfo
1695
1696     svnbase="."
1697     while [[ -d "${svnbase}/../.svn" ]]; do
1698         svnbase="${svnbase}/.."
1699     done
1700     svnbase="$(VCS_INFO_realpath ${svnbase})"
1701     svninfo=( ${${${(M)${(f)"$( svn info )"}:#(#s)(URL|Revision)*}/*: /}/*\//} )
1702
1703     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svnbranch || svnbranch="%b:%r"
1704     zformat -f svnbranch "${svnbranch}" "b:${svninfo[1]}" "r:${svninfo[2]}"
1705     VCS_INFO_formats '' "${svnbranch}" "${svnbase}"
1706     return 0
1707 }
1708 # }}}
1709 VCS_INFO_tla_get_data () { # {{{
1710     local tlabase tlabranch
1711
1712     tlabase="$(VCS_INFO_realpath ${vcs_comm[basedir]})"
1713     # tree-id gives us something like 'foo@example.com/demo--1.0--patch-4', so:
1714     tlabranch=${${"$( tla tree-id )"}/*\//}
1715     VCS_INFO_formats '' "${tlabranch}" "${tlabase}"
1716     return 0
1717 }
1718 # }}}
1719 # detection
1720 VCS_INFO_detect_by_dir() { #{{{
1721     local dirname=$1
1722     local basedir="." realbasedir
1723
1724     realbasedir="$(VCS_INFO_realpath ${basedir})"
1725     while [[ ${realbasedir} != '/' ]]; do
1726         if [[ -n ${vcs_comm[detect_need_file]} ]] ; then
1727             [[ -d ${basedir}/${dirname} ]] && \
1728             [[ -f ${basedir}/${dirname}/${vcs_comm[detect_need_file]} ]] && \
1729                 break
1730         else
1731             [[ -d ${basedir}/${dirname} ]] && break
1732         fi
1733
1734         basedir=${basedir}/..
1735         realbasedir="$(VCS_INFO_realpath ${basedir})"
1736     done
1737
1738     [[ ${realbasedir} == "/" ]] && return 1
1739     vcs_comm[basedir]=${realbasedir}
1740     return 0
1741 }
1742 # }}}
1743 VCS_INFO_bzr_detect() { #{{{
1744     VCS_INFO_check_com bzr || return 1
1745     vcs_comm[detect_need_file]=branch/format
1746     VCS_INFO_detect_by_dir '.bzr'
1747     return $?
1748 }
1749 # }}}
1750 VCS_INFO_cdv_detect() { #{{{
1751     VCS_INFO_check_com cdv || return 1
1752     vcs_comm[detect_need_file]=format
1753     VCS_INFO_detect_by_dir '.cdv'
1754     return $?
1755 }
1756 # }}}
1757 VCS_INFO_cvs_detect() { #{{{
1758     VCS_INFO_check_com svn || return 1
1759     [[ -d "./CVS" ]] && [[ -r "./CVS/Repository" ]] && return 0
1760     return 1
1761 }
1762 # }}}
1763 VCS_INFO_darcs_detect() { #{{{
1764     VCS_INFO_check_com darcs || return 1
1765     vcs_comm[detect_need_file]=format
1766     VCS_INFO_detect_by_dir '_darcs'
1767     return $?
1768 }
1769 # }}}
1770 VCS_INFO_git_detect() { #{{{
1771     if VCS_INFO_check_com git && git rev-parse --is-inside-work-tree &> /dev/null ; then
1772         vcs_comm[gitdir]="$(git rev-parse --git-dir 2> /dev/null)" || return 1
1773         if   [[ -d ${vcs_comm[gitdir]}/svn ]]             ; then vcs_comm[overwrite_name]='git-svn'
1774         elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]] ; then vcs_comm[overwrite_name]='git-p4' ; fi
1775         return 0
1776     fi
1777     return 1
1778 }
1779 # }}}
1780 VCS_INFO_hg_detect() { #{{{
1781     VCS_INFO_check_com hg || return 1
1782     vcs_comm[detect_need_file]=branch
1783     VCS_INFO_detect_by_dir '.hg'
1784     return $?
1785 }
1786 # }}}
1787 VCS_INFO_mtn_detect() { #{{{
1788     VCS_INFO_check_com mtn || return 1
1789     vcs_comm[detect_need_file]=revision
1790     VCS_INFO_detect_by_dir '_MTN'
1791     return $?
1792 }
1793 # }}}
1794 VCS_INFO_svk_detect() { #{{{
1795     setopt localoptions noksharrays extendedglob
1796     local -a info
1797     local -i fhash
1798     fhash=0
1799
1800     VCS_INFO_check_com svk || return 1
1801     [[ -f ~/.svk/config ]] || return 1
1802
1803     # This detection function is a bit different from the others.
1804     # We need to read svk's config file to detect a svk repository
1805     # in the first place. Therefore, we'll just proceed and read
1806     # the other information, too. This is more then any of the
1807     # other detections do but this takes only one file open for
1808     # svk at most. VCS_INFO_svk_get_data() get simpler, too. :-)
1809     while IFS= read -r line ; do
1810         if [[ -n ${vcs_comm[basedir]} ]] ; then
1811             line=${line## ##}
1812             [[ ${line} == depotpath:* ]] && vcs_comm[branch]=${line##*/}
1813             [[ ${line} == revision:* ]] && vcs_comm[revision]=${line##*[[:space:]]##}
1814             [[ -n ${vcs_comm[branch]} ]] && [[ -n ${vcs_comm[revision]} ]] && break
1815             continue
1816         fi
1817         (( fhash > 0 )) && [[ ${line} == '  '[^[:space:]]*:* ]] && break
1818         [[ ${line} == '  hash:'* ]] && fhash=1 && continue
1819         (( fhash == 0 )) && continue
1820         [[ ${PWD}/ == ${${line## ##}%:*}/* ]] && vcs_comm[basedir]=${${line## ##}%:*}
1821     done < ~/.svk/config
1822
1823     [[ -n ${vcs_comm[basedir]} ]]  && \
1824     [[ -n ${vcs_comm[branch]} ]]   && \
1825     [[ -n ${vcs_comm[revision]} ]] && return 0
1826     return 1
1827 }
1828 # }}}
1829 VCS_INFO_svn_detect() { #{{{
1830     VCS_INFO_check_com svn || return 1
1831     [[ -d ".svn" ]] && return 0
1832     return 1
1833 }
1834 # }}}
1835 VCS_INFO_tla_detect() { #{{{
1836     VCS_INFO_check_com tla || return 1
1837     vcs_comm[basedir]="$(tla tree-root 2> /dev/null)" && return 0
1838     return 1
1839 }
1840 # }}}
1841 # public API
1842 vcs_info_printsys () { # {{{
1843     vcs_info print_systems_
1844 }
1845 # }}}
1846 vcs_info_lastmsg () { # {{{
1847     local -i i
1848
1849     VCS_INFO_maxexports
1850     for i in {0..$((maxexports - 1))} ; do
1851         printf '$VCS_INFO_message_%d_: "' $i
1852         if zstyle -T ':vcs_info:formats:command' use-prompt-escapes ; then
1853             print -nP ${(P)${:-VCS_INFO_message_${i}_}}
1854         else
1855             print -n ${(P)${:-VCS_INFO_message_${i}_}}
1856         fi
1857         printf '"\n'
1858     done
1859 }
1860 # }}}
1861 vcs_info () { # {{{
1862     local pat
1863     local -i found
1864     local -a VCSs disabled dps
1865     local -x vcs usercontext
1866     local -ix maxexports
1867     local -ax msgs
1868     local -Ax vcs_comm
1869
1870     vcs="init"
1871     VCSs=(git hg bzr darcs svk mtn svn cvs cdv tla)
1872     case $1 in
1873         (print_systems_)
1874             zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1875             print -l '# list of supported version control backends:' \
1876                      '# disabled systems are prefixed by a hash sign (#)'
1877             for vcs in ${VCSs} ; do
1878                 [[ -n ${(M)disabled:#${vcs}} ]] && printf '#'
1879                 printf '%s\n' ${vcs}
1880             done
1881             print -l '# flavours (cannot be used in the disable style; they' \
1882                      '# are disabled with their master [git-svn -> git]):'   \
1883                      git-{p4,svn}
1884             return 0
1885             ;;
1886         ('')
1887             [[ -z ${usercontext} ]] && usercontext=default
1888             ;;
1889         (*) [[ -z ${usercontext} ]] && usercontext=$1
1890             ;;
1891     esac
1892
1893     zstyle -T ":vcs_info:${vcs}:${usercontext}" "enable" || {
1894         [[ -n ${VCS_INFO_message_0_} ]] && VCS_INFO_set --clear
1895         return 0
1896     }
1897     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1898
1899     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable-patterns" dps
1900     for pat in ${dps} ; do
1901         if [[ ${PWD} == ${~pat} ]] ; then
1902             [[ -n ${vcs_info_msg_0_} ]] && VCS_INFO_set --clear
1903             return 0
1904         fi
1905     done
1906
1907     VCS_INFO_maxexports
1908
1909     (( found = 0 ))
1910     for vcs in ${VCSs} ; do
1911         [[ -n ${(M)disabled:#${vcs}} ]] && continue
1912         vcs_comm=()
1913         VCS_INFO_${vcs}_detect && (( found = 1 )) && break
1914     done
1915
1916     (( found == 0 )) && {
1917         VCS_INFO_set --nvcs
1918         return 0
1919     }
1920
1921     VCS_INFO_${vcs}_get_data || {
1922         VCS_INFO_set --nvcs
1923         return 1
1924     }
1925
1926     VCS_INFO_set
1927     return 0
1928 }
1929
1930 VCS_INFO_set --nvcs preinit
1931 # }}}
1932
1933 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1934 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1935 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1936 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1937 #       to $vcs_info_msg_N_ as soon as we use the included version.
1938 if [[ "$TERM" == dumb ]] ; then
1939     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1940     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1941 else
1942     # these are the same, just with a lot of colours:
1943     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1944                                        "zsh: %r"
1945     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1946                                        "zsh: %r"
1947     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1948 fi
1949
1950 # }}}
1951
1952 # {{{ set prompt
1953 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1954     promptinit # people should be able to use their favourite prompt
1955 else
1956     print 'Notice: no promptinit available :('
1957 fi
1958
1959 setopt prompt_subst
1960
1961 # make sure to use right prompt only when not running a command
1962 is41 && setopt transient_rprompt
1963
1964 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1965     [[ $NOPRECMD -gt 0 ]] && return 0
1966     # update VCS information
1967     vcs_info
1968
1969     if [[ $TERM == screen* ]] ; then
1970         if [[ -n ${VCS_INFO_message_1_} ]] ; then
1971             print -nP "\ek${VCS_INFO_message_1_}\e\\"
1972         else
1973             print -nP "\ekzsh\e\\"
1974         fi
1975     fi
1976     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1977     if [[ $DONTSETRPROMPT -eq 0 ]] ; then
1978         if [[ $BATTERY -gt 0 ]] ; then
1979             # update battery (dropped into $PERCENT) information
1980             battery
1981             RPROMPT="%(?..:() ${PERCENT}"
1982         else
1983             RPROMPT="%(?..:() "
1984         fi
1985     fi
1986     # adjust title of xterm
1987     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1988     case $TERM in
1989         (xterm*|rxvt*)
1990             print -Pn "\e]0;%n@%m: %~\a"
1991             ;;
1992     esac
1993 }
1994
1995 # preexec() => a function running before every command
1996 is4 && [[ $NOPRECMD -eq 0 ]] && \
1997 preexec () {
1998     [[ $NOPRECMD -gt 0 ]] && return 0
1999 # set hostname if not running on host with name 'grml'
2000     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2001        NAME="@$HOSTNAME"
2002     fi
2003 # get the name of the program currently running and hostname of local machine
2004 # set screen window title if running in a screen
2005     if [[ "$TERM" == screen* ]] ; then
2006         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
2007         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
2008         echo -ne "\ek$CMD\e\\"
2009     fi
2010 # adjust title of xterm
2011     case $TERM in
2012         (xterm*|rxvt)
2013             print -Pn "\e]0;%n@%m: $1\a"
2014             ;;
2015     esac
2016 }
2017
2018 EXITCODE="%(?..%?%1v )"
2019 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
2020 PS3='?# '         # selection prompt used within a select loop.
2021 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
2022
2023 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
2024 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
2025     debian_chroot=$(cat /etc/debian_chroot)
2026 fi
2027
2028 # don't use colors on dumb terminals (like emacs):
2029 if [[ "$TERM" == dumb ]] ; then
2030     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2031 else
2032     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
2033     # set variable identifying the chroot you work in (used in the prompt below)
2034     if [[ $GRMLPROMPT -gt 0 ]] ; then
2035         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
2036 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
2037     else
2038         # This assembles the primary prompt string
2039         if (( EUID != 0 )); then
2040             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2041         else
2042             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2043         fi
2044     fi
2045 fi
2046
2047 # if we are inside a grml-chroot set a specific prompt theme
2048 if [[ -n "$GRML_CHROOT" ]] ; then
2049     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
2050 fi
2051 # }}}
2052
2053 # {{{ 'hash' some often used directories
2054 #d# start
2055 hash -d deb=/var/cache/apt/archives
2056 hash -d doc=/usr/share/doc
2057 hash -d linux=/lib/modules/$(command uname -r)/build/
2058 hash -d log=/var/log
2059 hash -d slog=/var/log/syslog
2060 hash -d src=/usr/src
2061 hash -d templ=/usr/share/doc/grml-templates
2062 hash -d tt=/usr/share/doc/texttools-doc
2063 hash -d www=/var/www
2064 #d# end
2065 # }}}
2066
2067 # {{{ some aliases
2068 if check_com -c screen ; then
2069     if [[ $UID -eq 0 ]] ; then
2070         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
2071     elif [[ -r $HOME/.screenrc ]] ; then
2072         alias screen="${commands[screen]} -c $HOME/.screenrc"
2073     else
2074         [[ -r /etc/grml/screenrc_grml ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2075     fi
2076 fi
2077
2078 # do we have GNU ls with color-support?
2079 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
2080     #a1# execute \kbd{@a@}:\quad ls with colors
2081     alias ls='ls -b -CF --color=auto'
2082     #a1# execute \kbd{@a@}:\quad list all files, with colors
2083     alias la='ls -la --color=auto'
2084     #a1# long colored list, without dotfiles (@a@)
2085     alias ll='ls -l --color=auto'
2086     #a1# long colored list, human readable sizes (@a@)
2087     alias lh='ls -hAl --color=auto'
2088     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2089     alias l='ls -lF --color=auto'
2090 else
2091     alias ls='ls -b -CF'
2092     alias la='ls -la'
2093     alias ll='ls -l'
2094     alias lh='ls -hAl'
2095     alias l='ls -lF'
2096 fi
2097
2098 alias mdstat='cat /proc/mdstat'
2099 alias ...='cd ../../'
2100
2101 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2102 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2103     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2104 fi
2105
2106 alias cp='nocorrect cp'         # no spelling correction on cp
2107 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
2108 alias mv='nocorrect mv'         # no spelling correction on mv
2109 alias rm='nocorrect rm'         # no spelling correction on rm
2110
2111 #a1# Execute \kbd{rmdir}
2112 alias rd='rmdir'
2113 #a1# Execute \kbd{rmdir}
2114 alias md='mkdir'
2115
2116 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2117 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2118 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2119
2120 # make sure it is not assigned yet
2121 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
2122
2123 utf2iso() {
2124     if isutfenv ; then
2125         for ENV in $(env | command grep -i '.utf') ; do
2126             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2127         done
2128     fi
2129 }
2130
2131 # make sure it is not assigned yet
2132 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
2133 iso2utf() {
2134     if ! isutfenv ; then
2135         for ENV in $(env | command grep -i '\.iso') ; do
2136             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2137         done
2138     fi
2139 }
2140
2141 # set up software synthesizer via speakup
2142 swspeak() {
2143     if [ -x /usr/sbin/swspeak-setup ] ; then
2144        setopt singlelinezle
2145        unsetopt prompt_cr
2146        export PS1="%m%# "
2147        /usr/sbin/swspeak-setup $@
2148      else # old version:
2149         aumix -w 90 -v 90 -p 90 -m 90
2150         if ! [[ -r /dev/softsynth ]] ; then
2151             flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
2152             return 1
2153         else
2154            setopt singlelinezle
2155            unsetopt prompt_cr
2156            export PS1="%m%# "
2157             nice -n -20 speechd-up
2158             sleep 2
2159             flite -o play -t "Finished setting up software synthesizer"
2160         fi
2161      fi
2162 }
2163
2164 # I like clean prompt, so provide simple way to get that
2165 check_com 0 || alias 0='return 0'
2166
2167 # for really lazy people like mika:
2168 check_com S &>/dev/null || alias S='screen'
2169 check_com s &>/dev/null || alias s='ssh'
2170
2171 # get top 10 shell commands:
2172 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
2173
2174 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
2175 if check_com -c truecrypt ; then
2176     if isutfenv ; then
2177         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
2178     else
2179         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
2180     fi
2181 fi
2182
2183 #f1# Hints for the use of zsh on grml
2184 zsh-help() {
2185     print "$bg[white]$fg[black]
2186 zsh-help - hints for use of zsh on grml
2187 =======================================$reset_color"
2188
2189     print '
2190 Main configuration of zsh happens in /etc/zsh/zshrc.
2191 That file is part of the package grml-etc-core, if you want to
2192 use them on a non-grml-system just get the tar.gz from
2193 http://deb.grml.org/ or (preferably) get it from the git repository:
2194
2195   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2196
2197 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2198 The file is still there, but it is empty for backwards compatibility.
2199
2200 For your own changes use these two files:
2201     $HOME/.zshrc.pre
2202     $HOME/.zshrc.local
2203
2204 The former is sourced very early in our zshrc, the latter is sourced
2205 very lately.
2206
2207 System wide configuration without touching configuration files of grml
2208 can take place in /etc/zsh/zshrc.local.
2209
2210 Normally, the root user (EUID == 0) does not get the whole grml setup.
2211 If you want to force the whole setup for that user, too, set
2212 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
2213
2214 For information regarding zsh start at http://grml.org/zsh/
2215
2216 Take a look at grml'\''s zsh refcard:
2217 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2218
2219 Check out the main zsh refcard:
2220 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2221
2222 And of course visit the zsh-lovers:
2223 % man zsh-lovers
2224
2225 You can adjust some options through environment variables when
2226 invoking zsh without having to edit configuration files.
2227 Basically meant for bash users who are not used to the power of
2228 the zsh yet. :)
2229
2230   "NOCOR=1    zsh" => deactivate automatic correction
2231   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
2232   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2233   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2234
2235 A value greater than 0 is enables a feature; a value equal to zero
2236 disables it. If you like one or the other of these settings, you can
2237 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2238 zshrc.'
2239
2240     print "
2241 $bg[white]$fg[black]
2242 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2243 Enjoy your grml system with the zsh!$reset_color"
2244 }
2245
2246 # debian stuff
2247 if [[ -r /etc/debian_version ]] ; then
2248     #a3# Execute \kbd{apt-cache search}
2249     alias acs='apt-cache search'
2250     #a3# Execute \kbd{apt-cache show}
2251     alias acsh='apt-cache show'
2252     #a3# Execute \kbd{apt-cache policy}
2253     alias acp='apt-cache policy'
2254     #a3# Execute \kbd{apt-get dist-upgrade}
2255     salias adg="apt-get dist-upgrade"
2256     #a3# Execute \kbd{apt-get install}
2257     salias agi="apt-get install"
2258     #a3# Execute \kbd{aptitude install}
2259     salias ati="aptitude install"
2260     #a3# Execute \kbd{apt-get upgrade}
2261     salias ag="apt-get upgrade"
2262     #a3# Execute \kbd{apt-get update}
2263     salias au="apt-get update"
2264     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2265     salias -a up="aptitude update ; aptitude safe-upgrade"
2266     #a3# Execute \kbd{dpkg-buildpackage}
2267     alias dbp='dpkg-buildpackage'
2268     #a3# Execute \kbd{grep-excuses}
2269     alias ge='grep-excuses'
2270
2271     # debian upgrade
2272     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
2273     upgrade() {
2274         if [[ -z "$1" ]] ; then
2275             $SUDO apt-get update
2276             $SUDO apt-get -u upgrade
2277         else
2278             ssh $1 $SUDO apt-get update
2279             # ask before the upgrade
2280             local dummy
2281             ssh $1 $SUDO apt-get --no-act upgrade
2282             echo -n 'Process the upgrade?'
2283             read -q dummy
2284             if [[ $dummy == "y" ]] ; then
2285                 ssh $1 $SUDO apt-get -u upgrade --yes
2286             fi
2287         fi
2288     }
2289
2290     # get a root shell as normal user in live-cd mode:
2291     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2292        alias su="sudo su"
2293      fi
2294
2295     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2296     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2297     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2298     alias tlog="tail -f /var/log/syslog"    # follow the syslog
2299 fi
2300
2301 # sort installed Debian-packages by size
2302 if check_com -c grep-status ; then
2303     #a3# List installed Debian-packages sorted by size
2304     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
2305 fi
2306
2307 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2308 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
2309     if check_com -c wodim ; then
2310         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
2311 See #377109 in the BTS of Debian for more details.
2312
2313 Please use the wodim binary instead' ; return 1"
2314     fi
2315 fi
2316
2317 # get_tw_cli has been renamed into get_3ware
2318 if check_com -c get_3ware ; then
2319     get_tw_cli() {
2320         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
2321         get_3ware
2322     }
2323 fi
2324
2325 # I hate lacking backward compatibility, so provide an alternative therefore
2326 if ! check_com -c apache2-ssl-certificate ; then
2327
2328     apache2-ssl-certificate() {
2329
2330     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
2331     print 'You might want to take a look at Debian the package ssl-cert as well.'
2332     print 'To generate a certificate for use with apache2 follow the instructions:'
2333
2334     echo '
2335
2336 export RANDFILE=/dev/random
2337 mkdir /etc/apache2/ssl/
2338 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
2339 chmod 600 /etc/apache2/ssl/apache.pem
2340
2341 Run "grml-tips ssl-certificate" if you need further instructions.
2342 '
2343     }
2344 fi
2345 # }}}
2346
2347 # {{{ Use hard limits, except for a smaller stack and no core dumps
2348 unlimit
2349 is425 && limit stack 8192
2350 isgrmlcd && limit core 0 # important for a live-cd-system
2351 limit -s
2352 # }}}
2353
2354 # {{{ completion system
2355
2356 # called later (via is4 && grmlcomp)
2357 # note: use 'zstyle' for getting current settings
2358 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
2359 grmlcomp() {
2360     # TODO: This could use some additional information
2361
2362     # allow one error for every three characters typed in approximate completer
2363     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
2364
2365     # don't complete backup files as executables
2366     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
2367
2368     # start menu completion only if it could find no unambiguous initial string
2369     zstyle ':completion:*:correct:*'       insert-unambiguous true
2370     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
2371     zstyle ':completion:*:correct:*'       original true
2372
2373     # activate color-completion
2374     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
2375
2376     # format on completion
2377     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
2378
2379     # complete 'cd -<tab>' with menu
2380     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
2381
2382     # insert all expansions for expand completer
2383     zstyle ':completion:*:expand:*'        tag-order all-expansions
2384     zstyle ':completion:*:history-words'   list false
2385
2386     # activate menu
2387     zstyle ':completion:*:history-words'   menu yes
2388
2389     # ignore duplicate entries
2390     zstyle ':completion:*:history-words'   remove-all-dups yes
2391     zstyle ':completion:*:history-words'   stop yes
2392
2393     # match uppercase from lowercase
2394     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
2395
2396     # separate matches into groups
2397     zstyle ':completion:*:matches'         group 'yes'
2398     zstyle ':completion:*'                 group-name ''
2399
2400     if [[ "$NOMENU" -eq 0 ]] ; then
2401         # if there are more than 5 options allow selecting from a menu
2402         zstyle ':completion:*'               menu select=5
2403     else
2404         # don't use any menus at all
2405         setopt no_auto_menu
2406     fi
2407
2408     zstyle ':completion:*:messages'        format '%d'
2409     zstyle ':completion:*:options'         auto-description '%d'
2410
2411     # describe options in full
2412     zstyle ':completion:*:options'         description 'yes'
2413
2414     # on processes completion complete all user processes
2415     zstyle ':completion:*:processes'       command 'ps -au$USER'
2416
2417     # offer indexes before parameters in subscripts
2418     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
2419
2420     # provide verbose completion information
2421     zstyle ':completion:*'                 verbose true
2422
2423     # recent (as of Dec 2007) zsh versions are able to provide descriptions
2424     # for commands (read: 1st word in the line) that it will list for the user
2425     # to choose from. The following disables that, because it's not exactly fast.
2426     zstyle ':completion:*:-command-:*:'    verbose false
2427
2428     # set format for warnings
2429     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
2430
2431     # define files to ignore for zcompile
2432     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
2433     zstyle ':completion:correct:'          prompt 'correct to: %e'
2434
2435     # Ignore completion functions for commands you don't have:
2436     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
2437
2438     # Provide more processes in completion of programs like killall:
2439     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
2440
2441     # complete manual by their section
2442     zstyle ':completion:*:manuals'    separate-sections true
2443     zstyle ':completion:*:manuals.*'  insert-sections   true
2444     zstyle ':completion:*:man:*'      menu yes select
2445
2446     # provide .. as a completion
2447     zstyle ':completion:*' special-dirs ..
2448
2449     # run rehash on completion so new installed program are found automatically:
2450     _force_rehash() {
2451         (( CURRENT == 1 )) && rehash
2452         return 1
2453     }
2454
2455     ## correction
2456     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2457     if [[ "$NOCOR" -gt 0 ]] ; then
2458         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2459         setopt nocorrect
2460     else
2461         # try to be smart about when to use what completer...
2462         setopt correct
2463         zstyle -e ':completion:*' completer '
2464             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2465                 _last_try="$HISTNO$BUFFER$CURSOR"
2466                 reply=(_complete _match _ignored _prefix _files)
2467             else
2468                 if [[ $words[1] == (rm|mv) ]] ; then
2469                     reply=(_complete _files)
2470                 else
2471                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2472                 fi
2473             fi'
2474     fi
2475
2476     # command for process lists, the local web server details and host completion
2477     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2478
2479     # caching
2480     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2481                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2482
2483     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
2484     if is42 ; then
2485         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2486         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2487     else
2488         _ssh_hosts=()
2489         _etc_hosts=()
2490     fi
2491     hosts=(
2492         $(hostname)
2493         "$_ssh_hosts[@]"
2494         "$_etc_hosts[@]"
2495         grml.org
2496         localhost
2497     )
2498     zstyle ':completion:*:hosts' hosts $hosts
2499     # TODO: so, why is this here?
2500     #  zstyle '*' hosts $hosts
2501
2502     # use generic completion system for programs not yet defined; (_gnu_generic works
2503     # with commands that provide a --help option with "standard" gnu-like output.)
2504     compdef _gnu_generic tail head feh cp mv df stow uname ipacsum fetchipac
2505
2506     # see upgrade function in this file
2507     compdef _hosts upgrade
2508 }
2509 # }}}
2510
2511 # {{{ grmlstuff
2512 grmlstuff() {
2513 # people should use 'grml-x'!
2514     startx() {
2515         if [[ -e /etc/X11/xorg.conf ]] ; then
2516             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
2517         else
2518             echo "Please use the script \"grml-x\" for starting the X Window System
2519 because there does not exist /etc/X11/xorg.conf yet.
2520 If you want to use startx anyway please call \"/usr/bin/startx\"."
2521             return -1
2522         fi
2523     }
2524
2525     xinit() {
2526         if [[ -e /etc/X11/xorg.conf ]] ; then
2527             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
2528         else
2529             echo "Please use the script \"grml-x\" for starting the X Window System.
2530 because there does not exist /etc/X11/xorg.conf yet.
2531 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
2532             return -1
2533         fi
2534     }
2535
2536     if check_com -c 915resolution ; then
2537         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
2538     fi
2539
2540     #a1# Output version of running grml
2541     alias grml-version='cat /etc/grml_version'
2542
2543     if check_com -c rebuildfstab ; then
2544         #a1# Rebuild /etc/fstab
2545         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2546     fi
2547
2548     if check_com -c grml-debootstrap ; then
2549         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
2550     fi
2551 }
2552 # }}}
2553
2554 # {{{ now run the functions
2555 isgrml && checkhome
2556 is4    && isgrml    && grmlstuff
2557 is4    && grmlcomp
2558 # }}}
2559
2560 # {{{ keephack
2561 is4 && xsource "/etc/zsh/keephack"
2562 # }}}
2563
2564 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
2565 # You use it as follows:
2566 # $ NTREF=/reference/file
2567 # $ ls -l *(e:nt:)
2568 # This lists all the files in the current directory newer than the reference file.
2569 # You can also specify the reference file inline; note quotes:
2570 # $ ls -l *(e:'nt ~/.zshenv':)
2571 is4 && nt() {
2572     if [[ -n $1 ]] ; then
2573         local NTREF=${~1}
2574     fi
2575     [[ $REPLY -nt $NTREF ]]
2576 }
2577 # }}}
2578
2579 # shell functions {{{
2580
2581 #f1# Provide csh compatibility
2582 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
2583
2584 #f1# Reload an autoloadable function
2585 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2586
2587 #f1# Reload zsh setup
2588 reload() {
2589     if [[ "$#*" -eq 0 ]] ; then
2590         [[ -r ~/.zshrc ]] && . ~/.zshrc
2591     else
2592         local fn
2593         for fn in "$@"; do
2594             unfunction $fn
2595             autoload -U $fn
2596         done
2597     fi
2598 }
2599 compdef _functions reload freload
2600
2601 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2602 sll() {
2603     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2604     for i in "$@" ; do
2605         file=$i
2606         while [[ -h "$file" ]] ; do
2607             ls -l $file
2608             file=$(readlink "$file")
2609         done
2610     done
2611 }
2612
2613 # fast manual access
2614 if check_com qma ; then
2615     #f1# View the zsh manual
2616     manzsh()  { qma zshall "$1" }
2617     compdef _man qma
2618 else
2619     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
2620 fi
2621
2622 if check_com -c $PAGER ; then
2623     #f1# View Debian's changelog of a given package
2624     dchange() {
2625         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
2626             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
2627         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2628             $PAGER /usr/share/doc/${1}/changelog.gz
2629         else
2630             if check_com -c aptitude ; then
2631                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2632                 if isgrml ; then
2633                     aptitude -t unstable changelog ${1}
2634                 else
2635                     aptitude changelog ${1}
2636                 fi
2637             else
2638                 echo "No changelog for package $1 found, sorry."
2639                 return 1
2640             fi
2641         fi
2642     }
2643     _dchange() { _files -W /usr/share/doc -/ }
2644     compdef _dchange dchange
2645
2646     #f1# View Debian's NEWS of a given package
2647     dnews() {
2648         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
2649             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
2650         else
2651             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
2652                 $PAGER /usr/share/doc/${1}/NEWS.gz
2653             else
2654                 echo "No NEWS file for package $1 found, sorry."
2655                 return 1
2656             fi
2657         fi
2658     }
2659     _dnews() { _files -W /usr/share/doc -/ }
2660     compdef _dnews dnews
2661
2662     #f1# View upstream's changelog of a given package
2663     uchange() {
2664         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2665             $PAGER /usr/share/doc/${1}/changelog.gz
2666         else
2667             echo "No changelog for package $1 found, sorry."
2668             return 1
2669         fi
2670     }
2671     _uchange() { _files -W /usr/share/doc -/ }
2672     compdef _uchange uchange
2673 fi
2674
2675 # zsh profiling
2676 profile() {
2677     ZSH_PROFILE_RC=1 $SHELL "$@"
2678 }
2679
2680 #f1# Edit an alias via zle
2681 edalias() {
2682     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2683 }
2684 compdef _aliases edalias
2685
2686 #f1# Edit a function via zle
2687 edfunc() {
2688     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
2689 }
2690 compdef _functions edfunc
2691
2692 # use it e.g. via 'Restart apache2'
2693 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2694 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2695 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2696 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2697 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2698 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2699     __start_stop() {
2700         local action_="${1:l}"  # e.g Start/Stop/Restart
2701         local service_="$2"
2702         local param_="$3"
2703
2704         local service_target_="$(readlink /etc/init.d/$service_)"
2705         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2706             # runit
2707             case "${action_}" in
2708                 start) if [[ ! -e /etc/service/$service_ ]]; then
2709                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2710                        else
2711                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2712                        fi ;;
2713                 # there is no reload in runits sysv emulation
2714                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2715                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2716             esac
2717         else
2718             # sysvinit
2719             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2720         fi
2721     }
2722
2723     for i in Start Restart Stop Force-Reload Reload ; do
2724         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2725     done
2726 fi
2727
2728 #f1# Provides useful information on globbing
2729 H-Glob() {
2730     echo -e "
2731     /      directories
2732     .      plain files
2733     @      symbolic links
2734     =      sockets
2735     p      named pipes (FIFOs)
2736     *      executable plain files (0100)
2737     %      device files (character or block special)
2738     %b     block special files
2739     %c     character special files
2740     r      owner-readable files (0400)
2741     w      owner-writable files (0200)
2742     x      owner-executable files (0100)
2743     A      group-readable files (0040)
2744     I      group-writable files (0020)
2745     E      group-executable files (0010)
2746     R      world-readable files (0004)
2747     W      world-writable files (0002)
2748     X      world-executable files (0001)
2749     s      setuid files (04000)
2750     S      setgid files (02000)
2751     t      files with the sticky bit (01000)
2752
2753   print *(m-1)          # Files modified up to a day ago
2754   print *(a1)           # Files accessed a day ago
2755   print *(@)            # Just symlinks
2756   print *(Lk+50)        # Files bigger than 50 kilobytes
2757   print *(Lk-50)        # Files smaller than 50 kilobytes
2758   print **/*.c          # All *.c files recursively starting in \$PWD
2759   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2760   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2761   print *~*.*           # All Files that do not contain a dot
2762   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2763   print -l *(.c|.h)     # Lists *.c and *.h
2764   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2765   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2766 }
2767 alias help-zshglob=H-Glob
2768
2769 check_com -c qma && alias ?='qma zshall'
2770
2771 # grep for running process, like: 'any vim'
2772 any() {
2773     if [[ -z "$1" ]] ; then
2774         echo "any - grep for process(es) by keyword" >&2
2775         echo "Usage: any <keyword>" >&2 ; return 1
2776     else
2777         local STRING=$1
2778         local LENGTH=$(expr length $STRING)
2779         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
2780         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
2781         ps xauwww| grep "[$FIRSCHAR]$REST"
2782     fi
2783 }
2784
2785 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2786 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2787 [[ -r /proc/1/maps ]] && \
2788 deswap() {
2789     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2790     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2791     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2792 }
2793
2794 # print hex value of a number
2795 hex() {
2796     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2797 }
2798
2799 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2800 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2801 peval() {
2802     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2803     perl -e "print eval($CALC),\"\n\";"
2804 }
2805 functions peval &>/dev/null && alias calc=peval
2806
2807 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
2808 # certain circumstances, so work around it, no matter which environment we have
2809 brltty() {
2810     if [[ -z "$DISPLAY" ]] ; then
2811         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
2812         command brltty "$@"
2813     else
2814         command brltty "$@"
2815     fi
2816 }
2817
2818 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2819 aoeu() {
2820     echo -n 'Switching to us keyboard layout: '
2821     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2822     echo 'Done'
2823 }
2824 asdf() {
2825     echo -n 'Switching to dvorak keyboard layout: '
2826     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2827     echo 'Done'
2828 }
2829 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2830 uiae() {
2831     echo -n 'Switching to us keyboard layout: '
2832     setxkbmap us && echo 'Done' || echo 'Failed'
2833 }
2834
2835 # set up an ipv6 tunnel
2836 ipv6-tunnel() {
2837     case $1 in
2838         start)
2839             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2840                 print 'ipv6 tunnel already set up, nothing to be done.'
2841                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2842             else
2843                 [[ -n "$PUBLIC_IP" ]] || \
2844                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2845                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2846
2847                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
2848                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
2849                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
2850                 ifconfig sit0 tunnel ::192.88.99.1 up
2851                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
2852             fi
2853             ;;
2854         status)
2855             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2856                 print 'ipv6 tunnel available' ; return 0
2857             else
2858                 print 'ipv6 tunnel not available' ; return 1
2859             fi
2860             ;;
2861         stop)
2862             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2863                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
2864                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
2865             else
2866                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
2867             fi
2868             ;;
2869         *)
2870             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
2871             ;;
2872     esac
2873 }
2874
2875 # run dhclient for wireless device
2876 iwclient() {
2877     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
2878 }
2879
2880 # spawn a minimally set up ksh - useful if you want to umount /usr/.
2881 minimal-shell() {
2882     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
2883 }
2884
2885 # make a backup of a file
2886 bk() {
2887     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2888 }
2889
2890 #f1# grep for patterns in grml's zsh setup
2891 zg() {
2892 #{{{
2893     LANG=C perl -e '
2894
2895 sub usage {
2896     print "usage: zg -[anr] <pattern>\n";
2897     print " Search for patterns in grml'\''s zshrc.\n";
2898     print " zg takes no or exactly one option plus a non empty pattern.\n\n";
2899     print "   options:\n";
2900     print "     --  no options (use if your pattern starts in with a dash.\n";
2901     print "     -a  search for the pattern in all code regions\n";
2902     print "     -n  search for the pattern in non-root code only\n";
2903     print "     -r  search in code for everyone (also root) only\n\n";
2904     print "   The default is -a for non-root users and -r for root.\n\n";
2905     print " If you installed the zshrc to a non-default locations (ie *NOT*\n";
2906     print " in /etc/zsh/zshrc) do: export GRML_ZSHRC=\$HOME/.zshrc\n";
2907     print " ...in case you copied the file to that location.\n\n";
2908     exit 1;
2909 }
2910
2911 if ($ENV{GRML_ZSHRC} ne "") {
2912     $RC = $ENV{GRML_ZSHRC};
2913 } else {
2914     $RC = "/etc/zsh/zshrc";
2915 }
2916
2917 usage if ($#ARGV < 0 || $#ARGV > 1);
2918 if ($> == 0) { $mode = "allonly"; }
2919 else { $mode = "all"; }
2920
2921 $opt = $ARGV[0];
2922 if ($opt eq "--")     { shift; }
2923 elsif ($opt eq "-a")  { $mode = "all"; shift; }
2924 elsif ($opt eq "-n")  { $mode = "nonroot"; shift; }
2925 elsif ($opt eq "-r" ) { $mode = "allonly"; shift; }
2926 elsif ($opt =~ m/^-/ || $#ARGV > 0) { usage(); }
2927
2928 $pattern = $ARGV[0];
2929 usage() if ($pattern eq "");
2930
2931 open FH, "<$RC" or die "zg: Could not open $RC: $!\n";
2932 while ($line = <FH>) {
2933     chomp $line;
2934     if ($line =~ m/^#:grep:marker:for:mika:/) { $markerfound = 1; next; }
2935     next if ($mode eq "nonroot" && markerfound == 0);
2936     break if ($mode eq "allonly" && markerfound == 1);
2937     print $line, "\n" if ($line =~ /$pattern/);
2938 }
2939 close FH;
2940 exit 0;
2941
2942     ' -- "$@"
2943 #}}}
2944     return $?
2945 }
2946
2947 # }}}
2948
2949 # {{{ make sure our environment is clean regarding colors
2950 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2951 # }}}
2952
2953 # source another config file if present {{{
2954 xsource "/etc/zsh/zshrc.local"
2955 # }}}
2956
2957 # "persistent history" {{{
2958 # just write important commands you always need to ~/.important_commands
2959 if [[ -r ~/.important_commands ]] ; then
2960     fc -R ~/.important_commands
2961 fi
2962 # }}}
2963
2964 #:grep:marker:for:mika: :-)
2965 ### non-root (EUID != 0) code below
2966 ###
2967
2968 (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) && return 0
2969
2970 # variables {{{
2971
2972 # set terminal property (used e.g. by msgid-chooser)
2973 export COLORTERM="yes"
2974
2975 # set default browser
2976 if [[ -z "$BROWSER" ]] ; then
2977     if [[ -n "$DISPLAY" ]] ; then
2978         #v# If X11 is running
2979         check_com -c firefox && export BROWSER=firefox
2980     else
2981         #v# If no X11 is running
2982         check_com -c w3m && export BROWSER=w3m
2983     fi
2984 fi
2985
2986 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
2987 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
2988 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
2989
2990 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
2991 #v# [for non-root only]
2992 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
2993 # }}}
2994
2995 # aliases {{{
2996
2997 # Xterm resizing-fu.
2998 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
2999 alias hide='echo -en "\033]50;nil2\007"'
3000 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
3001 alias small='echo -en "\033]50;6x10\007"'
3002 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
3003 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
3004 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
3005 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
3006 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
3007 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
3008
3009 # general
3010 #a2# Execute \kbd{du -sch}
3011 alias da='du -sch'
3012 #a2# Execute \kbd{jobs -l}
3013 alias j='jobs -l'
3014
3015 # compile stuff
3016 #a2# Execute \kbd{./configure}
3017 alias CO="./configure"
3018 #a2# Execute \kbd{./configure --help}
3019 alias CH="./configure --help"
3020
3021 # http://conkeror.mozdev.org/
3022 # TODO: I think this should be removed, as conkeror is not a simple extension anymore
3023 #a2# Run a keyboard driven firefox
3024 alias conkeror='firefox -chrome chrome://conkeror/content'
3025
3026 # arch/tla stuff
3027 if check_com -c tla ; then
3028     #a2# Execute \kbd{tla what-changed --diffs | less}
3029     alias tdi='tla what-changed --diffs | less'
3030     #a2# Execute \kbd{tla-buildpackage}
3031     alias tbp='tla-buildpackage'
3032     #a2# Execute \kbd{tla archive-mirror}
3033     alias tmi='tla archive-mirror'
3034     #a2# Execute \kbd{tla commit}
3035     alias tco='tla commit'
3036     #a2# Execute \kbd{tla star-merge}
3037     alias tme='tla star-merge'
3038 fi
3039
3040 # listing stuff
3041 #a2# Execute \kbd{ls -lSrah}
3042 alias dir="ls -lSrah"
3043 #a2# Only show dot-directories
3044 alias lad='ls -d .*(/)'                # only show dot-directories
3045 #a2# Only show dot-files
3046 alias lsa='ls -a .*(.)'                # only show dot-files
3047 #a2# Only files with setgid/setuid/sticky flag
3048 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
3049 #a2# Only show 1st ten symlinks
3050 alias lsl='ls -l *(@[1,10])'           # only symlinks
3051 #a2# Display only executables
3052 alias lsx='ls -l *(*[1,10])'           # only executables
3053 #a2# Display world-{readable,writable,executable} files
3054 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
3055 #a2# Display the ten biggest files
3056 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
3057 #a2# Only show directories
3058 alias lsd='ls -d *(/)'                 # only show directories
3059 #a2# Only show empty directories
3060 alias lse='ls -d *(/^F)'               # only show empty directories
3061 #a2# Display the ten newest files
3062 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
3063 #a2# Display the ten oldest files
3064 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
3065 #a2# Display the ten smallest files
3066 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
3067
3068 # chmod
3069 #a2# Execute \kbd{chmod 600}
3070 alias rw-='chmod 600'
3071 #a2# Execute \kbd{chmod 700}
3072 alias rwx='chmod 700'
3073 #m# a2 r-{}- Execute \kbd{chmod 644}
3074 alias r--='chmod 644'
3075 #a2# Execute \kbd{chmod 755}
3076 alias r-x='chmod 755'
3077
3078 # some useful aliases
3079 #a2# Execute \kbd{mkdir -o}
3080 alias md='mkdir -p'
3081
3082 check_com -c ipython && alias ips='ipython -p sh'
3083
3084 # console stuff
3085 #a2# Execute \kbd{mplayer -vo fbdev}
3086 alias cmplayer='mplayer -vo fbdev'
3087 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
3088 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
3089 #a2# Execute \kbd{links2 -driver fb}
3090 alias fblinks='links2 -driver fb'
3091
3092 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3093 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3094 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3095
3096 # simple webserver
3097 check_com -c python && alias http="python -m SimpleHTTPServer"
3098
3099 # Use 'g' instead of 'git':
3100 check_com g || alias g='git'
3101
3102 # use colors when browsing man pages, but only if not using LESS_TERMCAP_* from /etc/zsh/zshenv:
3103 if [[ -z "$LESS_TERMCAP_md" ]] ; then
3104     [[ -d ~/.terminfo/ ]] && alias man='TERMINFO=~/.terminfo/ LESS=C TERM=mostlike PAGER=less man'
3105 fi
3106
3107 # check whether Debian's package management (dpkg) is running
3108 if check_com salias ; then
3109     #a2# Check whether a dpkg instance is currently running
3110     salias check_dpkg_running="dpkg_running"
3111 fi
3112
3113 # work around non utf8 capable software in utf environment via $LANG and luit
3114 if check_com isutfenv && check_com luit ; then
3115     if check_com -c mrxvt ; then
3116         isutfenv && [[ -n "$LANG" ]] && \
3117             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3118     fi
3119
3120     if check_com -c aterm ; then
3121         isutfenv && [[ -n "$LANG" ]] && \
3122             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3123     fi
3124
3125     if check_com -c centericq ; then
3126         isutfenv && [[ -n "$LANG" ]] && \
3127             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3128     fi
3129 fi
3130 # }}}
3131
3132 # useful functions {{{
3133
3134 # searching
3135 #f4# Search for newspostings from authors
3136 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
3137 #f4# Search Debian Bug Tracking System
3138 debbug()  {
3139     setopt localoptions extendedglob
3140     if [[ $# -eq 1 ]]; then
3141         case "$1" in
3142             ([0-9]##)
3143             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
3144             ;;
3145             (*@*)
3146             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
3147             ;;
3148             (*)
3149             ${=BROWSER} "http://bugs.debian.org/$*"
3150             ;;
3151         esac
3152     else
3153         print "$0 needs one argument"
3154         return 1
3155     fi
3156 }
3157 #f4# Search Debian Bug Tracking System in mbox format
3158 debbugm() { bts show --mbox $1 } # provide bugnummer as "$1"
3159 #f4# Search DMOZ
3160 dmoz()    { ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_} }
3161 #f4# Search German   Wiktionary
3162 dwicti()  { ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_} }
3163 #f4# Search English  Wiktionary
3164 ewicti()  { ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_} }
3165 #f4# Search Google Groups
3166 ggogle()  { ${=BROWSER} "http://groups.google.com/groups?q=$*" }
3167 #f4# Search Google
3168 google()  { ${=BROWSER} "http://www.google.com/search?&num=100&q=$*" }
3169 #f4# Search Google Groups for MsgID
3170 mggogle() { ${=BROWSER} "http://groups.google.com/groups?selm=$*" }
3171 #f4# Search Netcraft
3172 netcraft(){ ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1" }
3173 #f4# Use German Wikipedia's full text search
3174 swiki()   { ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1} }
3175 #f4# search \kbd{dict.leo.org}
3176 oleo()    { ${=BROWSER} "http://dict.leo.org/?search=$*" }
3177 #f4# Search German   Wikipedia
3178 wikide()  { ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}" }
3179 #f4# Search English  Wikipedia
3180 wikien()  { ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}" }
3181 #f4# Search official debs
3182 wodeb()   { ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all" }
3183
3184 #m# f4 gex() Exact search via Google
3185 check_com google && gex () { google "\"[ $1]\" $*" } # exact search at google
3186
3187 # misc
3188 #f5# Backup \kbd{file {\rm to} file\_timestamp}
3189 bk()      { cp -b ${1} ${1}_`date --iso-8601=m` }
3190 #f5# Copied diff
3191 cdiff()   { diff -crd "$*" | egrep -v "^Only in |^Binary files " }
3192 #f5# cd to directoy and list files
3193 cl()      { cd $1 && ls -a }        # cd && ls
3194 #f5# Cvs add
3195 cvsa()    { cvs add $* && cvs com -m 'initial checkin' $* }
3196 #f5# Cvs diff
3197 cvsd()    { cvs diff -N $* |& $PAGER }
3198 #f5# Cvs log
3199 cvsl()    { cvs log $* |& $PAGER }
3200 #f5# Cvs update
3201 cvsq()    { cvs -nq update }
3202 #f5# Rcs2log
3203 cvsr()    { rcs2log $* | $PAGER }
3204 #f5# Cvs status
3205 cvss()    { cvs status -v $* }
3206 #f5# Disassemble source files using gcc and as
3207 disassemble(){ gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null }
3208 #f5# Firefox remote control - open given URL
3209 fir()     { firefox -a firefox -remote "openURL($1)" }
3210 #f5# Create Directoy and \kbd{cd} to it
3211 mcd()     { mkdir -p "$@"; cd "$@" } # mkdir && cd
3212 #f5# Unified diff to timestamped outputfile
3213 mdiff()   { diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1" }
3214 #f5# Memory overview
3215 memusage(){ ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc }
3216 #f5# Show contents of tar file
3217 shtar()   { gunzip -c $1 | tar -tf - -- | $PAGER }
3218 #f5# Show contents of tgz file
3219 shtgz()   { tar -ztf $1 | $PAGER }
3220 #f5# Show contents of zip file
3221 shzip()   { unzip -l $1 | $PAGER }
3222 #f5# Greps signature from file
3223 sig()     { agrep -d '^-- $' "$*" ~/.Signature }
3224 #f5# Unified diff
3225 udiff()   { diff -urd $* | egrep -v "^Only in |^Binary files " }
3226 #f5# (Mis)use \kbd{vim} as \kbd{less}
3227 viless()  { vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}" }
3228
3229 # download video from youtube
3230 ytdl() {
3231     if ! [[ -n "$2" ]] ; then
3232         print "Usage: ydtl http://youtube.com/watch?v=.... outputfile.flv">&2
3233         return 1
3234     else
3235         wget -O${2} "http://youtube.com/get_video?"${${${"$(wget -o/dev/null -O- "${1}" | grep -e watch_fullscreen)"}##*watch_fullscreen\?}%%\&fs=*}
3236     fi
3237 }
3238
3239 # Function Usage: uopen $URL/$file
3240 #f5# Download a file and display it locally
3241 uopen() {
3242     if ! [[ -n "$1" ]] ; then
3243         print "Usage: uopen \$URL/\$file">&2
3244         return 1
3245     else
3246         FILE=$1
3247         MIME=$(curl --head $FILE | grep Content-Type | cut -d ' ' -f 2 | cut -d\; -f 1)
3248         MIME=${MIME%$'\r'}
3249         curl $FILE | see ${MIME}:-
3250     fi
3251 }
3252
3253 # Function Usage: doc packagename
3254 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
3255 doc() { cd /usr/share/doc/$1 && ls }
3256 _doc() { _files -W /usr/share/doc -/ }
3257 check_com compdef && compdef _doc doc
3258
3259 #f5# Make screenshot
3260 sshot() {
3261     [[ ! -d ~/shots  ]] && mkdir ~/shots
3262     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
3263     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
3264 }
3265
3266 # list images only
3267 limg() {
3268     local -a images
3269     images=( *.{jpg,gif,png}(.N) )
3270
3271     if [[ $#images -eq 0 ]] ; then
3272         print "No image files found"
3273     else
3274         ls "$@" "$images[@]"
3275     fi
3276 }
3277
3278 #f5# Create PDF file from source code
3279 makereadable() {
3280     output=$1
3281     shift
3282     a2ps --medium A4dj -E -o $output $*
3283     ps2pdf $output
3284 }
3285
3286 # zsh with perl-regex - use it e.g. via:
3287 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
3288 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
3289 regcheck() {
3290     zmodload -i zsh/pcre
3291     pcre_compile $1 && \
3292     pcre_match $2 && echo "regex matches" || echo "regex does not match"
3293 }
3294
3295 #f5# List files which have been modified within the last {\it n} days
3296 new() { print -l *(m-$1) }
3297
3298 #f5# Grep in history
3299 greph() { history 0 | grep $1 }
3300 # use colors when GNU grep with color-support
3301 #a2# Execute \kbd{grep -{}-color=auto}
3302 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
3303 #a2# Execute \kbd{grep -i -{}-color=auto}
3304 alias GREP='grep -i --color=auto'
3305
3306 # one blank line between each line
3307 if [[ -r ~/.terminfo/m/mostlike ]] ; then
3308     #f5# Watch manpages in a stretched style
3309     man2() { PAGER='dash -c "sed G | /usr/bin/less"' TERM=mostlike /usr/bin/man "$@" ; }
3310 fi
3311
3312 # d():Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
3313 # note: option AUTO_PUSHD has to be set
3314 #f5# Jump between directories
3315 d() {
3316     emulate -L zsh
3317     autoload -U colors
3318     local color=$fg_bold[blue]
3319     integer i=0
3320     dirs -p | while read dir; do
3321         local num="${$(printf "%-4d " $i)/ /.}"
3322         printf " %s  $color%s$reset_color\n" $num $dir
3323         (( i++ ))
3324     done
3325     integer dir=-1
3326     read -r 'dir?Jump to directory: ' || return
3327     (( dir == -1 )) && return
3328     if (( dir < 0 || dir >= i )); then
3329         echo d: no such directory stack entry: $dir
3330         return 1
3331     fi
3332     cd ~$dir
3333 }
3334
3335 # usage example: 'lcheck strcpy'
3336 #f5# Find out which libs define a symbol
3337 lcheck() {
3338     if [[ -n "$1" ]] ; then
3339         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
3340     else
3341         echo "Usage: lcheck <function>" >&2
3342     fi
3343 }
3344
3345 #f5# Clean up directory - remove well known tempfiles
3346 purge() {
3347     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
3348     NBFILES=${#FILES}
3349     if [[ $NBFILES > 0 ]] ; then
3350         print $FILES
3351         local ans
3352         echo -n "Remove these files? [y/n] "
3353         read -q ans
3354         if [[ $ans == "y" ]] ; then
3355             rm ${FILES}
3356             echo ">> $PWD purged, $NBFILES files removed"
3357         else
3358             echo "Ok. .. than not.."
3359         fi
3360     fi
3361 }
3362
3363 # Translate DE<=>EN
3364 # 'translate' looks up fot a word in a file with language-to-language
3365 # translations (field separator should be " : "). A typical wordlist looks
3366 # like at follows:
3367 #  | english-word : german-transmission
3368 # It's also only possible to translate english to german but not reciprocal.
3369 # Use the following oneliner to turn back the sort order:
3370 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3371 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3372 #f5# Translates a word
3373 trans() {
3374     case "$1" in
3375         -[dD]*)
3376             translate -l de-en $2
3377             ;;
3378         -[eE]*)
3379             translate -l en-de $2
3380             ;;
3381         *)
3382             echo "Usage: $0 { -D | -E }"
3383             echo "         -D == German to English"
3384             echo "         -E == English to German"
3385     esac
3386 }
3387
3388 #f5# List all occurrences of programm in current PATH
3389 plap() {
3390     if [[ $# = 0 ]] ; then
3391         echo "Usage:    $0 program"
3392         echo "Example:  $0 zsh"
3393         echo "Lists all occurrences of program in the current PATH."
3394     else
3395         ls -l ${^path}/*$1*(*N)
3396     fi
3397 }
3398
3399 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
3400 #f5# Select items for specific command(s) from history
3401 selhist() {
3402     emulate -L zsh
3403     local TAB=$'\t';
3404     (( $# < 1 )) && {
3405         echo "Usage: $0 command"
3406         return 1
3407     };
3408     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
3409     print -l $cmd | less -F
3410     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
3411     local answer
3412     read answer
3413     print -z "${cmd[$answer]#*$TAB}"
3414 }
3415
3416 # Use vim to convert plaintext to HTML
3417 #f5# Transform files to html with highlighting
3418 2html() { vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null }
3419
3420 # Usage: simple-extract <file>
3421 #f5# Smart archive extractor
3422 simple-extract () {
3423     if [[ -f $1 ]] ; then
3424         case $1 in
3425             *.tar.bz2)  bzip2 -v -d $1      ;;
3426             *.tar.gz)   tar -xvzf $1        ;;
3427             *.rar)      unrar $1            ;;
3428             *.deb)      ar -x $1            ;;
3429             *.bz2)      bzip2 -d $1         ;;
3430             *.lzh)      lha x $1            ;;
3431             *.gz)       gunzip -d $1        ;;
3432             *.tar)      tar -xvf $1         ;;
3433             *.tgz)      gunzip -d $1        ;;
3434             *.tbz2)     tar -jxvf $1        ;;
3435             *.zip)      unzip $1            ;;
3436             *.Z)        uncompress $1       ;;
3437             *)          echo "'$1' Error. Please go away" ;;
3438         esac
3439     else
3440         echo "'$1' is not a valid file"
3441     fi
3442 }
3443
3444 # Usage: smartcompress <file> (<type>)
3445 #f5# Smart archive creator
3446 smartcompress() {
3447     if [[ -n $2 ]] ; then
3448         case $2 in
3449             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
3450             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
3451             tar.Z)          tar -Zcvf$1.$2 $1 ;;
3452             tar)            tar -cvf$1.$2  $1 ;;
3453             gz | gzip)      gzip           $1 ;;
3454             bz2 | bzip2)    bzip2          $1 ;;
3455             *)
3456                 echo "Error: $2 is not a valid compression type"
3457                 ;;
3458         esac
3459     else
3460         smartcompress $1 tar.gz
3461     fi
3462 }
3463
3464 # Usage: show-archive <archive>
3465 #f5# List an archive's content
3466 show-archive() {
3467     if [[ -f $1 ]] ; then
3468         case $1 in
3469             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
3470             *.tar)         tar -tf $1 ;;
3471             *.tgz)         tar -ztf $1 ;;
3472             *.zip)         unzip -l $1 ;;
3473             *.bz2)         bzless $1 ;;
3474             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
3475             *)             echo "'$1' Error. Please go away" ;;
3476         esac
3477     else
3478         echo "'$1' is not a valid archive"
3479     fi
3480 }
3481
3482 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
3483 #f5# Use \kbd{vim} as your manpage reader
3484 vman() { man $* | col -b | view -c 'set ft=man nomod nolist' - }
3485
3486 # function readme() { $PAGER -- (#ia3)readme* }
3487 #f5# View all README-like files in current directory in pager
3488 readme() {
3489     local files
3490     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
3491     if (($#files)) ; then
3492         $PAGER $files
3493     else
3494         print 'No README files.'
3495     fi
3496 }
3497
3498 # function ansi-colors()
3499 #f5# Display ANSI colors
3500 ansi-colors() {
3501     typeset esc="\033[" line1 line2
3502     echo " _ _ _40 _ _ _41_ _ _ _42 _ _ 43_ _ _ 44_ _ _45 _ _ _ 46_ _ _ 47_ _ _ 49_ _"
3503     for fore in 30 31 32 33 34 35 36 37; do
3504         line1="$fore "
3505         line2="   "
3506         for back in 40 41 42 43 44 45 46 47 49; do
3507             line1="${line1}${esc}${back};${fore}m Normal ${esc}0m"
3508             line2="${line2}${esc}${back};${fore};1m Bold   ${esc}0m"
3509         done
3510         echo -e "$line1\n$line2"
3511     done
3512 }
3513
3514 # suidfind() { ls -latg $path | grep '^...s' }
3515 #f5# Find all files in \$PATH with setuid bit set
3516 suidfind() { ls -latg $path/*(sN) }
3517
3518 # See above but this is /better/ ... anywise ..
3519 findsuid() {
3520     print 'Output will be written to ~/suid_* ...'
3521     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
3522     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
3523     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
3524     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
3525     print 'Finished'
3526 }
3527
3528 #f5# Reload given functions
3529 refunc() {
3530     for func in $argv ; do
3531         unfunction $func
3532         autoload $func
3533     done
3534 }
3535
3536 # a small check to see which DIR is located on which server/partition.
3537 # stolen and modified from Sven's zshrc.forall
3538 #f5# Report diskusage of a directory
3539 dirspace() {
3540     if [[ -n "$1" ]] ; then
3541         for dir in $* ; do
3542             if [[ -d "$dir" ]] ; then
3543                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3544             else
3545                 echo "warning: $dir does not exist" >&2
3546             fi
3547         done
3548     else
3549         for dir in $path; do
3550             if [[ -d "$dir" ]] ; then
3551                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3552             else
3553                 echo "warning: $dir does not exist" >&2
3554             fi
3555         done
3556     fi
3557 }
3558
3559 # % slow_print `cat /etc/passwd`
3560 #f5# Slowly print out parameters
3561 slow_print() {
3562     for argument in "${@}" ; do
3563         for ((i = 1; i <= ${#1} ;i++)) ; do
3564             print -n "${argument[i]}"
3565             sleep 0.08
3566         done
3567         print -n " "
3568     done
3569     print ""
3570 }
3571
3572 #f5# Show some status info
3573 status() {
3574     print ""
3575     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
3576     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
3577     print "Term..: $TTY ($TERM), ${BAUD:+$BAUD bauds, }$COLUMNS x $LINES cars"
3578     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
3579     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
3580     print "Uptime:$(uptime)"
3581     print ""
3582 }
3583
3584 # Rip an audio CD
3585 #f5# Rip an audio CD
3586 audiorip() {
3587     mkdir -p ~/ripps
3588     cd ~/ripps
3589     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
3590     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
3591     echo " * Would you like to burn the cd now? (yes/no)"
3592     read input
3593     if [[ "$input" = "yes" ]] ; then
3594         echo " ! Burning Audio CD"
3595         audioburn
3596         echo " * done."
3597     else
3598         echo " ! Invalid response."
3599     fi
3600 }
3601
3602 # and burn it
3603 #f5# Burn an audio CD (in combination with audiorip)
3604 audioburn() {
3605     cd ~/ripps
3606     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
3607     echo " * Should I remove the temporary files? (yes/no)"
3608     read input
3609     if [[ "$input" = "yes" ]] ; then
3610         echo " ! Removing Temporary Files."
3611         cd ~
3612         rm -rf ~/ripps
3613         echo " * done."
3614     else
3615         echo " ! Invalid response."
3616     fi
3617 }
3618
3619 #f5# Make an audio CD from all mp3 files
3620 mkaudiocd() {
3621     # TODO: do the renaming more zshish, possibly with zmv()
3622     cd ~/ripps
3623     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
3624     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
3625     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
3626     normalize -m *.wav
3627     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
3628 }
3629
3630 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
3631 mkiso() {
3632     echo " * Volume name "
3633     read volume
3634     echo " * ISO Name (ie. tmp.iso)"
3635     read iso
3636     echo " * Directory or File"
3637     read files
3638     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
3639 }
3640
3641 #f5# Simple thumbnails generator
3642 genthumbs() {
3643     rm -rf thumb-* index.html
3644     echo "
3645 <html>
3646   <head>
3647     <title>Images</title>
3648   </head>
3649   <body>" > index.html
3650     for f in *.(gif|jpeg|jpg|png) ; do
3651         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
3652         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
3653     done
3654     echo "
3655   </body>
3656 </html>" >> index.html
3657 }
3658
3659 #f5# Set all ulimit parameters to \kbd{unlimited}
3660 allulimit() {
3661     ulimit -c unlimited
3662     ulimit -d unlimited
3663     ulimit -f unlimited
3664     ulimit -l unlimited
3665     ulimit -n unlimited
3666     ulimit -s unlimited
3667     ulimit -t unlimited
3668 }
3669
3670 # ogg2mp3 with bitrate of 192
3671 ogg2mp3_192() {
3672     oggdec -o - ${1} | lame -b 192 - ${1:r}.mp3
3673 }
3674
3675 #f5# RFC 2396 URL encoding in Z-Shell
3676 urlencode() {
3677     setopt localoptions extendedglob
3678     input=( ${(s::)1} )
3679     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%${(l:2::0:)$(([##16]#match))}}
3680 }
3681
3682 #f5# Install x-lite (VoIP software)
3683 getxlite() {
3684     setopt local_options
3685     setopt errreturn
3686     [[ -d ~/tmp ]] || mkdir ~/tmp
3687     cd ~/tmp
3688
3689     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
3690     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
3691         unp X-Lite_Install.tar.gz && echo done || echo failed
3692     else
3693         echo "Error while downloading." ; return 1
3694     fi
3695
3696     if [[ -x xten-xlite/xtensoftphone ]] ; then
3697         echo "Execute xten-xlite/xtensoftphone to start xlite."
3698     fi
3699 }
3700
3701 #f5# Install skype
3702 getskype() {
3703     setopt local_options
3704     setopt errreturn
3705     echo "Downloading debian package of skype."
3706     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
3707     wget http://www.skype.com/go/getskype-linux-deb
3708     $SUDO dpkg -i skype*.deb && echo "skype installed."
3709 }
3710
3711 #f5# Install beta-version of skype
3712 getskypebeta() {
3713     setopt local_options
3714     setopt errreturn
3715     echo "Downloading debian package of skype (beta version)."
3716     wget http://www.skype.com/go/getskype-linux-beta-deb
3717     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
3718 }
3719
3720 #f5# Install gizmo (VoIP software)
3721 getgizmo() {
3722     setopt local_options
3723     setopt errreturn
3724     echo "libgtk2.0-0, gconf2, libstdc++6, libasound2 and zlib1g have to be available. Installing."
3725     $SUDO apt-get update
3726     $SUDO apt-get install libgtk2.0-0 gconf2 libstdc++6 libasound2 zlib1g
3727     wget "$(lynx --dump http://gizmo5.com/pc/download/linux/ | awk '/libstdc\+\+6.*\.deb/ {print $2}')"
3728     $SUDO dpkg -i gizmo-project*.deb && echo "gizmo installed."
3729 }
3730
3731 #f5# Get and run AIR (Automated Image and Restore)
3732 getair() {
3733     setopt local_options
3734     setopt errreturn
3735     [[ -w . ]] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
3736     local VER='1.2.8'
3737     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
3738     tar zxf air-$VER.tar.gz
3739     cd air-$VER
3740     INTERACTIVE=no $SUDO ./install-air-1.2.8
3741     [[ -x /usr/local/bin/air ]] && [[ -n "$DISPLAY" ]] && $SUDO air
3742 }
3743
3744 #f5# Get specific git commitdiff
3745 git-get-diff() {
3746     if [[ -z $GITTREE ]] ; then
3747         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3748     fi
3749     if ! [[ -z $1 ]] ; then
3750         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
3751     else
3752         echo "Usage: git-get-diff <commit>"
3753     fi
3754 }
3755
3756 #f5# Get specific git commit
3757 git-get-commit() {
3758     if [[ -z $GITTREE ]] ; then
3759         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3760     fi
3761     if ! [[ -z $1 ]] ; then
3762         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
3763     else
3764         echo "Usage: git-get-commit <commit>"
3765     fi
3766 }
3767
3768 #f5# Get specific git diff
3769 git-get-plaindiff () {
3770     if [[ -z $GITTREE ]] ; then
3771        GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3772     fi
3773     if [[ -z $1 ]] ; then
3774        echo 'Usage: git-get-plaindiff '
3775     else
3776        echo -n "Downloading $1.diff ... "
3777        # avoid "generating ..." stuff from kernel.org server:
3778        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O /dev/null
3779        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff \
3780             && echo done || echo failed
3781     fi
3782 }
3783
3784
3785 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
3786 #f5# Log 'make install' output
3787 mmake() {
3788     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
3789     make -n install > ~/.errorlogs/${PWD##*/}-makelog
3790 }
3791
3792 #f5# Indent source code
3793 smart-indent() {
3794     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs $*
3795 }
3796
3797 # highlight important stuff in diff output, usage example: hg diff | hidiff
3798 #m# a2 hidiff \kbd{histring} oneliner for diffs
3799 check_com -c histring && \
3800     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
3801
3802 # rename pictures based on information found in exif headers
3803 #f5# Rename pictures based on information found in exif headers
3804 exirename() {
3805     if [[ $# -lt 1 ]] ; then
3806         echo 'Usage: jpgrename $FILES' >& 2
3807         return 1
3808     else
3809         echo -n 'Checking for jhead with version newer than 1.9: '
3810         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
3811         if [[ $jhead_version > '1.9' ]]; then
3812             echo 'success - now running jhead.'
3813             jhead -n%Y-%m-%d_%Hh%M_%f $*
3814         else
3815             echo 'failed - exiting.'
3816         fi
3817     fi
3818 }
3819
3820 # open file in vim and jump to line
3821 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
3822 j2v() {
3823     local -a params
3824     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
3825     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
3826     vim ${params}
3827 }
3828
3829 # get_ic() - queries imap servers for capabilities; real simple. no imaps
3830 ic_get() {
3831     local port
3832     if [[ ! -z $1 ]] ; then
3833         port=${2:-143}
3834         print "querying imap server on $1:${port}...\n";
3835         print "a1 capability\na2 logout\n" | nc $1 ${port}
3836     else
3837         print "usage:\n  $0 <imap-server> [port]"
3838     fi
3839 }
3840
3841 # creates a Maildir/ with its {new,cur,tmp} subdirs
3842 mkmaildir() {
3843     local root subdir
3844     root=${MAILDIR_ROOT:-${HOME}/Mail}
3845     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
3846     subdir=${1}
3847     mkdir -p ${root}/${subdir}/{cur,new,tmp}
3848 }
3849
3850 #f5# Change the xterm title from within GNU-screen
3851 xtrename() {
3852     if [[ ${1} != "-f" ]] ; then
3853         if [[ -z ${DISPLAY} ]] ; then
3854             printf 'xtrename only makes sense in X11.\n'
3855             return 1
3856         fi
3857     else
3858         shift
3859     fi
3860     if [[ -z ${1} ]] ; then
3861         printf 'usage: xtrename [-f] "title for xterm"\n'
3862         printf '  renames the title of xterm from _within_ screen.\n'
3863         printf '  also works without screen.\n'
3864         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3865         return 0
3866     fi
3867     print -n "\eP\e]0;${1}\C-G\e\\"
3868     return 0
3869 }
3870
3871 # hl() highlighted less
3872 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
3873 if check_com -c highlight ; then
3874     function hl() {
3875         local theme lang
3876         theme=${HL_THEME:-""}
3877         case ${1} in
3878             (-l|--list)
3879                 ( printf 'available languages (syntax parameter):\n\n' ;
3880                     highlight --list-langs ; ) | less -SMr
3881                 ;;
3882             (-t|--themes)
3883                 ( printf 'available themes (style parameter):\n\n' ;
3884                     highlight --list-themes ; ) | less -SMr
3885                 ;;
3886             (-h|--help)
3887                 printf 'usage: hl <syntax[:theme]> <file>\n'
3888                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
3889                 printf '  Example: hl c main.c\n'
3890                 ;;
3891             (*)
3892                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
3893                     printf 'usage: hl <syntax[:theme]> <file>\n'
3894                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
3895                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
3896                     return 1
3897                 fi
3898                 lang=${1%:*}
3899                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
3900                 if [[ -n ${theme} ]] ; then
3901                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
3902                 else
3903                     highlight --ansi --syntax ${lang} ${2} | less -SMr
3904                 fi
3905                 ;;
3906         esac
3907         return 0
3908     }
3909     # ... and a proper completion for hl()
3910     # needs 'highlight' as well, so it fits fine in here.
3911     function _hl_genarg()  {
3912         local expl
3913         if [[ -prefix 1 *: ]] ; then
3914             local themes
3915             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
3916             compset -P 1 '*:'
3917             _wanted -C list themes expl theme compadd ${themes}
3918         else
3919             local langs
3920             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
3921             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
3922         fi
3923     }
3924     function _hl_complete() {
3925         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
3926     }
3927     compdef _hl_complete hl
3928 fi
3929
3930 # Create small urls via http://tinyurl.com using wget(1).
3931 function zurl() {
3932     [[ -z ${1} ]] && { print "USAGE: zurl <URL>" ; return 1 }
3933
3934     local PN url tiny grabber search result preview
3935     PN=${0}
3936     url=${1}
3937 #   Check existence of given URL with the help of ping(1).
3938 #   N.B. ping(1) only works without an eventual given protocol.
3939     ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
3940         read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
3941
3942     if (( $? == 0 )) ; then
3943 #           Prepend 'http://' to given URL where necessary for later output.
3944             [[ ${url} != http(s|)://* ]] && url='http://'${url}
3945             tiny='http://tinyurl.com/create.php?url='
3946             if check_com -c wget ; then
3947                 grabber='wget -O- -o/dev/null'
3948             else
3949                 print "wget is not available, but mandatory for ${PN}. Aborting."
3950             fi
3951 #           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
3952             search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
3953             result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
3954 #           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
3955             preview='http://preview.'${result#http://}
3956
3957             printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
3958             printf '%s\t%s\n\n' 'Given URL:' ${url}
3959             printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
3960     else
3961         return 1
3962     fi
3963 }
3964
3965 #f2# Print a specific line of file(s).
3966 linenr () {
3967 # {{{
3968     if [ $# -lt 2 ] ; then
3969        print "Usage: linenr <number>[,<number>] <file>" ; return 1
3970     elif [ $# -eq 2 ] ; then
3971          local number=$1
3972          local file=$2
3973          command ed -s $file <<< "${number}n"
3974     else
3975          local number=$1
3976          shift
3977          for file in "$@" ; do
3978              if [ ! -d $file ] ; then
3979                 echo "${file}:"
3980                 command ed -s $file <<< "${number}n" 2> /dev/null
3981              else
3982                 continue
3983              fi
3984          done | less
3985     fi
3986 # }}}
3987 }
3988
3989 #f2# Find history events by search pattern and list them by date.
3990 whatwhen()  {
3991 # {{{
3992     local usage help ident format_l format_s first_char remain first last
3993     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3994     help='Use' \`'whatwhen -h'\'' for further explanations.'
3995     ident=${(l,${#${:-Usage: }},, ,)}
3996     format_l="${ident}%s\t\t\t%s\n"
3997     format_s="${format_l//(\\t)##/\\t}"
3998     # Make the first char of the word to search for case
3999     # insensitive; e.g. [aA]
4000     first_char=[${(L)1[1]}${(U)1[1]}]
4001     remain=${1[2,-1]}
4002     # Default search range is `-100'.
4003     first=${2:-\-100}
4004     # Optional, just used for `<first> <last>' given.
4005     last=$3
4006     case $1 in
4007         ("")
4008             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
4009             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4010         ;;
4011         (-h)
4012             printf '%s\n\n' ${usage}
4013             print 'OPTIONS:'
4014             printf $format_l '-h' 'show help text'
4015             print '\f'
4016             print 'SEARCH RANGE:'
4017             printf $format_l "'0'" 'the whole history,'
4018             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
4019             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
4020             printf '\n%s\n' 'EXAMPLES:'
4021             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
4022             printf $format_l 'whatwhen zsh -250'
4023             printf $format_l 'whatwhen foo 1 99'
4024         ;;
4025         (\?)
4026             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4027         ;;
4028         (*)
4029             # -l list results on stout rather than invoking $EDITOR.
4030             # -i Print dates as in YYYY-MM-DD.
4031             # -m Search for a - quoted - pattern within the history.
4032             fc -li -m "*${first_char}${remain}*" $first $last
4033         ;;
4034     esac
4035 # }}}
4036 }
4037
4038 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
4039 fluxkey-change() {
4040     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
4041     if ! [[ -r "$FLUXKEYS" ]] ; then
4042         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
4043         return 1
4044     else
4045         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
4046             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
4047             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
4048         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
4049             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
4050             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
4051         else
4052             echo 'Sorry, do not know what to do.'
4053             return 1
4054         fi
4055     fi
4056 }
4057
4058 # retrieve weather information on the console
4059 # Usage example: 'weather LOWG'
4060 weather() {
4061     [[ -n "$1" ]] || {
4062         print 'Usage: weather <station_id>' >&2
4063         print 'List of stations: http://en.wikipedia.org/wiki/List_of_airports_by_ICAO_code'>&2
4064         return 1
4065     }
4066
4067     local PLACE="${1:u}"
4068     local FILE="$HOME/.weather/$PLACE"
4069     local LOG="$HOME/.weather/log"
4070
4071     [[ -d $HOME/.weather ]] || {
4072         print -n "Creating $HOME/.weather: "
4073         mkdir $HOME/.weather
4074         print 'done'
4075     }
4076
4077     print "Retrieving information for ${PLACE}:"
4078     print
4079     wget -T 10 --no-verbose --output-file=$LOG --output-document=$FILE --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
4080
4081     if [[ $? -eq 0 ]] ; then
4082         if [[ -n "$VERBOSE" ]] ; then
4083             cat $FILE
4084         else
4085             DATE=$(grep 'UTC' $FILE | sed 's#.* /##')
4086             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' $FILE| tr -d '(')
4087             echo "date: $DATE"
4088             echo "temp:  $TEMPERATURE"
4089         fi
4090     else
4091         print "There was an error retrieving the weather information for $PLACE" >&2
4092         cat $LOG
4093         return 1
4094     fi
4095 }
4096 # }}}
4097
4098 # mercurial related stuff {{{
4099 if check_com -c hg ; then
4100     # gnu like diff for mercurial
4101     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
4102     #f5# GNU like diff for mercurial
4103     hgdi() {
4104         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
4105     }
4106
4107     # build debian package
4108     #a2# Alias for \kbd{hg-buildpackage}
4109     alias hbp='hg-buildpackage'
4110
4111     # execute commands on the versioned patch-queue from the current repos
4112     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
4113
4114     # diffstat for specific version of a mercurial repository
4115     #   hgstat      => display diffstat between last revision and tip
4116     #   hgstat 1234 => display diffstat between revision 1234 and tip
4117     #f5# Diffstat for specific version of a mercurial repos
4118     hgstat() {
4119         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
4120     }
4121
4122     #f5# Get current mercurial tip via hg itself
4123     gethgclone() {
4124         setopt local_options
4125         setopt errreturn
4126         if [[ -f mercurial-tree/.hg ]] ; then
4127             cd mercurial-tree
4128             echo "Running hg pull for retreiving latest version..."
4129             hg pull
4130             echo "Finished update. Building mercurial"
4131             make local
4132             echo "Setting \$PATH to $PWD:\$PATH..."
4133             export PATH="$PWD:$PATH"
4134         else
4135             echo "Downloading mercurial via hg"
4136             hg clone http://selenic.com/repo/hg mercurial-tree
4137             cd mercurial-tree
4138             echo "Building mercurial"
4139             make local
4140             echo "Setting \$PATH to $PWD:\$PATH..."
4141             export PATH="$PWD:$PATH"
4142             echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4143             # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
4144             # export PYTHONPATH=${HOME}/lib/python
4145         fi
4146     }
4147
4148 fi # end of check whether we have the 'hg'-executable
4149
4150 # get current mercurial snapshot
4151 #f5# Get current mercurial snapshot
4152 gethgsnap() {
4153     setopt local_options
4154     setopt errreturn
4155     if [[ -f mercurial-snapshot.tar.gz ]] ; then
4156          echo "mercurial-snapshot.tar.gz exists already, skipping download."
4157     else
4158         echo "Downloading mercurial snapshot"
4159         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
4160     fi
4161     echo "Unpacking mercurial-snapshot.tar.gz"
4162     tar zxf mercurial-snapshot.tar.gz
4163     cd mercurial-snapshot/
4164     echo "Installing required build-dependencies"
4165     $SUDO apt-get update
4166     $SUDO apt-get install python2.4-dev
4167     echo "Building mercurial"
4168     make local
4169     echo "Setting \$PATH to $PWD:\$PATH..."
4170     export PATH="$PWD:$PATH"
4171     echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4172 }
4173 # }}}
4174
4175 # some useful commands often hard to remember - let's grep for them {{{
4176 # actually use our zg() function now. :)
4177
4178 # Work around ion/xterm resize bug.
4179 #if [[ "$SHLVL" -eq 1 ]]; then
4180 #       if check_com -c resize ; then
4181 #               eval `resize </dev/null`
4182 #       fi
4183 #fi
4184
4185 # enable jackd:
4186 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
4187 # now play audio file:
4188 #  alsaplayer -o jack foobar.mp3
4189
4190 # send files via netcat
4191 # on sending side:
4192 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
4193 #  send dir* $HOST
4194 #  alias receive='nc -vlp 51330 | tar xzvp'
4195
4196 # debian stuff:
4197 # dh_make -e foo@localhost -f $1
4198 # dpkg-buildpackage -rfakeroot
4199 # lintian *.deb
4200 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
4201 # dpkg-scansources . | gzip > Sources.gz
4202 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
4203
4204 # other stuff:
4205 # convert -geometry 200x200 -interlace LINE -verbose
4206 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
4207 # ps -ao user,pcpu,start,command
4208 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
4209 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
4210 # nc -vz $1 1-1024   # portscan via netcat
4211 # wget --mirror --no-parent --convert-links
4212 # pal -d `date +%d`
4213 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
4214 #
4215 # modify console cursor
4216 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
4217 # print $'\e[?96;0;64c'
4218 # }}}
4219
4220 # grml-small cleanups {{{
4221
4222 # The following is used to remove zsh-config-items that do not work
4223 # in grml-small by default.
4224 # If you do not want these adjustments (for whatever reason), set
4225 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
4226 # sources if it is there).
4227
4228 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
4229
4230     unset abk[V]
4231     unalias    'V'      &> /dev/null
4232     unfunction vman     &> /dev/null
4233     unfunction vimpm    &> /dev/null
4234     unfunction vimhelp  &> /dev/null
4235     unfunction viless   &> /dev/null
4236     unfunction 2html    &> /dev/null
4237
4238     # manpages are not in grmlsmall
4239     unfunction manzsh   &> /dev/null
4240     unalias    man2     &> /dev/null
4241     unalias    man      &> /dev/null
4242     unfunction man2     &> /dev/null
4243
4244 fi
4245
4246 #}}}
4247
4248 # finally source a local zshrc {{{
4249
4250 # this allows us to stay in sync with grml's zshrc and put own
4251 # modifications in ~/.zshrc.local
4252
4253 xsource "${HOME}/.zshrc.local"
4254
4255 # }}}
4256
4257 ## genrefcard.pl settings {{{
4258
4259 ### doc strings for external functions from files
4260 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
4261
4262 ### example: split functions-search 8,16,24,32
4263 #@# split functions-search 8
4264
4265 ## }}}
4266
4267 ## END OF FILE #################################################################
4268 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4