etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is437(){
 148     [[ $ZSH_VERSION == 4.3.<7->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 is439(){
 154     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 155                                  || $ZSH_VERSION == <5->* ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running grml
 160 isgrml(){
 161     [[ -f /etc/grml_version ]] && return 0
 162     return 1
 163 }
 164
 165 #f1# Checks whether or not you're running a grml cd
 166 isgrmlcd(){
 167     [[ -f /etc/grml_cd ]] && return 0
 168     return 1
 169 }
 170
 171 if isgrml ; then
 172 #f1# Checks whether or not you're running grml-small
 173     isgrmlsmall() {
 174         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 175             return 0
 176         fi
 177         return 1
 178     }
 179 else
 180     isgrmlsmall() { return 1 }
 181 fi
 182
 183 GRML_OSTYPE=$(uname -s)
 184
 185 islinux(){
 186     [[ $GRML_OSTYPE == "Linux" ]]
 187 }
 188
 189 isdarwin(){
 190     [[ $GRML_OSTYPE == "Darwin" ]]
 191 }
 192
 193 isfreebsd(){
 194     [[ $GRML_OSTYPE == "FreeBSD" ]]
 195 }
 196
 197 isopenbsd(){
 198     [[ $GRML_OSTYPE == "OpenBSD" ]]
 199 }
 200
 201 #f1# are we running within an utf environment?
 202 isutfenv() {
 203     case "$LANG $CHARSET $LANGUAGE" in
 204         *utf*) return 0 ;;
 205         *UTF*) return 0 ;;
 206         *)     return 1 ;;
 207     esac
 208 }
 209
 210 # check for user, if not running as root set $SUDO to sudo
 211 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 212
 213 # change directory to home on first invocation of zsh
 214 # important for rungetty -> autologin
 215 # Thanks go to Bart Schaefer!
 216 isgrml && checkhome() {
 217     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 218         export ALREADY_DID_CD_HOME=$HOME
 219         cd
 220     fi
 221 }
 222
 223 # check for zsh v3.1.7+
 224
 225 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 226      || ${ZSH_VERSION} == 3.<2->.<->*    \
 227      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 228
 229     printf '-!-\n'
 230     printf '-!- In this configuration we try to make use of features, that only\n'
 231     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 232     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 233     printf '-!- advanced features in all supported versions.\n'
 234     printf '-!-\n'
 235     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 236     printf '-!-\n'
 237     printf '-!- While this *may* work, it might as well fail.\n'
 238     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 239     printf '-!-\n'
 240     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 241     printf '-!- If it does today, you'\''ve been lucky.\n'
 242     printf '-!-\n'
 243     printf '-!- Ye been warned!\n'
 244     printf '-!-\n'
 245
 246     function zstyle() { : }
 247 fi
 248
 249 # autoload wrapper - use this one instead of autoload directly
 250 # We need to define this function as early as this, because autoloading
 251 # 'is-at-least()' needs it.
 252 function zrcautoload() {
 253     emulate -L zsh
 254     setopt extended_glob
 255     local fdir ffile
 256     local -i ffound
 257
 258     ffile=$1
 259     (( ffound = 0 ))
 260     for fdir in ${fpath} ; do
 261         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 262     done
 263
 264     (( ffound == 0 )) && return 1
 265     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 266         autoload -U ${ffile} || return 1
 267     else
 268         autoload ${ffile} || return 1
 269     fi
 270     return 0
 271 }
 272
 273 # Load is-at-least() for more precise version checks Note that this test will
 274 # *always* fail, if the is-at-least function could not be marked for
 275 # autoloading.
 276 zrcautoload is-at-least || is-at-least() { return 1 }
 277
 278 # set some important options (as early as possible)
 279
 280 # append history list to the history file; this is the default but we make sure
 281 # because it's required for share_history.
 282 setopt append_history
 283
 284 # import new commands from the history file also in other zsh-session
 285 is4 && setopt share_history
 286
 287 # save each command's beginning timestamp and the duration to the history file
 288 setopt extended_history
 289
 290 # If a new command line being added to the history list duplicates an older
 291 # one, the older command is removed from the list
 292 is4 && setopt histignorealldups
 293
 294 # remove command lines from the history list when the first character on the
 295 # line is a space
 296 setopt histignorespace
 297
 298 # if a command is issued that can't be executed as a normal command, and the
 299 # command is the name of a directory, perform the cd command to that directory.
 300 setopt auto_cd
 301
 302 # in order to use #, ~ and ^ for filename generation grep word
 303 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 304 # don't forget to quote '^', '~' and '#'!
 305 setopt extended_glob
 306
 307 # display PID when suspending processes as well
 308 setopt longlistjobs
 309
 310 # try to avoid the 'zsh: no matches found...'
 311 setopt nonomatch
 312
 313 # report the status of backgrounds jobs immediately
 314 setopt notify
 315
 316 # whenever a command completion is attempted, make sure the entire command path
 317 # is hashed first.
 318 setopt hash_list_all
 319
 320 # not just at the end
 321 setopt completeinword
 322
 323 # Don't send SIGHUP to background processes when the shell exits.
 324 setopt nohup
 325
 326 # make cd push the old directory onto the directory stack.
 327 setopt auto_pushd
 328
 329 # avoid "beep"ing
 330 setopt nobeep
 331
 332 # don't push the same dir twice.
 333 setopt pushd_ignore_dups
 334
 335 # * shouldn't match dotfiles. ever.
 336 setopt noglobdots
 337
 338 # use zsh style word splitting
 339 setopt noshwordsplit
 340
 341 # don't error out when unset parameters are used
 342 setopt unset
 343
 344 # setting some default values
 345 NOCOR=${NOCOR:-0}
 346 NOMENU=${NOMENU:-0}
 347 NOPRECMD=${NOPRECMD:-0}
 348 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 349 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 350 GRML_DISPLAY_BATTERY=${GRML_DISPLAY_BATTERY:-${BATTERY:-0}}
 351 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 352 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 353
 354 typeset -ga ls_options
 355 typeset -ga grep_options
 356 if ls --color=auto / >/dev/null 2>&1; then
 357     ls_options=( --color=auto )
 358 elif ls -G / >/dev/null 2>&1; then
 359     ls_options=( -G )
 360 fi
 361 if grep --color=auto -q "a" <<< "a" >/dev/null 2>&1; then
 362     grep_options=( --color=auto )
 363 fi
 364
 365 # utility functions
 366 # this function checks if a command exists and returns either true
 367 # or false. This avoids using 'which' and 'whence', which will
 368 # avoid problems with aliases for which on certain weird systems. :-)
 369 # Usage: check_com [-c|-g] word
 370 #   -c  only checks for external commands
 371 #   -g  does the usual tests and also checks for global aliases
 372 check_com() {
 373     emulate -L zsh
 374     local -i comonly gatoo
 375
 376     if [[ $1 == '-c' ]] ; then
 377         (( comonly = 1 ))
 378         shift
 379     elif [[ $1 == '-g' ]] ; then
 380         (( gatoo = 1 ))
 381     else
 382         (( comonly = 0 ))
 383         (( gatoo = 0 ))
 384     fi
 385
 386     if (( ${#argv} != 1 )) ; then
 387         printf 'usage: check_com [-c] <command>\n' >&2
 388         return 1
 389     fi
 390
 391     if (( comonly > 0 )) ; then
 392         [[ -n ${commands[$1]}  ]] && return 0
 393         return 1
 394     fi
 395
 396     if   [[ -n ${commands[$1]}    ]] \
 397       || [[ -n ${functions[$1]}   ]] \
 398       || [[ -n ${aliases[$1]}     ]] \
 399       || [[ -n ${reswords[(r)$1]} ]] ; then
 400
 401         return 0
 402     fi
 403
 404     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 405         return 0
 406     fi
 407
 408     return 1
 409 }
 410
 411 # creates an alias and precedes the command with
 412 # sudo if $EUID is not zero.
 413 salias() {
 414     emulate -L zsh
 415     local only=0 ; local multi=0
 416     local key val
 417     while [[ $1 == -* ]] ; do
 418         case $1 in
 419             (-o) only=1 ;;
 420             (-a) multi=1 ;;
 421             (--) shift ; break ;;
 422             (-h)
 423                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 424                 printf '  -h      shows this help text.\n'
 425                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 426                 printf '          be careful using this option.\n'
 427                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 428                 return 0
 429                 ;;
 430             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 431         esac
 432         shift
 433     done
 434
 435     if (( ${#argv} > 1 )) ; then
 436         printf 'Too many arguments %s\n' "${#argv}"
 437         return 1
 438     fi
 439
 440     key="${1%%\=*}" ;  val="${1#*\=}"
 441     if (( EUID == 0 )) && (( only == 0 )); then
 442         alias -- "${key}=${val}"
 443     elif (( EUID > 0 )) ; then
 444         (( multi > 0 )) && val="${val// ; / ; sudo }"
 445         alias -- "${key}=sudo ${val}"
 446     fi
 447
 448     return 0
 449 }
 450
 451 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 452 # usage: uprint foo
 453 #   Where foo is the *name* of the parameter you want printed.
 454 #   Note that foo is no typo; $foo would be wrong here!
 455 if ! is42 ; then
 456     uprint () {
 457         emulate -L zsh
 458         local -a u
 459         local w
 460         local parameter=$1
 461
 462         if [[ -z ${parameter} ]] ; then
 463             printf 'usage: uprint <parameter>\n'
 464             return 1
 465         fi
 466
 467         for w in ${(P)parameter} ; do
 468             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 469         done
 470
 471         builtin print -l $u
 472     }
 473 fi
 474
 475 # Check if we can read given files and source those we can.
 476 xsource() {
 477     if (( ${#argv} < 1 )) ; then
 478         printf 'usage: xsource FILE(s)...\n' >&2
 479         return 1
 480     fi
 481
 482     while (( ${#argv} > 0 )) ; do
 483         [[ -r "$1" ]] && source "$1"
 484         shift
 485     done
 486     return 0
 487 }
 488
 489 # Check if we can read a given file and 'cat(1)' it.
 490 xcat() {
 491     emulate -L zsh
 492     if (( ${#argv} != 1 )) ; then
 493         printf 'usage: xcat FILE\n' >&2
 494         return 1
 495     fi
 496
 497     [[ -r $1 ]] && cat $1
 498     return 0
 499 }
 500
 501 # Remove these functions again, they are of use only in these
 502 # setup files. This should be called at the end of .zshrc.
 503 xunfunction() {
 504     emulate -L zsh
 505     local -a funcs
 506     funcs=(salias xcat xsource xunfunction zrcautoload zrcautozle)
 507     for func in $funcs ; do
 508         [[ -n ${functions[$func]} ]] \
 509             && unfunction $func
 510     done
 511     return 0
 512 }
 513
 514 # this allows us to stay in sync with grml's zshrc and put own
 515 # modifications in ~/.zshrc.local
 516 zrclocal() {
 517     xsource "/etc/zsh/zshrc.local"
 518     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 519     return 0
 520 }
 521
 522 # locale setup
 523 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 524     xsource "/etc/default/locale"
 525 fi
 526
 527 for var in LANG LC_ALL LC_MESSAGES ; do
 528     [[ -n ${(P)var} ]] && export $var
 529 done
 530
 531 # set some variables
 532 if check_com -c vim ; then
 533 #v#
 534     export EDITOR=${EDITOR:-vim}
 535 else
 536     export EDITOR=${EDITOR:-vi}
 537 fi
 538
 539 #v#
 540 export PAGER=${PAGER:-less}
 541
 542 #v#
 543 export MAIL=${MAIL:-/var/mail/$USER}
 544
 545 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 546 if [[ -z "$SHELL" ]] ; then
 547   SHELL="$(which zsh)"
 548   if [[ -x "$SHELL" ]] ; then
 549     export SHELL
 550   fi
 551 fi
 552
 553 # color setup for ls:
 554 check_com -c dircolors && eval $(dircolors -b)
 555 # color setup for ls on OS X / FreeBSD:
 556 isdarwin && export CLICOLOR=1
 557 isfreebsd && export CLICOLOR=1
 558
 559 # do MacPorts setup on darwin
 560 if isdarwin && [[ -d /opt/local ]]; then
 561     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 562     # zshenv.
 563     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 564     MANPATH="/opt/local/share/man:$MANPATH"
 565 fi
 566 # do Fink setup on darwin
 567 isdarwin && xsource /sw/bin/init.sh
 568
 569 # load our function and completion directories
 570 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 571     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 572     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 573         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 574             zrcautoload ${func:t}
 575         done
 576     fi
 577 done
 578 unset fdir func
 579
 580 # support colors in less
 581 export LESS_TERMCAP_mb=$'\E[01;31m'
 582 export LESS_TERMCAP_md=$'\E[01;31m'
 583 export LESS_TERMCAP_me=$'\E[0m'
 584 export LESS_TERMCAP_se=$'\E[0m'
 585 export LESS_TERMCAP_so=$'\E[01;44;33m'
 586 export LESS_TERMCAP_ue=$'\E[0m'
 587 export LESS_TERMCAP_us=$'\E[01;32m'
 588
 589 # mailchecks
 590 MAILCHECK=30
 591
 592 # report about cpu-/system-/user-time of command if running longer than
 593 # 5 seconds
 594 REPORTTIME=5
 595
 596 # watch for everyone but me and root
 597 watch=(notme root)
 598
 599 # automatically remove duplicates from these arrays
 600 typeset -U path cdpath fpath manpath
 601
 602 # Load a few modules
 603 is4 && \
 604 for mod in parameter complist deltochar mathfunc ; do
 605     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 606 done
 607
 608 # autoload zsh modules when they are referenced
 609 if is4 ; then
 610     zmodload -a  zsh/stat    zstat
 611     zmodload -a  zsh/zpty    zpty
 612     zmodload -ap zsh/mapfile mapfile
 613 fi
 614
 615 # completion system
 616 COMPDUMPFILE=${COMPDUMPFILE:-${ZDOTDIR:-${HOME}}/.zcompdump}
 617 if zrcautoload compinit ; then
 618     compinit -d ${COMPDUMPFILE} || print 'Notice: no compinit available :('
 619 else
 620     print 'Notice: no compinit available :('
 621     function compdef { }
 622 fi
 623
 624 # completion system
 625
 626 # called later (via is4 && grmlcomp)
 627 # note: use 'zstyle' for getting current settings
 628 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
 629 grmlcomp() {
 630     # TODO: This could use some additional information
 631
 632     # Make sure the completion system is initialised
 633     (( ${+_comps} )) || return 1
 634
 635     # allow one error for every three characters typed in approximate completer
 636     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
 637
 638     # don't complete backup files as executables
 639     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
 640
 641     # start menu completion only if it could find no unambiguous initial string
 642     zstyle ':completion:*:correct:*'       insert-unambiguous true
 643     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
 644     zstyle ':completion:*:correct:*'       original true
 645
 646     # activate color-completion
 647     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
 648
 649     # format on completion
 650     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
 651
 652     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
 653     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
 654
 655     # insert all expansions for expand completer
 656     zstyle ':completion:*:expand:*'        tag-order all-expansions
 657     zstyle ':completion:*:history-words'   list false
 658
 659     # activate menu
 660     zstyle ':completion:*:history-words'   menu yes
 661
 662     # ignore duplicate entries
 663     zstyle ':completion:*:history-words'   remove-all-dups yes
 664     zstyle ':completion:*:history-words'   stop yes
 665
 666     # match uppercase from lowercase
 667     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
 668
 669     # separate matches into groups
 670     zstyle ':completion:*:matches'         group 'yes'
 671     zstyle ':completion:*'                 group-name ''
 672
 673     if [[ "$NOMENU" -eq 0 ]] ; then
 674         # if there are more than 5 options allow selecting from a menu
 675         zstyle ':completion:*'               menu select=5
 676     else
 677         # don't use any menus at all
 678         setopt no_auto_menu
 679     fi
 680
 681     zstyle ':completion:*:messages'        format '%d'
 682     zstyle ':completion:*:options'         auto-description '%d'
 683
 684     # describe options in full
 685     zstyle ':completion:*:options'         description 'yes'
 686
 687     # on processes completion complete all user processes
 688     zstyle ':completion:*:processes'       command 'ps -au$USER'
 689
 690     # offer indexes before parameters in subscripts
 691     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
 692
 693     # provide verbose completion information
 694     zstyle ':completion:*'                 verbose true
 695
 696     # recent (as of Dec 2007) zsh versions are able to provide descriptions
 697     # for commands (read: 1st word in the line) that it will list for the user
 698     # to choose from. The following disables that, because it's not exactly fast.
 699     zstyle ':completion:*:-command-:*:'    verbose false
 700
 701     # set format for warnings
 702     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
 703
 704     # define files to ignore for zcompile
 705     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
 706     zstyle ':completion:correct:'          prompt 'correct to: %e'
 707
 708     # Ignore completion functions for commands you don't have:
 709     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
 710
 711     # Provide more processes in completion of programs like killall:
 712     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
 713
 714     # complete manual by their section
 715     zstyle ':completion:*:manuals'    separate-sections true
 716     zstyle ':completion:*:manuals.*'  insert-sections   true
 717     zstyle ':completion:*:man:*'      menu yes select
 718
 719     # Search path for sudo completion
 720     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
 721                                                /usr/local/bin  \
 722                                                /usr/sbin       \
 723                                                /usr/bin        \
 724                                                /sbin           \
 725                                                /bin            \
 726                                                /usr/X11R6/bin
 727
 728     # provide .. as a completion
 729     zstyle ':completion:*' special-dirs ..
 730
 731     # run rehash on completion so new installed program are found automatically:
 732     _force_rehash() {
 733         (( CURRENT == 1 )) && rehash
 734         return 1
 735     }
 736
 737     ## correction
 738     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
 739     if [[ "$NOCOR" -gt 0 ]] ; then
 740         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
 741         setopt nocorrect
 742     else
 743         # try to be smart about when to use what completer...
 744         setopt correct
 745         zstyle -e ':completion:*' completer '
 746             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
 747                 _last_try="$HISTNO$BUFFER$CURSOR"
 748                 reply=(_complete _match _ignored _prefix _files)
 749             else
 750                 if [[ $words[1] == (rm|mv) ]] ; then
 751                     reply=(_complete _files)
 752                 else
 753                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
 754                 fi
 755             fi'
 756     fi
 757
 758     # command for process lists, the local web server details and host completion
 759     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
 760
 761     # caching
 762     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
 763                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
 764
 765     # host completion
 766     if is42 ; then
 767         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
 768         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
 769     else
 770         _ssh_hosts=()
 771         _etc_hosts=()
 772     fi
 773     hosts=(
 774         $(hostname)
 775         "$_ssh_hosts[@]"
 776         "$_etc_hosts[@]"
 777         localhost
 778     )
 779     zstyle ':completion:*:hosts' hosts $hosts
 780     # TODO: so, why is this here?
 781     #  zstyle '*' hosts $hosts
 782
 783     # use generic completion system for programs not yet defined; (_gnu_generic works
 784     # with commands that provide a --help option with "standard" gnu-like output.)
 785     for compcom in cp deborphan df feh fetchipac gpasswd head hnb ipacsum mv \
 786                    pal stow tail uname ; do
 787         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
 788     done; unset compcom
 789
 790     # see upgrade function in this file
 791     compdef _hosts upgrade
 792 }
 793
 794 # Keyboard setup: The following is based on the same code, we wrote for
 795 # debian's setup. It ensures the terminal is in the right mode, when zle is
 796 # active, so the values from $terminfo are valid. Therefore, this setup should
 797 # work on all systems, that have support for `terminfo'. It also requires the
 798 # zsh in use to have the `zsh/terminfo' module built.
 799 #
 800 # If you are customising your `zle-line-init()' or `zle-line-finish()'
 801 # functions, make sure you call the following utility functions in there:
 802 #
 803 #     - zle-line-init():      zle-smkx
 804 #     - zle-line-finish():    zle-rmkx
 805
 806 # Use emacs-like key bindings by default:
 807 bindkey -e
 808
 809 # Custom widgets:
 810
 811 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 812 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 813 beginning-or-end-of-somewhere() {
 814     local hno=$HISTNO
 815     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 816       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 817         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 818     else
 819         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 820         if (( HISTNO != hno )); then
 821             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 822         fi
 823     fi
 824 }
 825 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 826 zle -N end-of-somewhere beginning-or-end-of-somewhere
 827
 828 # add a command line to the shells history without executing it
 829 commit-to-history() {
 830     print -s ${(z)BUFFER}
 831     zle send-break
 832 }
 833 zle -N commit-to-history
 834
 835 # only slash should be considered as a word separator:
 836 slash-backward-kill-word() {
 837     local WORDCHARS="${WORDCHARS:s@/@}"
 838     # zle backward-word
 839     zle backward-kill-word
 840 }
 841 zle -N slash-backward-kill-word
 842
 843 # a generic accept-line wrapper
 844
 845 # This widget can prevent unwanted autocorrections from command-name
 846 # to _command-name, rehash automatically on enter and call any number
 847 # of builtin and user-defined widgets in different contexts.
 848 #
 849 # For a broader description, see:
 850 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 851 #
 852 # The code is imported from the file 'zsh/functions/accept-line' from
 853 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 854 # distributed under the same terms as zsh itself.
 855
 856 # A newly added command will may not be found or will cause false
 857 # correction attempts, if you got auto-correction set. By setting the
 858 # following style, we force accept-line() to rehash, if it cannot
 859 # find the first word on the command line in the $command[] hash.
 860 zstyle ':acceptline:*' rehash true
 861
 862 function Accept-Line() {
 863     setopt localoptions noksharrays
 864     local -a subs
 865     local -xi aldone
 866     local sub
 867     local alcontext=${1:-$alcontext}
 868
 869     zstyle -a ":acceptline:${alcontext}" actions subs
 870
 871     (( ${#subs} < 1 )) && return 0
 872
 873     (( aldone = 0 ))
 874     for sub in ${subs} ; do
 875         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 876         zle ${sub}
 877
 878         (( aldone > 0 )) && break
 879     done
 880 }
 881
 882 function Accept-Line-getdefault() {
 883     emulate -L zsh
 884     local default_action
 885
 886     zstyle -s ":acceptline:${alcontext}" default_action default_action
 887     case ${default_action} in
 888         ((accept-line|))
 889             printf ".accept-line"
 890             ;;
 891         (*)
 892             printf ${default_action}
 893             ;;
 894     esac
 895 }
 896
 897 function Accept-Line-HandleContext() {
 898     zle Accept-Line
 899
 900     default_action=$(Accept-Line-getdefault)
 901     zstyle -T ":acceptline:${alcontext}" call_default \
 902         && zle ${default_action}
 903 }
 904
 905 function accept-line() {
 906     setopt localoptions noksharrays
 907     local -ax cmdline
 908     local -x alcontext
 909     local buf com fname format msg default_action
 910
 911     alcontext='default'
 912     buf="${BUFFER}"
 913     cmdline=(${(z)BUFFER})
 914     com="${cmdline[1]}"
 915     fname="_${com}"
 916
 917     Accept-Line 'preprocess'
 918
 919     zstyle -t ":acceptline:${alcontext}" rehash \
 920         && [[ -z ${commands[$com]} ]]           \
 921         && rehash
 922
 923     if    [[ -n ${com}               ]] \
 924        && [[ -n ${reswords[(r)$com]} ]] \
 925        || [[ -n ${aliases[$com]}     ]] \
 926        || [[ -n ${functions[$com]}   ]] \
 927        || [[ -n ${builtins[$com]}    ]] \
 928        || [[ -n ${commands[$com]}    ]] ; then
 929
 930         # there is something sensible to execute, just do it.
 931         alcontext='normal'
 932         Accept-Line-HandleContext
 933
 934         return
 935     fi
 936
 937     if    [[ -o correct              ]] \
 938        || [[ -o correctall           ]] \
 939        && [[ -n ${functions[$fname]} ]] ; then
 940
 941         # nothing there to execute but there is a function called
 942         # _command_name; a completion widget. Makes no sense to
 943         # call it on the commandline, but the correct{,all} options
 944         # will ask for it nevertheless, so warn the user.
 945         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 946             # Okay, we warned the user before, he called us again,
 947             # so have it his way.
 948             alcontext='force'
 949             Accept-Line-HandleContext
 950
 951             return
 952         fi
 953
 954         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
 955             alcontext='normal'
 956             Accept-Line-HandleContext
 957         else
 958             # prepare warning message for the user, configurable via zstyle.
 959             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 960
 961             if [[ -z ${msg} ]] ; then
 962                 msg="%c will not execute and completion %f exists."
 963             fi
 964
 965             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 966
 967             zle -M -- "${msg}"
 968         fi
 969         return
 970     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 971         # If we are here, the commandline contains something that is not
 972         # executable, which is neither subject to _command_name correction
 973         # and is not empty. might be a variable assignment
 974         alcontext='misc'
 975         Accept-Line-HandleContext
 976
 977         return
 978     fi
 979
 980     # If we got this far, the commandline only contains whitespace, or is empty.
 981     alcontext='empty'
 982     Accept-Line-HandleContext
 983 }
 984
 985 zle -N accept-line
 986 zle -N Accept-Line
 987 zle -N Accept-Line-HandleContext
 988
 989 # power completion / abbreviation expansion / buffer expansion
 990 # see http://zshwiki.org/home/examples/zleiab for details
 991 # less risky than the global aliases but powerful as well
 992 # just type the abbreviation key and afterwards 'ctrl-x .' to expand it
 993 declare -A abk
 994 setopt extendedglob
 995 setopt interactivecomments
 996 abk=(
 997 #   key   # value                  (#d additional doc string)
 998 #A# start
 999     '...'  '../..'
1000     '....' '../../..'
1001     'BG'   '& exit'
1002     'C'    '| wc -l'
1003     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
1004     'H'    '| head'
1005     'Hl'   ' --help |& less -r'    #d (Display help in pager)
1006     'L'    '| less'
1007     'LL'   '|& less -r'
1008     'M'    '| most'
1009     'N'    '&>/dev/null'           #d (No Output)
1010     'R'    '| tr A-z N-za-m'       #d (ROT13)
1011     'SL'   '| sort | less'
1012     'S'    '| sort -u'
1013     'T'    '| tail'
1014     'V'    '|& vim -'
1015 #A# end
1016     'co'   './configure && make && sudo make install'
1017 )
1018
1019 zleiab() {
1020     emulate -L zsh
1021     setopt extendedglob
1022     local MATCH
1023
1024     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
1025     LBUFFER+=${abk[$MATCH]:-$MATCH}
1026 }
1027
1028 zle -N zleiab
1029
1030 help-show-abk()
1031 {
1032   zle -M "$(print "Available abbreviations for expansion:"; print -a -C 2 ${(kv)abk})"
1033 }
1034
1035 zle -N help-show-abk
1036
1037 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1038 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1039 zle -N insert-datestamp
1040
1041 # press esc-m for inserting last typed word again (thanks to caphuso!)
1042 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1043 zle -N insert-last-typed-word;
1044
1045 function grml-zsh-fg() {
1046   if (( ${#jobstates} )); then
1047     zle .push-input
1048     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1049     BUFFER="${BUFFER}fg"
1050     zle .accept-line
1051   else
1052     zle -M 'No background jobs. Doing nothing.'
1053   fi
1054 }
1055 zle -N grml-zsh-fg
1056
1057 # run command line as user root via sudo:
1058 sudo-command-line() {
1059     [[ -z $BUFFER ]] && zle up-history
1060     if [[ $BUFFER != sudo\ * ]]; then
1061         BUFFER="sudo $BUFFER"
1062         CURSOR=$(( CURSOR+5 ))
1063     fi
1064 }
1065 zle -N sudo-command-line
1066
1067 ### jump behind the first word on the cmdline.
1068 ### useful to add options.
1069 function jump_after_first_word() {
1070     local words
1071     words=(${(z)BUFFER})
1072
1073     if (( ${#words} <= 1 )) ; then
1074         CURSOR=${#BUFFER}
1075     else
1076         CURSOR=${#${words[1]}}
1077     fi
1078 }
1079 zle -N jump_after_first_word
1080
1081 #f5# Create directory under cursor or the selected area
1082 inplaceMkDirs() {
1083     # Press ctrl-xM to create the directory under the cursor or the selected area.
1084     # To select an area press ctrl-@ or ctrl-space and use the cursor.
1085     # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
1086     # directory does not exist yet -> press ctrl-XM and problem solved
1087     local PATHTOMKDIR
1088     if ((REGION_ACTIVE==1)); then
1089         local F=$MARK T=$CURSOR
1090         if [[ $F -gt $T ]]; then
1091             F=${CURSOR}
1092             T=${MARK}
1093         fi
1094         # get marked area from buffer and eliminate whitespace
1095         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
1096         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
1097     else
1098         local bufwords iword
1099         bufwords=(${(z)LBUFFER})
1100         iword=${#bufwords}
1101         bufwords=(${(z)BUFFER})
1102         PATHTOMKDIR="${(Q)bufwords[iword]}"
1103     fi
1104     [[ -z "${PATHTOMKDIR}" ]] && return 1
1105     PATHTOMKDIR=${~PATHTOMKDIR}
1106     if [[ -e "${PATHTOMKDIR}" ]]; then
1107         zle -M " path already exists, doing nothing"
1108     else
1109         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
1110         zle end-of-line
1111     fi
1112 }
1113
1114 zle -N inplaceMkDirs
1115
1116 #v1# set number of lines to display per page
1117 HELP_LINES_PER_PAGE=20
1118 #v1# set location of help-zle cache file
1119 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1120 # helper function for help-zle, actually generates the help text
1121 help_zle_parse_keybindings()
1122 {
1123     emulate -L zsh
1124     setopt extendedglob
1125     unsetopt ksharrays  #indexing starts at 1
1126
1127     #v1# choose files that help-zle will parse for keybindings
1128     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1129
1130     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1131         local load_cache=0
1132         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1133         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1134     fi
1135
1136     #fill with default keybindings, possibly to be overwriten in a file later
1137     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
1138     local -A help_zle_keybindings
1139     help_zle_keybindings['<Ctrl>@']="set MARK"
1140     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
1141     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
1142     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
1143     help_zle_keybindings['<Ctrl>_']="undo"
1144     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
1145     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
1146     help_zle_keybindings['<Ctrl>e']="goto end of line"
1147     help_zle_keybindings['<Ctrl>t']="transpose charaters"
1148     help_zle_keybindings['<Alt>t']="transpose words"
1149     help_zle_keybindings['<Alt>s']="spellcheck word"
1150     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
1151     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
1152     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
1153     help_zle_keybindings["<Alt>'"]="quote line"
1154     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
1155     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
1156     help_zle_keybindings['<Alt>u']="make next word Uppercase"
1157     help_zle_keybindings['<Alt>l']="make next word lowercase"
1158     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
1159     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
1160     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
1161     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
1162     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
1163     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
1164     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
1165     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
1166     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
1167
1168     #init global variables
1169     unset help_zle_lines help_zle_sln
1170     typeset -g -a help_zle_lines
1171     typeset -g help_zle_sln=1
1172
1173     local k v
1174     local lastkeybind_desc contents     #last description starting with #k# that we found
1175     local num_lines_elapsed=0            #number of lines between last description and keybinding
1176     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
1177     for f in $HELPZLE_KEYBINDING_FILES; do
1178         [[ -r "$f" ]] || continue   #not readable ? skip it
1179         contents="$(<$f)"
1180         for cline in "${(f)contents}"; do
1181             #zsh pattern: matches lines like: #k# ..............
1182             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
1183                 lastkeybind_desc="$match[*]"
1184                 num_lines_elapsed=0
1185             #zsh pattern: matches lines that set a keybinding using bind2map, bindkey or compdef -k
1186             #             ignores lines that are commentend out
1187             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
1188             elif [[ "$cline" == [^#]#(bind2maps[[:space:]](*)-s|bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
1189                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
1190                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
1191                     #substitute keybinding string with something readable
1192                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
1193                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
1194                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
1195                     help_zle_keybindings[${k}]=$lastkeybind_desc
1196                 fi
1197                 lastkeybind_desc=""
1198             else
1199               ((num_lines_elapsed++))
1200             fi
1201         done
1202     done
1203     unset contents
1204     #calculate length of keybinding column
1205     local kstrlen=0
1206     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
1207     #convert the assoc array into preformated lines, which we are able to sort
1208     for k v in ${(kv)help_zle_keybindings[@]}; do
1209         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
1210         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
1211     done
1212     #sort lines alphabetically
1213     help_zle_lines=("${(i)help_zle_lines[@]}")
1214     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
1215     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
1216     zcompile $HELP_ZLE_CACHE_FILE
1217 }
1218 typeset -g help_zle_sln
1219 typeset -g -a help_zle_lines
1220
1221 # Provides (partially autogenerated) help on keybindings and the zsh line editor
1222 help-zle()
1223 {
1224     emulate -L zsh
1225     unsetopt ksharrays  #indexing starts at 1
1226     #help lines already generated ? no ? then do it
1227     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
1228     #already displayed all lines ? go back to the start
1229     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
1230     local sln=$help_zle_sln
1231     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
1232     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
1233     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
1234 }
1235 zle -N help-zle
1236
1237 ## complete word from currently visible Screen or Tmux buffer.
1238 if check_com -c screen || check_com -c tmux; then
1239     _complete_screen_display() {
1240         [[ "$TERM" != "screen" ]] && return 1
1241
1242         local TMPFILE=$(mktemp)
1243         local -U -a _screen_display_wordlist
1244         trap "rm -f $TMPFILE" EXIT
1245
1246         # fill array with contents from screen hardcopy
1247         if ((${+TMUX})); then
1248             #works, but crashes tmux below version 1.4
1249             #luckily tmux -V option to ask for version, was also added in 1.4
1250             tmux -V &>/dev/null || return
1251             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1252         else
1253             screen -X hardcopy $TMPFILE
1254             # screen sucks, it dumps in latin1, apparently always. so recode it
1255             # to system charset
1256             check_com recode && recode latin1 $TMPFILE
1257         fi
1258         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1259         # remove PREFIX to be completed from that array
1260         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1261         compadd -a _screen_display_wordlist
1262     }
1263     #m# k CTRL-x\,\,\,S Complete word from GNU screen buffer
1264     bindkey -r "^xS"
1265     compdef -k _complete_screen_display complete-word '^xS'
1266 fi
1267
1268 # Load a few more functions and tie them to widgets, so they can be bound:
1269
1270 function zrcautozle() {
1271     emulate -L zsh
1272     local fnc=$1
1273     zrcautoload $fnc && zle -N $fnc
1274 }
1275
1276 function zrcgotwidget() {
1277     (( ${+widgets[$1]} ))
1278 }
1279
1280 function zrcgotkeymap() {
1281     [[ -n ${(M)keymaps:#$1} ]]
1282 }
1283
1284 zrcautozle insert-files
1285 zrcautozle edit-command-line
1286 zrcautozle insert-unicode-char
1287 if zrcautoload history-search-end; then
1288     zle -N history-beginning-search-backward-end history-search-end
1289     zle -N history-beginning-search-forward-end  history-search-end
1290 fi
1291 zle -C hist-complete complete-word _generic
1292 zstyle ':completion:hist-complete:*' completer _history
1293
1294 # The actual terminal setup hooks and bindkey-calls:
1295
1296 # An array to note missing features to ease diagnosis in case of problems.
1297 typeset -ga grml_missing_features
1298
1299 function zrcbindkey() {
1300     if (( ARGC )) && zrcgotwidget ${argv[-1]}; then
1301         bindkey "$@"
1302     fi
1303 }
1304
1305 function bind2maps () {
1306     local i sequence widget
1307     local -a maps
1308
1309     while [[ "$1" != "--" ]]; do
1310         maps+=( "$1" )
1311         shift
1312     done
1313     shift
1314
1315     if [[ "$1" == "-s" ]]; then
1316         shift
1317         sequence="$1"
1318     else
1319         sequence="${key[$1]}"
1320     fi
1321     widget="$2"
1322
1323     [[ -z "$sequence" ]] && return 1
1324
1325     for i in "${maps[@]}"; do
1326         zrcbindkey -M "$i" "$sequence" "$widget"
1327     done
1328 }
1329
1330 if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
1331     function zle-smkx () {
1332         emulate -L zsh
1333         printf '%s' ${terminfo[smkx]}
1334     }
1335     function zle-rmkx () {
1336         emulate -L zsh
1337         printf '%s' ${terminfo[rmkx]}
1338     }
1339     function zle-line-init () {
1340         zle-smkx
1341     }
1342     function zle-line-finish () {
1343         zle-rmkx
1344     }
1345     zle -N zle-line-init
1346     zle -N zle-line-finish
1347 else
1348     for i in {s,r}mkx; do
1349         (( ${+terminfo[$i]} )) || grml_missing_features+=($i)
1350     done
1351     unset i
1352 fi
1353
1354 typeset -A key
1355 key=(
1356     Home     "${terminfo[khome]}"
1357     End      "${terminfo[kend]}"
1358     Insert   "${terminfo[kich1]}"
1359     Delete   "${terminfo[kdch1]}"
1360     Up       "${terminfo[kcuu1]}"
1361     Down     "${terminfo[kcud1]}"
1362     Left     "${terminfo[kcub1]}"
1363     Right    "${terminfo[kcuf1]}"
1364     PageUp   "${terminfo[kpp]}"
1365     PageDown "${terminfo[knp]}"
1366     BackTab  "${terminfo[kcbt]}"
1367 )
1368
1369 # Guidelines for adding key bindings:
1370 #
1371 #   - Do not add hardcoded escape sequences, to enable non standard key
1372 #     combinations such as Ctrl-Meta-Left-Cursor. They are not easily portable.
1373 #
1374 #   - Adding Ctrl characters, such as '^b' is okay; note that '^b' and '^B' are
1375 #     the same key.
1376 #
1377 #   - All keys from the $key[] mapping are obviously okay.
1378 #
1379 #   - Most terminals send "ESC x" when Meta-x is pressed. Thus, sequences like
1380 #     '\ex' are allowed in here as well.
1381
1382 bind2maps emacs             -- Home   beginning-of-somewhere
1383 bind2maps       viins vicmd -- Home   vi-beginning-of-line
1384 bind2maps emacs             -- End    end-of-somewhere
1385 bind2maps       viins vicmd -- End    vi-end-of-line
1386 bind2maps emacs viins       -- Insert overwrite-mode
1387 bind2maps             vicmd -- Insert vi-insert
1388 bind2maps emacs             -- Delete delete-char
1389 bind2maps       viins vicmd -- Delete vi-delete-char
1390 bind2maps emacs viins vicmd -- Up     up-line-or-search
1391 bind2maps emacs viins vicmd -- Down   down-line-or-search
1392 bind2maps emacs             -- Left   backward-char
1393 bind2maps       viins vicmd -- Left   vi-backward-char
1394 bind2maps emacs             -- Right  forward-char
1395 bind2maps       viins vicmd -- Right  vi-forward-char
1396 bind2maps       viins vicmd -- Right  vi-forward-char
1397 #k# Perform abbreviation expansion
1398 bind2maps emacs viins       -- -s '^x.' zleiab
1399 #k# Display list of abbreviations that would expand
1400 bind2maps emacs viins       -- -s '^xb' help-show-abk
1401 #k# mkdir -p <dir> from string under cursor or marked area
1402 bind2maps emacs viins       -- -s '^xM' inplaceMkDirs
1403 #k# display help for keybindings and ZLE
1404 bind2maps emacs viins       -- -s '^xz' help-zle
1405 #k# Insert files and test globbing
1406 bind2maps emacs viins       -- -s "^xf" insert-files
1407 #k# Edit the current line in \kbd{\$EDITOR}
1408 bind2maps emacs viins       -- -s '\ee' edit-command-line
1409 #k# search history backward for entry beginning with typed text
1410 bind2maps emacs viins       -- -s '^xp' history-beginning-search-backward-end
1411 #k# search history forward for entry beginning with typed text
1412 bind2maps emacs viins       -- -s '^xP' history-beginning-search-forward-end
1413 #k# search history backward for entry beginning with typed text
1414 bind2maps emacs viins       -- PageUp history-beginning-search-backward-end
1415 #k# search history forward for entry beginning with typed text
1416 bind2maps emacs viins       -- PageDown history-beginning-search-forward-end
1417 bind2maps emacs viins       -- -s "^x^h" commit-to-history
1418 #k# Kill left-side word or everything up to next slash
1419 bind2maps emacs viins       -- -s '\ev' slash-backward-kill-word
1420 #k# Kill left-side word or everything up to next slash
1421 bind2maps emacs viins       -- -s '\e^h' slash-backward-kill-word
1422 #k# Kill left-side word or everything up to next slash
1423 bind2maps emacs viins       -- -s '\e^?' slash-backward-kill-word
1424 # Do history expansion on space:
1425 bind2maps emacs viins       -- -s ' ' magic-space
1426 #k# Trigger menu-complete
1427 bind2maps emacs viins       -- -s '\ei' menu-complete  # menu completion via esc-i
1428 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1429 bind2maps emacs viins       -- -s '^ed' insert-datestamp
1430 #k# Insert last typed word
1431 bind2maps emacs viins       -- -s "\em" insert-last-typed-word
1432 #k# A smart shortcut for \kbd{fg<enter>}
1433 bind2maps emacs viins       -- -s '^z' grml-zsh-fg
1434 #k# prepend the current command with "sudo"
1435 bind2maps emacs viins       -- -s "^os" sudo-command-line
1436 #k# jump to after first word (for adding options)
1437 bind2maps emacs viins       -- -s '^x1' jump_after_first_word
1438 #k# complete word from history with menu
1439 bind2maps emacs viins       -- -s "^x^x" hist-complete
1440
1441 # insert unicode character
1442 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
1443 # See for example http://unicode.org/charts/ for unicode characters code
1444 #k# Insert Unicode character
1445 bind2maps emacs viins       -- -s '^xi' insert-unicode-char
1446
1447 # use the new *-pattern-* widgets for incremental history search
1448 if zrcgotwidget history-incremental-pattern-search-backward; then
1449     for seq wid in '^r' history-incremental-pattern-search-backward \
1450                    '^s' history-incremental-pattern-search-forward
1451     do
1452         bind2maps emacs viins vicmd -- -s $seq $wid
1453     done
1454 fi
1455
1456 if zrcgotkeymap menuselect; then
1457     #m# k Shift-tab Perform backwards menu completion
1458     bind2maps menuselect -- BackTab reverse-menu-complete
1459
1460     #k# menu selection: pick item but stay in the menu
1461     bind2maps menuselect -- -s '\e^M' accept-and-menu-complete
1462     # also use + and INSERT since it's easier to press repeatedly
1463     bind2maps menuselect -- -s '+' accept-and-menu-complete
1464     bind2maps menuselect -- Insert accept-and-menu-complete
1465
1466     # accept a completion and try to complete again by using menu
1467     # completion; very useful with completing directories
1468     # by using 'undo' one's got a simple file browser
1469     bind2maps menuselect -- -s '^o' accept-and-infer-next-history
1470 fi
1471
1472 # Finally, here are still a few hardcoded escape sequences; Special sequences
1473 # like Ctrl-<Cursor-key> etc do suck a fair bit, because they are not
1474 # standardised and most of the time are not available in a terminals terminfo
1475 # entry.
1476 #
1477 # While we do not encourage adding bindings like these, we will keep these for
1478 # backward compatibility.
1479
1480 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on
1481 ## the command line.
1482 # URxvt sequences:
1483 bind2maps emacs viins vicmd -- -s '\eOc' forward-word
1484 bind2maps emacs viins vicmd -- -s '\eOd' backward-word
1485 # These are for xterm:
1486 bind2maps emacs viins vicmd -- -s '\e[1;5C' forward-word
1487 bind2maps emacs viins vicmd -- -s '\e[1;5D' backward-word
1488 ## the same for alt-left-arrow and alt-right-arrow
1489 # URxvt again:
1490 bind2maps emacs viins vicmd -- -s '\e\e[C' forward-word
1491 bind2maps emacs viins vicmd -- -s '\e\e[D' backward-word
1492 # Xterm again:
1493 bind2maps emacs viins vicmd -- -s '^[[1;3C' forward-word
1494 bind2maps emacs viins vicmd -- -s '^[[1;3D' backward-word
1495 # Also try ESC Left/Right:
1496 bind2maps emacs viins vicmd -- -s '\e'${key[Right]} forward-word
1497 bind2maps emacs viins vicmd -- -s '\e'${key[Left]}  backward-word
1498
1499 # autoloading
1500
1501 zrcautoload zmv
1502 zrcautoload zed
1503
1504 # we don't want to quote/espace URLs on our own...
1505 # if autoload -U url-quote-magic ; then
1506 #    zle -N self-insert url-quote-magic
1507 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
1508 # else
1509 #    print 'Notice: no url-quote-magic available :('
1510 # fi
1511 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
1512
1513 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
1514 alias run-help >&/dev/null && unalias run-help
1515 for rh in run-help{,-git,-svk,-svn}; do
1516     zrcautoload $rh
1517 done; unset rh
1518
1519 # command not found handling
1520
1521 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1522 function command_not_found_handler() {
1523     emulate -L zsh
1524     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1525         ${GRML_ZSH_CNF_HANDLER} $1
1526     fi
1527     return 1
1528 }
1529
1530 # history
1531
1532 ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1533
1534 #v#
1535 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1536 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1537 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1538
1539 # dirstack handling
1540
1541 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1542 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1543
1544 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1545     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1546     # "cd -" won't work after login by just setting $OLDPWD, so
1547     [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1548 fi
1549
1550 chpwd() {
1551     if (( $DIRSTACKSIZE <= 0 )) || [[ -z $DIRSTACKFILE ]]; then return; fi
1552     local -ax my_stack
1553     my_stack=( ${PWD} ${dirstack} )
1554     if is42 ; then
1555         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1556     else
1557         uprint my_stack >! ${DIRSTACKFILE}
1558     fi
1559 }
1560
1561 # directory based profiles
1562
1563 if is433 ; then
1564
1565 # chpwd_profiles(): Directory Profiles, Quickstart:
1566 #
1567 # In .zshrc.local:
1568 #
1569 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1570 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1571 #   chpwd_profiles
1572 #
1573 # For details see the `grmlzshrc.5' manual page.
1574 function chpwd_profiles() {
1575     local profile context
1576     local -i reexecute
1577
1578     context=":chpwd:profiles:$PWD"
1579     zstyle -s "$context" profile profile || profile='default'
1580     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1581
1582     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1583         typeset -g CHPWD_PROFILE
1584         local CHPWD_PROFILES_INIT=1
1585         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1586     elif [[ $profile != $CHPWD_PROFILE ]]; then
1587         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1588             && chpwd_leave_profile_${CHPWD_PROFILE}
1589     fi
1590     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1591         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1592     fi
1593
1594     CHPWD_PROFILE="${profile}"
1595     return 0
1596 }
1597
1598 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1599
1600 fi # is433
1601
1602 # Prompt setup for grml:
1603
1604 # set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1605 # in prompts to get a red "foo" embedded, but it's good to keep these for
1606 # backwards compatibility).
1607 if is437; then
1608     BLUE="%F{blue}"
1609     RED="%F{red}"
1610     GREEN="%F{green}"
1611     CYAN="%F{cyan}"
1612     MAGENTA="%F{magenta}"
1613     YELLOW="%F{yellow}"
1614     WHITE="%F{white}"
1615     NO_COLOR="%f"
1616 elif zrcautoload colors && colors 2>/dev/null ; then
1617     BLUE="%{${fg[blue]}%}"
1618     RED="%{${fg_bold[red]}%}"
1619     GREEN="%{${fg[green]}%}"
1620     CYAN="%{${fg[cyan]}%}"
1621     MAGENTA="%{${fg[magenta]}%}"
1622     YELLOW="%{${fg[yellow]}%}"
1623     WHITE="%{${fg[white]}%}"
1624     NO_COLOR="%{${reset_color}%}"
1625 else
1626     BLUE=$'%{\e[1;34m%}'
1627     RED=$'%{\e[1;31m%}'
1628     GREEN=$'%{\e[1;32m%}'
1629     CYAN=$'%{\e[1;36m%}'
1630     WHITE=$'%{\e[1;37m%}'
1631     MAGENTA=$'%{\e[1;35m%}'
1632     YELLOW=$'%{\e[1;33m%}'
1633     NO_COLOR=$'%{\e[0m%}'
1634 fi
1635
1636 # First, the easy ones: PS2..4:
1637
1638 # secondary prompt, printed when the shell needs more information to complete a
1639 # command.
1640 PS2='\`%_> '
1641 # selection prompt used within a select loop.
1642 PS3='?# '
1643 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1644 PS4='+%N:%i:%_> '
1645
1646 # Some additional features to use with our prompt:
1647 #
1648 #    - battery status
1649 #    - debian_chroot
1650 #    - vcs_info setup and version specific fixes
1651
1652 # display battery status on right side of prompt using 'GRML_DISPLAY_BATTERY=1' in .zshrc.pre
1653
1654 battery() {
1655 if [[ $GRML_DISPLAY_BATTERY -gt 0 ]] ; then
1656     if islinux ; then
1657         batterylinux
1658     elif isopenbsd ; then
1659         batteryopenbsd
1660     elif isfreebsd ; then
1661         batteryfreebsd
1662     else
1663         #not yet supported
1664         GRML_DISPLAY_BATTERY=0
1665     fi
1666 fi
1667 }
1668
1669 batterylinux(){
1670 GRML_BATTERY_LEVEL=''
1671 local batteries bat capacity
1672 batteries=( /sys/class/power_supply/BAT*(N) )
1673 if (( $#batteries > 0 )) ; then
1674     for bat in $batteries ; do
1675         capacity=$(< $bat/capacity)
1676         case $(< $bat/status) in
1677         Charging)
1678             GRML_BATTERY_LEVEL+=" ^"
1679             ;;
1680         Discharging)
1681             if (( capacity < 20 )) ; then
1682                 GRML_BATTERY_LEVEL+=" !v"
1683             else
1684                 GRML_BATTERY_LEVEL+=" v"
1685             fi
1686             ;;
1687         *) # Full, Unknown
1688             GRML_BATTERY_LEVEL+=" ="
1689             ;;
1690         esac
1691         GRML_BATTERY_LEVEL+="${capacity}%%"
1692     done
1693 fi
1694 }
1695
1696 batteryopenbsd(){
1697 GRML_BATTERY_LEVEL=''
1698 local batfull batwarn batnow num
1699 for num in 0 1 ; do
1700     bat=$(sysctl -n hw.sensors.acpibat${num})
1701     if [[ ! -z $bat ]]; then
1702         batfull=${"$(sysctl -n hw.sensors.acpibat${num}.amphour0)"%% *}
1703         batwarn=${"$(sysctl -n hw.sensors.acpibat${num}.amphour1)"%% *}
1704         batnow=${"$(sysctl -n hw.sensors.acpibat${num}.amphour3)"%% *}
1705         case "$(sysctl -n hw.sensors.acpibat${num}.raw0)" in
1706             *" discharging"*)
1707                 if (( batnow < batwarn )) ; then
1708                     GRML_BATTERY_LEVEL+=" !v"
1709                 else
1710                     GRML_BATTERY_LEVEL+=" v"
1711                 fi
1712                 ;;
1713             *" charging"*)
1714                 GRML_BATTERY_LEVEL+=" ^"
1715                 ;;
1716             *)
1717                 GRML_BATTERY_LEVEL+=" ="
1718                 ;;
1719         esac
1720         GRML_BATTERY_LEVEL+="${$(( 100 * batnow / batfull ))%%.*}%%"
1721     fi
1722 done
1723 }
1724
1725 batteryfreebsd(){
1726 GRML_BATTERY_LEVEL=''
1727 local num
1728 local -A table
1729 for num in 0 1 ; do
1730     table=( ${=${${${${${(M)${(f)"$(acpiconf -i $num)"}:#(State|Remaining capacity):*}%%( ##|%)}//:[ $'\t']##/@}// /-}//@/ }} )
1731     if [[ $table[State] != "not-present" ]] ; then
1732         case $table[State] in
1733             *discharging*)
1734                 if (( $table[Remaining-capacity] < 20 )) ; then
1735                     GRML_BATTERY_LEVEL+=" !v"
1736                 else
1737                     GRML_BATTERY_LEVEL+=" v"
1738                 fi
1739                 ;;
1740             *charging*)
1741                 GRML_BATTERY_LEVEL+=" ^"
1742                 ;;
1743             *)
1744                 GRML_BATTERY_LEVEL+=" ="
1745                 ;;
1746         esac
1747         GRML_BATTERY_LEVEL+="$table[Remaining-capacity]%%"
1748     fi
1749 done
1750 }
1751
1752 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1753 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1754     debian_chroot=$(</etc/debian_chroot)
1755 fi
1756
1757 # gather version control information for inclusion in a prompt
1758
1759 if zrcautoload vcs_info; then
1760     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1761     # function, which can cause a lot of trouble with our directory-based
1762     # profiles. So:
1763     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1764         function VCS_INFO_realpath () {
1765             setopt localoptions NO_shwordsplit chaselinks
1766             ( builtin cd -q $1 2> /dev/null && pwd; )
1767         }
1768     fi
1769
1770     zstyle ':vcs_info:*' max-exports 2
1771
1772     if [[ -o restricted ]]; then
1773         zstyle ':vcs_info:*' enable NONE
1774     fi
1775 fi
1776
1777 typeset -A grml_vcs_coloured_formats
1778 typeset -A grml_vcs_plain_formats
1779
1780 grml_vcs_plain_formats=(
1781     format "(%s%)-[%b] "    "zsh: %r"
1782     actionformat "(%s%)-[%b|%a] " "zsh: %r"
1783     rev-branchformat "%b:%r"
1784 )
1785
1786 grml_vcs_coloured_formats=(
1787     format "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR} "
1788     actionformat "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} "
1789     rev-branchformat "%b${RED}:${YELLOW}%r"
1790 )
1791
1792 typeset GRML_VCS_COLOUR_MODE=xxx
1793
1794 grml_vcs_info_toggle_colour () {
1795     emulate -L zsh
1796     if [[ $GRML_VCS_COLOUR_MODE == plain ]]; then
1797         grml_vcs_info_set_formats coloured
1798     else
1799         grml_vcs_info_set_formats plain
1800     fi
1801     return 0
1802 }
1803
1804 grml_vcs_info_set_formats () {
1805     emulate -L zsh
1806     #setopt localoptions xtrace
1807     local mode=$1 AF F BF
1808     if [[ $mode == coloured ]]; then
1809         AF=${grml_vcs_coloured_formats[actionformat]}
1810         F=${grml_vcs_coloured_formats[format]}
1811         BF=${grml_vcs_coloured_formats[rev-branchformat]}
1812         GRML_VCS_COLOUR_MODE=coloured
1813     else
1814         AF=${grml_vcs_plain_formats[actionformat]}
1815         F=${grml_vcs_plain_formats[format]}
1816         BF=${grml_vcs_plain_formats[rev-branchformat]}
1817         GRML_VCS_COLOUR_MODE=plain
1818     fi
1819
1820     zstyle ':vcs_info:*'              actionformats "$AF" "zsh: %r"
1821     zstyle ':vcs_info:*'              formats       "$F"  "zsh: %r"
1822     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat  "$BF"
1823     return 0
1824 }
1825
1826 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1827 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1828 if [[ "$TERM" == dumb ]] ; then
1829     grml_vcs_info_set_formats plain
1830 else
1831     grml_vcs_info_set_formats coloured
1832 fi
1833
1834 # Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1835
1836 # This actually defines three prompts:
1837 #
1838 #    - grml
1839 #    - grml-large
1840 #    - grml-chroot
1841 #
1842 # They all share the same code and only differ with respect to which items they
1843 # contain. The main source of documentation is the `prompt_grml_help' function
1844 # below, which gets called when the user does this: prompt -h grml
1845
1846 function prompt_grml_help () {
1847     cat <<__EOF0__
1848   prompt grml
1849
1850     This is the prompt as used by the grml-live system <http://grml.org>. It is
1851     a rather simple one-line prompt, that by default looks something like this:
1852
1853         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1854
1855     The prompt itself integrates with zsh's prompt themes system (as you are
1856     witnessing right now) and is configurable to a certain degree. In
1857     particular, these aspects are customisable:
1858
1859         - The items used in the prompt (e.g. you can remove \`user' from
1860           the list of activated items, which will cause the user name to
1861           be omitted from the prompt string).
1862
1863         - The attributes used with the items are customisable via strings
1864           used before and after the actual item.
1865
1866     The available items are: at, battery, change-root, date, grml-chroot,
1867     history, host, jobs, newline, path, percent, rc, rc-always, sad-smiley,
1868     shell-level, time, user, vcs
1869
1870     The actual configuration is done via zsh's \`zstyle' mechanism. The
1871     context, that is used while looking up styles is:
1872
1873         ':prompt:grml:<left-or-right>:<subcontext>'
1874
1875     Here <left-or-right> is either \`left' or \`right', signifying whether the
1876     style should affect the left or the right prompt. <subcontext> is either
1877     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1878
1879     The styles:
1880
1881         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1882           in $RPROMPT if the last command a returned non-successful error code.
1883           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1884
1885         - items (list): The list of items used in the prompt. If \`vcs' is
1886           present in the list, the theme's code invokes \`vcs_info'
1887           accordingly. Default (left): rc change-root user at host path vcs
1888           percent; Default (right): sad-smiley
1889
1890     Available styles in 'items:<item>' are: pre, post. These are strings that
1891     are inserted before (pre) and after (post) the item in question. Thus, the
1892     following would cause the user name to be printed in red instead of the
1893     default blue:
1894
1895         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
1896
1897     Note, that the \`post' style may remain at its default value, because its
1898     default value is '%f', which turns the foreground text attribute off (which
1899     is exactly, what is still required with the new \`pre' value).
1900 __EOF0__
1901 }
1902
1903 function prompt_grml-chroot_help () {
1904     cat <<__EOF0__
1905   prompt grml-chroot
1906
1907     This is a variation of the grml prompt, see: prompt -h grml
1908
1909     The main difference is the default value of the \`items' style. The rest
1910     behaves exactly the same. Here are the defaults for \`grml-chroot':
1911
1912         - left: grml-chroot user at host path percent
1913         - right: (empty list)
1914 __EOF0__
1915 }
1916
1917 function prompt_grml-large_help () {
1918     cat <<__EOF0__
1919   prompt grml-large
1920
1921     This is a variation of the grml prompt, see: prompt -h grml
1922
1923     The main difference is the default value of the \`items' style. In
1924     particular, this theme uses _two_ lines instead of one with the plain
1925     \`grml' theme. The rest behaves exactly the same. Here are the defaults
1926     for \`grml-large':
1927
1928         - left: rc jobs history shell-level change-root time date newline user
1929                 at host path vcs percent
1930         - right: sad-smiley
1931 __EOF0__
1932 }
1933
1934 function grml_prompt_setup () {
1935     emulate -L zsh
1936     autoload -Uz vcs_info
1937     autoload -Uz add-zsh-hook
1938     add-zsh-hook precmd prompt_$1_precmd
1939 }
1940
1941 function prompt_grml_setup () {
1942     grml_prompt_setup grml
1943 }
1944
1945 function prompt_grml-chroot_setup () {
1946     grml_prompt_setup grml-chroot
1947 }
1948
1949 function prompt_grml-large_setup () {
1950     grml_prompt_setup grml-large
1951 }
1952
1953 # These maps define default tokens and pre-/post-decoration for items to be
1954 # used within the themes. All defaults may be customised in a context sensitive
1955 # matter by using zsh's `zstyle' mechanism.
1956 typeset -gA grml_prompt_pre_default \
1957             grml_prompt_post_default \
1958             grml_prompt_token_default \
1959             grml_prompt_token_function
1960
1961 grml_prompt_pre_default=(
1962     at                ''
1963     battery           ' '
1964     change-root       ''
1965     date              '%F{blue}'
1966     grml-chroot       '%F{red}'
1967     history           '%F{green}'
1968     host              ''
1969     jobs              '%F{cyan}'
1970     newline           ''
1971     path              '%B'
1972     percent           ''
1973     rc                '%B%F{red}'
1974     rc-always         ''
1975     sad-smiley        ''
1976     shell-level       '%F{red}'
1977     time              '%F{blue}'
1978     user              '%B%F{blue}'
1979     vcs               ''
1980 )
1981
1982 grml_prompt_post_default=(
1983     at                ''
1984     battery           ''
1985     change-root       ''
1986     date              '%f'
1987     grml-chroot       '%f '
1988     history           '%f'
1989     host              ''
1990     jobs              '%f'
1991     newline           ''
1992     path              '%b'
1993     percent           ''
1994     rc                '%f%b'
1995     rc-always         ''
1996     sad-smiley        ''
1997     shell-level       '%f'
1998     time              '%f'
1999     user              '%f%b'
2000     vcs               ''
2001 )
2002
2003 grml_prompt_token_default=(
2004     at                '@'
2005     battery           'GRML_BATTERY_LEVEL'
2006     change-root       'debian_chroot'
2007     date              '%D{%Y-%m-%d}'
2008     grml-chroot       'GRML_CHROOT'
2009     history           '{history#%!} '
2010     host              '%m '
2011     jobs              '[%j running job(s)] '
2012     newline           $'\n'
2013     path              '%40<..<%~%<< '
2014     percent           '%# '
2015     rc                '%(?..%? )'
2016     rc-always         '%?'
2017     sad-smiley        '%(?..:()'
2018     shell-level       '%(3L.+ .)'
2019     time              '%D{%H:%M:%S} '
2020     user              '%n'
2021     vcs               '0'
2022 )
2023
2024 function grml_theme_has_token () {
2025     if (( ARGC != 1 )); then
2026         printf 'usage: grml_theme_has_token <name>\n'
2027         return 1
2028     fi
2029     (( ${+grml_prompt_token_default[$1]} ))
2030 }
2031
2032 function GRML_theme_add_token_usage () {
2033     cat <<__EOF__
2034   Usage: grml_theme_add_token <name> [-f|-i] <token/function> [<pre> <post>]
2035
2036     <name> is the name for the newly added token. If the \`-f' or \`-i' options
2037     are used, <token/function> is the name of the function (see below for
2038     details). Otherwise it is the literal token string to be used. <pre> and
2039     <post> are optional.
2040
2041   Options:
2042
2043     -f <function>   Use a function named \`<function>' each time the token
2044                     is to be expanded.
2045
2046     -i <function>   Use a function named \`<function>' to initialise the
2047                     value of the token _once_ at runtime.
2048
2049     The functions are called with one argument: the token's new name. The
2050     return value is expected in the \$REPLY parameter. The use of these
2051     options is mutually exclusive.
2052
2053     There is a utility function \`grml_theme_has_token', which you can use
2054     to test if a token exists before trying to add it. This can be a guard
2055     for situations in which a \`grml_theme_add_token' call may happen more
2056     than once.
2057
2058   Example:
2059
2060     To add a new token \`day' that expands to the current weekday in the
2061     current locale in green foreground colour, use this:
2062
2063       grml_theme_add_token day '%D{%A}' '%F{green}' '%f'
2064
2065     Another example would be support for \$VIRTUAL_ENV:
2066
2067       function virtual_env_prompt () {
2068         REPLY=\${VIRTUAL_ENV+\${VIRTUAL_ENV:t} }
2069       }
2070       grml_theme_add_token virtual-env -f virtual_env_prompt
2071
2072     After that, you will be able to use a changed \`items' style to
2073     assemble your prompt.
2074 __EOF__
2075 }
2076
2077 function grml_theme_add_token () {
2078     emulate -L zsh
2079     local name token pre post
2080     local -i init funcall
2081
2082     if (( ARGC == 0 )); then
2083         GRML_theme_add_token_usage
2084         return 0
2085     fi
2086
2087     init=0
2088     funcall=0
2089     pre=''
2090     post=''
2091     name=$1
2092     shift
2093     if [[ $1 == '-f' ]]; then
2094         funcall=1
2095         shift
2096     elif [[ $1 == '-i' ]]; then
2097         init=1
2098         shift
2099     fi
2100
2101     if (( ARGC == 0 )); then
2102         printf '
2103 grml_theme_add_token: No token-string/function-name provided!\n\n'
2104         GRML_theme_add_token_usage
2105         return 1
2106     fi
2107     token=$1
2108     shift
2109     if (( ARGC != 0 && ARGC != 2 )); then
2110         printf '
2111 grml_theme_add_token: <pre> and <post> need to by specified _both_!\n\n'
2112         GRML_theme_add_token_usage
2113         return 1
2114     fi
2115     if (( ARGC )); then
2116         pre=$1
2117         post=$2
2118         shift 2
2119     fi
2120
2121     if grml_theme_has_token $name; then
2122         printf '
2123 grml_theme_add_token: Token `%s'\'' exists! Giving up!\n\n' $name
2124         GRML_theme_add_token_usage
2125         return 2
2126     fi
2127     if (( init )); then
2128         $token $name
2129         token=$REPLY
2130     fi
2131     grml_prompt_pre_default[$name]=$pre
2132     grml_prompt_post_default[$name]=$post
2133     if (( funcall )); then
2134         grml_prompt_token_function[$name]=$token
2135         grml_prompt_token_default[$name]=23
2136     else
2137         grml_prompt_token_default[$name]=$token
2138     fi
2139 }
2140
2141 function grml_typeset_and_wrap () {
2142     emulate -L zsh
2143     local target="$1"
2144     local new="$2"
2145     local left="$3"
2146     local right="$4"
2147
2148     if (( ${+parameters[$new]} )); then
2149         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
2150     fi
2151 }
2152
2153 function grml_prompt_addto () {
2154     emulate -L zsh
2155     local target="$1"
2156     local lr it apre apost new v
2157     local -a items
2158     shift
2159
2160     [[ $target == PS1 ]] && lr=left || lr=right
2161     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
2162     typeset -g "${target}="
2163     for it in "${items[@]}"; do
2164         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
2165             || apre=${grml_prompt_pre_default[$it]}
2166         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" post apost \
2167             || apost=${grml_prompt_post_default[$it]}
2168         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
2169             || new=${grml_prompt_token_default[$it]}
2170         typeset -g "${target}=${(P)target}${apre}"
2171         if (( ${+grml_prompt_token_function[$it]} )); then
2172             ${grml_prompt_token_function[$it]} $it
2173             typeset -g "${target}=${(P)target}${REPLY}"
2174         else
2175             case $it in
2176             battery)
2177                 grml_typeset_and_wrap $target $new '' ''
2178                 ;;
2179             change-root)
2180                 grml_typeset_and_wrap $target $new '(' ')'
2181                 ;;
2182             grml-chroot)
2183                 if [[ -n ${(P)new} ]]; then
2184                     typeset -g "${target}=${(P)target}(CHROOT)"
2185                 fi
2186                 ;;
2187             vcs)
2188                 v="vcs_info_msg_${new}_"
2189                 if (( ! vcscalled )); then
2190                     vcs_info
2191                     vcscalled=1
2192                 fi
2193                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
2194                     typeset -g "${target}=${(P)target}${(P)v}"
2195                 fi
2196                 ;;
2197             *) typeset -g "${target}=${(P)target}${new}" ;;
2198             esac
2199         fi
2200         typeset -g "${target}=${(P)target}${apost}"
2201     done
2202 }
2203
2204 function prompt_grml_precmd () {
2205     emulate -L zsh
2206     local grmltheme=grml
2207     local -a left_items right_items
2208     left_items=(rc change-root user at host path vcs percent)
2209     right_items=(sad-smiley)
2210
2211     prompt_grml_precmd_worker
2212 }
2213
2214 function prompt_grml-chroot_precmd () {
2215     emulate -L zsh
2216     local grmltheme=grml-chroot
2217     local -a left_items right_items
2218     left_items=(grml-chroot user at host path percent)
2219     right_items=()
2220
2221     prompt_grml_precmd_worker
2222 }
2223
2224 function prompt_grml-large_precmd () {
2225     emulate -L zsh
2226     local grmltheme=grml-large
2227     local -a left_items right_items
2228     left_items=(rc jobs history shell-level change-root time date newline
2229                 user at host path vcs percent)
2230     right_items=(sad-smiley)
2231
2232     prompt_grml_precmd_worker
2233 }
2234
2235 function prompt_grml_precmd_worker () {
2236     emulate -L zsh
2237     local -i vcscalled=0
2238
2239     grml_prompt_addto PS1 "${left_items[@]}"
2240     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
2241         grml_prompt_addto RPS1 "${right_items[@]}"
2242     fi
2243 }
2244
2245 grml_prompt_fallback() {
2246     setopt prompt_subst
2247     precmd() {
2248         (( ${+functions[vcs_info]} )) && vcs_info
2249     }
2250
2251     p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
2252     p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
2253     if (( EUID == 0 )); then
2254         PROMPT="${BLUE}${p0}${RED}${p1}"
2255     else
2256         PROMPT="${RED}${p0}${BLUE}${p1}"
2257     fi
2258     unset p0 p1
2259 }
2260
2261 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2262     # Since we define the required functions in here and not in files in
2263     # $fpath, we need to stick the theme's name into `$prompt_themes'
2264     # ourselves, since promptinit does not pick them up otherwise.
2265     prompt_themes+=( grml grml-chroot grml-large )
2266     # Also, keep the array sorted...
2267     prompt_themes=( "${(@on)prompt_themes}" )
2268 else
2269     print 'Notice: no promptinit available :('
2270     grml_prompt_fallback
2271 fi
2272
2273 if is437; then
2274     # The prompt themes use modern features of zsh, that require at least
2275     # version 4.3.7 of the shell. Use the fallback otherwise.
2276     if [[ $GRML_DISPLAY_BATTERY -gt 0 ]]; then
2277         zstyle ':prompt:grml:right:setup' items sad-smiley battery
2278         add-zsh-hook precmd battery
2279     fi
2280     if [[ "$TERM" == dumb ]] ; then
2281         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
2282         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
2283         for i in rc user path jobs history date time shell-level; do
2284             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
2285             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
2286         done
2287         unset i
2288         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
2289     elif (( EUID == 0 )); then
2290         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%B%F{red}'
2291     fi
2292
2293     # Finally enable one of the prompts.
2294     if [[ -n $GRML_CHROOT ]]; then
2295         prompt grml-chroot
2296     elif [[ $GRMLPROMPT -gt 0 ]]; then
2297         prompt grml-large
2298     else
2299         prompt grml
2300     fi
2301 else
2302     grml_prompt_fallback
2303 fi
2304
2305 # Terminal-title wizardry
2306
2307 function ESC_print () {
2308     info_print $'\ek' $'\e\\' "$@"
2309 }
2310 function set_title () {
2311     info_print  $'\e]0;' $'\a' "$@"
2312 }
2313
2314 function info_print () {
2315     local esc_begin esc_end
2316     esc_begin="$1"
2317     esc_end="$2"
2318     shift 2
2319     printf '%s' ${esc_begin}
2320     printf '%s' "$*"
2321     printf '%s' "${esc_end}"
2322 }
2323
2324 function grml_reset_screen_title () {
2325     # adjust title of xterm
2326     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2327     [[ ${NOTITLE:-} -gt 0 ]] && return 0
2328     case $TERM in
2329         (xterm*|rxvt*)
2330             set_title ${(%):-"%n@%m: %~"}
2331             ;;
2332     esac
2333 }
2334
2335 function grml_vcs_to_screen_title () {
2336     if [[ $TERM == screen* ]] ; then
2337         if [[ -n ${vcs_info_msg_1_} ]] ; then
2338             ESC_print ${vcs_info_msg_1_}
2339         else
2340             ESC_print "zsh"
2341         fi
2342     fi
2343 }
2344
2345 function grml_maintain_name () {
2346     # set hostname if not running on host with name 'grml'
2347     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2348        NAME="@$HOSTNAME"
2349     fi
2350 }
2351
2352 function grml_cmd_to_screen_title () {
2353     # get the name of the program currently running and hostname of local
2354     # machine set screen window title if running in a screen
2355     if [[ "$TERM" == screen* ]] ; then
2356         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME"
2357         ESC_print ${CMD}
2358     fi
2359 }
2360
2361 function grml_control_xterm_title () {
2362     case $TERM in
2363         (xterm*|rxvt*)
2364             set_title "${(%):-"%n@%m:"}" "$1"
2365             ;;
2366     esac
2367 }
2368
2369 zrcautoload add-zsh-hook || add-zsh-hook () { :; }
2370 if [[ $NOPRECMD -eq 0 ]]; then
2371     add-zsh-hook precmd grml_reset_screen_title
2372     add-zsh-hook precmd grml_vcs_to_screen_title
2373     add-zsh-hook preexec grml_maintain_name
2374     add-zsh-hook preexec grml_cmd_to_screen_title
2375     if [[ $NOTITLE -eq 0 ]]; then
2376         add-zsh-hook preexec grml_control_xterm_title
2377     fi
2378 fi
2379
2380 # 'hash' some often used directories
2381 #d# start
2382 hash -d deb=/var/cache/apt/archives
2383 hash -d doc=/usr/share/doc
2384 hash -d linux=/lib/modules/$(command uname -r)/build/
2385 hash -d log=/var/log
2386 hash -d slog=/var/log/syslog
2387 hash -d src=/usr/src
2388 hash -d templ=/usr/share/doc/grml-templates
2389 hash -d tt=/usr/share/doc/texttools-doc
2390 hash -d www=/var/www
2391 #d# end
2392
2393 # some aliases
2394 if check_com -c screen ; then
2395     if [[ $UID -eq 0 ]] ; then
2396         if [[ -r /etc/grml/screenrc ]]; then
2397             alias screen="${commands[screen]} -c /etc/grml/screenrc"
2398         fi
2399     elif [[ -r $HOME/.screenrc ]] ; then
2400         alias screen="${commands[screen]} -c $HOME/.screenrc"
2401     else
2402         if [[ -r /etc/grml/screenrc_grml ]]; then
2403             alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2404         else
2405             if [[ -r /etc/grml/screenrc ]]; then
2406                 alias screen="${commands[screen]} -c /etc/grml/screenrc"
2407             fi
2408         fi
2409     fi
2410 fi
2411
2412 # do we have GNU ls with color-support?
2413 if [[ "$TERM" != dumb ]]; then
2414     #a1# List files with colors (\kbd{ls -F \ldots})
2415     alias ls='ls -F '${ls_options:+"${ls_options[*]}"}
2416     #a1# List all files, with colors (\kbd{ls -la \ldots})
2417     alias la='ls -la '${ls_options:+"${ls_options[*]}"}
2418     #a1# List files with long colored list, without dotfiles (\kbd{ls -l \ldots})
2419     alias ll='ls -l '${ls_options:+"${ls_options[*]}"}
2420     #a1# List files with long colored list, human readable sizes (\kbd{ls -hAl \ldots})
2421     alias lh='ls -hAl '${ls_options:+"${ls_options[*]}"}
2422     #a1# List files with long colored list, append qualifier to filenames (\kbd{ls -lF \ldots})\\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2423     alias l='ls -lF '${ls_options:+"${ls_options[*]}"}
2424 else
2425     alias ls='ls -F'
2426     alias la='ls -la'
2427     alias ll='ls -l'
2428     alias lh='ls -hAl'
2429     alias l='ls -lF'
2430 fi
2431
2432 alias mdstat='cat /proc/mdstat'
2433 alias ...='cd ../../'
2434
2435 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2436 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2437     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2438 fi
2439
2440 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2441 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2442 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2443
2444 # make sure it is not assigned yet
2445 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2446 utf2iso() {
2447     if isutfenv ; then
2448         for ENV in $(env | command grep -i '.utf') ; do
2449             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2450         done
2451     fi
2452 }
2453
2454 # make sure it is not assigned yet
2455 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2456 iso2utf() {
2457     if ! isutfenv ; then
2458         for ENV in $(env | command grep -i '\.iso') ; do
2459             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2460         done
2461     fi
2462 }
2463
2464 # especially for roadwarriors using GNU screen and ssh:
2465 if ! check_com asc &>/dev/null ; then
2466   asc() { autossh -t "$@" 'screen -RdU' }
2467   compdef asc=ssh
2468 fi
2469
2470 #f1# Hints for the use of zsh on grml
2471 zsh-help() {
2472     print "$bg[white]$fg[black]
2473 zsh-help - hints for use of zsh on grml
2474 =======================================$reset_color"
2475
2476     print '
2477 Main configuration of zsh happens in /etc/zsh/zshrc.
2478 That file is part of the package grml-etc-core, if you want to
2479 use them on a non-grml-system just get the tar.gz from
2480 http://deb.grml.org/ or (preferably) get it from the git repository:
2481
2482   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2483
2484 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2485 The file is still there, but it is empty for backwards compatibility.
2486
2487 For your own changes use these two files:
2488     $HOME/.zshrc.pre
2489     $HOME/.zshrc.local
2490
2491 The former is sourced very early in our zshrc, the latter is sourced
2492 very lately.
2493
2494 System wide configuration without touching configuration files of grml
2495 can take place in /etc/zsh/zshrc.local.
2496
2497 For information regarding zsh start at http://grml.org/zsh/
2498
2499 Take a look at grml'\''s zsh refcard:
2500 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2501
2502 Check out the main zsh refcard:
2503 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2504
2505 And of course visit the zsh-lovers:
2506 % man zsh-lovers
2507
2508 You can adjust some options through environment variables when
2509 invoking zsh without having to edit configuration files.
2510 Basically meant for bash users who are not used to the power of
2511 the zsh yet. :)
2512
2513   "NOCOR=1    zsh" => deactivate automatic correction
2514   "NOMENU=1   zsh" => do not use auto menu completion
2515                       (note: use ctrl-d for completion instead!)
2516   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2517   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2518                       preexec() and precmd() completely
2519   "GRML_DISPLAY_BATTERY=1  zsh"
2520                    => activate battery status on right side of prompt (WIP)
2521   "COMMAND_NOT_FOUND=1 zsh"
2522                    => Enable a handler if an external command was not found
2523                       The command called in the handler can be altered by setting
2524                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2525                       "/usr/share/command-not-found/command-not-found"
2526
2527 A value greater than 0 is enables a feature; a value equal to zero
2528 disables it. If you like one or the other of these settings, you can
2529 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2530 zshrc.'
2531
2532     print "
2533 $bg[white]$fg[black]
2534 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2535 Enjoy your grml system with the zsh!$reset_color"
2536 }
2537
2538 # debian stuff
2539 if [[ -r /etc/debian_version ]] ; then
2540     #a3# Execute \kbd{apt-cache search}
2541     alias acs='apt-cache search'
2542     #a3# Execute \kbd{apt-cache show}
2543     alias acsh='apt-cache show'
2544     #a3# Execute \kbd{apt-cache policy}
2545     alias acp='apt-cache policy'
2546     #a3# Execute \kbd{apt-get dist-upgrade}
2547     salias adg="apt-get dist-upgrade"
2548     #a3# Execute \kbd{apt-get install}
2549     salias agi="apt-get install"
2550     #a3# Execute \kbd{aptitude install}
2551     salias ati="aptitude install"
2552     #a3# Execute \kbd{apt-get upgrade}
2553     salias ag="apt-get upgrade"
2554     #a3# Execute \kbd{apt-get update}
2555     salias au="apt-get update"
2556     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2557     salias -a up="aptitude update ; aptitude safe-upgrade"
2558     #a3# Execute \kbd{dpkg-buildpackage}
2559     alias dbp='dpkg-buildpackage'
2560     #a3# Execute \kbd{grep-excuses}
2561     alias ge='grep-excuses'
2562
2563     # get a root shell as normal user in live-cd mode:
2564     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2565        alias su="sudo su"
2566      fi
2567
2568     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2569     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2570     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2571     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2572 fi
2573
2574 # sort installed Debian-packages by size
2575 if check_com -c dpkg-query ; then
2576     #a3# List installed Debian-packages sorted by size
2577     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
2578 fi
2579
2580 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2581 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2582     if check_com -c wodim; then
2583         cdrecord() {
2584             cat <<EOMESS
2585 cdrecord is not provided under its original name by Debian anymore.
2586 See #377109 in the BTS of Debian for more details.
2587
2588 Please use the wodim binary instead
2589 EOMESS
2590             return 1
2591         }
2592     fi
2593 fi
2594
2595 # Use hard limits, except for a smaller stack and no core dumps
2596 unlimit
2597 is425 && limit stack 8192
2598 isgrmlcd && limit core 0 # important for a live-cd-system
2599 limit -s
2600
2601 # grmlstuff
2602 grmlstuff() {
2603 # people should use 'grml-x'!
2604     if check_com -c 915resolution; then
2605         855resolution() {
2606             echo "Please use 915resolution as resolution modifying tool for Intel \
2607 graphic chipset."
2608             return -1
2609         }
2610     fi
2611
2612     #a1# Output version of running grml
2613     alias grml-version='cat /etc/grml_version'
2614
2615     if check_com -c grml-debootstrap ; then
2616         debian2hd() {
2617             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2618             return 1
2619         }
2620     fi
2621 }
2622
2623 # now run the functions
2624 isgrml && checkhome
2625 is4    && isgrml    && grmlstuff
2626 is4    && grmlcomp
2627
2628 # keephack
2629 is4 && xsource "/etc/zsh/keephack"
2630
2631 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2632 # You use it as follows:
2633 # $ NTREF=/reference/file
2634 # $ ls -l *(e:nt:)
2635 # This lists all the files in the current directory newer than the reference file.
2636 # You can also specify the reference file inline; note quotes:
2637 # $ ls -l *(e:'nt ~/.zshenv':)
2638 is4 && nt() {
2639     if [[ -n $1 ]] ; then
2640         local NTREF=${~1}
2641     fi
2642     [[ $REPLY -nt $NTREF ]]
2643 }
2644
2645 # shell functions
2646
2647 #f1# Reload an autoloadable function
2648 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2649 compdef _functions freload
2650
2651 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2652 sll() {
2653     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2654     local file
2655     for file in "$@" ; do
2656         while [[ -h "$file" ]] ; do
2657             ls -l $file
2658             file=$(readlink "$file")
2659         done
2660     done
2661 }
2662
2663 # TODO: Is it supported to use pager settings like this?
2664 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2665 # with respect to wordsplitting. (ie. ${=PAGER})
2666 if check_com -c $PAGER ; then
2667     #f3# View Debian's changelog of given package(s)
2668     dchange() {
2669         emulate -L zsh
2670         [[ -z "$1" ]] && printf 'Usage: %s <package_name(s)>\n' "$0" && return 1
2671
2672         local package
2673         for package in "$@" ; do
2674             if [[ -r /usr/share/doc/${package}/changelog.Debian.gz ]] ; then
2675                 $PAGER /usr/share/doc/${package}/changelog.Debian.gz
2676             elif [[ -r /usr/share/doc/${package}/changelog.gz ]] ; then
2677                 $PAGER /usr/share/doc/${package}/changelog.gz
2678             elif [[ -r /usr/share/doc/${package}/changelog ]] ; then
2679                 $PAGER /usr/share/doc/${package}/changelog
2680             else
2681                 if check_com -c aptitude ; then
2682                     echo "No changelog for package $package found, using aptitude to retrieve it."
2683                     aptitude changelog "$package"
2684                 elif check_com -c apt-get ; then
2685                     echo "No changelog for package $package found, using apt-get to retrieve it."
2686                     apt-get changelog "$package"
2687                 else
2688                     echo "No changelog for package $package found, sorry."
2689                 fi
2690             fi
2691         done
2692     }
2693     _dchange() { _files -W /usr/share/doc -/ }
2694     compdef _dchange dchange
2695
2696     #f3# View Debian's NEWS of a given package
2697     dnews() {
2698         emulate -L zsh
2699         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2700             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2701         else
2702             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2703                 $PAGER /usr/share/doc/$1/NEWS.gz
2704             else
2705                 echo "No NEWS file for package $1 found, sorry."
2706                 return 1
2707             fi
2708         fi
2709     }
2710     _dnews() { _files -W /usr/share/doc -/ }
2711     compdef _dnews dnews
2712
2713     #f3# View Debian's copyright of a given package
2714     dcopyright() {
2715         emulate -L zsh
2716         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2717             $PAGER /usr/share/doc/$1/copyright
2718         else
2719             echo "No copyright file for package $1 found, sorry."
2720             return 1
2721         fi
2722     }
2723     _dcopyright() { _files -W /usr/share/doc -/ }
2724     compdef _dcopyright dcopyright
2725
2726     #f3# View upstream's changelog of a given package
2727     uchange() {
2728         emulate -L zsh
2729         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2730             $PAGER /usr/share/doc/$1/changelog.gz
2731         else
2732             echo "No changelog for package $1 found, sorry."
2733             return 1
2734         fi
2735     }
2736     _uchange() { _files -W /usr/share/doc -/ }
2737     compdef _uchange uchange
2738 fi
2739
2740 # zsh profiling
2741 profile() {
2742     ZSH_PROFILE_RC=1 $SHELL "$@"
2743 }
2744
2745 #f1# Edit an alias via zle
2746 edalias() {
2747     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2748 }
2749 compdef _aliases edalias
2750
2751 #f1# Edit a function via zle
2752 edfunc() {
2753     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2754 }
2755 compdef _functions edfunc
2756
2757 # use it e.g. via 'Restart apache2'
2758 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2759 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2760 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2761 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2762 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2763 #m# f6 Status() \kbd{/etc/init.d/\em{process}}\quad\kbd{status}
2764 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2765     __start_stop() {
2766         local action_="${1:l}"  # e.g Start/Stop/Restart
2767         local service_="$2"
2768         local param_="$3"
2769
2770         local service_target_="$(readlink /etc/init.d/$service_)"
2771         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2772             # runit
2773             case "${action_}" in
2774                 start) if [[ ! -e /etc/service/$service_ ]]; then
2775                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2776                        else
2777                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2778                        fi ;;
2779                 # there is no reload in runits sysv emulation
2780                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2781                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2782             esac
2783         else
2784             # sysvinit
2785             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2786         fi
2787     }
2788
2789     _grmlinitd() {
2790         local -a scripts
2791         scripts=( /etc/init.d/*(x:t) )
2792         _describe "service startup script" scripts
2793     }
2794
2795     for i in Start Restart Stop Force-Reload Reload Status ; do
2796         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2797         compdef _grmlinitd $i
2798     done
2799 fi
2800
2801 #f1# Provides useful information on globbing
2802 H-Glob() {
2803     echo -e "
2804     /      directories
2805     .      plain files
2806     @      symbolic links
2807     =      sockets
2808     p      named pipes (FIFOs)
2809     *      executable plain files (0100)
2810     %      device files (character or block special)
2811     %b     block special files
2812     %c     character special files
2813     r      owner-readable files (0400)
2814     w      owner-writable files (0200)
2815     x      owner-executable files (0100)
2816     A      group-readable files (0040)
2817     I      group-writable files (0020)
2818     E      group-executable files (0010)
2819     R      world-readable files (0004)
2820     W      world-writable files (0002)
2821     X      world-executable files (0001)
2822     s      setuid files (04000)
2823     S      setgid files (02000)
2824     t      files with the sticky bit (01000)
2825
2826   print *(m-1)          # Files modified up to a day ago
2827   print *(a1)           # Files accessed a day ago
2828   print *(@)            # Just symlinks
2829   print *(Lk+50)        # Files bigger than 50 kilobytes
2830   print *(Lk-50)        # Files smaller than 50 kilobytes
2831   print **/*.c          # All *.c files recursively starting in \$PWD
2832   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2833   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2834   print *~*.*           # All Files that do not contain a dot
2835   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2836   print -l *(.c|.h)     # Lists *.c and *.h
2837   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2838   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2839 }
2840 alias help-zshglob=H-Glob
2841
2842 # grep for running process, like: 'any vim'
2843 any() {
2844     emulate -L zsh
2845     unsetopt KSH_ARRAYS
2846     if [[ -z "$1" ]] ; then
2847         echo "any - grep for process(es) by keyword" >&2
2848         echo "Usage: any <keyword>" >&2 ; return 1
2849     else
2850         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2851     fi
2852 }
2853
2854
2855 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2856 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2857 [[ -r /proc/1/maps ]] && \
2858 deswap() {
2859     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2860     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2861     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2862 }
2863
2864 # a wrapper for vim, that deals with title setting
2865 #   VIM_OPTIONS
2866 #       set this array to a set of options to vim you always want
2867 #       to have set when calling vim (in .zshrc.local), like:
2868 #           VIM_OPTIONS=( -p )
2869 #       This will cause vim to send every file given on the
2870 #       commandline to be send to it's own tab (needs vim7).
2871 if check_com vim; then
2872     vim() {
2873         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2874     }
2875 fi
2876
2877 ssl_hashes=( sha512 sha256 sha1 md5 )
2878
2879 for sh in ${ssl_hashes}; do
2880     eval 'ssl-cert-'${sh}'() {
2881         emulate -L zsh
2882         if [[ -z $1 ]] ; then
2883             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2884             return 1
2885         fi
2886         openssl x509 -noout -fingerprint -'${sh}' -in $1
2887     }'
2888 done; unset sh
2889
2890 ssl-cert-fingerprints() {
2891     emulate -L zsh
2892     local i
2893     if [[ -z $1 ]] ; then
2894         printf 'usage: ssl-cert-fingerprints <file>\n'
2895         return 1
2896     fi
2897     for i in ${ssl_hashes}
2898         do ssl-cert-$i $1;
2899     done
2900 }
2901
2902 ssl-cert-info() {
2903     emulate -L zsh
2904     if [[ -z $1 ]] ; then
2905         printf 'usage: ssl-cert-info <file>\n'
2906         return 1
2907     fi
2908     openssl x509 -noout -text -in $1
2909     ssl-cert-fingerprints $1
2910 }
2911
2912 # make sure our environment is clean regarding colors
2913 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2914
2915 # "persistent history"
2916 # just write important commands you always need to ~/.important_commands
2917 if [[ -r ~/.important_commands ]] ; then
2918     fc -R ~/.important_commands
2919 fi
2920
2921 # load the lookup subsystem if it's available on the system
2922 zrcautoload lookupinit && lookupinit
2923
2924 # variables
2925
2926 # set terminal property (used e.g. by msgid-chooser)
2927 export COLORTERM="yes"
2928
2929 # aliases
2930
2931 # general
2932 #a2# Execute \kbd{du -sch}
2933 alias da='du -sch'
2934 #a2# Execute \kbd{jobs -l}
2935 alias j='jobs -l'
2936
2937 # listing stuff
2938 #a2# Execute \kbd{ls -lSrah}
2939 alias dir="ls -lSrah"
2940 #a2# Only show dot-directories
2941 alias lad='ls -d .*(/)'
2942 #a2# Only show dot-files
2943 alias lsa='ls -a .*(.)'
2944 #a2# Only files with setgid/setuid/sticky flag
2945 alias lss='ls -l *(s,S,t)'
2946 #a2# Only show symlinks
2947 alias lsl='ls -l *(@)'
2948 #a2# Display only executables
2949 alias lsx='ls -l *(*)'
2950 #a2# Display world-{readable,writable,executable} files
2951 alias lsw='ls -ld *(R,W,X.^ND/)'
2952 #a2# Display the ten biggest files
2953 alias lsbig="ls -flh *(.OL[1,10])"
2954 #a2# Only show directories
2955 alias lsd='ls -d *(/)'
2956 #a2# Only show empty directories
2957 alias lse='ls -d *(/^F)'
2958 #a2# Display the ten newest files
2959 alias lsnew="ls -rtlh *(D.om[1,10])"
2960 #a2# Display the ten oldest files
2961 alias lsold="ls -rtlh *(D.Om[1,10])"
2962 #a2# Display the ten smallest files
2963 alias lssmall="ls -Srl *(.oL[1,10])"
2964 #a2# Display the ten newest directories and ten newest .directories
2965 alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2966 #a2# Display the ten oldest directories and ten oldest .directories
2967 alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2968
2969 # some useful aliases
2970 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir \$OLDCWD}
2971 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2972
2973 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2974 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2975 #a2# scp with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2976 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2977
2978 # work around non utf8 capable software in utf environment via $LANG and luit
2979 if check_com isutfenv && check_com luit ; then
2980     if check_com -c mrxvt ; then
2981         isutfenv && [[ -n "$LANG" ]] && \
2982             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2983     fi
2984
2985     if check_com -c aterm ; then
2986         isutfenv && [[ -n "$LANG" ]] && \
2987             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2988     fi
2989
2990     if check_com -c centericq ; then
2991         isutfenv && [[ -n "$LANG" ]] && \
2992             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2993     fi
2994 fi
2995
2996 # useful functions
2997
2998 #f5# Backup \kbd{file {\rm to} file\_timestamp}
2999 bk() {
3000     emulate -L zsh
3001     cp -b $1 $1_`date --iso-8601=m`
3002 }
3003
3004 #f5# cd to directoy and list files
3005 cl() {
3006     emulate -L zsh
3007     cd $1 && ls -a
3008 }
3009
3010 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
3011 cd() {
3012     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
3013         [[ ! -e ${1:h} ]] && return 1
3014         print "Correcting ${1} to ${1:h}"
3015         builtin cd ${1:h}
3016     else
3017         builtin cd "$@"
3018     fi
3019 }
3020
3021 #f5# Create Directoy and \kbd{cd} to it
3022 mkcd() {
3023     if (( ARGC != 1 )); then
3024         printf 'usage: mkcd <new-directory>\n'
3025         return 1;
3026     fi
3027     if [[ ! -d "$1" ]]; then
3028         command mkdir -p "$1"
3029     else
3030         printf '`%s'\'' already exists: cd-ing.\n' "$1"
3031     fi
3032     builtin cd "$1"
3033 }
3034
3035 #f5# Create temporary directory and \kbd{cd} to it
3036 cdt() {
3037     local t
3038     t=$(mktemp -d)
3039     echo "$t"
3040     builtin cd "$t"
3041 }
3042
3043 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
3044 accessed() {
3045     emulate -L zsh
3046     print -l -- *(a-${1:-1})
3047 }
3048
3049 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
3050 changed() {
3051     emulate -L zsh
3052     print -l -- *(c-${1:-1})
3053 }
3054
3055 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
3056 modified() {
3057     emulate -L zsh
3058     print -l -- *(m-${1:-1})
3059 }
3060 # modified() was named new() in earlier versions, add an alias for backwards compatibility
3061 check_com new || alias new=modified
3062
3063 # use colors when GNU grep with color-support
3064 if (( $#grep_options > 0 )); then
3065     o=${grep_options:+"${grep_options[*]}"}
3066     #a2# Execute \kbd{grep -{}-color=auto}
3067     alias grep='grep '$o
3068     alias egrep='egrep '$o
3069     unset o
3070 fi
3071
3072 # Translate DE<=>EN
3073 # 'translate' looks up fot a word in a file with language-to-language
3074 # translations (field separator should be " : "). A typical wordlist looks
3075 # like at follows:
3076 #  | english-word : german-transmission
3077 # It's also only possible to translate english to german but not reciprocal.
3078 # Use the following oneliner to turn back the sort order:
3079 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3080 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3081 #f5# Translates a word
3082 trans() {
3083     emulate -L zsh
3084     case "$1" in
3085         -[dD]*)
3086             translate -l de-en $2
3087             ;;
3088         -[eE]*)
3089             translate -l en-de $2
3090             ;;
3091         *)
3092             echo "Usage: $0 { -D | -E }"
3093             echo "         -D == German to English"
3094             echo "         -E == English to German"
3095     esac
3096 }
3097
3098 # Usage: simple-extract <file>
3099 # Using option -d deletes the original archive file.
3100 #f5# Smart archive extractor
3101 simple-extract() {
3102     emulate -L zsh
3103     setopt extended_glob noclobber
3104     local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
3105     local RC=0
3106     zparseopts -D -E "d=DELETE_ORIGINAL"
3107     for ARCHIVE in "${@}"; do
3108         case $ARCHIVE in
3109             *(tar.bz2|tbz2|tbz))
3110                 DECOMP_CMD="tar -xvjf -"
3111                 USES_STDIN=true
3112                 USES_STDOUT=false
3113                 ;;
3114             *(tar.gz|tgz))
3115                 DECOMP_CMD="tar -xvzf -"
3116                 USES_STDIN=true
3117                 USES_STDOUT=false
3118                 ;;
3119             *(tar.xz|txz|tar.lzma))
3120                 DECOMP_CMD="tar -xvJf -"
3121                 USES_STDIN=true
3122                 USES_STDOUT=false
3123                 ;;
3124             *tar)
3125                 DECOMP_CMD="tar -xvf -"
3126                 USES_STDIN=true
3127                 USES_STDOUT=false
3128                 ;;
3129             *rar)
3130                 DECOMP_CMD="unrar x"
3131                 USES_STDIN=false
3132                 USES_STDOUT=false
3133                 ;;
3134             *lzh)
3135                 DECOMP_CMD="lha x"
3136                 USES_STDIN=false
3137                 USES_STDOUT=false
3138                 ;;
3139             *7z)
3140                 DECOMP_CMD="7z x"
3141                 USES_STDIN=false
3142                 USES_STDOUT=false
3143                 ;;
3144             *(zip|jar))
3145                 DECOMP_CMD="unzip"
3146                 USES_STDIN=false
3147                 USES_STDOUT=false
3148                 ;;
3149             *deb)
3150                 DECOMP_CMD="ar -x"
3151                 USES_STDIN=false
3152                 USES_STDOUT=false
3153                 ;;
3154             *bz2)
3155                 DECOMP_CMD="bzip2 -d -c -"
3156                 USES_STDIN=true
3157                 USES_STDOUT=true
3158                 ;;
3159             *(gz|Z))
3160                 DECOMP_CMD="gzip -d -c -"
3161                 USES_STDIN=true
3162                 USES_STDOUT=true
3163                 ;;
3164             *(xz|lzma))
3165                 DECOMP_CMD="xz -d -c -"
3166                 USES_STDIN=true
3167                 USES_STDOUT=true
3168                 ;;
3169             *)
3170                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
3171                 RC=$((RC+1))
3172                 continue
3173                 ;;
3174         esac
3175
3176         if ! check_com ${DECOMP_CMD[(w)1]}; then
3177             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
3178             RC=$((RC+2))
3179             continue
3180         fi
3181
3182         GZTARGET="${ARCHIVE:t:r}"
3183         if [[ -f $ARCHIVE ]] ; then
3184
3185             print "Extracting '$ARCHIVE' ..."
3186             if $USES_STDIN; then
3187                 if $USES_STDOUT; then
3188                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3189                 else
3190                     ${=DECOMP_CMD} < "$ARCHIVE"
3191                 fi
3192             else
3193                 if $USES_STDOUT; then
3194                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3195                 else
3196                     ${=DECOMP_CMD} "$ARCHIVE"
3197                 fi
3198             fi
3199             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3200
3201         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3202             if check_com curl; then
3203                 WGET_CMD="curl -L -k -s -o -"
3204             elif check_com wget; then
3205                 WGET_CMD="wget -q -O - --no-check-certificate"
3206             else
3207                 print "ERROR: neither wget nor curl is installed" >&2
3208                 RC=$((RC+4))
3209                 continue
3210             fi
3211             print "Downloading and Extracting '$ARCHIVE' ..."
3212             if $USES_STDIN; then
3213                 if $USES_STDOUT; then
3214                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3215                     RC=$((RC+$?))
3216                 else
3217                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3218                     RC=$((RC+$?))
3219                 fi
3220             else
3221                 if $USES_STDOUT; then
3222                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3223                 else
3224                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3225                 fi
3226             fi
3227
3228         else
3229             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3230             RC=$((RC+8))
3231         fi
3232     done
3233     return $RC
3234 }
3235
3236 __archive_or_uri()
3237 {
3238     _alternative \
3239         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3240         '_urls:Remote Archives:_urls'
3241 }
3242
3243 _simple_extract()
3244 {
3245     _arguments \
3246         '-d[delete original archivefile after extraction]' \
3247         '*:Archive Or Uri:__archive_or_uri'
3248 }
3249 compdef _simple_extract simple-extract
3250 alias se=simple-extract
3251
3252 #f5# Set all ulimit parameters to \kbd{unlimited}
3253 allulimit() {
3254     ulimit -c unlimited
3255     ulimit -d unlimited
3256     ulimit -f unlimited
3257     ulimit -l unlimited
3258     ulimit -n unlimited
3259     ulimit -s unlimited
3260     ulimit -t unlimited
3261 }
3262
3263 #f5# Change the xterm title from within GNU-screen
3264 xtrename() {
3265     emulate -L zsh
3266     if [[ $1 != "-f" ]] ; then
3267         if [[ -z ${DISPLAY} ]] ; then
3268             printf 'xtrename only makes sense in X11.\n'
3269             return 1
3270         fi
3271     else
3272         shift
3273     fi
3274     if [[ -z $1 ]] ; then
3275         printf 'usage: xtrename [-f] "title for xterm"\n'
3276         printf '  renames the title of xterm from _within_ screen.\n'
3277         printf '  also works without screen.\n'
3278         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3279         return 0
3280     fi
3281     print -n "\eP\e]0;${1}\C-G\e\\"
3282     return 0
3283 }
3284
3285 # Create small urls via http://goo.gl using curl(1).
3286 # API reference: https://code.google.com/apis/urlshortener/
3287 function zurl() {
3288     emulate -L zsh
3289     setopt extended_glob
3290
3291     if [[ -z $1 ]]; then
3292         print "USAGE: zurl <URL>"
3293         return 1
3294     fi
3295
3296     local PN url prog api json contenttype item
3297     local -a data
3298     PN=$0
3299     url=$1
3300
3301     # Prepend 'http://' to given URL where necessary for later output.
3302     if [[ ${url} != http(s|)://* ]]; then
3303         url='http://'${url}
3304     fi
3305
3306     if check_com -c curl; then
3307         prog=curl
3308     else
3309         print "curl is not available, but mandatory for ${PN}. Aborting."
3310         return 1
3311     fi
3312     api='https://www.googleapis.com/urlshortener/v1/url'
3313     contenttype="Content-Type: application/json"
3314     json="{\"longUrl\": \"${url}\"}"
3315     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
3316     # Parse the response
3317     for item in "${data[@]}"; do
3318         case "$item" in
3319             ' '#'"id":'*)
3320                 item=${item#*: \"}
3321                 item=${item%\",*}
3322                 printf '%s\n' "$item"
3323                 return 0
3324                 ;;
3325         esac
3326     done
3327     return 1
3328 }
3329
3330 #f2# Find history events by search pattern and list them by date.
3331 whatwhen()  {
3332     emulate -L zsh
3333     local usage help ident format_l format_s first_char remain first last
3334     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3335     help='Use `whatwhen -h'\'' for further explanations.'
3336     ident=${(l,${#${:-Usage: }},, ,)}
3337     format_l="${ident}%s\t\t\t%s\n"
3338     format_s="${format_l//(\\t)##/\\t}"
3339     # Make the first char of the word to search for case
3340     # insensitive; e.g. [aA]
3341     first_char=[${(L)1[1]}${(U)1[1]}]
3342     remain=${1[2,-1]}
3343     # Default search range is `-100'.
3344     first=${2:-\-100}
3345     # Optional, just used for `<first> <last>' given.
3346     last=$3
3347     case $1 in
3348         ("")
3349             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3350             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3351         ;;
3352         (-h)
3353             printf '%s\n\n' ${usage}
3354             print 'OPTIONS:'
3355             printf $format_l '-h' 'show help text'
3356             print '\f'
3357             print 'SEARCH RANGE:'
3358             printf $format_l "'0'" 'the whole history,'
3359             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3360             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3361             printf '\n%s\n' 'EXAMPLES:'
3362             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3363             printf $format_l 'whatwhen zsh -250'
3364             printf $format_l 'whatwhen foo 1 99'
3365         ;;
3366         (\?)
3367             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3368         ;;
3369         (*)
3370             # -l list results on stout rather than invoking $EDITOR.
3371             # -i Print dates as in YYYY-MM-DD.
3372             # -m Search for a - quoted - pattern within the history.
3373             fc -li -m "*${first_char}${remain}*" $first $last
3374         ;;
3375     esac
3376 }
3377
3378 # mercurial related stuff
3379 if check_com -c hg ; then
3380     # gnu like diff for mercurial
3381     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3382     #f5# GNU like diff for mercurial
3383     hgdi() {
3384         emulate -L zsh
3385         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3386     }
3387
3388     # build debian package
3389     #a2# Alias for \kbd{hg-buildpackage}
3390     alias hbp='hg-buildpackage'
3391
3392     # execute commands on the versioned patch-queue from the current repos
3393     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3394
3395     # diffstat for specific version of a mercurial repository
3396     #   hgstat      => display diffstat between last revision and tip
3397     #   hgstat 1234 => display diffstat between revision 1234 and tip
3398     #f5# Diffstat for specific version of a mercurial repos
3399     hgstat() {
3400         emulate -L zsh
3401         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3402     }
3403
3404 fi # end of check whether we have the 'hg'-executable
3405
3406 # grml-small cleanups
3407
3408 # The following is used to remove zsh-config-items that do not work
3409 # in grml-small by default.
3410 # If you do not want these adjustments (for whatever reason), set
3411 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3412 # sources if it is there).
3413
3414 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3415
3416     unset abk[V]
3417     unalias    'V'      &> /dev/null
3418     unfunction vman     &> /dev/null
3419     unfunction viless   &> /dev/null
3420     unfunction 2html    &> /dev/null
3421
3422     # manpages are not in grmlsmall
3423     unfunction manzsh   &> /dev/null
3424     unfunction man2     &> /dev/null
3425
3426 fi
3427
3428 zrclocal
3429
3430 ## genrefcard.pl settings
3431
3432 ### doc strings for external functions from files
3433 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3434
3435 ### example: split functions-search 8,16,24,32
3436 #@# split functions-search 8
3437
3438 ## END OF FILE #################################################################
3439 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3440 # Local variables:
3441 # mode: sh
3442 # End: