etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # USAGE
  15 # If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
  16 # and ~/.zshrc.local for your own customisations. The former file is read
  17 # before ~/.zshrc, the latter is read after it. Also, consider reading the
  18 # refcard and the reference manual for this setup, both available from:
  19 #     <http://grml.org/zsh/>
  20
  21 # Contributing:
  22 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  23 # repository from git.grml.org:
  24 #   git clone git://git.grml.org/grml-etc-core.git
  25 #
  26 # Make your changes, commit them; use 'git format-patch' to create a series
  27 # of patches and send those to the following address via 'git send-email':
  28 #   grml-etc-core@grml.org
  29 #
  30 # Doing so makes sure the right people get your patches for review and
  31 # possibly inclusion.
  32
  33 # zsh-refcard-tag documentation:
  34 #   You may notice strange looking comments in this file.
  35 #   These are there for a purpose. grml's zsh-refcard can now be
  36 #   automatically generated from the contents of the actual configuration
  37 #   file. However, we need a little extra information on which comments
  38 #   and what lines of code to take into account (and for what purpose).
  39 #
  40 # Here is what they mean:
  41 #
  42 # List of tags (comment types) used:
  43 #   #a#     Next line contains an important alias, that should
  44 #           be included in the grml-zsh-refcard.
  45 #           (placement tag: @@INSERT-aliases@@)
  46 #   #f#     Next line contains the beginning of an important function.
  47 #           (placement tag: @@INSERT-functions@@)
  48 #   #v#     Next line contains an important variable.
  49 #           (placement tag: @@INSERT-variables@@)
  50 #   #k#     Next line contains an important keybinding.
  51 #           (placement tag: @@INSERT-keybindings@@)
  52 #   #d#     Hashed directories list generation:
  53 #               start   denotes the start of a list of 'hash -d'
  54 #                       definitions.
  55 #               end     denotes its end.
  56 #           (placement tag: @@INSERT-hasheddirs@@)
  57 #   #A#     Abbreviation expansion list generation:
  58 #               start   denotes the beginning of abbreviations.
  59 #               end     denotes their end.
  60 #           Lines within this section that end in '#d .*' provide
  61 #           extra documentation to be included in the refcard.
  62 #           (placement tag: @@INSERT-abbrev@@)
  63 #   #m#     This tag allows you to manually generate refcard entries
  64 #           for code lines that are hard/impossible to parse.
  65 #               Example:
  66 #                   #m# k ESC-h Call the run-help function
  67 #               That would add a refcard entry in the keybindings table
  68 #               for 'ESC-h' with the given comment.
  69 #           So the syntax is: #m# <section> <argument> <comment>
  70 #   #o#     This tag lets you insert entries to the 'other' hash.
  71 #           Generally, this should not be used. It is there for
  72 #           things that cannot be done easily in another way.
  73 #           (placement tag: @@INSERT-other-foobar@@)
  74 #
  75 #   All of these tags (except for m and o) take two arguments, the first
  76 #   within the tag, the other after the tag:
  77 #
  78 #   #<tag><section># <comment>
  79 #
  80 #   Where <section> is really just a number, which are defined by the
  81 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  82 #   instead of names is, that for the reader, the tag should not differ
  83 #   much from a regular comment. For zsh, it is a regular comment indeed.
  84 #   The numbers have got the following meanings:
  85 #         0 -> "default"
  86 #         1 -> "system"
  87 #         2 -> "user"
  88 #         3 -> "debian"
  89 #         4 -> "search"
  90 #         5 -> "shortcuts"
  91 #         6 -> "services"
  92 #
  93 #   So, the following will add an entry to the 'functions' table in the
  94 #   'system' section, with a (hopefully) descriptive comment:
  95 #       #f1# Edit an alias via zle
  96 #       edalias() {
  97 #
  98 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  99 #   that can be found in 'grml-zsh-refcard.tex.in'.
 100 #   If the section number is omitted, the 'default' section is assumed.
 101 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
 102 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
 103 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
 104
 105 # zsh profiling
 106 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 107 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 108     zmodload zsh/zprof
 109 fi
 110
 111 # load .zshrc.pre to give the user the chance to overwrite the defaults
 112 [[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
 113
 114 # check for version/system
 115 # check for versions (compatibility reasons)
 116 is4(){
 117     [[ $ZSH_VERSION == <4->* ]] && return 0
 118     return 1
 119 }
 120
 121 is41(){
 122     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is42(){
 127     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is425(){
 132     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is43(){
 137     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 is433(){
 142     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
 143                                  || $ZSH_VERSION == <5->* ]] && return 0
 144     return 1
 145 }
 146
 147 is437(){
 148     [[ $ZSH_VERSION == 4.3.<7->* || $ZSH_VERSION == 4.<4->* \
 149                                  || $ZSH_VERSION == <5->* ]] && return 0
 150     return 1
 151 }
 152
 153 is439(){
 154     [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
 155                                  || $ZSH_VERSION == <5->* ]] && return 0
 156     return 1
 157 }
 158
 159 #f1# Checks whether or not you're running grml
 160 isgrml(){
 161     [[ -f /etc/grml_version ]] && return 0
 162     return 1
 163 }
 164
 165 #f1# Checks whether or not you're running a grml cd
 166 isgrmlcd(){
 167     [[ -f /etc/grml_cd ]] && return 0
 168     return 1
 169 }
 170
 171 if isgrml ; then
 172 #f1# Checks whether or not you're running grml-small
 173     isgrmlsmall() {
 174         if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
 175             return 0
 176         fi
 177         return 1
 178     }
 179 else
 180     isgrmlsmall() { return 1 }
 181 fi
 182
 183 GRML_OSTYPE=$(uname -s)
 184
 185 islinux(){
 186     [[ $GRML_OSTYPE == "Linux" ]]
 187 }
 188
 189 isdarwin(){
 190     [[ $GRML_OSTYPE == "Darwin" ]]
 191 }
 192
 193 isfreebsd(){
 194     [[ $GRML_OSTYPE == "FreeBSD" ]]
 195 }
 196
 197 isopenbsd(){
 198     [[ $GRML_OSTYPE == "OpenBSD" ]]
 199 }
 200
 201 issolaris(){
 202     [[ $GRML_OSTYPE == "SunOS" ]]
 203 }
 204
 205 #f1# are we running within an utf environment?
 206 isutfenv() {
 207     case "$LANG $CHARSET $LANGUAGE" in
 208         *utf*) return 0 ;;
 209         *UTF*) return 0 ;;
 210         *)     return 1 ;;
 211     esac
 212 }
 213
 214 # check for user, if not running as root set $SUDO to sudo
 215 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 216
 217 # change directory to home on first invocation of zsh
 218 # important for rungetty -> autologin
 219 # Thanks go to Bart Schaefer!
 220 isgrml && checkhome() {
 221     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 222         export ALREADY_DID_CD_HOME=$HOME
 223         cd
 224     fi
 225 }
 226
 227 # check for zsh v3.1.7+
 228
 229 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 230      || ${ZSH_VERSION} == 3.<2->.<->*    \
 231      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 232
 233     printf '-!-\n'
 234     printf '-!- In this configuration we try to make use of features, that only\n'
 235     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 236     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 237     printf '-!- advanced features in all supported versions.\n'
 238     printf '-!-\n'
 239     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 240     printf '-!-\n'
 241     printf '-!- While this *may* work, it might as well fail.\n'
 242     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 243     printf '-!-\n'
 244     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 245     printf '-!- If it does today, you'\''ve been lucky.\n'
 246     printf '-!-\n'
 247     printf '-!- Ye been warned!\n'
 248     printf '-!-\n'
 249
 250     function zstyle() { : }
 251 fi
 252
 253 # autoload wrapper - use this one instead of autoload directly
 254 # We need to define this function as early as this, because autoloading
 255 # 'is-at-least()' needs it.
 256 function zrcautoload() {
 257     emulate -L zsh
 258     setopt extended_glob
 259     local fdir ffile
 260     local -i ffound
 261
 262     ffile=$1
 263     (( ffound = 0 ))
 264     for fdir in ${fpath} ; do
 265         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 266     done
 267
 268     (( ffound == 0 )) && return 1
 269     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 270         autoload -U ${ffile} || return 1
 271     else
 272         autoload ${ffile} || return 1
 273     fi
 274     return 0
 275 }
 276
 277 # The following is the ‘add-zsh-hook’ function from zsh upstream. It is
 278 # included here to make the setup work with older versions of zsh (prior to
 279 # 4.3.7) in which this function had a bug that triggers annoying errors during
 280 # shell startup. This is exactly upstreams code from f0068edb4888a4d8fe94def,
 281 # with just a few adjustments in coding style to make the function look more
 282 # compact. This definition can be removed as soon as we raise the minimum
 283 # version requirement to 4.3.7 or newer.
 284 function add-zsh-hook() {
 285     # Add to HOOK the given FUNCTION.
 286     # HOOK is one of chpwd, precmd, preexec, periodic, zshaddhistory,
 287     # zshexit, zsh_directory_name (the _functions subscript is not required).
 288     #
 289     # With -d, remove the function from the hook instead; delete the hook
 290     # variable if it is empty.
 291     #
 292     # -D behaves like -d, but pattern characters are active in the function
 293     # name, so any matching function will be deleted from the hook.
 294     #
 295     # Without -d, the FUNCTION is marked for autoload; -U is passed down to
 296     # autoload if that is given, as are -z and -k. (This is harmless if the
 297     # function is actually defined inline.)
 298     emulate -L zsh
 299     local -a hooktypes
 300     hooktypes=(
 301         chpwd precmd preexec periodic zshaddhistory zshexit
 302         zsh_directory_name
 303     )
 304     local usage="Usage: $0 hook function\nValid hooks are:\n  $hooktypes"
 305     local opt
 306     local -a autoopts
 307     integer del list help
 308     while getopts "dDhLUzk" opt; do
 309         case $opt in
 310         (d) del=1 ;;
 311         (D) del=2 ;;
 312         (h) help=1 ;;
 313         (L) list=1 ;;
 314         ([Uzk]) autoopts+=(-$opt) ;;
 315         (*) return 1 ;;
 316         esac
 317     done
 318     shift $(( OPTIND - 1 ))
 319     if (( list )); then
 320         typeset -mp "(${1:-${(@j:|:)hooktypes}})_functions"
 321         return $?
 322     elif (( help || $# != 2 || ${hooktypes[(I)$1]} == 0 )); then
 323         print -u$(( 2 - help )) $usage
 324         return $(( 1 - help ))
 325     fi
 326     local hook="${1}_functions"
 327     local fn="$2"
 328     if (( del )); then
 329         # delete, if hook is set
 330         if (( ${(P)+hook} )); then
 331             if (( del == 2 )); then
 332                 set -A $hook ${(P)hook:#${~fn}}
 333             else
 334                 set -A $hook ${(P)hook:#$fn}
 335             fi
 336             # unset if no remaining entries --- this can give better
 337             # performance in some cases
 338             if (( ! ${(P)#hook} )); then
 339                 unset $hook
 340             fi
 341         fi
 342     else
 343         if (( ${(P)+hook} )); then
 344             if (( ${${(P)hook}[(I)$fn]} == 0 )); then
 345                 set -A $hook ${(P)hook} $fn
 346             fi
 347         else
 348             set -A $hook $fn
 349         fi
 350         autoload $autoopts -- $fn
 351     fi
 352 }
 353
 354 # Load is-at-least() for more precise version checks Note that this test will
 355 # *always* fail, if the is-at-least function could not be marked for
 356 # autoloading.
 357 zrcautoload is-at-least || is-at-least() { return 1 }
 358
 359 # set some important options (as early as possible)
 360
 361 # append history list to the history file; this is the default but we make sure
 362 # because it's required for share_history.
 363 setopt append_history
 364
 365 # import new commands from the history file also in other zsh-session
 366 is4 && setopt share_history
 367
 368 # save each command's beginning timestamp and the duration to the history file
 369 setopt extended_history
 370
 371 # If a new command line being added to the history list duplicates an older
 372 # one, the older command is removed from the list
 373 is4 && setopt histignorealldups
 374
 375 # remove command lines from the history list when the first character on the
 376 # line is a space
 377 setopt histignorespace
 378
 379 # if a command is issued that can't be executed as a normal command, and the
 380 # command is the name of a directory, perform the cd command to that directory.
 381 setopt auto_cd
 382
 383 # in order to use #, ~ and ^ for filename generation grep word
 384 # *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
 385 # don't forget to quote '^', '~' and '#'!
 386 setopt extended_glob
 387
 388 # display PID when suspending processes as well
 389 setopt longlistjobs
 390
 391 # report the status of backgrounds jobs immediately
 392 setopt notify
 393
 394 # whenever a command completion is attempted, make sure the entire command path
 395 # is hashed first.
 396 setopt hash_list_all
 397
 398 # not just at the end
 399 setopt completeinword
 400
 401 # Don't send SIGHUP to background processes when the shell exits.
 402 setopt nohup
 403
 404 # make cd push the old directory onto the directory stack.
 405 setopt auto_pushd
 406
 407 # avoid "beep"ing
 408 setopt nobeep
 409
 410 # don't push the same dir twice.
 411 setopt pushd_ignore_dups
 412
 413 # * shouldn't match dotfiles. ever.
 414 setopt noglobdots
 415
 416 # use zsh style word splitting
 417 setopt noshwordsplit
 418
 419 # don't error out when unset parameters are used
 420 setopt unset
 421
 422 # setting some default values
 423 NOCOR=${NOCOR:-0}
 424 NOMENU=${NOMENU:-0}
 425 NOPRECMD=${NOPRECMD:-0}
 426 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 427 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 428 GRML_DISPLAY_BATTERY=${GRML_DISPLAY_BATTERY:-${BATTERY:-0}}
 429 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 430 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 431
 432 typeset -ga ls_options
 433 typeset -ga grep_options
 434 if ls --color=auto / >/dev/null 2>&1; then
 435     ls_options+=( --color=auto )
 436 elif ls -G / >/dev/null 2>&1; then
 437     ls_options+=( -G )
 438 fi
 439 if grep --color=auto -q "a" <<< "a" >/dev/null 2>&1; then
 440     grep_options+=( --color=auto )
 441 fi
 442
 443 # utility functions
 444 # this function checks if a command exists and returns either true
 445 # or false. This avoids using 'which' and 'whence', which will
 446 # avoid problems with aliases for which on certain weird systems. :-)
 447 # Usage: check_com [-c|-g] word
 448 #   -c  only checks for external commands
 449 #   -g  does the usual tests and also checks for global aliases
 450 check_com() {
 451     emulate -L zsh
 452     local -i comonly gatoo
 453
 454     if [[ $1 == '-c' ]] ; then
 455         (( comonly = 1 ))
 456         shift
 457     elif [[ $1 == '-g' ]] ; then
 458         (( gatoo = 1 ))
 459     else
 460         (( comonly = 0 ))
 461         (( gatoo = 0 ))
 462     fi
 463
 464     if (( ${#argv} != 1 )) ; then
 465         printf 'usage: check_com [-c] <command>\n' >&2
 466         return 1
 467     fi
 468
 469     if (( comonly > 0 )) ; then
 470         [[ -n ${commands[$1]}  ]] && return 0
 471         return 1
 472     fi
 473
 474     if   [[ -n ${commands[$1]}    ]] \
 475       || [[ -n ${functions[$1]}   ]] \
 476       || [[ -n ${aliases[$1]}     ]] \
 477       || [[ -n ${reswords[(r)$1]} ]] ; then
 478
 479         return 0
 480     fi
 481
 482     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 483         return 0
 484     fi
 485
 486     return 1
 487 }
 488
 489 # creates an alias and precedes the command with
 490 # sudo if $EUID is not zero.
 491 salias() {
 492     emulate -L zsh
 493     local only=0 ; local multi=0
 494     local key val
 495     while getopts ":hao" opt; do
 496         case $opt in
 497             o) only=1 ;;
 498             a) multi=1 ;;
 499             h)
 500                 printf 'usage: salias [-hoa] <alias-expression>\n'
 501                 printf '  -h      shows this help text.\n'
 502                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 503                 printf '          be careful using this option.\n'
 504                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 505                 return 0
 506                 ;;
 507             *) salias -h >&2; return 1 ;;
 508         esac
 509     done
 510     shift "$((OPTIND-1))"
 511
 512     if (( ${#argv} > 1 )) ; then
 513         printf 'Too many arguments %s\n' "${#argv}"
 514         return 1
 515     fi
 516
 517     key="${1%%\=*}" ;  val="${1#*\=}"
 518     if (( EUID == 0 )) && (( only == 0 )); then
 519         alias -- "${key}=${val}"
 520     elif (( EUID > 0 )) ; then
 521         (( multi > 0 )) && val="${val// ; / ; sudo }"
 522         alias -- "${key}=sudo ${val}"
 523     fi
 524
 525     return 0
 526 }
 527
 528 # Check if we can read given files and source those we can.
 529 xsource() {
 530     if (( ${#argv} < 1 )) ; then
 531         printf 'usage: xsource FILE(s)...\n' >&2
 532         return 1
 533     fi
 534
 535     while (( ${#argv} > 0 )) ; do
 536         [[ -r "$1" ]] && source "$1"
 537         shift
 538     done
 539     return 0
 540 }
 541
 542 # Check if we can read a given file and 'cat(1)' it.
 543 xcat() {
 544     emulate -L zsh
 545     if (( ${#argv} != 1 )) ; then
 546         printf 'usage: xcat FILE\n' >&2
 547         return 1
 548     fi
 549
 550     [[ -r $1 ]] && cat $1
 551     return 0
 552 }
 553
 554 # Remove these functions again, they are of use only in these
 555 # setup files. This should be called at the end of .zshrc.
 556 xunfunction() {
 557     emulate -L zsh
 558     local -a funcs
 559     local func
 560     funcs=(salias xcat xsource xunfunction zrcautoload zrcautozle)
 561     for func in $funcs ; do
 562         [[ -n ${functions[$func]} ]] \
 563             && unfunction $func
 564     done
 565     return 0
 566 }
 567
 568 # this allows us to stay in sync with grml's zshrc and put own
 569 # modifications in ~/.zshrc.local
 570 zrclocal() {
 571     xsource "/etc/zsh/zshrc.local"
 572     xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
 573     return 0
 574 }
 575
 576 # locale setup
 577 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 578     xsource "/etc/default/locale"
 579 fi
 580
 581 for var in LANG LC_ALL LC_MESSAGES ; do
 582     [[ -n ${(P)var} ]] && export $var
 583 done
 584 builtin unset -v var
 585
 586 # set some variables
 587 if check_com -c vim ; then
 588 #v#
 589     export EDITOR=${EDITOR:-vim}
 590 else
 591     export EDITOR=${EDITOR:-vi}
 592 fi
 593
 594 #v#
 595 export PAGER=${PAGER:-less}
 596
 597 #v#
 598 export MAIL=${MAIL:-/var/mail/$USER}
 599
 600 # color setup for ls:
 601 check_com -c dircolors && eval $(dircolors -b)
 602 # color setup for ls on OS X / FreeBSD:
 603 isdarwin && export CLICOLOR=1
 604 isfreebsd && export CLICOLOR=1
 605
 606 # do MacPorts setup on darwin
 607 if isdarwin && [[ -d /opt/local ]]; then
 608     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 609     # zshenv.
 610     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 611     MANPATH="/opt/local/share/man:$MANPATH"
 612 fi
 613 # do Fink setup on darwin
 614 isdarwin && xsource /sw/bin/init.sh
 615
 616 # load our function and completion directories
 617 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
 618     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 619     if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
 620         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 621             zrcautoload ${func:t}
 622         done
 623     fi
 624 done
 625 unset fdir func
 626
 627 # support colors in less
 628 export LESS_TERMCAP_mb=$'\E[01;31m'
 629 export LESS_TERMCAP_md=$'\E[01;31m'
 630 export LESS_TERMCAP_me=$'\E[0m'
 631 export LESS_TERMCAP_se=$'\E[0m'
 632 export LESS_TERMCAP_so=$'\E[01;44;33m'
 633 export LESS_TERMCAP_ue=$'\E[0m'
 634 export LESS_TERMCAP_us=$'\E[01;32m'
 635
 636 # mailchecks
 637 MAILCHECK=30
 638
 639 # report about cpu-/system-/user-time of command if running longer than
 640 # 5 seconds
 641 REPORTTIME=5
 642
 643 # watch for everyone but me and root
 644 watch=(notme root)
 645
 646 # automatically remove duplicates from these arrays
 647 typeset -U path cdpath fpath manpath
 648
 649 # Load a few modules
 650 is4 && \
 651 for mod in parameter complist deltochar mathfunc ; do
 652     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 653 done && builtin unset -v mod
 654
 655 # autoload zsh modules when they are referenced
 656 if is4 ; then
 657     zmodload -a  zsh/stat    zstat
 658     zmodload -a  zsh/zpty    zpty
 659     zmodload -ap zsh/mapfile mapfile
 660 fi
 661
 662 # completion system
 663 COMPDUMPFILE=${COMPDUMPFILE:-${ZDOTDIR:-${HOME}}/.zcompdump}
 664 if zrcautoload compinit ; then
 665     compinit -d ${COMPDUMPFILE} || print 'Notice: no compinit available :('
 666 else
 667     print 'Notice: no compinit available :('
 668     function compdef { }
 669 fi
 670
 671 # completion system
 672
 673 # called later (via is4 && grmlcomp)
 674 # note: use 'zstyle' for getting current settings
 675 #         press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
 676 grmlcomp() {
 677     # TODO: This could use some additional information
 678
 679     # Make sure the completion system is initialised
 680     (( ${+_comps} )) || return 1
 681
 682     # allow one error for every three characters typed in approximate completer
 683     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
 684
 685     # don't complete backup files as executables
 686     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
 687
 688     # start menu completion only if it could find no unambiguous initial string
 689     zstyle ':completion:*:correct:*'       insert-unambiguous true
 690     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
 691     zstyle ':completion:*:correct:*'       original true
 692
 693     # activate color-completion
 694     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
 695
 696     # format on completion
 697     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
 698
 699     # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
 700     # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
 701
 702     # insert all expansions for expand completer
 703     zstyle ':completion:*:expand:*'        tag-order all-expansions
 704     zstyle ':completion:*:history-words'   list false
 705
 706     # activate menu
 707     zstyle ':completion:*:history-words'   menu yes
 708
 709     # ignore duplicate entries
 710     zstyle ':completion:*:history-words'   remove-all-dups yes
 711     zstyle ':completion:*:history-words'   stop yes
 712
 713     # match uppercase from lowercase
 714     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
 715
 716     # separate matches into groups
 717     zstyle ':completion:*:matches'         group 'yes'
 718     zstyle ':completion:*'                 group-name ''
 719
 720     if [[ "$NOMENU" -eq 0 ]] ; then
 721         # if there are more than 5 options allow selecting from a menu
 722         zstyle ':completion:*'               menu select=5
 723     else
 724         # don't use any menus at all
 725         setopt no_auto_menu
 726     fi
 727
 728     zstyle ':completion:*:messages'        format '%d'
 729     zstyle ':completion:*:options'         auto-description '%d'
 730
 731     # describe options in full
 732     zstyle ':completion:*:options'         description 'yes'
 733
 734     # on processes completion complete all user processes
 735     zstyle ':completion:*:processes'       command 'ps -au$USER'
 736
 737     # offer indexes before parameters in subscripts
 738     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
 739
 740     # provide verbose completion information
 741     zstyle ':completion:*'                 verbose true
 742
 743     # recent (as of Dec 2007) zsh versions are able to provide descriptions
 744     # for commands (read: 1st word in the line) that it will list for the user
 745     # to choose from. The following disables that, because it's not exactly fast.
 746     zstyle ':completion:*:-command-:*:'    verbose false
 747
 748     # set format for warnings
 749     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
 750
 751     # define files to ignore for zcompile
 752     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
 753     zstyle ':completion:correct:'          prompt 'correct to: %e'
 754
 755     # Ignore completion functions for commands you don't have:
 756     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
 757
 758     # Provide more processes in completion of programs like killall:
 759     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
 760
 761     # complete manual by their section
 762     zstyle ':completion:*:manuals'    separate-sections true
 763     zstyle ':completion:*:manuals.*'  insert-sections   true
 764     zstyle ':completion:*:man:*'      menu yes select
 765
 766     # Search path for sudo completion
 767     zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
 768                                                /usr/local/bin  \
 769                                                /usr/sbin       \
 770                                                /usr/bin        \
 771                                                /sbin           \
 772                                                /bin            \
 773                                                /usr/X11R6/bin
 774
 775     # provide .. as a completion
 776     zstyle ':completion:*' special-dirs ..
 777
 778     # run rehash on completion so new installed program are found automatically:
 779     _force_rehash() {
 780         (( CURRENT == 1 )) && rehash
 781         return 1
 782     }
 783
 784     ## correction
 785     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
 786     if [[ "$NOCOR" -gt 0 ]] ; then
 787         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
 788         setopt nocorrect
 789     else
 790         # try to be smart about when to use what completer...
 791         setopt correct
 792         zstyle -e ':completion:*' completer '
 793             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
 794                 _last_try="$HISTNO$BUFFER$CURSOR"
 795                 reply=(_complete _match _ignored _prefix _files)
 796             else
 797                 if [[ $words[1] == (rm|mv) ]] ; then
 798                     reply=(_complete _files)
 799                 else
 800                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
 801                 fi
 802             fi'
 803     fi
 804
 805     # command for process lists, the local web server details and host completion
 806     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
 807
 808     # Some functions, like _apt and _dpkg, are very slow. We can use a cache in
 809     # order to speed things up
 810     if [[ ${GRML_COMP_CACHING:-yes} == yes ]]; then
 811         GRML_COMP_CACHE_DIR=${GRML_COMP_CACHE_DIR:-${ZDOTDIR:-$HOME}/.cache}
 812         if [[ ! -d ${GRML_COMP_CACHE_DIR} ]]; then
 813             command mkdir -p "${GRML_COMP_CACHE_DIR}"
 814         fi
 815         zstyle ':completion:*' use-cache  yes
 816         zstyle ':completion:*:complete:*' cache-path "${GRML_COMP_CACHE_DIR}"
 817     fi
 818
 819     # host completion
 820     if is42 ; then
 821         [[ -r ~/.ssh/config ]] && _ssh_config_hosts=(${${(s: :)${(ps:\t:)${${(@M)${(f)"$(<$HOME/.ssh/config)"}:#Host *}#Host }}}:#*[*?]*}) || _ssh_config_hosts=()
 822         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
 823         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
 824     else
 825         _ssh_config_hosts=()
 826         _ssh_hosts=()
 827         _etc_hosts=()
 828     fi
 829     hosts=(
 830         $(hostname)
 831         "$_ssh_config_hosts[@]"
 832         "$_ssh_hosts[@]"
 833         "$_etc_hosts[@]"
 834         localhost
 835     )
 836     zstyle ':completion:*:hosts' hosts $hosts
 837     # TODO: so, why is this here?
 838     #  zstyle '*' hosts $hosts
 839
 840     # use generic completion system for programs not yet defined; (_gnu_generic works
 841     # with commands that provide a --help option with "standard" gnu-like output.)
 842     for compcom in cp deborphan df feh fetchipac gpasswd head hnb ipacsum mv \
 843                    pal stow uname ; do
 844         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
 845     done; unset compcom
 846
 847     # see upgrade function in this file
 848     compdef _hosts upgrade
 849 }
 850
 851 # Keyboard setup: The following is based on the same code, we wrote for
 852 # debian's setup. It ensures the terminal is in the right mode, when zle is
 853 # active, so the values from $terminfo are valid. Therefore, this setup should
 854 # work on all systems, that have support for `terminfo'. It also requires the
 855 # zsh in use to have the `zsh/terminfo' module built.
 856 #
 857 # If you are customising your `zle-line-init()' or `zle-line-finish()'
 858 # functions, make sure you call the following utility functions in there:
 859 #
 860 #     - zle-line-init():      zle-smkx
 861 #     - zle-line-finish():    zle-rmkx
 862
 863 # Use emacs-like key bindings by default:
 864 bindkey -e
 865
 866 # Custom widgets:
 867
 868 ## beginning-of-line OR beginning-of-buffer OR beginning of history
 869 ## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
 870 beginning-or-end-of-somewhere() {
 871     local hno=$HISTNO
 872     if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
 873       ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
 874         zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 875     else
 876         zle .${WIDGET:s/somewhere/line-hist/} "$@"
 877         if (( HISTNO != hno )); then
 878             zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
 879         fi
 880     fi
 881 }
 882 zle -N beginning-of-somewhere beginning-or-end-of-somewhere
 883 zle -N end-of-somewhere beginning-or-end-of-somewhere
 884
 885 # add a command line to the shells history without executing it
 886 commit-to-history() {
 887     print -s ${(z)BUFFER}
 888     zle send-break
 889 }
 890 zle -N commit-to-history
 891
 892 # only slash should be considered as a word separator:
 893 slash-backward-kill-word() {
 894     local WORDCHARS="${WORDCHARS:s@/@}"
 895     # zle backward-word
 896     zle backward-kill-word
 897 }
 898 zle -N slash-backward-kill-word
 899
 900 # a generic accept-line wrapper
 901
 902 # This widget can prevent unwanted autocorrections from command-name
 903 # to _command-name, rehash automatically on enter and call any number
 904 # of builtin and user-defined widgets in different contexts.
 905 #
 906 # For a broader description, see:
 907 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 908 #
 909 # The code is imported from the file 'zsh/functions/accept-line' from
 910 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 911 # distributed under the same terms as zsh itself.
 912
 913 # A newly added command will may not be found or will cause false
 914 # correction attempts, if you got auto-correction set. By setting the
 915 # following style, we force accept-line() to rehash, if it cannot
 916 # find the first word on the command line in the $command[] hash.
 917 zstyle ':acceptline:*' rehash true
 918
 919 function Accept-Line() {
 920     setopt localoptions noksharrays
 921     local -a subs
 922     local -xi aldone
 923     local sub
 924     local alcontext=${1:-$alcontext}
 925
 926     zstyle -a ":acceptline:${alcontext}" actions subs
 927
 928     (( ${#subs} < 1 )) && return 0
 929
 930     (( aldone = 0 ))
 931     for sub in ${subs} ; do
 932         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 933         zle ${sub}
 934
 935         (( aldone > 0 )) && break
 936     done
 937 }
 938
 939 function Accept-Line-getdefault() {
 940     emulate -L zsh
 941     local default_action
 942
 943     zstyle -s ":acceptline:${alcontext}" default_action default_action
 944     case ${default_action} in
 945         ((accept-line|))
 946             printf ".accept-line"
 947             ;;
 948         (*)
 949             printf ${default_action}
 950             ;;
 951     esac
 952 }
 953
 954 function Accept-Line-HandleContext() {
 955     zle Accept-Line
 956
 957     default_action=$(Accept-Line-getdefault)
 958     zstyle -T ":acceptline:${alcontext}" call_default \
 959         && zle ${default_action}
 960 }
 961
 962 function accept-line() {
 963     setopt localoptions noksharrays
 964     local -a cmdline
 965     local -x alcontext
 966     local buf com fname format msg default_action
 967
 968     alcontext='default'
 969     buf="${BUFFER}"
 970     cmdline=(${(z)BUFFER})
 971     com="${cmdline[1]}"
 972     fname="_${com}"
 973
 974     Accept-Line 'preprocess'
 975
 976     zstyle -t ":acceptline:${alcontext}" rehash \
 977         && [[ -z ${commands[$com]} ]]           \
 978         && rehash
 979
 980     if    [[ -n ${com}               ]] \
 981        && [[ -n ${reswords[(r)$com]} ]] \
 982        || [[ -n ${aliases[$com]}     ]] \
 983        || [[ -n ${functions[$com]}   ]] \
 984        || [[ -n ${builtins[$com]}    ]] \
 985        || [[ -n ${commands[$com]}    ]] ; then
 986
 987         # there is something sensible to execute, just do it.
 988         alcontext='normal'
 989         Accept-Line-HandleContext
 990
 991         return
 992     fi
 993
 994     if    [[ -o correct              ]] \
 995        || [[ -o correctall           ]] \
 996        && [[ -n ${functions[$fname]} ]] ; then
 997
 998         # nothing there to execute but there is a function called
 999         # _command_name; a completion widget. Makes no sense to
1000         # call it on the commandline, but the correct{,all} options
1001         # will ask for it nevertheless, so warn the user.
1002         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
1003             # Okay, we warned the user before, he called us again,
1004             # so have it his way.
1005             alcontext='force'
1006             Accept-Line-HandleContext
1007
1008             return
1009         fi
1010
1011         if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
1012             alcontext='normal'
1013             Accept-Line-HandleContext
1014         else
1015             # prepare warning message for the user, configurable via zstyle.
1016             zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
1017
1018             if [[ -z ${msg} ]] ; then
1019                 msg="%c will not execute and completion %f exists."
1020             fi
1021
1022             zformat -f msg "${msg}" "c:${com}" "f:${fname}"
1023
1024             zle -M -- "${msg}"
1025         fi
1026         return
1027     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
1028         # If we are here, the commandline contains something that is not
1029         # executable, which is neither subject to _command_name correction
1030         # and is not empty. might be a variable assignment
1031         alcontext='misc'
1032         Accept-Line-HandleContext
1033
1034         return
1035     fi
1036
1037     # If we got this far, the commandline only contains whitespace, or is empty.
1038     alcontext='empty'
1039     Accept-Line-HandleContext
1040 }
1041
1042 zle -N accept-line
1043 zle -N Accept-Line
1044 zle -N Accept-Line-HandleContext
1045
1046 # power completion / abbreviation expansion / buffer expansion
1047 # see http://zshwiki.org/home/examples/zleiab for details
1048 # less risky than the global aliases but powerful as well
1049 # just type the abbreviation key and afterwards 'ctrl-x .' to expand it
1050 declare -A abk
1051 setopt extendedglob
1052 setopt interactivecomments
1053 abk=(
1054 #   key   # value                  (#d additional doc string)
1055 #A# start
1056     '...'  '../..'
1057     '....' '../../..'
1058     'BG'   '& exit'
1059     'C'    '| wc -l'
1060     'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
1061     'H'    '| head'
1062     'Hl'   ' --help |& less -r'    #d (Display help in pager)
1063     'L'    '| less'
1064     'LL'   '|& less -r'
1065     'M'    '| most'
1066     'N'    '&>/dev/null'           #d (No Output)
1067     'R'    '| tr A-z N-za-m'       #d (ROT13)
1068     'SL'   '| sort | less'
1069     'S'    '| sort -u'
1070     'T'    '| tail'
1071     'V'    '|& vim -'
1072 #A# end
1073     'co'   './configure && make && sudo make install'
1074 )
1075
1076 zleiab() {
1077     emulate -L zsh
1078     setopt extendedglob
1079     local MATCH
1080
1081     LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
1082     LBUFFER+=${abk[$MATCH]:-$MATCH}
1083 }
1084
1085 zle -N zleiab
1086
1087 help-show-abk()
1088 {
1089   zle -M "$(print "Available abbreviations for expansion:"; print -a -C 2 ${(kv)abk})"
1090 }
1091
1092 zle -N help-show-abk
1093
1094 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1095 insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1096 zle -N insert-datestamp
1097
1098 # press esc-m for inserting last typed word again (thanks to caphuso!)
1099 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1100 zle -N insert-last-typed-word;
1101
1102 function grml-zsh-fg() {
1103   if (( ${#jobstates} )); then
1104     zle .push-input
1105     [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1106     BUFFER="${BUFFER}fg"
1107     zle .accept-line
1108   else
1109     zle -M 'No background jobs. Doing nothing.'
1110   fi
1111 }
1112 zle -N grml-zsh-fg
1113
1114 # run command line as user root via sudo:
1115 sudo-command-line() {
1116     [[ -z $BUFFER ]] && zle up-history
1117     if [[ $BUFFER != sudo\ * ]]; then
1118         BUFFER="sudo $BUFFER"
1119         CURSOR=$(( CURSOR+5 ))
1120     fi
1121 }
1122 zle -N sudo-command-line
1123
1124 ### jump behind the first word on the cmdline.
1125 ### useful to add options.
1126 function jump_after_first_word() {
1127     local words
1128     words=(${(z)BUFFER})
1129
1130     if (( ${#words} <= 1 )) ; then
1131         CURSOR=${#BUFFER}
1132     else
1133         CURSOR=${#${words[1]}}
1134     fi
1135 }
1136 zle -N jump_after_first_word
1137
1138 #f5# Create directory under cursor or the selected area
1139 inplaceMkDirs() {
1140     # Press ctrl-xM to create the directory under the cursor or the selected area.
1141     # To select an area press ctrl-@ or ctrl-space and use the cursor.
1142     # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
1143     # directory does not exist yet -> press ctrl-XM and problem solved
1144     local PATHTOMKDIR
1145     if ((REGION_ACTIVE==1)); then
1146         local F=$MARK T=$CURSOR
1147         if [[ $F -gt $T ]]; then
1148             F=${CURSOR}
1149             T=${MARK}
1150         fi
1151         # get marked area from buffer and eliminate whitespace
1152         PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
1153         PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
1154     else
1155         local bufwords iword
1156         bufwords=(${(z)LBUFFER})
1157         iword=${#bufwords}
1158         bufwords=(${(z)BUFFER})
1159         PATHTOMKDIR="${(Q)bufwords[iword]}"
1160     fi
1161     [[ -z "${PATHTOMKDIR}" ]] && return 1
1162     PATHTOMKDIR=${~PATHTOMKDIR}
1163     if [[ -e "${PATHTOMKDIR}" ]]; then
1164         zle -M " path already exists, doing nothing"
1165     else
1166         zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
1167         zle end-of-line
1168     fi
1169 }
1170
1171 zle -N inplaceMkDirs
1172
1173 #v1# set number of lines to display per page
1174 HELP_LINES_PER_PAGE=20
1175 #v1# set location of help-zle cache file
1176 HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1177 # helper function for help-zle, actually generates the help text
1178 help_zle_parse_keybindings()
1179 {
1180     emulate -L zsh
1181     setopt extendedglob
1182     unsetopt ksharrays  #indexing starts at 1
1183
1184     #v1# choose files that help-zle will parse for keybindings
1185     ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1186
1187     if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1188         local load_cache=0
1189         local f
1190         for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1191         [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1192     fi
1193
1194     #fill with default keybindings, possibly to be overwriten in a file later
1195     #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
1196     local -A help_zle_keybindings
1197     help_zle_keybindings['<Ctrl>@']="set MARK"
1198     help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
1199     help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
1200     help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
1201     help_zle_keybindings['<Ctrl>_']="undo"
1202     help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
1203     help_zle_keybindings['<Ctrl>a']="goto beginning of line"
1204     help_zle_keybindings['<Ctrl>e']="goto end of line"
1205     help_zle_keybindings['<Ctrl>t']="transpose charaters"
1206     help_zle_keybindings['<Alt>t']="transpose words"
1207     help_zle_keybindings['<Alt>s']="spellcheck word"
1208     help_zle_keybindings['<Ctrl>k']="backward kill buffer"
1209     help_zle_keybindings['<Ctrl>u']="forward kill buffer"
1210     help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
1211     help_zle_keybindings["<Alt>'"]="quote line"
1212     help_zle_keybindings['<Alt>"']="quote from mark to cursor"
1213     help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
1214     help_zle_keybindings['<Alt>u']="make next word Uppercase"
1215     help_zle_keybindings['<Alt>l']="make next word lowercase"
1216     help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
1217     help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
1218     help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
1219     help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
1220     help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
1221     help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
1222     help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
1223     help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
1224     help_zle_keybindings['<Alt>h']="show help/manpage for current command"
1225
1226     #init global variables
1227     unset help_zle_lines help_zle_sln
1228     typeset -g -a help_zle_lines
1229     typeset -g help_zle_sln=1
1230
1231     local k v f cline
1232     local lastkeybind_desc contents     #last description starting with #k# that we found
1233     local num_lines_elapsed=0            #number of lines between last description and keybinding
1234     #search config files in the order they a called (and thus the order in which they overwrite keybindings)
1235     for f in $HELPZLE_KEYBINDING_FILES; do
1236         [[ -r "$f" ]] || continue   #not readable ? skip it
1237         contents="$(<$f)"
1238         for cline in "${(f)contents}"; do
1239             #zsh pattern: matches lines like: #k# ..............
1240             if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
1241                 lastkeybind_desc="$match[*]"
1242                 num_lines_elapsed=0
1243             #zsh pattern: matches lines that set a keybinding using bind2map, bindkey or compdef -k
1244             #             ignores lines that are commentend out
1245             #             grabs first in '' or "" enclosed string with length between 1 and 6 characters
1246             elif [[ "$cline" == [^#]#(bind2maps[[:space:]](*)-s|bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*)  ]]; then
1247                 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
1248                 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
1249                     #substitute keybinding string with something readable
1250                     k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
1251                     #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
1252                     #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
1253                     help_zle_keybindings[${k}]=$lastkeybind_desc
1254                 fi
1255                 lastkeybind_desc=""
1256             else
1257               ((num_lines_elapsed++))
1258             fi
1259         done
1260     done
1261     unset contents
1262     #calculate length of keybinding column
1263     local kstrlen=0
1264     for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
1265     #convert the assoc array into preformated lines, which we are able to sort
1266     for k v in ${(kv)help_zle_keybindings[@]}; do
1267         #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
1268         help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
1269     done
1270     #sort lines alphabetically
1271     help_zle_lines=("${(i)help_zle_lines[@]}")
1272     [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
1273     echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
1274     zcompile $HELP_ZLE_CACHE_FILE
1275 }
1276 typeset -g help_zle_sln
1277 typeset -g -a help_zle_lines
1278
1279 # Provides (partially autogenerated) help on keybindings and the zsh line editor
1280 help-zle()
1281 {
1282     emulate -L zsh
1283     unsetopt ksharrays  #indexing starts at 1
1284     #help lines already generated ? no ? then do it
1285     [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
1286     #already displayed all lines ? go back to the start
1287     [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
1288     local sln=$help_zle_sln
1289     #note that help_zle_sln is a global var, meaning we remember the last page we viewed
1290     help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
1291     zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
1292 }
1293 zle -N help-zle
1294
1295 ## complete word from currently visible Screen or Tmux buffer.
1296 if check_com -c screen || check_com -c tmux; then
1297     _complete_screen_display() {
1298         [[ "$TERM" != "screen" ]] && return 1
1299
1300         local TMPFILE=$(mktemp)
1301         local -U -a _screen_display_wordlist
1302         trap "rm -f $TMPFILE" EXIT
1303
1304         # fill array with contents from screen hardcopy
1305         if ((${+TMUX})); then
1306             #works, but crashes tmux below version 1.4
1307             #luckily tmux -V option to ask for version, was also added in 1.4
1308             tmux -V &>/dev/null || return
1309             tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1310         else
1311             screen -X hardcopy $TMPFILE
1312             # screen sucks, it dumps in latin1, apparently always. so recode it
1313             # to system charset
1314             check_com recode && recode latin1 $TMPFILE
1315         fi
1316         _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1317         # remove PREFIX to be completed from that array
1318         _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1319         compadd -a _screen_display_wordlist
1320     }
1321     #m# k CTRL-x\,\,\,S Complete word from GNU screen buffer
1322     bindkey -r "^xS"
1323     compdef -k _complete_screen_display complete-word '^xS'
1324 fi
1325
1326 # Load a few more functions and tie them to widgets, so they can be bound:
1327
1328 function zrcautozle() {
1329     emulate -L zsh
1330     local fnc=$1
1331     zrcautoload $fnc && zle -N $fnc
1332 }
1333
1334 function zrcgotwidget() {
1335     (( ${+widgets[$1]} ))
1336 }
1337
1338 function zrcgotkeymap() {
1339     [[ -n ${(M)keymaps:#$1} ]]
1340 }
1341
1342 zrcautozle insert-files
1343 zrcautozle edit-command-line
1344 zrcautozle insert-unicode-char
1345 if zrcautoload history-search-end; then
1346     zle -N history-beginning-search-backward-end history-search-end
1347     zle -N history-beginning-search-forward-end  history-search-end
1348 fi
1349 zle -C hist-complete complete-word _generic
1350 zstyle ':completion:hist-complete:*' completer _history
1351
1352 # The actual terminal setup hooks and bindkey-calls:
1353
1354 # An array to note missing features to ease diagnosis in case of problems.
1355 typeset -ga grml_missing_features
1356
1357 function zrcbindkey() {
1358     if (( ARGC )) && zrcgotwidget ${argv[-1]}; then
1359         bindkey "$@"
1360     fi
1361 }
1362
1363 function bind2maps () {
1364     local i sequence widget
1365     local -a maps
1366
1367     while [[ "$1" != "--" ]]; do
1368         maps+=( "$1" )
1369         shift
1370     done
1371     shift
1372
1373     if [[ "$1" == "-s" ]]; then
1374         shift
1375         sequence="$1"
1376     else
1377         sequence="${key[$1]}"
1378     fi
1379     widget="$2"
1380
1381     [[ -z "$sequence" ]] && return 1
1382
1383     for i in "${maps[@]}"; do
1384         zrcbindkey -M "$i" "$sequence" "$widget"
1385     done
1386 }
1387
1388 if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
1389     function zle-smkx () {
1390         emulate -L zsh
1391         printf '%s' ${terminfo[smkx]}
1392     }
1393     function zle-rmkx () {
1394         emulate -L zsh
1395         printf '%s' ${terminfo[rmkx]}
1396     }
1397     function zle-line-init () {
1398         zle-smkx
1399     }
1400     function zle-line-finish () {
1401         zle-rmkx
1402     }
1403     zle -N zle-line-init
1404     zle -N zle-line-finish
1405 else
1406     for i in {s,r}mkx; do
1407         (( ${+terminfo[$i]} )) || grml_missing_features+=($i)
1408     done
1409     unset i
1410 fi
1411
1412 typeset -A key
1413 key=(
1414     Home     "${terminfo[khome]}"
1415     End      "${terminfo[kend]}"
1416     Insert   "${terminfo[kich1]}"
1417     Delete   "${terminfo[kdch1]}"
1418     Up       "${terminfo[kcuu1]}"
1419     Down     "${terminfo[kcud1]}"
1420     Left     "${terminfo[kcub1]}"
1421     Right    "${terminfo[kcuf1]}"
1422     PageUp   "${terminfo[kpp]}"
1423     PageDown "${terminfo[knp]}"
1424     BackTab  "${terminfo[kcbt]}"
1425 )
1426
1427 # Guidelines for adding key bindings:
1428 #
1429 #   - Do not add hardcoded escape sequences, to enable non standard key
1430 #     combinations such as Ctrl-Meta-Left-Cursor. They are not easily portable.
1431 #
1432 #   - Adding Ctrl characters, such as '^b' is okay; note that '^b' and '^B' are
1433 #     the same key.
1434 #
1435 #   - All keys from the $key[] mapping are obviously okay.
1436 #
1437 #   - Most terminals send "ESC x" when Meta-x is pressed. Thus, sequences like
1438 #     '\ex' are allowed in here as well.
1439
1440 bind2maps emacs             -- Home   beginning-of-somewhere
1441 bind2maps       viins vicmd -- Home   vi-beginning-of-line
1442 bind2maps emacs             -- End    end-of-somewhere
1443 bind2maps       viins vicmd -- End    vi-end-of-line
1444 bind2maps emacs viins       -- Insert overwrite-mode
1445 bind2maps             vicmd -- Insert vi-insert
1446 bind2maps emacs             -- Delete delete-char
1447 bind2maps       viins vicmd -- Delete vi-delete-char
1448 bind2maps emacs viins vicmd -- Up     up-line-or-search
1449 bind2maps emacs viins vicmd -- Down   down-line-or-search
1450 bind2maps emacs             -- Left   backward-char
1451 bind2maps       viins vicmd -- Left   vi-backward-char
1452 bind2maps emacs             -- Right  forward-char
1453 bind2maps       viins vicmd -- Right  vi-forward-char
1454 #k# Perform abbreviation expansion
1455 bind2maps emacs viins       -- -s '^x.' zleiab
1456 #k# Display list of abbreviations that would expand
1457 bind2maps emacs viins       -- -s '^xb' help-show-abk
1458 #k# mkdir -p <dir> from string under cursor or marked area
1459 bind2maps emacs viins       -- -s '^xM' inplaceMkDirs
1460 #k# display help for keybindings and ZLE
1461 bind2maps emacs viins       -- -s '^xz' help-zle
1462 #k# Insert files and test globbing
1463 bind2maps emacs viins       -- -s "^xf" insert-files
1464 #k# Edit the current line in \kbd{\$EDITOR}
1465 bind2maps emacs viins       -- -s '\ee' edit-command-line
1466 #k# search history backward for entry beginning with typed text
1467 bind2maps emacs viins       -- -s '^xp' history-beginning-search-backward-end
1468 #k# search history forward for entry beginning with typed text
1469 bind2maps emacs viins       -- -s '^xP' history-beginning-search-forward-end
1470 #k# search history backward for entry beginning with typed text
1471 bind2maps emacs viins       -- PageUp history-beginning-search-backward-end
1472 #k# search history forward for entry beginning with typed text
1473 bind2maps emacs viins       -- PageDown history-beginning-search-forward-end
1474 bind2maps emacs viins       -- -s "^x^h" commit-to-history
1475 #k# Kill left-side word or everything up to next slash
1476 bind2maps emacs viins       -- -s '\ev' slash-backward-kill-word
1477 #k# Kill left-side word or everything up to next slash
1478 bind2maps emacs viins       -- -s '\e^h' slash-backward-kill-word
1479 #k# Kill left-side word or everything up to next slash
1480 bind2maps emacs viins       -- -s '\e^?' slash-backward-kill-word
1481 # Do history expansion on space:
1482 bind2maps emacs viins       -- -s ' ' magic-space
1483 #k# Trigger menu-complete
1484 bind2maps emacs viins       -- -s '\ei' menu-complete  # menu completion via esc-i
1485 #k# Insert a timestamp on the command line (yyyy-mm-dd)
1486 bind2maps emacs viins       -- -s '^ed' insert-datestamp
1487 #k# Insert last typed word
1488 bind2maps emacs viins       -- -s "\em" insert-last-typed-word
1489 #k# A smart shortcut for \kbd{fg<enter>}
1490 bind2maps emacs viins       -- -s '^z' grml-zsh-fg
1491 #k# prepend the current command with "sudo"
1492 bind2maps emacs viins       -- -s "^os" sudo-command-line
1493 #k# jump to after first word (for adding options)
1494 bind2maps emacs viins       -- -s '^x1' jump_after_first_word
1495 #k# complete word from history with menu
1496 bind2maps emacs viins       -- -s "^x^x" hist-complete
1497
1498 # insert unicode character
1499 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
1500 # See for example http://unicode.org/charts/ for unicode characters code
1501 #k# Insert Unicode character
1502 bind2maps emacs viins       -- -s '^xi' insert-unicode-char
1503
1504 # use the new *-pattern-* widgets for incremental history search
1505 if zrcgotwidget history-incremental-pattern-search-backward; then
1506     for seq wid in '^r' history-incremental-pattern-search-backward \
1507                    '^s' history-incremental-pattern-search-forward
1508     do
1509         bind2maps emacs viins vicmd -- -s $seq $wid
1510     done
1511     builtin unset -v seq wid
1512 fi
1513
1514 if zrcgotkeymap menuselect; then
1515     #m# k Shift-tab Perform backwards menu completion
1516     bind2maps menuselect -- BackTab reverse-menu-complete
1517
1518     #k# menu selection: pick item but stay in the menu
1519     bind2maps menuselect -- -s '\e^M' accept-and-menu-complete
1520     # also use + and INSERT since it's easier to press repeatedly
1521     bind2maps menuselect -- -s '+' accept-and-menu-complete
1522     bind2maps menuselect -- Insert accept-and-menu-complete
1523
1524     # accept a completion and try to complete again by using menu
1525     # completion; very useful with completing directories
1526     # by using 'undo' one's got a simple file browser
1527     bind2maps menuselect -- -s '^o' accept-and-infer-next-history
1528 fi
1529
1530 # Finally, here are still a few hardcoded escape sequences; Special sequences
1531 # like Ctrl-<Cursor-key> etc do suck a fair bit, because they are not
1532 # standardised and most of the time are not available in a terminals terminfo
1533 # entry.
1534 #
1535 # While we do not encourage adding bindings like these, we will keep these for
1536 # backward compatibility.
1537
1538 ## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on
1539 ## the command line.
1540 # URxvt sequences:
1541 bind2maps emacs viins vicmd -- -s '\eOc' forward-word
1542 bind2maps emacs viins vicmd -- -s '\eOd' backward-word
1543 # These are for xterm:
1544 bind2maps emacs viins vicmd -- -s '\e[1;5C' forward-word
1545 bind2maps emacs viins vicmd -- -s '\e[1;5D' backward-word
1546 ## the same for alt-left-arrow and alt-right-arrow
1547 # URxvt again:
1548 bind2maps emacs viins vicmd -- -s '\e\e[C' forward-word
1549 bind2maps emacs viins vicmd -- -s '\e\e[D' backward-word
1550 # Xterm again:
1551 bind2maps emacs viins vicmd -- -s '^[[1;3C' forward-word
1552 bind2maps emacs viins vicmd -- -s '^[[1;3D' backward-word
1553 # Also try ESC Left/Right:
1554 bind2maps emacs viins vicmd -- -s '\e'${key[Right]} forward-word
1555 bind2maps emacs viins vicmd -- -s '\e'${key[Left]}  backward-word
1556
1557 # autoloading
1558
1559 zrcautoload zmv
1560 zrcautoload zed
1561
1562 # we don't want to quote/espace URLs on our own...
1563 # if autoload -U url-quote-magic ; then
1564 #    zle -N self-insert url-quote-magic
1565 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
1566 # else
1567 #    print 'Notice: no url-quote-magic available :('
1568 # fi
1569 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
1570
1571 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
1572 alias run-help >&/dev/null && unalias run-help
1573 for rh in run-help{,-git,-svk,-svn}; do
1574     zrcautoload $rh
1575 done; unset rh
1576
1577 # command not found handling
1578
1579 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1580 function command_not_found_handler() {
1581     emulate -L zsh
1582     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1583         ${GRML_ZSH_CNF_HANDLER} $1
1584     fi
1585     return 1
1586 }
1587
1588 # history
1589
1590 #v#
1591 HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1592 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1593 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1594
1595 # dirstack handling
1596
1597 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1598 DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1599
1600 typeset -gaU GRML_PERSISTENT_DIRSTACK
1601 function grml_dirstack_filter() {
1602     local -a exclude
1603     local filter entry
1604     if zstyle -s ':grml:chpwd:dirstack' filter filter; then
1605         $filter $1 && return 0
1606     fi
1607     if zstyle -a ':grml:chpwd:dirstack' exclude exclude; then
1608         for entry in "${exclude[@]}"; do
1609             [[ $1 == ${~entry} ]] && return 0
1610         done
1611     fi
1612     return 1
1613 }
1614
1615 chpwd() {
1616     (( $DIRSTACKSIZE <= 0 )) && return
1617     [[ -z $DIRSTACKFILE ]] && return
1618     grml_dirstack_filter $PWD && return
1619     GRML_PERSISTENT_DIRSTACK=(
1620         $PWD "${(@)GRML_PERSISTENT_DIRSTACK[1,$DIRSTACKSIZE]}"
1621     )
1622     builtin print -l ${GRML_PERSISTENT_DIRSTACK} >! ${DIRSTACKFILE}
1623 }
1624
1625 if [[ -f ${DIRSTACKFILE} ]]; then
1626     # Enabling NULL_GLOB via (N) weeds out any non-existing
1627     # directories from the saved dir-stack file.
1628     dirstack=( ${(f)"$(< $DIRSTACKFILE)"}(N) )
1629     # "cd -" won't work after login by just setting $OLDPWD, so
1630     [[ -d $dirstack[1] ]] && cd -q $dirstack[1] && cd -q $OLDPWD
1631 fi
1632
1633 if zstyle -t ':grml:chpwd:dirstack' filter-on-load; then
1634     for i in "${dirstack[@]}"; do
1635         if ! grml_dirstack_filter "$i"; then
1636             GRML_PERSISTENT_DIRSTACK=(
1637                 "${GRML_PERSISTENT_DIRSTACK[@]}"
1638                 $i
1639             )
1640         fi
1641     done
1642 else
1643     GRML_PERSISTENT_DIRSTACK=( "${dirstack[@]}" )
1644 fi
1645
1646 # directory based profiles
1647
1648 if is433 ; then
1649
1650 # chpwd_profiles(): Directory Profiles, Quickstart:
1651 #
1652 # In .zshrc.local:
1653 #
1654 #   zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1655 #   zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1656 #   chpwd_profiles
1657 #
1658 # For details see the `grmlzshrc.5' manual page.
1659 function chpwd_profiles() {
1660     local profile context
1661     local -i reexecute
1662
1663     context=":chpwd:profiles:$PWD"
1664     zstyle -s "$context" profile profile || profile='default'
1665     zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1666
1667     if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1668         typeset -g CHPWD_PROFILE
1669         local CHPWD_PROFILES_INIT=1
1670         (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1671     elif [[ $profile != $CHPWD_PROFILE ]]; then
1672         (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1673             && chpwd_leave_profile_${CHPWD_PROFILE}
1674     fi
1675     if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1676         (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1677     fi
1678
1679     CHPWD_PROFILE="${profile}"
1680     return 0
1681 }
1682
1683 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1684
1685 fi # is433
1686
1687 # Prompt setup for grml:
1688
1689 # set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1690 # in prompts to get a red "foo" embedded, but it's good to keep these for
1691 # backwards compatibility).
1692 if is437; then
1693     BLUE="%F{blue}"
1694     RED="%F{red}"
1695     GREEN="%F{green}"
1696     CYAN="%F{cyan}"
1697     MAGENTA="%F{magenta}"
1698     YELLOW="%F{yellow}"
1699     WHITE="%F{white}"
1700     NO_COLOR="%f"
1701 elif zrcautoload colors && colors 2>/dev/null ; then
1702     BLUE="%{${fg[blue]}%}"
1703     RED="%{${fg_bold[red]}%}"
1704     GREEN="%{${fg[green]}%}"
1705     CYAN="%{${fg[cyan]}%}"
1706     MAGENTA="%{${fg[magenta]}%}"
1707     YELLOW="%{${fg[yellow]}%}"
1708     WHITE="%{${fg[white]}%}"
1709     NO_COLOR="%{${reset_color}%}"
1710 else
1711     BLUE=$'%{\e[1;34m%}'
1712     RED=$'%{\e[1;31m%}'
1713     GREEN=$'%{\e[1;32m%}'
1714     CYAN=$'%{\e[1;36m%}'
1715     WHITE=$'%{\e[1;37m%}'
1716     MAGENTA=$'%{\e[1;35m%}'
1717     YELLOW=$'%{\e[1;33m%}'
1718     NO_COLOR=$'%{\e[0m%}'
1719 fi
1720
1721 # First, the easy ones: PS2..4:
1722
1723 # secondary prompt, printed when the shell needs more information to complete a
1724 # command.
1725 PS2='\`%_> '
1726 # selection prompt used within a select loop.
1727 PS3='?# '
1728 # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1729 PS4='+%N:%i:%_> '
1730
1731 # Some additional features to use with our prompt:
1732 #
1733 #    - battery status
1734 #    - debian_chroot
1735 #    - vcs_info setup and version specific fixes
1736
1737 # display battery status on right side of prompt using 'GRML_DISPLAY_BATTERY=1' in .zshrc.pre
1738
1739 battery() {
1740 if [[ $GRML_DISPLAY_BATTERY -gt 0 ]] ; then
1741     if islinux ; then
1742         batterylinux
1743     elif isopenbsd ; then
1744         batteryopenbsd
1745     elif isfreebsd ; then
1746         batteryfreebsd
1747     elif isdarwin ; then
1748         batterydarwin
1749     else
1750         #not yet supported
1751         GRML_DISPLAY_BATTERY=0
1752     fi
1753 fi
1754 }
1755
1756 batterylinux(){
1757 GRML_BATTERY_LEVEL=''
1758 local batteries bat capacity
1759 batteries=( /sys/class/power_supply/BAT*(N) )
1760 if (( $#batteries > 0 )) ; then
1761     for bat in $batteries ; do
1762         capacity=$(< $bat/capacity)
1763         case $(< $bat/status) in
1764         Charging)
1765             GRML_BATTERY_LEVEL+=" ^"
1766             ;;
1767         Discharging)
1768             if (( capacity < 20 )) ; then
1769                 GRML_BATTERY_LEVEL+=" !v"
1770             else
1771                 GRML_BATTERY_LEVEL+=" v"
1772             fi
1773             ;;
1774         *) # Full, Unknown
1775             GRML_BATTERY_LEVEL+=" ="
1776             ;;
1777         esac
1778         GRML_BATTERY_LEVEL+="${capacity}%%"
1779     done
1780 fi
1781 }
1782
1783 batteryopenbsd(){
1784 GRML_BATTERY_LEVEL=''
1785 local bat batfull batwarn batnow num
1786 for num in 0 1 ; do
1787     bat=$(sysctl -n hw.sensors.acpibat${num} 2>/dev/null)
1788     if [[ -n $bat ]]; then
1789         batfull=${"$(sysctl -n hw.sensors.acpibat${num}.amphour0)"%% *}
1790         batwarn=${"$(sysctl -n hw.sensors.acpibat${num}.amphour1)"%% *}
1791         batnow=${"$(sysctl -n hw.sensors.acpibat${num}.amphour3)"%% *}
1792         case "$(sysctl -n hw.sensors.acpibat${num}.raw0)" in
1793             *" discharging"*)
1794                 if (( batnow < batwarn )) ; then
1795                     GRML_BATTERY_LEVEL+=" !v"
1796                 else
1797                     GRML_BATTERY_LEVEL+=" v"
1798                 fi
1799                 ;;
1800             *" charging"*)
1801                 GRML_BATTERY_LEVEL+=" ^"
1802                 ;;
1803             *)
1804                 GRML_BATTERY_LEVEL+=" ="
1805                 ;;
1806         esac
1807         GRML_BATTERY_LEVEL+="${$(( 100 * batnow / batfull ))%%.*}%%"
1808     fi
1809 done
1810 }
1811
1812 batteryfreebsd(){
1813 GRML_BATTERY_LEVEL=''
1814 local num
1815 local -A table
1816 for num in 0 1 ; do
1817     table=( ${=${${${${${(M)${(f)"$(acpiconf -i $num 2>&1)"}:#(State|Remaining capacity):*}%%( ##|%)}//:[ $'\t']##/@}// /-}//@/ }} )
1818     if [[ -n $table ]] && [[ $table[State] != "not-present" ]] ; then
1819         case $table[State] in
1820             *discharging*)
1821                 if (( $table[Remaining-capacity] < 20 )) ; then
1822                     GRML_BATTERY_LEVEL+=" !v"
1823                 else
1824                     GRML_BATTERY_LEVEL+=" v"
1825                 fi
1826                 ;;
1827             *charging*)
1828                 GRML_BATTERY_LEVEL+=" ^"
1829                 ;;
1830             *)
1831                 GRML_BATTERY_LEVEL+=" ="
1832                 ;;
1833         esac
1834         GRML_BATTERY_LEVEL+="$table[Remaining-capacity]%%"
1835     fi
1836 done
1837 }
1838
1839 batterydarwin(){
1840 GRML_BATTERY_LEVEL=''
1841 local -a table
1842 table=( ${$(pmset -g ps)[(w)7,8]%%(\%|);} )
1843 if [[ -n $table[2] ]] ; then
1844     case $table[2] in
1845         charging)
1846             GRML_BATTERY_LEVEL+=" ^"
1847             ;;
1848         discharging)
1849             if (( $table[1] < 20 )) ; then
1850                 GRML_BATTERY_LEVEL+=" !v"
1851             else
1852                 GRML_BATTERY_LEVEL+=" v"
1853             fi
1854             ;;
1855         *)
1856             GRML_BATTERY_LEVEL+=" ="
1857             ;;
1858     esac
1859     GRML_BATTERY_LEVEL+="$table[1]%%"
1860 fi
1861 }
1862
1863 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
1864 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1865     debian_chroot=$(</etc/debian_chroot)
1866 fi
1867
1868 # gather version control information for inclusion in a prompt
1869
1870 if zrcautoload vcs_info; then
1871     # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1872     # function, which can cause a lot of trouble with our directory-based
1873     # profiles. So:
1874     if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1875         function VCS_INFO_realpath () {
1876             setopt localoptions NO_shwordsplit chaselinks
1877             ( builtin cd -q $1 2> /dev/null && pwd; )
1878         }
1879     fi
1880
1881     zstyle ':vcs_info:*' max-exports 2
1882
1883     if [[ -o restricted ]]; then
1884         zstyle ':vcs_info:*' enable NONE
1885     fi
1886 fi
1887
1888 typeset -A grml_vcs_coloured_formats
1889 typeset -A grml_vcs_plain_formats
1890
1891 grml_vcs_plain_formats=(
1892     format "(%s%)-[%b] "    "zsh: %r"
1893     actionformat "(%s%)-[%b|%a] " "zsh: %r"
1894     rev-branchformat "%b:%r"
1895 )
1896
1897 grml_vcs_coloured_formats=(
1898     format "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR} "
1899     actionformat "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} "
1900     rev-branchformat "%b${RED}:${YELLOW}%r"
1901 )
1902
1903 typeset GRML_VCS_COLOUR_MODE=xxx
1904
1905 grml_vcs_info_toggle_colour () {
1906     emulate -L zsh
1907     if [[ $GRML_VCS_COLOUR_MODE == plain ]]; then
1908         grml_vcs_info_set_formats coloured
1909     else
1910         grml_vcs_info_set_formats plain
1911     fi
1912     return 0
1913 }
1914
1915 grml_vcs_info_set_formats () {
1916     emulate -L zsh
1917     #setopt localoptions xtrace
1918     local mode=$1 AF F BF
1919     if [[ $mode == coloured ]]; then
1920         AF=${grml_vcs_coloured_formats[actionformat]}
1921         F=${grml_vcs_coloured_formats[format]}
1922         BF=${grml_vcs_coloured_formats[rev-branchformat]}
1923         GRML_VCS_COLOUR_MODE=coloured
1924     else
1925         AF=${grml_vcs_plain_formats[actionformat]}
1926         F=${grml_vcs_plain_formats[format]}
1927         BF=${grml_vcs_plain_formats[rev-branchformat]}
1928         GRML_VCS_COLOUR_MODE=plain
1929     fi
1930
1931     zstyle ':vcs_info:*'              actionformats "$AF" "zsh: %r"
1932     zstyle ':vcs_info:*'              formats       "$F"  "zsh: %r"
1933     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat  "$BF"
1934     return 0
1935 }
1936
1937 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1938 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1939 if [[ "$TERM" == dumb ]] ; then
1940     grml_vcs_info_set_formats plain
1941 else
1942     grml_vcs_info_set_formats coloured
1943 fi
1944
1945 # Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1946
1947 # This actually defines three prompts:
1948 #
1949 #    - grml
1950 #    - grml-large
1951 #    - grml-chroot
1952 #
1953 # They all share the same code and only differ with respect to which items they
1954 # contain. The main source of documentation is the `prompt_grml_help' function
1955 # below, which gets called when the user does this: prompt -h grml
1956
1957 function prompt_grml_help () {
1958     <<__EOF0__
1959   prompt grml
1960
1961     This is the prompt as used by the grml-live system <http://grml.org>. It is
1962     a rather simple one-line prompt, that by default looks something like this:
1963
1964         <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1965
1966     The prompt itself integrates with zsh's prompt themes system (as you are
1967     witnessing right now) and is configurable to a certain degree. In
1968     particular, these aspects are customisable:
1969
1970         - The items used in the prompt (e.g. you can remove \`user' from
1971           the list of activated items, which will cause the user name to
1972           be omitted from the prompt string).
1973
1974         - The attributes used with the items are customisable via strings
1975           used before and after the actual item.
1976
1977     The available items are: at, battery, change-root, date, grml-chroot,
1978     history, host, jobs, newline, path, percent, rc, rc-always, sad-smiley,
1979     shell-level, time, user, vcs
1980
1981     The actual configuration is done via zsh's \`zstyle' mechanism. The
1982     context, that is used while looking up styles is:
1983
1984         ':prompt:grml:<left-or-right>:<subcontext>'
1985
1986     Here <left-or-right> is either \`left' or \`right', signifying whether the
1987     style should affect the left or the right prompt. <subcontext> is either
1988     \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1989
1990     The styles:
1991
1992         - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1993           in $RPROMPT if the last command a returned non-successful error code.
1994           (This in only valid if <left-or-right> is "right"; ignored otherwise)
1995
1996         - items (list): The list of items used in the prompt. If \`vcs' is
1997           present in the list, the theme's code invokes \`vcs_info'
1998           accordingly. Default (left): rc change-root user at host path vcs
1999           percent; Default (right): sad-smiley
2000
2001     Available styles in 'items:<item>' are: pre, post. These are strings that
2002     are inserted before (pre) and after (post) the item in question. Thus, the
2003     following would cause the user name to be printed in red instead of the
2004     default blue:
2005
2006         zstyle ':prompt:grml:*:items:user' pre '%F{red}'
2007
2008     Note, that the \`post' style may remain at its default value, because its
2009     default value is '%f', which turns the foreground text attribute off (which
2010     is exactly, what is still required with the new \`pre' value).
2011 __EOF0__
2012 }
2013
2014 function prompt_grml-chroot_help () {
2015     <<__EOF0__
2016   prompt grml-chroot
2017
2018     This is a variation of the grml prompt, see: prompt -h grml
2019
2020     The main difference is the default value of the \`items' style. The rest
2021     behaves exactly the same. Here are the defaults for \`grml-chroot':
2022
2023         - left: grml-chroot user at host path percent
2024         - right: (empty list)
2025 __EOF0__
2026 }
2027
2028 function prompt_grml-large_help () {
2029     <<__EOF0__
2030   prompt grml-large
2031
2032     This is a variation of the grml prompt, see: prompt -h grml
2033
2034     The main difference is the default value of the \`items' style. In
2035     particular, this theme uses _two_ lines instead of one with the plain
2036     \`grml' theme. The rest behaves exactly the same. Here are the defaults
2037     for \`grml-large':
2038
2039         - left: rc jobs history shell-level change-root time date newline user
2040                 at host path vcs percent
2041         - right: sad-smiley
2042 __EOF0__
2043 }
2044
2045 function grml_prompt_setup () {
2046     emulate -L zsh
2047     autoload -Uz vcs_info
2048     # The following autoload is disabled for now, since this setup includes a
2049     # static version of the ‘add-zsh-hook’ function above. It needs to be
2050     # reenabled as soon as that static definition is removed again.
2051     #autoload -Uz add-zsh-hook
2052     add-zsh-hook precmd prompt_$1_precmd
2053 }
2054
2055 function prompt_grml_setup () {
2056     grml_prompt_setup grml
2057 }
2058
2059 function prompt_grml-chroot_setup () {
2060     grml_prompt_setup grml-chroot
2061 }
2062
2063 function prompt_grml-large_setup () {
2064     grml_prompt_setup grml-large
2065 }
2066
2067 # These maps define default tokens and pre-/post-decoration for items to be
2068 # used within the themes. All defaults may be customised in a context sensitive
2069 # matter by using zsh's `zstyle' mechanism.
2070 typeset -gA grml_prompt_pre_default \
2071             grml_prompt_post_default \
2072             grml_prompt_token_default \
2073             grml_prompt_token_function
2074
2075 grml_prompt_pre_default=(
2076     at                ''
2077     battery           ' '
2078     change-root       ''
2079     date              '%F{blue}'
2080     grml-chroot       '%F{red}'
2081     history           '%F{green}'
2082     host              ''
2083     jobs              '%F{cyan}'
2084     newline           ''
2085     path              '%B'
2086     percent           ''
2087     rc                '%B%F{red}'
2088     rc-always         ''
2089     sad-smiley        ''
2090     shell-level       '%F{red}'
2091     time              '%F{blue}'
2092     user              '%B%F{blue}'
2093     vcs               ''
2094 )
2095
2096 grml_prompt_post_default=(
2097     at                ''
2098     battery           ''
2099     change-root       ''
2100     date              '%f'
2101     grml-chroot       '%f '
2102     history           '%f'
2103     host              ''
2104     jobs              '%f'
2105     newline           ''
2106     path              '%b'
2107     percent           ''
2108     rc                '%f%b'
2109     rc-always         ''
2110     sad-smiley        ''
2111     shell-level       '%f'
2112     time              '%f'
2113     user              '%f%b'
2114     vcs               ''
2115 )
2116
2117 grml_prompt_token_default=(
2118     at                '@'
2119     battery           'GRML_BATTERY_LEVEL'
2120     change-root       'debian_chroot'
2121     date              '%D{%Y-%m-%d}'
2122     grml-chroot       'GRML_CHROOT'
2123     history           '{history#%!} '
2124     host              '%m '
2125     jobs              '[%j running job(s)] '
2126     newline           $'\n'
2127     path              '%40<..<%~%<< '
2128     percent           '%# '
2129     rc                '%(?..%? )'
2130     rc-always         '%?'
2131     sad-smiley        '%(?..:()'
2132     shell-level       '%(3L.+ .)'
2133     time              '%D{%H:%M:%S} '
2134     user              '%n'
2135     vcs               '0'
2136 )
2137
2138 function grml_theme_has_token () {
2139     if (( ARGC != 1 )); then
2140         printf 'usage: grml_theme_has_token <name>\n'
2141         return 1
2142     fi
2143     (( ${+grml_prompt_token_default[$1]} ))
2144 }
2145
2146 function GRML_theme_add_token_usage () {
2147     <<__EOF0__
2148   Usage: grml_theme_add_token <name> [-f|-i] <token/function> [<pre> <post>]
2149
2150     <name> is the name for the newly added token. If the \`-f' or \`-i' options
2151     are used, <token/function> is the name of the function (see below for
2152     details). Otherwise it is the literal token string to be used. <pre> and
2153     <post> are optional.
2154
2155   Options:
2156
2157     -f <function>   Use a function named \`<function>' each time the token
2158                     is to be expanded.
2159
2160     -i <function>   Use a function named \`<function>' to initialise the
2161                     value of the token _once_ at runtime.
2162
2163     The functions are called with one argument: the token's new name. The
2164     return value is expected in the \$REPLY parameter. The use of these
2165     options is mutually exclusive.
2166
2167     There is a utility function \`grml_theme_has_token', which you can use
2168     to test if a token exists before trying to add it. This can be a guard
2169     for situations in which a \`grml_theme_add_token' call may happen more
2170     than once.
2171
2172   Example:
2173
2174     To add a new token \`day' that expands to the current weekday in the
2175     current locale in green foreground colour, use this:
2176
2177       grml_theme_add_token day '%D{%A}' '%F{green}' '%f'
2178
2179     Another example would be support for \$VIRTUAL_ENV:
2180
2181       function virtual_env_prompt () {
2182         REPLY=\${VIRTUAL_ENV+\${VIRTUAL_ENV:t} }
2183       }
2184       grml_theme_add_token virtual-env -f virtual_env_prompt
2185
2186     After that, you will be able to use a changed \`items' style to
2187     assemble your prompt.
2188 __EOF0__
2189 }
2190
2191 function grml_theme_add_token () {
2192     emulate -L zsh
2193     local name token pre post
2194     local -i init funcall
2195
2196     if (( ARGC == 0 )); then
2197         GRML_theme_add_token_usage
2198         return 0
2199     fi
2200
2201     init=0
2202     funcall=0
2203     pre=''
2204     post=''
2205     name=$1
2206     shift
2207     if [[ $1 == '-f' ]]; then
2208         funcall=1
2209         shift
2210     elif [[ $1 == '-i' ]]; then
2211         init=1
2212         shift
2213     fi
2214
2215     if (( ARGC == 0 )); then
2216         printf '
2217 grml_theme_add_token: No token-string/function-name provided!\n\n'
2218         GRML_theme_add_token_usage
2219         return 1
2220     fi
2221     token=$1
2222     shift
2223     if (( ARGC != 0 && ARGC != 2 )); then
2224         printf '
2225 grml_theme_add_token: <pre> and <post> need to by specified _both_!\n\n'
2226         GRML_theme_add_token_usage
2227         return 1
2228     fi
2229     if (( ARGC )); then
2230         pre=$1
2231         post=$2
2232         shift 2
2233     fi
2234
2235     if grml_theme_has_token $name; then
2236         printf '
2237 grml_theme_add_token: Token `%s'\'' exists! Giving up!\n\n' $name
2238         GRML_theme_add_token_usage
2239         return 2
2240     fi
2241     if (( init )); then
2242         $token $name
2243         token=$REPLY
2244     fi
2245     grml_prompt_pre_default[$name]=$pre
2246     grml_prompt_post_default[$name]=$post
2247     if (( funcall )); then
2248         grml_prompt_token_function[$name]=$token
2249         grml_prompt_token_default[$name]=23
2250     else
2251         grml_prompt_token_default[$name]=$token
2252     fi
2253 }
2254
2255 function grml_typeset_and_wrap () {
2256     emulate -L zsh
2257     local target="$1"
2258     local new="$2"
2259     local left="$3"
2260     local right="$4"
2261
2262     if (( ${+parameters[$new]} )); then
2263         typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
2264     fi
2265 }
2266
2267 function grml_prompt_addto () {
2268     emulate -L zsh
2269     local target="$1"
2270     local lr it apre apost new v
2271     local -a items
2272     shift
2273
2274     [[ $target == PS1 ]] && lr=left || lr=right
2275     zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
2276     typeset -g "${target}="
2277     for it in "${items[@]}"; do
2278         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
2279             || apre=${grml_prompt_pre_default[$it]}
2280         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" post apost \
2281             || apost=${grml_prompt_post_default[$it]}
2282         zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
2283             || new=${grml_prompt_token_default[$it]}
2284         typeset -g "${target}=${(P)target}${apre}"
2285         if (( ${+grml_prompt_token_function[$it]} )); then
2286             ${grml_prompt_token_function[$it]} $it
2287             typeset -g "${target}=${(P)target}${REPLY}"
2288         else
2289             case $it in
2290             battery)
2291                 grml_typeset_and_wrap $target $new '' ''
2292                 ;;
2293             change-root)
2294                 grml_typeset_and_wrap $target $new '(' ')'
2295                 ;;
2296             grml-chroot)
2297                 if [[ -n ${(P)new} ]]; then
2298                     typeset -g "${target}=${(P)target}(CHROOT)"
2299                 fi
2300                 ;;
2301             vcs)
2302                 v="vcs_info_msg_${new}_"
2303                 if (( ! vcscalled )); then
2304                     vcs_info
2305                     vcscalled=1
2306                 fi
2307                 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
2308                     typeset -g "${target}=${(P)target}${(P)v}"
2309                 fi
2310                 ;;
2311             *) typeset -g "${target}=${(P)target}${new}" ;;
2312             esac
2313         fi
2314         typeset -g "${target}=${(P)target}${apost}"
2315     done
2316 }
2317
2318 function prompt_grml_precmd () {
2319     emulate -L zsh
2320     local grmltheme=grml
2321     local -a left_items right_items
2322     left_items=(rc change-root user at host path vcs percent)
2323     right_items=(sad-smiley)
2324
2325     prompt_grml_precmd_worker
2326 }
2327
2328 function prompt_grml-chroot_precmd () {
2329     emulate -L zsh
2330     local grmltheme=grml-chroot
2331     local -a left_items right_items
2332     left_items=(grml-chroot user at host path percent)
2333     right_items=()
2334
2335     prompt_grml_precmd_worker
2336 }
2337
2338 function prompt_grml-large_precmd () {
2339     emulate -L zsh
2340     local grmltheme=grml-large
2341     local -a left_items right_items
2342     left_items=(rc jobs history shell-level change-root time date newline
2343                 user at host path vcs percent)
2344     right_items=(sad-smiley)
2345
2346     prompt_grml_precmd_worker
2347 }
2348
2349 function prompt_grml_precmd_worker () {
2350     emulate -L zsh
2351     local -i vcscalled=0
2352
2353     grml_prompt_addto PS1 "${left_items[@]}"
2354     if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
2355         grml_prompt_addto RPS1 "${right_items[@]}"
2356     fi
2357 }
2358
2359 grml_prompt_fallback() {
2360     setopt prompt_subst
2361     precmd() {
2362         (( ${+functions[vcs_info]} )) && vcs_info
2363     }
2364
2365     p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
2366     p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
2367     if (( EUID == 0 )); then
2368         PROMPT="${BLUE}${p0}${RED}${p1}"
2369     else
2370         PROMPT="${RED}${p0}${BLUE}${p1}"
2371     fi
2372     unset p0 p1
2373 }
2374
2375 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2376     # Since we define the required functions in here and not in files in
2377     # $fpath, we need to stick the theme's name into `$prompt_themes'
2378     # ourselves, since promptinit does not pick them up otherwise.
2379     prompt_themes+=( grml grml-chroot grml-large )
2380     # Also, keep the array sorted...
2381     prompt_themes=( "${(@on)prompt_themes}" )
2382 else
2383     print 'Notice: no promptinit available :('
2384     grml_prompt_fallback
2385 fi
2386
2387 if is437; then
2388     # The prompt themes use modern features of zsh, that require at least
2389     # version 4.3.7 of the shell. Use the fallback otherwise.
2390     if [[ $GRML_DISPLAY_BATTERY -gt 0 ]]; then
2391         zstyle ':prompt:grml:right:setup' items sad-smiley battery
2392         add-zsh-hook precmd battery
2393     fi
2394     if [[ "$TERM" == dumb ]] ; then
2395         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
2396         zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
2397         for i in rc user path jobs history date time shell-level; do
2398             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
2399             zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
2400         done
2401         unset i
2402         zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
2403     elif (( EUID == 0 )); then
2404         zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%B%F{red}'
2405     fi
2406
2407     # Finally enable one of the prompts.
2408     if [[ -n $GRML_CHROOT ]]; then
2409         prompt grml-chroot
2410     elif [[ $GRMLPROMPT -gt 0 ]]; then
2411         prompt grml-large
2412     else
2413         prompt grml
2414     fi
2415 else
2416     grml_prompt_fallback
2417 fi
2418
2419 # Terminal-title wizardry
2420
2421 function ESC_print () {
2422     info_print $'\ek' $'\e\\' "$@"
2423 }
2424 function set_title () {
2425     info_print  $'\e]0;' $'\a' "$@"
2426 }
2427
2428 function info_print () {
2429     local esc_begin esc_end
2430     esc_begin="$1"
2431     esc_end="$2"
2432     shift 2
2433     printf '%s' ${esc_begin}
2434     printf '%s' "$*"
2435     printf '%s' "${esc_end}"
2436 }
2437
2438 function grml_reset_screen_title () {
2439     # adjust title of xterm
2440     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2441     [[ ${NOTITLE:-} -gt 0 ]] && return 0
2442     case $TERM in
2443         (xterm*|rxvt*)
2444             set_title ${(%):-"%n@%m: %~"}
2445             ;;
2446     esac
2447 }
2448
2449 function grml_vcs_to_screen_title () {
2450     if [[ $TERM == screen* ]] ; then
2451         if [[ -n ${vcs_info_msg_1_} ]] ; then
2452             ESC_print ${vcs_info_msg_1_}
2453         else
2454             ESC_print "zsh"
2455         fi
2456     fi
2457 }
2458
2459 function grml_maintain_name () {
2460     # set hostname if not running on host with name 'grml'
2461     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2462        NAME="@$HOSTNAME"
2463     fi
2464 }
2465
2466 function grml_cmd_to_screen_title () {
2467     # get the name of the program currently running and hostname of local
2468     # machine set screen window title if running in a screen
2469     if [[ "$TERM" == screen* ]] ; then
2470         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME"
2471         ESC_print ${CMD}
2472     fi
2473 }
2474
2475 function grml_control_xterm_title () {
2476     case $TERM in
2477         (xterm*|rxvt*)
2478             set_title "${(%):-"%n@%m:"}" "$1"
2479             ;;
2480     esac
2481 }
2482
2483 # The following autoload is disabled for now, since this setup includes a
2484 # static version of the ‘add-zsh-hook’ function above. It needs to be
2485 # reenabled as soon as that static definition is removed again.
2486 #zrcautoload add-zsh-hook || add-zsh-hook () { :; }
2487 if [[ $NOPRECMD -eq 0 ]]; then
2488     add-zsh-hook precmd grml_reset_screen_title
2489     add-zsh-hook precmd grml_vcs_to_screen_title
2490     add-zsh-hook preexec grml_maintain_name
2491     add-zsh-hook preexec grml_cmd_to_screen_title
2492     if [[ $NOTITLE -eq 0 ]]; then
2493         add-zsh-hook preexec grml_control_xterm_title
2494     fi
2495 fi
2496
2497 # 'hash' some often used directories
2498 #d# start
2499 hash -d deb=/var/cache/apt/archives
2500 hash -d doc=/usr/share/doc
2501 hash -d linux=/lib/modules/$(command uname -r)/build/
2502 hash -d log=/var/log
2503 hash -d slog=/var/log/syslog
2504 hash -d src=/usr/src
2505 hash -d www=/var/www
2506 #d# end
2507
2508 # some aliases
2509 if check_com -c screen ; then
2510     if [[ $UID -eq 0 ]] ; then
2511         if [[ -r /etc/grml/screenrc ]]; then
2512             alias screen='screen -c /etc/grml/screenrc'
2513         fi
2514     elif [[ ! -r $HOME/.screenrc ]] ; then
2515         if [[ -r /etc/grml/screenrc_grml ]]; then
2516             alias screen='screen -c /etc/grml/screenrc_grml'
2517         else
2518             if [[ -r /etc/grml/screenrc ]]; then
2519                 alias screen='screen -c /etc/grml/screenrc'
2520             fi
2521         fi
2522     fi
2523 fi
2524
2525 # do we have GNU ls with color-support?
2526 if [[ "$TERM" != dumb ]]; then
2527     #a1# List files with colors (\kbd{ls \ldots})
2528     alias ls="command ls ${ls_options:+${ls_options[*]}}"
2529     #a1# List all files, with colors (\kbd{ls -la \ldots})
2530     alias la="command ls -la ${ls_options:+${ls_options[*]}}"
2531     #a1# List files with long colored list, without dotfiles (\kbd{ls -l \ldots})
2532     alias ll="command ls -l ${ls_options:+${ls_options[*]}}"
2533     #a1# List files with long colored list, human readable sizes (\kbd{ls -hAl \ldots})
2534     alias lh="command ls -hAl ${ls_options:+${ls_options[*]}}"
2535     #a1# List files with long colored list, append qualifier to filenames (\kbd{ls -l \ldots})\\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2536     alias l="command ls -l ${ls_options:+${ls_options[*]}}"
2537 else
2538     alias la='command ls -la'
2539     alias ll='command ls -l'
2540     alias lh='command ls -hAl'
2541     alias l='command ls -l'
2542 fi
2543
2544 alias mdstat='cat /proc/mdstat'
2545 alias ...='cd ../../'
2546
2547 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2548 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2549     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2550 fi
2551
2552 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2553 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2554 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2555
2556 # make sure it is not assigned yet
2557 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2558 utf2iso() {
2559     if isutfenv ; then
2560         local ENV
2561         for ENV in $(env | command grep -i '.utf') ; do
2562             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2563         done
2564     fi
2565 }
2566
2567 # make sure it is not assigned yet
2568 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2569 iso2utf() {
2570     if ! isutfenv ; then
2571         local ENV
2572         for ENV in $(env | command grep -i '\.iso') ; do
2573             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2574         done
2575     fi
2576 }
2577
2578 # especially for roadwarriors using GNU screen and ssh:
2579 if ! check_com asc &>/dev/null ; then
2580   asc() { autossh -t "$@" 'screen -RdU' }
2581   compdef asc=ssh
2582 fi
2583
2584 #f1# Hints for the use of zsh on grml
2585 zsh-help() {
2586     print "$bg[white]$fg[black]
2587 zsh-help - hints for use of zsh on grml
2588 =======================================$reset_color"
2589
2590     print '
2591 Main configuration of zsh happens in /etc/zsh/zshrc.
2592 That file is part of the package grml-etc-core, if you want to
2593 use them on a non-grml-system just get the tar.gz from
2594 http://deb.grml.org/ or (preferably) get it from the git repository:
2595
2596   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2597
2598 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2599 The file is still there, but it is empty for backwards compatibility.
2600
2601 For your own changes use these two files:
2602     $HOME/.zshrc.pre
2603     $HOME/.zshrc.local
2604
2605 The former is sourced very early in our zshrc, the latter is sourced
2606 very lately.
2607
2608 System wide configuration without touching configuration files of grml
2609 can take place in /etc/zsh/zshrc.local.
2610
2611 For information regarding zsh start at http://grml.org/zsh/
2612
2613 Take a look at grml'\''s zsh refcard:
2614 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2615
2616 Check out the main zsh refcard:
2617 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2618
2619 And of course visit the zsh-lovers:
2620 % man zsh-lovers
2621
2622 You can adjust some options through environment variables when
2623 invoking zsh without having to edit configuration files.
2624 Basically meant for bash users who are not used to the power of
2625 the zsh yet. :)
2626
2627   "NOCOR=1    zsh" => deactivate automatic correction
2628   "NOMENU=1   zsh" => do not use auto menu completion
2629                       (note: use ctrl-d for completion instead!)
2630   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2631   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2632                       preexec() and precmd() completely
2633   "GRML_DISPLAY_BATTERY=1  zsh"
2634                    => activate battery status on right side of prompt (WIP)
2635   "COMMAND_NOT_FOUND=1 zsh"
2636                    => Enable a handler if an external command was not found
2637                       The command called in the handler can be altered by setting
2638                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2639                       "/usr/share/command-not-found/command-not-found"
2640
2641 A value greater than 0 is enables a feature; a value equal to zero
2642 disables it. If you like one or the other of these settings, you can
2643 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2644 zshrc.'
2645
2646     print "
2647 $bg[white]$fg[black]
2648 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2649 Enjoy your grml system with the zsh!$reset_color"
2650 }
2651
2652 # debian stuff
2653 if [[ -r /etc/debian_version ]] ; then
2654     #a3# Execute \kbd{apt-cache search}
2655     alias acs='apt-cache search'
2656     #a3# Execute \kbd{apt-cache show}
2657     alias acsh='apt-cache show'
2658     #a3# Execute \kbd{apt-cache policy}
2659     alias acp='apt-cache policy'
2660     #a3# Execute \kbd{apt-get dist-upgrade}
2661     salias adg="apt-get dist-upgrade"
2662     #a3# Execute \kbd{apt-get install}
2663     salias agi="apt-get install"
2664     #a3# Execute \kbd{aptitude install}
2665     salias ati="aptitude install"
2666     #a3# Execute \kbd{apt-get upgrade}
2667     salias ag="apt-get upgrade"
2668     #a3# Execute \kbd{apt-get update}
2669     salias au="apt-get update"
2670     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2671     salias -a up="aptitude update ; aptitude safe-upgrade"
2672     #a3# Execute \kbd{dpkg-buildpackage}
2673     alias dbp='dpkg-buildpackage'
2674     #a3# Execute \kbd{grep-excuses}
2675     alias ge='grep-excuses'
2676
2677     # get a root shell as normal user in live-cd mode:
2678     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2679        alias su="sudo su"
2680     fi
2681
2682     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2683     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2684     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2685     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2686 fi
2687
2688 # sort installed Debian-packages by size
2689 if check_com -c dpkg-query ; then
2690     #a3# List installed Debian-packages sorted by size
2691     alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x  /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
2692 fi
2693
2694 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2695 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2696     if check_com -c wodim; then
2697         cdrecord() {
2698             <<__EOF0__
2699 cdrecord is not provided under its original name by Debian anymore.
2700 See #377109 in the BTS of Debian for more details.
2701
2702 Please use the wodim binary instead
2703 __EOF0__
2704             return 1
2705         }
2706     fi
2707 fi
2708
2709 if isgrmlcd; then
2710     # No core dumps: important for a live-cd-system
2711     limit -s core 0
2712 fi
2713
2714 # grmlstuff
2715 grmlstuff() {
2716 # people should use 'grml-x'!
2717     if check_com -c 915resolution; then
2718         855resolution() {
2719             echo "Please use 915resolution as resolution modifying tool for Intel \
2720 graphic chipset."
2721             return -1
2722         }
2723     fi
2724
2725     #a1# Output version of running grml
2726     alias grml-version='cat /etc/grml_version'
2727
2728     if check_com -c grml-debootstrap ; then
2729         debian2hd() {
2730             echo "Installing debian to harddisk is possible by using grml-debootstrap."
2731             return 1
2732         }
2733     fi
2734 }
2735
2736 # now run the functions
2737 isgrml && checkhome
2738 is4    && isgrml    && grmlstuff
2739 is4    && grmlcomp
2740
2741 # keephack
2742 is4 && xsource "/etc/zsh/keephack"
2743
2744 # wonderful idea of using "e" glob qualifier by Peter Stephenson
2745 # You use it as follows:
2746 # $ NTREF=/reference/file
2747 # $ ls -l *(e:nt:)
2748 # This lists all the files in the current directory newer than the reference file.
2749 # You can also specify the reference file inline; note quotes:
2750 # $ ls -l *(e:'nt ~/.zshenv':)
2751 is4 && nt() {
2752     if [[ -n $1 ]] ; then
2753         local NTREF=${~1}
2754     fi
2755     [[ $REPLY -nt $NTREF ]]
2756 }
2757
2758 # shell functions
2759
2760 #f1# Reload an autoloadable function
2761 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2762 compdef _functions freload
2763
2764 #
2765 # Usage:
2766 #
2767 #      e.g.:   a -> b -> c -> d  ....
2768 #
2769 #      sll a
2770 #
2771 #
2772 #      if parameter is given with leading '=', lookup $PATH for parameter and resolve that
2773 #
2774 #      sll =java
2775 #
2776 #      Note: limit for recursive symlinks on linux:
2777 #            http://git.kernel.org/cgit/linux/kernel/git/torvalds/linux.git/tree/fs/namei.c?id=refs/heads/master#l808
2778 #            This limits recursive symlink follows to 8,
2779 #            while limiting consecutive symlinks to 40.
2780 #
2781 #      When resolving and displaying information about symlinks, no check is made
2782 #      that the displayed information does make any sense on your OS.
2783 #      We leave that decission to the user.
2784 #
2785 #      The zstat module is used to detect symlink loops. zstat is available since zsh4.
2786 #      With an older zsh you will need to abort with <C-c> in that case.
2787 #      When a symlink loop is detected, a warning ist printed and further processing is stopped.
2788 #
2789 #      Module zstat is loaded by default in grml zshrc, no extra action needed for that.
2790 #
2791 #      Known bugs:
2792 #      If you happen to come accross a symlink that points to a destination on an other partition
2793 #      with the same inode number, that will be marked as symlink loop though it is not.
2794 #      Two hints for this situation:
2795 #      I)  Play lottery the same day, as you seem to be rather lucky right now.
2796 #      II) Send patches.
2797 #
2798 #      return status:
2799 #      0 upon success
2800 #      1 file/dir not accesible
2801 #      2 symlink loop detected
2802 #
2803 #f1# List symlinks in detail (more detailed version of 'readlink -f', 'whence -s' and 'namei -l')
2804 sll() {
2805     if [[ -z ${1} ]] ; then
2806         printf 'Usage: %s <symlink(s)>\n' "${0}"
2807         return 1
2808     fi
2809
2810     local file jumpd curdir
2811     local -i RTN LINODE i
2812     local -a SEENINODES
2813     curdir="${PWD}"
2814     RTN=0
2815
2816     for file in "${@}" ; do
2817         SEENINODES=()
2818         ls -l "${file:a}"   || RTN=1
2819
2820         while [[ -h "$file" ]] ; do
2821             if is4 ; then
2822                 LINODE=$(zstat -L +inode "${file}")
2823                 for i in ${SEENINODES} ; do
2824                     if (( ${i} == ${LINODE} )) ; then
2825                         builtin cd "${curdir}"
2826                         print "link loop detected, aborting!"
2827                         return 2
2828                     fi
2829                 done
2830                 SEENINODES+=${LINODE}
2831             fi
2832             jumpd="${file:h}"
2833             file="${file:t}"
2834
2835             if [[ -d ${jumpd} ]] ; then
2836                 builtin cd "${jumpd}"  || RTN=1
2837             fi
2838             file=$(readlink "$file")
2839
2840             jumpd="${file:h}"
2841             file="${file:t}"
2842
2843             if [[ -d ${jumpd} ]] ; then
2844                 builtin cd "${jumpd}"  || RTN=1
2845             fi
2846
2847             ls -l "${PWD}/${file}"     || RTN=1
2848         done
2849         shift 1
2850         if (( ${#} >= 1 )) ; then
2851             print ""
2852         fi
2853         builtin cd "${curdir}"
2854     done
2855     return ${RTN}
2856 }
2857
2858 # TODO: Is it supported to use pager settings like this?
2859 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2860 # with respect to wordsplitting. (ie. ${=PAGER})
2861 if check_com -c $PAGER ; then
2862     #f3# View Debian's changelog of given package(s)
2863     dchange() {
2864         emulate -L zsh
2865         [[ -z "$1" ]] && printf 'Usage: %s <package_name(s)>\n' "$0" && return 1
2866
2867         local package
2868         for package in "$@" ; do
2869             if [[ -r /usr/share/doc/${package}/changelog.Debian.gz ]] ; then
2870                 $PAGER /usr/share/doc/${package}/changelog.Debian.gz
2871             elif [[ -r /usr/share/doc/${package}/changelog.gz ]] ; then
2872                 $PAGER /usr/share/doc/${package}/changelog.gz
2873             elif [[ -r /usr/share/doc/${package}/changelog ]] ; then
2874                 $PAGER /usr/share/doc/${package}/changelog
2875             else
2876                 if check_com -c aptitude ; then
2877                     echo "No changelog for package $package found, using aptitude to retrieve it."
2878                     aptitude changelog "$package"
2879                 elif check_com -c apt-get ; then
2880                     echo "No changelog for package $package found, using apt-get to retrieve it."
2881                     apt-get changelog "$package"
2882                 else
2883                     echo "No changelog for package $package found, sorry."
2884                 fi
2885             fi
2886         done
2887     }
2888     _dchange() { _files -W /usr/share/doc -/ }
2889     compdef _dchange dchange
2890
2891     #f3# View Debian's NEWS of a given package
2892     dnews() {
2893         emulate -L zsh
2894         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2895             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2896         else
2897             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2898                 $PAGER /usr/share/doc/$1/NEWS.gz
2899             else
2900                 echo "No NEWS file for package $1 found, sorry."
2901                 return 1
2902             fi
2903         fi
2904     }
2905     _dnews() { _files -W /usr/share/doc -/ }
2906     compdef _dnews dnews
2907
2908     #f3# View Debian's copyright of a given package
2909     dcopyright() {
2910         emulate -L zsh
2911         if [[ -r /usr/share/doc/$1/copyright ]] ; then
2912             $PAGER /usr/share/doc/$1/copyright
2913         else
2914             echo "No copyright file for package $1 found, sorry."
2915             return 1
2916         fi
2917     }
2918     _dcopyright() { _files -W /usr/share/doc -/ }
2919     compdef _dcopyright dcopyright
2920
2921     #f3# View upstream's changelog of a given package
2922     uchange() {
2923         emulate -L zsh
2924         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2925             $PAGER /usr/share/doc/$1/changelog.gz
2926         else
2927             echo "No changelog for package $1 found, sorry."
2928             return 1
2929         fi
2930     }
2931     _uchange() { _files -W /usr/share/doc -/ }
2932     compdef _uchange uchange
2933 fi
2934
2935 # zsh profiling
2936 profile() {
2937     ZSH_PROFILE_RC=1 zsh "$@"
2938 }
2939
2940 #f1# Edit an alias via zle
2941 edalias() {
2942     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2943 }
2944 compdef _aliases edalias
2945
2946 #f1# Edit a function via zle
2947 edfunc() {
2948     [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2949 }
2950 compdef _functions edfunc
2951
2952 # use it e.g. via 'Restart apache2'
2953 #m# f6 Start() \kbd{service \em{process}}\quad\kbd{start}
2954 #m# f6 Restart() \kbd{service \em{process}}\quad\kbd{restart}
2955 #m# f6 Stop() \kbd{service \em{process}}\quad\kbd{stop}
2956 #m# f6 Reload() \kbd{service \em{process}}\quad\kbd{reload}
2957 #m# f6 Force-Reload() \kbd{service \em{process}}\quad\kbd{force-reload}
2958 #m# f6 Status() \kbd{service \em{process}}\quad\kbd{status}
2959 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2960     __start_stop() {
2961         local action_="${1:l}"  # e.g Start/Stop/Restart
2962         local service_="$2"
2963         local param_="$3"
2964
2965         local service_target_="$(readlink /etc/init.d/$service_)"
2966         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2967             # runit
2968             case "${action_}" in
2969                 start) if [[ ! -e /etc/service/$service_ ]]; then
2970                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2971                        else
2972                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2973                        fi ;;
2974                 # there is no reload in runits sysv emulation
2975                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2976                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2977             esac
2978         else
2979             # sysv/sysvinit-utils, upstart
2980             if check_com -c service ; then
2981               $SUDO service "$service_" "${action_}" "$param_"
2982             else
2983               $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2984             fi
2985         fi
2986     }
2987
2988     _grmlinitd() {
2989         local -a scripts
2990         scripts=( /etc/init.d/*(x:t) )
2991         _describe "service startup script" scripts
2992     }
2993
2994     for i in Start Restart Stop Force-Reload Reload Status ; do
2995         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2996         compdef _grmlinitd $i
2997     done
2998     builtin unset -v i
2999 fi
3000
3001 #f1# Provides useful information on globbing
3002 H-Glob() {
3003     echo -e "
3004     /      directories
3005     .      plain files
3006     @      symbolic links
3007     =      sockets
3008     p      named pipes (FIFOs)
3009     *      executable plain files (0100)
3010     %      device files (character or block special)
3011     %b     block special files
3012     %c     character special files
3013     r      owner-readable files (0400)
3014     w      owner-writable files (0200)
3015     x      owner-executable files (0100)
3016     A      group-readable files (0040)
3017     I      group-writable files (0020)
3018     E      group-executable files (0010)
3019     R      world-readable files (0004)
3020     W      world-writable files (0002)
3021     X      world-executable files (0001)
3022     s      setuid files (04000)
3023     S      setgid files (02000)
3024     t      files with the sticky bit (01000)
3025
3026   print *(m-1)          # Files modified up to a day ago
3027   print *(a1)           # Files accessed a day ago
3028   print *(@)            # Just symlinks
3029   print *(Lk+50)        # Files bigger than 50 kilobytes
3030   print *(Lk-50)        # Files smaller than 50 kilobytes
3031   print **/*.c          # All *.c files recursively starting in \$PWD
3032   print **/*.c~file.c   # Same as above, but excluding 'file.c'
3033   print (foo|bar).*     # Files starting with 'foo' or 'bar'
3034   print *~*.*           # All Files that do not contain a dot
3035   chmod 644 *(.^x)      # make all plain non-executable files publically readable
3036   print -l *(.c|.h)     # Lists *.c and *.h
3037   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
3038   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
3039 }
3040 alias help-zshglob=H-Glob
3041
3042 # grep for running process, like: 'any vim'
3043 any() {
3044     emulate -L zsh
3045     unsetopt KSH_ARRAYS
3046     if [[ -z "$1" ]] ; then
3047         echo "any - grep for process(es) by keyword" >&2
3048         echo "Usage: any <keyword>" >&2 ; return 1
3049     else
3050         ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
3051     fi
3052 }
3053
3054
3055 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
3056 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
3057 [[ -r /proc/1/maps ]] && \
3058 deswap() {
3059     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
3060     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
3061     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
3062 }
3063
3064 # a wrapper for vim, that deals with title setting
3065 #   VIM_OPTIONS
3066 #       set this array to a set of options to vim you always want
3067 #       to have set when calling vim (in .zshrc.local), like:
3068 #           VIM_OPTIONS=( -p )
3069 #       This will cause vim to send every file given on the
3070 #       commandline to be send to it's own tab (needs vim7).
3071 if check_com vim; then
3072     vim() {
3073         VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
3074     }
3075 fi
3076
3077 ssl_hashes=( sha512 sha256 sha1 md5 )
3078
3079 for sh in ${ssl_hashes}; do
3080     eval 'ssl-cert-'${sh}'() {
3081         emulate -L zsh
3082         if [[ -z $1 ]] ; then
3083             printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
3084             return 1
3085         fi
3086         openssl x509 -noout -fingerprint -'${sh}' -in $1
3087     }'
3088 done; unset sh
3089
3090 ssl-cert-fingerprints() {
3091     emulate -L zsh
3092     local i
3093     if [[ -z $1 ]] ; then
3094         printf 'usage: ssl-cert-fingerprints <file>\n'
3095         return 1
3096     fi
3097     for i in ${ssl_hashes}
3098         do ssl-cert-$i $1;
3099     done
3100 }
3101
3102 ssl-cert-info() {
3103     emulate -L zsh
3104     if [[ -z $1 ]] ; then
3105         printf 'usage: ssl-cert-info <file>\n'
3106         return 1
3107     fi
3108     openssl x509 -noout -text -in $1
3109     ssl-cert-fingerprints $1
3110 }
3111
3112 # make sure our environment is clean regarding colors
3113 for var in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $var
3114 builtin unset -v var
3115
3116 # "persistent history"
3117 # just write important commands you always need to ~/.important_commands
3118 if [[ -r ~/.important_commands ]] ; then
3119     fc -R ~/.important_commands
3120 fi
3121
3122 # load the lookup subsystem if it's available on the system
3123 zrcautoload lookupinit && lookupinit
3124
3125 # variables
3126
3127 # set terminal property (used e.g. by msgid-chooser)
3128 export COLORTERM="yes"
3129
3130 # aliases
3131
3132 # general
3133 #a2# Execute \kbd{du -sch}
3134 alias da='du -sch'
3135
3136 # listing stuff
3137 #a2# Execute \kbd{ls -lSrah}
3138 alias dir="command ls -lSrah"
3139 #a2# Only show dot-directories
3140 alias lad='command ls -d .*(/)'
3141 #a2# Only show dot-files
3142 alias lsa='command ls -a .*(.)'
3143 #a2# Only files with setgid/setuid/sticky flag
3144 alias lss='command ls -l *(s,S,t)'
3145 #a2# Only show symlinks
3146 alias lsl='command ls -l *(@)'
3147 #a2# Display only executables
3148 alias lsx='command ls -l *(*)'
3149 #a2# Display world-{readable,writable,executable} files
3150 alias lsw='command ls -ld *(R,W,X.^ND/)'
3151 #a2# Display the ten biggest files
3152 alias lsbig="command ls -flh *(.OL[1,10])"
3153 #a2# Only show directories
3154 alias lsd='command ls -d *(/)'
3155 #a2# Only show empty directories
3156 alias lse='command ls -d *(/^F)'
3157 #a2# Display the ten newest files
3158 alias lsnew="command ls -rtlh *(D.om[1,10])"
3159 #a2# Display the ten oldest files
3160 alias lsold="command ls -rtlh *(D.Om[1,10])"
3161 #a2# Display the ten smallest files
3162 alias lssmall="command ls -Srl *(.oL[1,10])"
3163 #a2# Display the ten newest directories and ten newest .directories
3164 alias lsnewdir="command ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
3165 #a2# Display the ten oldest directories and ten oldest .directories
3166 alias lsolddir="command ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
3167
3168 # some useful aliases
3169 #a2# Remove current empty directory. Execute \kbd{cd ..; rmdir \$OLDCWD}
3170 alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
3171
3172 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3173 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3174 #a2# scp with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3175 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3176
3177 # work around non utf8 capable software in utf environment via $LANG and luit
3178 if check_com isutfenv && check_com luit ; then
3179     if check_com -c mrxvt ; then
3180         isutfenv && [[ -n "$LANG" ]] && \
3181             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3182     fi
3183
3184     if check_com -c aterm ; then
3185         isutfenv && [[ -n "$LANG" ]] && \
3186             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3187     fi
3188
3189     if check_com -c centericq ; then
3190         isutfenv && [[ -n "$LANG" ]] && \
3191             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3192     fi
3193 fi
3194
3195 # useful functions
3196
3197 #f5# Backup \kbd{file_or_folder {\rm to} file_or_folder\_timestamp}
3198 bk() {
3199     emulate -L zsh
3200     local current_date=$(date -u "+%Y-%m-%dT%H:%M:%SZ")
3201     local clean keep move verbose result all to_bk
3202     setopt extended_glob
3203     keep=1
3204     while getopts ":hacmrv" opt; do
3205         case $opt in
3206             a) (( all++ ));;
3207             c) unset move clean && (( ++keep ));;
3208             m) unset keep clean && (( ++move ));;
3209             r) unset move keep && (( ++clean ));;
3210             v) verbose="-v";;
3211             h) <<__EOF0__
3212 bk [-hcmv] FILE [FILE ...]
3213 bk -r [-av] [FILE [FILE ...]]
3214 Backup a file or folder in place and append the timestamp
3215 Remove backups of a file or folder, or all backups in the current directory
3216
3217 Usage:
3218 -h    Display this help text
3219 -c    Keep the file/folder as is, create a copy backup using cp(1) (default)
3220 -m    Move the file/folder, using mv(1)
3221 -r    Remove backups of the specified file or directory, using rm(1). If none
3222       is provided, remove all backups in the current directory.
3223 -a    Remove all (even hidden) backups.
3224 -v    Verbose
3225
3226 The -c, -r and -m options are mutually exclusive. If specified at the same time,
3227 the last one is used.
3228
3229 The return code is the sum of all cp/mv/rm return codes.
3230 __EOF0__
3231 return 0;;
3232             \?) bk -h >&2; return 1;;
3233         esac
3234     done
3235     shift "$((OPTIND-1))"
3236     if (( keep > 0 )); then
3237         if islinux || isfreebsd; then
3238             for to_bk in "$@"; do
3239                 cp $verbose -a "${to_bk%/}" "${to_bk%/}_$current_date"
3240                 (( result += $? ))
3241             done
3242         else
3243             for to_bk in "$@"; do
3244                 cp $verbose -pR "${to_bk%/}" "${to_bk%/}_$current_date"
3245                 (( result += $? ))
3246             done
3247         fi
3248     elif (( move > 0 )); then
3249         while (( $# > 0 )); do
3250             mv $verbose "${1%/}" "${1%/}_$current_date"
3251             (( result += $? ))
3252             shift
3253         done
3254     elif (( clean > 0 )); then
3255         if (( $# > 0 )); then
3256             for to_bk in "$@"; do
3257                 rm $verbose -rf "${to_bk%/}"_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3258                 (( result += $? ))
3259             done
3260         else
3261             if (( all > 0 )); then
3262                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z(D)
3263             else
3264                 rm $verbose -rf *_[0-9](#c4,)-(0[0-9]|1[0-2])-([0-2][0-9]|3[0-1])T([0-1][0-9]|2[0-3])(:[0-5][0-9])(#c2)Z
3265             fi
3266             (( result += $? ))
3267         fi
3268     fi
3269     return $result
3270 }
3271
3272 #f5# cd to directoy and list files
3273 cl() {
3274     emulate -L zsh
3275     cd $1 && ls -a
3276 }
3277
3278 # smart cd function, allows switching to /etc when running 'cd /etc/fstab'
3279 cd() {
3280     if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
3281         [[ ! -e ${1:h} ]] && return 1
3282         print "Correcting ${1} to ${1:h}"
3283         builtin cd ${1:h}
3284     else
3285         builtin cd "$@"
3286     fi
3287 }
3288
3289 #f5# Create Directoy and \kbd{cd} to it
3290 mkcd() {
3291     if (( ARGC != 1 )); then
3292         printf 'usage: mkcd <new-directory>\n'
3293         return 1;
3294     fi
3295     if [[ ! -d "$1" ]]; then
3296         command mkdir -p "$1"
3297     else
3298         printf '`%s'\'' already exists: cd-ing.\n' "$1"
3299     fi
3300     builtin cd "$1"
3301 }
3302
3303 #f5# Create temporary directory and \kbd{cd} to it
3304 cdt() {
3305     builtin cd "$(mktemp -d)"
3306     builtin pwd
3307 }
3308
3309 #f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
3310 accessed() {
3311     emulate -L zsh
3312     print -l -- *(a-${1:-1})
3313 }
3314
3315 #f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
3316 changed() {
3317     emulate -L zsh
3318     print -l -- *(c-${1:-1})
3319 }
3320
3321 #f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
3322 modified() {
3323     emulate -L zsh
3324     print -l -- *(m-${1:-1})
3325 }
3326 # modified() was named new() in earlier versions, add an alias for backwards compatibility
3327 check_com new || alias new=modified
3328
3329 # use colors when GNU grep with color-support
3330 if (( $#grep_options > 0 )); then
3331     o=${grep_options:+"${grep_options[*]}"}
3332     #a2# Execute \kbd{grep -{}-color=auto}
3333     alias grep='grep '$o
3334     alias egrep='egrep '$o
3335     unset o
3336 fi
3337
3338 # Translate DE<=>EN
3339 # 'translate' looks up a word in a file with language-to-language
3340 # translations (field separator should be " : "). A typical wordlist looks
3341 # like the following:
3342 #  | english-word : german-translation
3343 # It's also only possible to translate english to german but not reciprocal.
3344 # Use the following oneliner to reverse the sort order:
3345 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3346 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3347 #f5# Translates a word
3348 trans() {
3349     emulate -L zsh
3350     case "$1" in
3351         -[dD]*)
3352             translate -l de-en $2
3353             ;;
3354         -[eE]*)
3355             translate -l en-de $2
3356             ;;
3357         *)
3358             echo "Usage: $0 { -D | -E }"
3359             echo "         -D == German to English"
3360             echo "         -E == English to German"
3361     esac
3362 }
3363
3364 # Usage: simple-extract <file>
3365 # Using option -d deletes the original archive file.
3366 #f5# Smart archive extractor
3367 simple-extract() {
3368     emulate -L zsh
3369     setopt extended_glob noclobber
3370     local ARCHIVE DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
3371     local RC=0
3372     zparseopts -D -E "d=DELETE_ORIGINAL"
3373     for ARCHIVE in "${@}"; do
3374         case $ARCHIVE in
3375             *(tar.bz2|tbz2|tbz))
3376                 DECOMP_CMD="tar -xvjf -"
3377                 USES_STDIN=true
3378                 USES_STDOUT=false
3379                 ;;
3380             *(tar.gz|tgz))
3381                 DECOMP_CMD="tar -xvzf -"
3382                 USES_STDIN=true
3383                 USES_STDOUT=false
3384                 ;;
3385             *(tar.xz|txz|tar.lzma))
3386                 DECOMP_CMD="tar -xvJf -"
3387                 USES_STDIN=true
3388                 USES_STDOUT=false
3389                 ;;
3390             *tar)
3391                 DECOMP_CMD="tar -xvf -"
3392                 USES_STDIN=true
3393                 USES_STDOUT=false
3394                 ;;
3395             *rar)
3396                 DECOMP_CMD="unrar x"
3397                 USES_STDIN=false
3398                 USES_STDOUT=false
3399                 ;;
3400             *lzh)
3401                 DECOMP_CMD="lha x"
3402                 USES_STDIN=false
3403                 USES_STDOUT=false
3404                 ;;
3405             *7z)
3406                 DECOMP_CMD="7z x"
3407                 USES_STDIN=false
3408                 USES_STDOUT=false
3409                 ;;
3410             *(zip|jar))
3411                 DECOMP_CMD="unzip"
3412                 USES_STDIN=false
3413                 USES_STDOUT=false
3414                 ;;
3415             *deb)
3416                 DECOMP_CMD="ar -x"
3417                 USES_STDIN=false
3418                 USES_STDOUT=false
3419                 ;;
3420             *bz2)
3421                 DECOMP_CMD="bzip2 -d -c -"
3422                 USES_STDIN=true
3423                 USES_STDOUT=true
3424                 ;;
3425             *(gz|Z))
3426                 DECOMP_CMD="gzip -d -c -"
3427                 USES_STDIN=true
3428                 USES_STDOUT=true
3429                 ;;
3430             *(xz|lzma))
3431                 DECOMP_CMD="xz -d -c -"
3432                 USES_STDIN=true
3433                 USES_STDOUT=true
3434                 ;;
3435             *)
3436                 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
3437                 RC=$((RC+1))
3438                 continue
3439                 ;;
3440         esac
3441
3442         if ! check_com ${DECOMP_CMD[(w)1]}; then
3443             echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
3444             RC=$((RC+2))
3445             continue
3446         fi
3447
3448         GZTARGET="${ARCHIVE:t:r}"
3449         if [[ -f $ARCHIVE ]] ; then
3450
3451             print "Extracting '$ARCHIVE' ..."
3452             if $USES_STDIN; then
3453                 if $USES_STDOUT; then
3454                     ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3455                 else
3456                     ${=DECOMP_CMD} < "$ARCHIVE"
3457                 fi
3458             else
3459                 if $USES_STDOUT; then
3460                     ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3461                 else
3462                     ${=DECOMP_CMD} "$ARCHIVE"
3463                 fi
3464             fi
3465             [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3466
3467         elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3468             if check_com curl; then
3469                 WGET_CMD="curl -L -s -o -"
3470             elif check_com wget; then
3471                 WGET_CMD="wget -q -O -"
3472             elif check_com fetch; then
3473                 WGET_CMD="fetch -q -o -"
3474             else
3475                 print "ERROR: neither wget, curl nor fetch is installed" >&2
3476                 RC=$((RC+4))
3477                 continue
3478             fi
3479             print "Downloading and Extracting '$ARCHIVE' ..."
3480             if $USES_STDIN; then
3481                 if $USES_STDOUT; then
3482                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3483                     RC=$((RC+$?))
3484                 else
3485                     ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3486                     RC=$((RC+$?))
3487                 fi
3488             else
3489                 if $USES_STDOUT; then
3490                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3491                 else
3492                     ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3493                 fi
3494             fi
3495
3496         else
3497             print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3498             RC=$((RC+8))
3499         fi
3500     done
3501     return $RC
3502 }
3503
3504 __archive_or_uri()
3505 {
3506     _alternative \
3507         'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3508         '_urls:Remote Archives:_urls'
3509 }
3510
3511 _simple_extract()
3512 {
3513     _arguments \
3514         '-d[delete original archivefile after extraction]' \
3515         '*:Archive Or Uri:__archive_or_uri'
3516 }
3517 compdef _simple_extract simple-extract
3518 alias se=simple-extract
3519
3520 #f5# Change the xterm title from within GNU-screen
3521 xtrename() {
3522     emulate -L zsh
3523     if [[ $1 != "-f" ]] ; then
3524         if [[ -z ${DISPLAY} ]] ; then
3525             printf 'xtrename only makes sense in X11.\n'
3526             return 1
3527         fi
3528     else
3529         shift
3530     fi
3531     if [[ -z $1 ]] ; then
3532         printf 'usage: xtrename [-f] "title for xterm"\n'
3533         printf '  renames the title of xterm from _within_ screen.\n'
3534         printf '  also works without screen.\n'
3535         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3536         return 0
3537     fi
3538     print -n "\eP\e]0;${1}\C-G\e\\"
3539     return 0
3540 }
3541
3542 # Create small urls via http://goo.gl using curl(1).
3543 # API reference: https://code.google.com/apis/urlshortener/
3544 function zurl() {
3545     emulate -L zsh
3546     setopt extended_glob
3547
3548     if [[ -z $1 ]]; then
3549         print "USAGE: zurl <URL>"
3550         return 1
3551     fi
3552
3553     local PN url prog api json contenttype item
3554     local -a data
3555     PN=$0
3556     url=$1
3557
3558     # Prepend 'http://' to given URL where necessary for later output.
3559     if [[ ${url} != http(s|)://* ]]; then
3560         url='http://'${url}
3561     fi
3562
3563     if check_com -c curl; then
3564         prog=curl
3565     else
3566         print "curl is not available, but mandatory for ${PN}. Aborting."
3567         return 1
3568     fi
3569     api='https://www.googleapis.com/urlshortener/v1/url'
3570     contenttype="Content-Type: application/json"
3571     json="{\"longUrl\": \"${url}\"}"
3572     data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
3573     # Parse the response
3574     for item in "${data[@]}"; do
3575         case "$item" in
3576             ' '#'"id":'*)
3577                 item=${item#*: \"}
3578                 item=${item%\",*}
3579                 printf '%s\n' "$item"
3580                 return 0
3581                 ;;
3582         esac
3583     done
3584     return 1
3585 }
3586
3587 #f2# Find history events by search pattern and list them by date.
3588 whatwhen()  {
3589     emulate -L zsh
3590     local usage help ident format_l format_s first_char remain first last
3591     usage='USAGE: whatwhen [options] <searchstring> <search range>'
3592     help='Use `whatwhen -h'\'' for further explanations.'
3593     ident=${(l,${#${:-Usage: }},, ,)}
3594     format_l="${ident}%s\t\t\t%s\n"
3595     format_s="${format_l//(\\t)##/\\t}"
3596     # Make the first char of the word to search for case
3597     # insensitive; e.g. [aA]
3598     first_char=[${(L)1[1]}${(U)1[1]}]
3599     remain=${1[2,-1]}
3600     # Default search range is `-100'.
3601     first=${2:-\-100}
3602     # Optional, just used for `<first> <last>' given.
3603     last=$3
3604     case $1 in
3605         ("")
3606             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3607             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3608         ;;
3609         (-h)
3610             printf '%s\n\n' ${usage}
3611             print 'OPTIONS:'
3612             printf $format_l '-h' 'show help text'
3613             print '\f'
3614             print 'SEARCH RANGE:'
3615             printf $format_l "'0'" 'the whole history,'
3616             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3617             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3618             printf '\n%s\n' 'EXAMPLES:'
3619             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3620             printf $format_l 'whatwhen zsh -250'
3621             printf $format_l 'whatwhen foo 1 99'
3622         ;;
3623         (\?)
3624             printf '%s\n%s\n\n' ${usage} ${help} && return 1
3625         ;;
3626         (*)
3627             # -l list results on stout rather than invoking $EDITOR.
3628             # -i Print dates as in YYYY-MM-DD.
3629             # -m Search for a - quoted - pattern within the history.
3630             fc -li -m "*${first_char}${remain}*" $first $last
3631         ;;
3632     esac
3633 }
3634
3635 # mercurial related stuff
3636 if check_com -c hg ; then
3637     # gnu like diff for mercurial
3638     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3639     #f5# GNU like diff for mercurial
3640     hgdi() {
3641         emulate -L zsh
3642         local i
3643         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3644     }
3645
3646     # build debian package
3647     #a2# Alias for \kbd{hg-buildpackage}
3648     alias hbp='hg-buildpackage'
3649
3650     # execute commands on the versioned patch-queue from the current repos
3651     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3652
3653     # diffstat for specific version of a mercurial repository
3654     #   hgstat      => display diffstat between last revision and tip
3655     #   hgstat 1234 => display diffstat between revision 1234 and tip
3656     #f5# Diffstat for specific version of a mercurial repos
3657     hgstat() {
3658         emulate -L zsh
3659         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3660     }
3661
3662 fi # end of check whether we have the 'hg'-executable
3663
3664 # grml-small cleanups
3665
3666 # The following is used to remove zsh-config-items that do not work
3667 # in grml-small by default.
3668 # If you do not want these adjustments (for whatever reason), set
3669 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3670 # sources if it is there).
3671
3672 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3673
3674     unset abk[V]
3675     unalias    'V'      &> /dev/null
3676     unfunction vman     &> /dev/null
3677     unfunction viless   &> /dev/null
3678     unfunction 2html    &> /dev/null
3679
3680     # manpages are not in grmlsmall
3681     unfunction manzsh   &> /dev/null
3682     unfunction man2     &> /dev/null
3683
3684 fi
3685
3686 zrclocal
3687
3688 ## genrefcard.pl settings
3689
3690 ### doc strings for external functions from files
3691 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3692
3693 ### example: split functions-search 8,16,24,32
3694 #@# split functions-search 8
3695
3696 ## END OF FILE #################################################################
3697 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3698 # Local variables:
3699 # mode: sh
3700 # End: