etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # Contributing:
  15 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  16 # repository from git.grml.org:
  17 #   git clone git://git.grml.org/grml-etc-core.git
  18 #
  19 # Make your changes, commit them; use 'git format-patch' to create a series
  20 # of patches and send those to the following address via 'git send-email':
  21 #   grml-etc-core@grml.org
  22 #
  23 # Doing so makes sure the right people get your patches for review and
  24 # possibly inclusion.
  25
  26 # zsh-refcard-tag documentation: {{{
  27 #   You may notice strange looking comments in this file.
  28 #   These are there for a purpose. grml's zsh-refcard can now be
  29 #   automatically generated from the contents of the actual configuration
  30 #   file. However, we need a little extra information on which comments
  31 #   and what lines of code to take into account (and for what purpose).
  32 #
  33 # Here is what they mean:
  34 #
  35 # List of tags (comment types) used:
  36 #   #a#     Next line contains an important alias, that should
  37 #           be included in the grml-zsh-refcard.
  38 #           (placement tag: @@INSERT-aliases@@)
  39 #   #f#     Next line contains the beginning of an important function.
  40 #           (placement tag: @@INSERT-functions@@)
  41 #   #v#     Next line contains an important variable.
  42 #           (placement tag: @@INSERT-variables@@)
  43 #   #k#     Next line contains an important keybinding.
  44 #           (placement tag: @@INSERT-keybindings@@)
  45 #   #d#     Hashed directories list generation:
  46 #               start   denotes the start of a list of 'hash -d'
  47 #                       definitions.
  48 #               end     denotes its end.
  49 #           (placement tag: @@INSERT-hasheddirs@@)
  50 #   #A#     Abbreviation expansion list generation:
  51 #               start   denotes the beginning of abbreviations.
  52 #               end     denotes their end.
  53 #           Lines within this section that end in '#d .*' provide
  54 #           extra documentation to be included in the refcard.
  55 #           (placement tag: @@INSERT-abbrev@@)
  56 #   #m#     This tag allows you to manually generate refcard entries
  57 #           for code lines that are hard/impossible to parse.
  58 #               Example:
  59 #                   #m# k ESC-h Call the run-help function
  60 #               That would add a refcard entry in the keybindings table
  61 #               for 'ESC-h' with the given comment.
  62 #           So the syntax is: #m# <section> <argument> <comment>
  63 #   #o#     This tag lets you insert entries to the 'other' hash.
  64 #           Generally, this should not be used. It is there for
  65 #           things that cannot be done easily in another way.
  66 #           (placement tag: @@INSERT-other-foobar@@)
  67 #
  68 #   All of these tags (except for m and o) take two arguments, the first
  69 #   within the tag, the other after the tag:
  70 #
  71 #   #<tag><section># <comment>
  72 #
  73 #   Where <section> is really just a number, which are defined by the
  74 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  75 #   instead of names is, that for the reader, the tag should not differ
  76 #   much from a regular comment. For zsh, it is a regular comment indeed.
  77 #   The numbers have got the following meanings:
  78 #         0 -> "default"
  79 #         1 -> "system"
  80 #         2 -> "user"
  81 #         3 -> "debian"
  82 #         4 -> "search"
  83 #         5 -> "shortcuts"
  84 #         6 -> "services"
  85 #
  86 #   So, the following will add an entry to the 'functions' table in the
  87 #   'system' section, with a (hopefully) descriptive comment:
  88 #       #f1# Edit an alias via zle
  89 #       edalias() {
  90 #
  91 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  92 #   that can be found in 'grml-zsh-refcard.tex.in'.
  93 #   If the section number is omitted, the 'default' section is assumed.
  94 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  95 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  96 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  97 #}}}
  98
  99 # zsh profiling {{{
 100 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 101 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 102     zmodload zsh/zprof
 103 fi
 104 # }}}
 105
 106 # load .zshrc.pre to give the user the chance to overwrite the defaults
 107 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 108
 109 # {{{ check for version/system
 110 # check for versions (compatibility reasons)
 111 is4(){
 112     [[ $ZSH_VERSION == <4->* ]] && return 0
 113     return 1
 114 }
 115
 116 is41(){
 117     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 118     return 1
 119 }
 120
 121 is42(){
 122     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is425(){
 127     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is43(){
 132     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is433(){
 137     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 #f1# Checks whether or not you're running grml
 142 isgrml(){
 143     [[ -f /etc/grml_version ]] && return 0
 144     return 1
 145 }
 146
 147 #f1# Checks whether or not you're running a grml cd
 148 isgrmlcd(){
 149     [[ -f /etc/grml_cd ]] && return 0
 150     return 1
 151 }
 152
 153 if isgrml ; then
 154 #f1# Checks whether or not you're running grml-small
 155     isgrmlsmall() {
 156         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 157     }
 158 else
 159     isgrmlsmall() { return 1 }
 160 fi
 161
 162 isdarwin(){
 163     [[ $OSTYPE == darwin* ]] && return 0
 164     return 1
 165 }
 166
 167 #f1# are we running within an utf environment?
 168 isutfenv() {
 169     case "$LANG $CHARSET $LANGUAGE" in
 170         *utf*) return 0 ;;
 171         *UTF*) return 0 ;;
 172         *)     return 1 ;;
 173     esac
 174 }
 175
 176 # check for user, if not running as root set $SUDO to sudo
 177 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 178
 179 # change directory to home on first invocation of zsh
 180 # important for rungetty -> autologin
 181 # Thanks go to Bart Schaefer!
 182 isgrml && checkhome() {
 183     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 184         export ALREADY_DID_CD_HOME=$HOME
 185         cd
 186     fi
 187 }
 188
 189 # check for zsh v3.1.7+
 190
 191 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 192      || ${ZSH_VERSION} == 3.<2->.<->*    \
 193      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 194
 195     printf '-!-\n'
 196     printf '-!- In this configuration we try to make use of features, that only\n'
 197     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 198     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 199     printf '-!- advanced features in all supported versions.\n'
 200     printf '-!-\n'
 201     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 202     printf '-!-\n'
 203     printf '-!- While this *may* work, it might as well fail.\n'
 204     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 205     printf '-!-\n'
 206     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 207     printf '-!- If it does today, you'\''ve been lucky.\n'
 208     printf '-!-\n'
 209     printf '-!- Ye been warned!\n'
 210     printf '-!-\n'
 211
 212     function zstyle() { : }
 213 fi
 214
 215 # autoload wrapper - use this one instead of autoload directly
 216 # We need to define this function as early as this, because autoloading
 217 # 'is-at-least()' needs it.
 218 function zrcautoload() {
 219     emulate -L zsh
 220     setopt extended_glob
 221     local fdir ffile
 222     local -i ffound
 223
 224     ffile=$1
 225     (( found = 0 ))
 226     for fdir in ${fpath} ; do
 227         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 228     done
 229
 230     (( ffound == 0 )) && return 1
 231     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 232         autoload -U ${ffile} || return 1
 233     else
 234         autoload ${ffile} || return 1
 235     fi
 236     return 0
 237 }
 238
 239 # Load is-at-least() for more precise version checks
 240 # Note that this test will *always* fail, if the is-at-least
 241 # function could not be marked for autoloading.
 242 zrcautoload is-at-least || is-at-least() { return 1 }
 243
 244 # }}}
 245
 246 # {{{ set some important options (as early as possible)
 247 # Please update these tags, if you change the umask settings below.
 248 #o# r_umask     002
 249 #o# r_umaskstr  rwxrwxr-x
 250 #o# umask       022
 251 #o# umaskstr    rwxr-xr-x
 252 (( EUID != 0 )) && umask 002 || umask 022
 253
 254 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 255 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 256 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 257 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
 258                             # list duplicates an older one, the older command is removed from the list
 259 setopt histignorespace      # remove command lines from the history list when
 260                             # the first character on the line is a space
 261 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
 262                             # and the command is the name of a directory, perform the cd command to that directory
 263 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
 264                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
 265                             # -> searches for word not in compressed files
 266                             # don't forget to quote '^', '~' and '#'!
 267 setopt longlistjobs         # display PID when suspending processes as well
 268 setopt notify               # report the status of backgrounds jobs immediately
 269 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
 270                             # the entire command path is hashed first.
 271 setopt completeinword       # not just at the end
 272 setopt nohup                # and don't kill them, either
 273 setopt auto_pushd           # make cd push the old directory onto the directory stack.
 274 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
 275 setopt nobeep               # avoid "beep"ing
 276 setopt pushd_ignore_dups    # don't push the same dir twice.
 277 setopt noglobdots           # * shouldn't match dotfiles. ever.
 278 setopt noshwordsplit        # use zsh style word splitting
 279
 280 # }}}
 281
 282 # setting some default values {{{
 283
 284 NOCOR=${NOCOR:-0}
 285 NOMENU=${NOMENU:-0}
 286 NOPRECMD=${NOPRECMD:-0}
 287 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 288 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 289 BATTERY=${BATTERY:-0}
 290 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 291 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 292 ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
 293
 294 # }}}
 295
 296 # utility functions {{{
 297 # this function checks if a command exists and returns either true
 298 # or false. This avoids using 'which' and 'whence', which will
 299 # avoid problems with aliases for which on certain weird systems. :-)
 300 # Usage: check_com [-c|-g] word
 301 #   -c  only checks for external commands
 302 #   -g  does the usual tests and also checks for global aliases
 303 check_com() {
 304     emulate -L zsh
 305     local -i comonly gatoo
 306
 307     if [[ $1 == '-c' ]] ; then
 308         (( comonly = 1 ))
 309         shift
 310     elif [[ $1 == '-g' ]] ; then
 311         (( gatoo = 1 ))
 312     else
 313         (( comonly = 0 ))
 314         (( gatoo = 0 ))
 315     fi
 316
 317     if (( ${#argv} != 1 )) ; then
 318         printf 'usage: check_com [-c] <command>\n' >&2
 319         return 1
 320     fi
 321
 322     if (( comonly > 0 )) ; then
 323         [[ -n ${commands[$1]}  ]] && return 0
 324         return 1
 325     fi
 326
 327     if   [[ -n ${commands[$1]}    ]] \
 328       || [[ -n ${functions[$1]}   ]] \
 329       || [[ -n ${aliases[$1]}     ]] \
 330       || [[ -n ${reswords[(r)$1]} ]] ; then
 331
 332         return 0
 333     fi
 334
 335     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 336         return 0
 337     fi
 338
 339     return 1
 340 }
 341
 342 # creates an alias and precedes the command with
 343 # sudo if $EUID is not zero.
 344 salias() {
 345     emulate -L zsh
 346     local only=0 ; local multi=0
 347     while [[ $1 == -* ]] ; do
 348         case $1 in
 349             (-o) only=1 ;;
 350             (-a) multi=1 ;;
 351             (--) shift ; break ;;
 352             (-h)
 353                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 354                 printf '  -h      shows this help text.\n'
 355                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 356                 printf '          be careful using this option.\n'
 357                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 358                 return 0
 359                 ;;
 360             (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
 361         esac
 362         shift
 363     done
 364
 365     if (( ${#argv} > 1 )) ; then
 366         printf 'Too many arguments %s\n' "${#argv}"
 367         return 1
 368     fi
 369
 370     key="${1%%\=*}" ;  val="${1#*\=}"
 371     if (( EUID == 0 )) && (( only == 0 )); then
 372         alias -- "${key}=${val}"
 373     elif (( EUID > 0 )) ; then
 374         (( multi > 0 )) && val="${val// ; / ; sudo }"
 375         alias -- "${key}=sudo ${val}"
 376     fi
 377
 378     return 0
 379 }
 380
 381 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 382 # usage: uprint foo
 383 #   Where foo is the *name* of the parameter you want printed.
 384 #   Note that foo is no typo; $foo would be wrong here!
 385 if ! is42 ; then
 386     uprint () {
 387         emulate -L zsh
 388         local -a u
 389         local w
 390         local parameter=$1
 391
 392         if [[ -z ${parameter} ]] ; then
 393             printf 'usage: uprint <parameter>\n'
 394             return 1
 395         fi
 396
 397         for w in ${(P)parameter} ; do
 398             [[ -z ${(M)u:#$w} ]] && u=( $u $w )
 399         done
 400
 401         builtin print -l $u
 402     }
 403 fi
 404
 405 # Check if we can read given files and source those we can.
 406 xsource() {
 407     emulate -L zsh
 408     if (( ${#argv} < 1 )) ; then
 409         printf 'usage: xsource FILE(s)...\n' >&2
 410         return 1
 411     fi
 412
 413     while (( ${#argv} > 0 )) ; do
 414         [[ -r $1 ]] && source $1
 415         shift
 416     done
 417     return 0
 418 }
 419
 420 # Check if we can read a given file and 'cat(1)' it.
 421 xcat() {
 422     emulate -L zsh
 423     if (( ${#argv} != 1 )) ; then
 424         printf 'usage: xcat FILE\n' >&2
 425         return 1
 426     fi
 427
 428     [[ -r $1 ]] && cat $1
 429     return 0
 430 }
 431
 432 # Remove these functions again, they are of use only in these
 433 # setup files. This should be called at the end of .zshrc.
 434 xunfunction() {
 435     emulate -L zsh
 436     local -a funcs
 437     funcs=(salias xcat xsource xunfunction zrcautoload)
 438
 439     for func in $funcs ; do
 440         [[ -n ${functions[$func]} ]] \
 441             && unfunction $func
 442     done
 443     return 0
 444 }
 445
 446 # this allows us to stay in sync with grml's zshrc and put own
 447 # modifications in ~/.zshrc.local
 448 zrclocal() {
 449     xsource "/etc/zsh/zshrc.local"
 450     xsource "${HOME}/.zshrc.local"
 451     return 0
 452 }
 453
 454 #}}}
 455
 456 # locale setup {{{
 457 if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
 458     xsource "/etc/default/locale"
 459 fi
 460
 461 for var in LANG LC_ALL LC_MESSAGES ; do
 462     [[ -n ${(P)var} ]] && export $var
 463 done
 464
 465 xsource "/etc/sysconfig/keyboard"
 466
 467 TZ=$(xcat /etc/timezone)
 468 # }}}
 469
 470 # check for potentially old files in 'completion.d' {{{
 471 setopt extendedglob
 472 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 473 if (( ${#xof} > 0 )) ; then
 474     printf '\n -!- INFORMATION\n\n'
 475     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 476     printf ' -!- /etc/zsh/completion.d/.\n\n'
 477     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 478     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 479     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 480     printf ' -!- named _* to that directory.\n\n'
 481     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 482     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 483     printf ' -!- starting with an underscore are marked for automatic loading\n'
 484     printf ' -!- by default (so that is quite convenient).\n\n'
 485     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 486     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 487     printf ' -!- Delete the files for example via running:\n\n'
 488     printf "      rm ${xof}\n\n"
 489     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 490     printf ' -!- resolve the situation manually.\n\n'
 491     BROKEN_COMPLETION_DIR=1
 492 fi
 493 unset xof
 494 # }}}
 495
 496 # {{{ set some variables
 497 if check_com -c vim ; then
 498 #v#
 499     export EDITOR=${EDITOR:-vim}
 500 else
 501     export EDITOR=${EDITOR:-vi}
 502 fi
 503
 504 #v#
 505 export PAGER=${PAGER:-less}
 506
 507 #v#
 508 export MAIL=${MAIL:-/var/mail/$USER}
 509
 510 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 511 export SHELL='/bin/zsh'
 512
 513 # color setup for ls:
 514 check_com -c dircolors && eval $(dircolors -b)
 515 # color setup for ls on OS X:
 516 isdarwin && export CLICOLOR=1
 517
 518 # do MacPorts setup on darwin
 519 if isdarwin && [[ -d /opt/local ]]; then
 520     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 521     # zshenv.
 522     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 523     MANPATH="/opt/local/share/man:$MANPATH"
 524 fi
 525 # do Fink setup on darwin
 526 isdarwin && xsource /sw/bin/init.sh
 527
 528 # load our function and completion directories
 529 for fdir in /usr/share/grml/zsh/completion /usr/share/grml/functions; do
 530     fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 531     if [[ ${fpath} == '/usr/share/grml/zsh/functions' ]] ; then
 532         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 533             zrcautoload ${func:t}
 534         done
 535     fi
 536 done
 537 unset fdir func
 538
 539 # support colors in less
 540 export LESS_TERMCAP_mb=$'\E[01;31m'
 541 export LESS_TERMCAP_md=$'\E[01;31m'
 542 export LESS_TERMCAP_me=$'\E[0m'
 543 export LESS_TERMCAP_se=$'\E[0m'
 544 export LESS_TERMCAP_so=$'\E[01;44;33m'
 545 export LESS_TERMCAP_ue=$'\E[0m'
 546 export LESS_TERMCAP_us=$'\E[01;32m'
 547
 548 MAILCHECK=30       # mailchecks
 549 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
 550 watch=(notme root) # watch for everyone but me and root
 551
 552 # automatically remove duplicates from these arrays
 553 typeset -U path cdpath fpath manpath
 554 # }}}
 555
 556 # {{{ keybindings
 557 if [[ "$TERM" != emacs ]] ; then
 558     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 559     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 560     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 561     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 562     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 563     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 564     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 565     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 566     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 567     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 568     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 569     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 570     # ncurses stuff:
 571     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 572     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 573     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 574     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 575     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 576     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 577     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 578     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 579 fi
 580
 581 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 582 # use emacs style per default:
 583 bindkey -e
 584 # use vi style:
 585 # bindkey -v
 586
 587 #if [[ "$TERM" == screen ]] ; then
 588 bindkey '\e[1~' beginning-of-line       # home
 589 bindkey '\e[4~' end-of-line             # end
 590 bindkey '\e[A'  up-line-or-search       # cursor up
 591 bindkey '\e[B'  down-line-or-search     # <ESC>-
 592
 593 bindkey '^xp'   history-beginning-search-backward
 594 bindkey '^xP'   history-beginning-search-forward
 595 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 596 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 597 # if terminal type is set to 'rxvt':
 598 bindkey '\e[7~' beginning-of-line       # home
 599 bindkey '\e[8~' end-of-line             # end
 600 #fi
 601
 602 # insert unicode character
 603 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 604 # See for example http://unicode.org/charts/ for unicode characters code
 605 zrcautoload insert-unicode-char
 606 zle -N insert-unicode-char
 607 #k# Insert Unicode character
 608 bindkey '^Xi' insert-unicode-char
 609
 610 # just type 'cd ...' to get 'cd ../..'
 611 #  rationalise-dot() {
 612 #  if [[ $LBUFFER == *.. ]] ; then
 613 #    LBUFFER+=/..
 614 #  else
 615 #    LBUFFER+=.
 616 #  fi
 617 #  }
 618 #  zle -N rationalise-dot
 619 #  bindkey . rationalise-dot
 620
 621 #  bindkey '\eq' push-line-or-edit
 622
 623 ## toggle the ,. abbreviation feature on/off
 624 # NOABBREVIATION: default abbreviation-state
 625 #                 0 - enabled (default)
 626 #                 1 - disabled
 627 NOABBREVIATION=${NOABBREVIATION:-0}
 628
 629 grml_toggle_abbrev() {
 630     if (( ${NOABBREVIATION} > 0 )) ; then
 631         NOABBREVIATION=0
 632     else
 633         NOABBREVIATION=1
 634     fi
 635 }
 636
 637 zle -N grml_toggle_abbrev
 638 bindkey '^xA' grml_toggle_abbrev
 639
 640 # add a command line to the shells history without executing it
 641 commit-to-history() {
 642     print -s ${(z)BUFFER}
 643     zle send-break
 644 }
 645 zle -N commit-to-history
 646 bindkey "^x^h" commit-to-history
 647
 648 # only slash should be considered as a word separator:
 649 slash-backward-kill-word() {
 650     local WORDCHARS="${WORDCHARS:s@/@}"
 651     # zle backward-word
 652     zle backward-kill-word
 653 }
 654 zle -N slash-backward-kill-word
 655
 656 #k# Kill everything in a word up to its last \kbd{/}
 657 bindkey '\ev' slash-backward-kill-word
 658
 659 # }}}
 660
 661 # a generic accept-line wrapper {{{
 662
 663 # This widget can prevent unwanted autocorrections from command-name
 664 # to _command-name, rehash automatically on enter and call any number
 665 # of builtin and user-defined widgets in different contexts.
 666 #
 667 # For a broader description, see:
 668 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 669 #
 670 # The code is imported from the file 'zsh/functions/accept-line' from
 671 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 672 # distributed under the same terms as zsh itself.
 673
 674 # A newly added command will may not be found or will cause false
 675 # correction attempts, if you got auto-correction set. By setting the
 676 # following style, we force accept-line() to rehash, if it cannot
 677 # find the first word on the command line in the $command[] hash.
 678 zstyle ':acceptline:*' rehash true
 679
 680 function Accept-Line() {
 681     setopt localoptions noksharrays
 682     local -a subs
 683     local -xi aldone
 684     local sub
 685
 686     zstyle -a ":acceptline:${alcontext}" actions subs
 687
 688     (( ${#subs} < 1 )) && return 0
 689
 690     (( aldone = 0 ))
 691     for sub in ${subs} ; do
 692         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 693         zle ${sub}
 694
 695         (( aldone > 0 )) && break
 696     done
 697 }
 698
 699 function Accept-Line-getdefault() {
 700     local default_action
 701
 702     zstyle -s ":acceptline:${alcontext}" default_action default_action
 703     case ${default_action} in
 704         ((accept-line|))
 705             printf ".accept-line"
 706             ;;
 707         (*)
 708             printf ${default_action}
 709             ;;
 710     esac
 711 }
 712
 713 function accept-line() {
 714     setopt localoptions noksharrays
 715     local -a cmdline
 716     local -x alcontext
 717     local buf com fname format msg default_action
 718
 719     alcontext='default'
 720     buf="${BUFFER}"
 721     cmdline=(${(z)BUFFER})
 722     com="${cmdline[1]}"
 723     fname="_${com}"
 724
 725     zstyle -t ":acceptline:${alcontext}" rehash \
 726         && [[ -z ${commands[$com]} ]]           \
 727         && rehash
 728
 729     if    [[ -n ${reswords[(r)$com]} ]] \
 730        || [[ -n ${aliases[$com]}     ]] \
 731        || [[ -n ${functions[$com]}   ]] \
 732        || [[ -n ${builtins[$com]}    ]] \
 733        || [[ -n ${commands[$com]}    ]] ; then
 734
 735         # there is something sensible to execute, just do it.
 736         alcontext='normal'
 737         zle Accept-Line
 738
 739         default_action=$(Accept-Line-getdefault)
 740         zstyle -T ":acceptline:${alcontext}" call_default \
 741             && zle ${default_action}
 742         return
 743     fi
 744
 745     if    [[ -o correct              ]] \
 746        || [[ -o correctall           ]] \
 747        && [[ -n ${functions[$fname]} ]] ; then
 748
 749         # nothing there to execute but there is a function called
 750         # _command_name; a completion widget. Makes no sense to
 751         # call it on the commandline, but the correct{,all} options
 752         # will ask for it nevertheless, so warn the user.
 753         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 754             # Okay, we warned the user before, he called us again,
 755             # so have it his way.
 756             alcontext='force'
 757             zle Accept-Line
 758
 759             default_action=$(Accept-Line-getdefault)
 760             zstyle -T ":acceptline:${alcontext}" call_default \
 761                 && zle ${default_action}
 762             return
 763         fi
 764
 765         # prepare warning message for the user, configurable via zstyle.
 766         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 767
 768         if [[ -z ${msg} ]] ; then
 769             msg="%c will not execute and completion %f exists."
 770         fi
 771
 772         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 773
 774         zle -M -- "${msg}"
 775         return
 776     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 777         # If we are here, the commandline contains something that is not
 778         # executable, which is neither subject to _command_name correction
 779         # and is not empty. might be a variable assignment
 780         alcontext='misc'
 781         zle Accept-Line
 782
 783         default_action=$(Accept-Line-getdefault)
 784         zstyle -T ":acceptline:${alcontext}" call_default \
 785             && zle ${default_action}
 786         return
 787     fi
 788
 789     # If we got this far, the commandline only contains whitespace, or is empty.
 790     alcontext='empty'
 791     zle Accept-Line
 792
 793     default_action=$(Accept-Line-getdefault)
 794     zstyle -T ":acceptline:${alcontext}" call_default \
 795         && zle ${default_action}
 796 }
 797
 798 zle -N accept-line
 799 zle -N Accept-Line
 800
 801 # }}}
 802
 803 # power completion - abbreviation expansion {{{
 804 # power completion / abbreviation expansion / buffer expansion
 805 # see http://zshwiki.org/home/examples/zleiab for details
 806 # less risky than the global aliases but powerful as well
 807 # just type the abbreviation key and afterwards ',.' to expand it
 808 declare -A abk
 809 setopt extendedglob
 810 setopt interactivecomments
 811 abk=(
 812 #   key   # value                  (#d additional doc string)
 813 #A# start
 814     '...'  '../..'
 815     '....' '../../..'
 816     'BG'   '& exit'
 817     'C'    '| wc -l'
 818     'G'    '|& grep --color=auto '
 819     'H'    '| head'
 820     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 821     'L'    '| less'
 822     'LL'   '|& less -r'
 823     'M'    '| most'
 824     'N'    '&>/dev/null'           #d (No Output)
 825     'R'    '| tr A-z N-za-m'       #d (ROT13)
 826     'SL'   '| sort | less'
 827     'S'    '| sort -u'
 828     'T'    '| tail'
 829     'V'    '|& vim -'
 830 #A# end
 831     'co'   './configure && make && sudo make install'
 832 )
 833
 834 globalias() {
 835     emulate -L zsh
 836     setopt extendedglob
 837     local MATCH
 838
 839     if (( NOABBREVIATION > 0 )) ; then
 840         LBUFFER="${LBUFFER},."
 841         return 0
 842     fi
 843
 844     matched_chars='[.-|_a-zA-Z0-9]#'
 845     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 846     LBUFFER+=${abk[$MATCH]:-$MATCH}
 847 }
 848
 849 zle -N globalias
 850 bindkey ",." globalias
 851 # }}}
 852
 853 # {{{ autoloading
 854 zrcautoload zmv    # who needs mmv or rename?
 855 zrcautoload history-search-end
 856
 857 # we don't want to quote/espace URLs on our own...
 858 # if autoload -U url-quote-magic ; then
 859 #    zle -N self-insert url-quote-magic
 860 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 861 # else
 862 #    print 'Notice: no url-quote-magic available :('
 863 # fi
 864 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 865
 866 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 867 alias run-help >&/dev/null && unalias run-help
 868 for rh in run-help{,-git,-svk,-svn}; do
 869     zrcautoload $rh
 870 done; unset rh
 871
 872 # completion system
 873 if zrcautoload compinit ; then
 874     compinit || print 'Notice: no compinit available :('
 875 else
 876     print 'Notice: no compinit available :('
 877     function zstyle { }
 878     function compdef { }
 879 fi
 880
 881 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 882
 883 is4 && \
 884 for mod in complist deltochar mathfunc ; do
 885     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 886 done
 887
 888 # autoload zsh modules when they are referenced
 889 if is4 ; then
 890     tmpargs=(
 891         a   stat
 892         a   zpty
 893         ap  mapfile
 894     )
 895
 896     while (( ${#tmpargs} > 0 )) ; do
 897         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 898         shift 2 tmpargs
 899     done
 900     unset tmpargs
 901 fi
 902
 903 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 904     #k# Insert files
 905     bindkey "^Xf" insert-files # C-x-f
 906 fi
 907
 908 bindkey ' '   magic-space    # also do history expansion on space
 909 #k# Trigger menu-complete
 910 bindkey '\ei' menu-complete  # menu completion via esc-i
 911
 912 # press esc-e for editing command line in $EDITOR or $VISUAL
 913 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 914     #k# Edit the current line in \kbd{\$EDITOR}
 915     bindkey '\ee' edit-command-line
 916 fi
 917
 918 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 919     #k# menu selection: pick item but stay in the menu
 920     bindkey -M menuselect '\e^M' accept-and-menu-complete
 921
 922     # accept a completion and try to complete again by using menu
 923     # completion; very useful with completing directories
 924     # by using 'undo' one's got a simple file browser
 925     bindkey -M menuselect '^o' accept-and-infer-next-history
 926 fi
 927
 928 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 929 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 930 zle -N _bkdate
 931
 932 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 933 bindkey '^Ed' _bkdate
 934
 935 # press esc-m for inserting last typed word again (thanks to caphuso!)
 936 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 937 zle -N insert-last-typed-word;
 938
 939 #k# Insert last typed word
 940 bindkey "\em" insert-last-typed-word
 941
 942 #k# Shortcut for \kbd{fg<enter>}
 943 bindkey -s '^z' "fg\n"
 944
 945 # run command line as user root via sudo:
 946 sudo-command-line() {
 947     [[ -z $BUFFER ]] && zle up-history
 948     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 949 }
 950 zle -N sudo-command-line
 951
 952 #k# Put the current command line into a \kbd{sudo} call
 953 bindkey "^Os" sudo-command-line
 954
 955 ### jump behind the first word on the cmdline.
 956 ### useful to add options.
 957 function jump_after_first_word() {
 958     local words
 959     words=(${(z)BUFFER})
 960
 961     if (( ${#words} <= 1 )) ; then
 962         CURSOR=${#BUFFER}
 963     else
 964         CURSOR=${#${words[1]}}
 965     fi
 966 }
 967 zle -N jump_after_first_word
 968
 969 bindkey '^x1' jump_after_first_word
 970
 971 # }}}
 972
 973 # {{{ history
 974
 975 ZSHDIR=$HOME/.zsh
 976
 977 #v#
 978 HISTFILE=$HOME/.zsh_history
 979 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
 980 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
 981
 982 # }}}
 983
 984 # dirstack handling {{{
 985
 986 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
 987 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
 988
 989 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
 990     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
 991     # "cd -" won't work after login by just setting $OLDPWD, so
 992     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
 993 fi
 994
 995 chpwd() {
 996     local -ax my_stack
 997     my_stack=( ${PWD} ${dirstack} )
 998     if is42 ; then
 999         builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1000     else
1001         uprint my_stack >! ${DIRSTACKFILE}
1002     fi
1003 }
1004
1005 # }}}
1006
1007 # directory based profiles {{{
1008
1009 if is433 ; then
1010
1011 CHPWD_PROFILE='default'
1012 function chpwd_profiles() {
1013     # Say you want certain settings to be active in certain directories.
1014     # This is what you want.
1015     #
1016     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1017     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1018     #
1019     # When that's done and you enter a directory that matches the pattern
1020     # in the third part of the context, a function called chpwd_profile_grml,
1021     # for example, is called (if it exists).
1022     #
1023     # If no pattern matches (read: no profile is detected) the profile is
1024     # set to 'default', which means chpwd_profile_default is attempted to
1025     # be called.
1026     #
1027     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1028     # command) which is used: The third part in the context is matched against
1029     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1030     # Because that way the profile is detected for all these values of ${PWD}:
1031     #   /foo/bar
1032     #   /foo/bar/
1033     #   /foo/bar/baz
1034     # So, if you want to make double damn sure a profile works in /foo/bar
1035     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1036     #
1037     # The name of the detected profile will be available in a variable called
1038     # 'profile' in your functions. You don't need to do anything, it'll just
1039     # be there.
1040     #
1041     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1042     # was is currently active. That way you can avoid running code for a
1043     # profile that is already active, by running code such as the following
1044     # at the start of your function:
1045     #
1046     # function chpwd_profile_grml() {
1047     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1048     #   ...
1049     # }
1050     #
1051     # The initial value for $CHPWD_PROFILE is 'default'.
1052     #
1053     # Version requirement:
1054     #   This feature requires zsh 4.3.3 or newer.
1055     #   If you use this feature and need to know whether it is active in your
1056     #   current shell, there are several ways to do that. Here are two simple
1057     #   ways:
1058     #
1059     #   a) If knowing if the profiles feature is active when zsh starts is
1060     #      good enough for you, you can put the following snippet into your
1061     #      .zshrc.local:
1062     #
1063     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1064     #
1065     #   b) If that is not good enough, and you would prefer to be notified
1066     #      whenever a profile changes, you can solve that by making sure you
1067     #      start *every* profile function you create like this:
1068     #
1069     #   function chpwd_profile_myprofilename() {
1070     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1071     #       print "chpwd(): Switching to profile: $profile"
1072     #     ...
1073     #   }
1074     #
1075     #      That makes sure you only get notified if a profile is *changed*,
1076     #      not everytime you change directory, which would probably piss
1077     #      you off fairly quickly. :-)
1078     #
1079     # There you go. Now have fun with that.
1080     local -x profile
1081
1082     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1083     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1084         chpwd_profile_${profile}
1085     fi
1086
1087     CHPWD_PROFILE="${profile}"
1088     return 0
1089 }
1090 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1091
1092 fi # is433
1093
1094 # }}}
1095
1096 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1097 if [[ $BATTERY -gt 0 ]] ; then
1098     if ! check_com -c acpi ; then
1099         BATTERY=0
1100     fi
1101 fi
1102
1103 battery() {
1104 if [[ $BATTERY -gt 0 ]] ; then
1105     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1106     if [[ -z "$PERCENT" ]] ; then
1107         PERCENT='acpi not present'
1108     else
1109         if [[ "$PERCENT" -lt 20 ]] ; then
1110             PERCENT="warning: ${PERCENT}%%"
1111         else
1112             PERCENT="${PERCENT}%%"
1113         fi
1114     fi
1115 fi
1116 }
1117 # }}}
1118
1119 # set colors for use in prompts {{{
1120 if zrcautoload colors && colors 2>/dev/null ; then
1121     BLUE="%{${fg[blue]}%}"
1122     RED="%{${fg_bold[red]}%}"
1123     GREEN="%{${fg[green]}%}"
1124     CYAN="%{${fg[cyan]}%}"
1125     MAGENTA="%{${fg[magenta]}%}"
1126     YELLOW="%{${fg[yellow]}%}"
1127     WHITE="%{${fg[white]}%}"
1128     NO_COLOUR="%{${reset_color}%}"
1129 else
1130     BLUE=$'%{\e[1;34m%}'
1131     RED=$'%{\e[1;31m%}'
1132     GREEN=$'%{\e[1;32m%}'
1133     CYAN=$'%{\e[1;36m%}'
1134     WHITE=$'%{\e[1;37m%}'
1135     MAGENTA=$'%{\e[1;35m%}'
1136     YELLOW=$'%{\e[1;33m%}'
1137     NO_COLOUR=$'%{\e[0m%}'
1138 fi
1139
1140 # }}}
1141
1142 # gather version control information for inclusion in a prompt {{{
1143
1144 if ! is41 ; then
1145     # Be quiet about version problems in grml's zshrc as the user cannot disable
1146     # loading vcs_info() as it is *in* the zshrc - as you can see. :-)
1147     # Just unset most probable variables and disable vcs_info altogether.
1148     local -i i
1149     for i in {0..9} ; do
1150         unset VCS_INFO_message_${i}_
1151     done
1152     zstyle ':vcs_info:*' enable false
1153 fi
1154
1155 # The following code is imported from the file 'zsh/functions/vcs_info'
1156 # from <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>,
1157 # which distributed under the same terms as zsh itself.
1158
1159 # we will be using two variables, so let the code know now.
1160 zstyle ':vcs_info:*' max-exports 2
1161
1162 # vcs_info() documentation:
1163 #{{{
1164 # REQUIREMENTS:
1165 #{{{
1166 #     This functionality requires zsh version >= 4.1.*.
1167 #}}}
1168 #
1169 # LOADING:
1170 #{{{
1171 # To load vcs_info(), copy this file to your $fpath[] and do:
1172 #   % autoload -Uz vcs_info && vcs_info
1173 #
1174 # To work, vcs_info() needs 'setopt prompt_subst' in your setup.
1175 #}}}
1176 #
1177 # QUICKSTART:
1178 #{{{
1179 # To get vcs_info() working quickly (including colors), you can do the
1180 # following (assuming, you loaded vcs_info() properly - see above):
1181 #
1182 # % RED=$'%{\e[31m%}'
1183 # % GR=$'%{\e[32m%}'
1184 # % MA=$'%{\e[35m%}'
1185 # % YE=$'%{\e[33m%}'
1186 # % NC=$'%{\e[0m%}'
1187 #
1188 # % zstyle ':vcs_info:*' actionformats \
1189 #       "${MA}(${NC}%s${MA})${YE}-${MA}[${GR}%b${YE}|${RED}%a${MA}]${NC} "
1190 #
1191 # % zstyle ':vcs_info:*' formats       \
1192 #       "${MA}(${NC}%s${MA})${Y}-${MA}[${GR}%b${MA}]${NC}%} "
1193 #
1194 # % zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YE}%r"
1195 #
1196 # % precmd () { vcs_info }
1197 # % PS1='${MA}[${GR}%n${MA}] ${MA}(${RED}%!${MA}) ${YE}%3~ ${VCS_INFO_message_0_}${NC}%# '
1198 #
1199 # Obviously, the las two lines are there for demonstration: You need to
1200 # call vcs_info() from your precmd() function (see 'SPECIAL FUNCTIONS' in
1201 # 'man zshmisc'). Once that is done you need a *single* quoted
1202 # '${VCS_INFO_message_0_}' in your prompt.
1203 #
1204 # Now call the 'vcs_info_printsys' utility from the command line:
1205 #
1206 # % vcs_info_printsys
1207 # # list of supported version control backends:
1208 # # disabled systems are prefixed by a hash sign (#)
1209 # git
1210 # hg
1211 # bzr
1212 # darcs
1213 # svk
1214 # mtn
1215 # svn
1216 # cvs
1217 # cdv
1218 # tla
1219 # # flavours (cannot be used in the disable style; they
1220 # # are disabled with their master [git-svn -> git]):
1221 # git-p4
1222 # git-svn
1223 #
1224 # Ten version control backends as you can see. You may not want all
1225 # of these. Because there is no point in running the code to detect
1226 # systems you do not use. ever. So, there is a way to disable some
1227 # backends altogether:
1228 #
1229 # % zstyle ':vcs_info:*' disable bzr cdv darcs mtn svk tla
1230 #
1231 # If you rerun 'vcs_info_printsys' now, you will see the backends listed
1232 # in the 'disable' style marked as diabled by a hash sign. That means the
1233 # detection of these systems is skipped *completely*. No wasted time there.
1234 #
1235 # For more control, read the reference below.
1236 #}}}
1237 #
1238 # CONFIGURATION:
1239 #{{{
1240 # The vcs_info() feature can be configured via zstyle.
1241 #
1242 # First, the context in which we are working:
1243 #       :vcs_info:<vcs-string>:<user-context>
1244 #
1245 # ...where <vcs-string> is one of:
1246 #   - git, git-svn, git-p4, hg, darcs, bzr, cdv, mtn, svn, cvs, svk or tla.
1247 #
1248 # ...and <user-context> is a freely configurable string, assignable by the
1249 # user as the first argument to vcs_info() (see its description below).
1250 #
1251 # There is are three special values for <vcs-string>: The first is named
1252 # 'init', that is in effect as long as there was no decision what vcs
1253 # backend to use. The second is 'preinit; it is used *before* vcs_info()
1254 # is run, when initializing the data exporting variables. The third
1255 # special value is 'formats' and is used by the 'vcs_info_lastmsg' for
1256 # looking up its styles.
1257 #
1258 # There are two pre-defined values for <user-context>:
1259 #   default  - the one used if none is specified
1260 #   command  - used by vcs_info_lastmsg to lookup its styles.
1261 #
1262 # You may *not* use 'print_systems_' as a user-context string, because it
1263 # is used internally.
1264 #
1265 # You can of course use ':vcs_info:*' to match all VCSs in all
1266 # user-contexts at once.
1267 #
1268 # Another special context is 'formats', which is used by the
1269 # vcs_info_lastmsg() utility function (see below).
1270 #
1271 #
1272 # This is a description of all styles, that are looked up:
1273 #   formats             - A list of formats, used when actionformats is not
1274 #                         used (which is most of the time).
1275 #   actionformats       - A list of formats, used if a there is a special
1276 #                         action going on in your current repository;
1277 #                         (like an interactive rebase or a merge conflict)
1278 #   branchformat        - Some backends replace %b in the formats and
1279 #                         actionformats styles above, not only by a branch
1280 #                         name but also by a revision number. This style
1281 #                         let's you modify how that string should look like.
1282 #   nvcsformats         - These "formats" are exported, when we didn't detect
1283 #                         a version control system for the current directory.
1284 #                         This is useful, if you want vcs_info() to completely
1285 #                         take over the generation of your prompt.
1286 #                         You would do something like
1287 #                           PS1='${VCS_INFO_message_0_}'
1288 #                         to accomplish that.
1289 #   max-exports         - Defines the maximum number if VCS_INFO_message_*_
1290 #                         variables vcs_info() will export.
1291 #   enable              - Checked in the 'init' context. If set to false,
1292 #                         vcs_info() will do nothing.
1293 #   disable             - Provide a list of systems, you don't want
1294 #                         the vcs_info() to check for repositories
1295 #                         (checked in the 'init' context, too).
1296 #   disable-patterns    - A list of patterns that are checked against $PWD.
1297 #                         If the pattern matches, vcs_info will be disabled.
1298 #                         Say, ~/.zsh is a directory under version control,
1299 #                         in which you do not want vcs_info to be active, do:
1300 #                         zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh+(|/*)"
1301 #   use-simple          - If there are two different ways of gathering
1302 #                         information, you can select the simpler one
1303 #                         by setting this style to true; the default
1304 #                         is to use the not-that-simple code, which is
1305 #                         potentially a lot slower but might be more
1306 #                         accurate in all possible cases.
1307 #   use-prompt-escapes  - determines if we assume that the assembled
1308 #                         string from vcs_info() includes prompt escapes.
1309 #                         (Used by vcs_info_lastmsg().
1310 #
1311 # The use-simple style is only available for the bzr backend.
1312 #
1313 # The default values for these in all contexts are:
1314 #   formats             " (%s)-[%b|%a]-"
1315 #   actionformats       " (%s)-[%b]-"
1316 #   branchformat        "%b:%r" (for bzr, svn and svk)
1317 #   nvcsformats         ""
1318 #   max-exports         2
1319 #   enable              true
1320 #   disable             (empty list)
1321 #   disable-patterns    (empty list)
1322 #   use-simple          false
1323 #   use-prompt-escapes  true
1324 #
1325 #
1326 # In normal formats and actionformats, the following replacements
1327 # are done:
1328 #   %s  - The vcs in use (git, hg, svn etc.)
1329 #   %b  - Information about the current branch.
1330 #   %a  - An identifier, that describes the action.
1331 #         Only makes sense in actionformats.
1332 #   %R  - base directory of the repository.
1333 #   %r  - repository name
1334 #         If %R is '/foo/bar/repoXY', %r is 'repoXY'.
1335 #   %S  - subdirectory within a repository. if $PWD is
1336 #         '/foo/bar/reposXY/beer/tasty', %S is 'beer/tasty'.
1337 #
1338 #
1339 # In branchformat these replacements are done:
1340 #   %b  - the branch name
1341 #   %r  - the current revision number
1342 #
1343 # Not all vcs backends have to support all replacements.
1344 # nvcsformat does not perform *any* replacements. It is just a string.
1345 #}}}
1346 #
1347 # ODDITIES:
1348 #{{{
1349 # If you want to use the %b (bold off) prompt expansion in 'formats', which
1350 # expands %b itself, use %%b. That will cause the vcs_info() expansion to
1351 # replace %%b with %b. So zsh's prompt expansion mechanism can handle it.
1352 # Similarly, to hand down %b from branchformat, use %%%%b. Sorry for this
1353 # inconvenience, but it cannot be easily avoided. Luckily we do not clash
1354 # with a lot of prompt expansions and this only needs to be done for those.
1355 # See 'man zshmisc' for details about EXPANSION OF PROMPT SEQUENCES.
1356 #}}}
1357 #
1358 # FUNCTION DESCRIPTIONS (public API):
1359 #{{{
1360 #   vcs_info()
1361 #       The main function, that runs all backends and assembles
1362 #       all data into ${VCS_INFO_message_*_}. This is the function
1363 #       you want to call from precmd() if you want to include
1364 #       up-to-date information in your prompt (see VARIABLE
1365 #       DESCRIPTION below).
1366 #
1367 #   vcs_info_printsys()
1368 #       Prints a list of all supported version control systems.
1369 #       Useful to find out possible contexts (and which of them are enabled)
1370 #       or values for the 'disable' style.
1371 #
1372 #   vcs_info_lastmsg()
1373 #       Outputs the last ${VCS_INFO_message_*_} value. Takes into account
1374 #       the value of the use-prompt-escapes style in ':vcs_info:formats'.
1375 #       It also only prints max-exports values.
1376 #
1377 # All functions named VCS_INFO_* are for internal use only.
1378 #}}}
1379 #
1380 # VARIABLE DESCRIPTION:
1381 #{{{
1382 #   ${VCS_INFO_message_N_}    (Note the trailing underscore)
1383 #       Where 'N' is an integer, eg: VCS_INFO_message_0_
1384 #       These variables are the storage for the informational message the
1385 #       last vcs_info() call has assembled. These are strongly connected
1386 #       to the formats, actionformats and nvcsformats styles described
1387 #       above. Those styles are lists. the first member of that list gets
1388 #       expanded into ${VCS_INFO_message_0_}, the second into
1389 #       ${VCS_INFO_message_1_} and the Nth into ${VCS_INFO_message_N-1_}.
1390 #       These parameters are exported into the environment.
1391 #       (See the max-exports style above.)
1392 #}}}
1393 #
1394 # EXAMPLES:
1395 #{{{
1396 #   Don't use vcs_info at all (even though it's in your prompt):
1397 #   % zstyle ':vcs_info:*' enable false
1398 #
1399 #   Disable the backends for bzr and svk:
1400 #   % zstyle ':vcs_info:*' disable bzr svk
1401 #
1402 #   Provide a special formats for git:
1403 #   % zstyle ':vcs_info:git:*' formats       ' GIT, BABY! [%b]'
1404 #   % zstyle ':vcs_info:git:*' actionformats ' GIT ACTION! [%b|%a]'
1405 #
1406 #   Use the quicker bzr backend (if you do, please report if it does
1407 #   the-right-thing[tm] - thanks):
1408 #   % zstyle ':vcs_info:bzr:*' use-simple true
1409 #
1410 #   Display the revision number in yellow for bzr and svn:
1411 #   % zstyle ':vcs_info:(svn|bzr):*' branchformat '%b%{'${fg[yellow]}'%}:%r'
1412 #
1413 # If you want colors, make sure you enclose the color codes in %{...%},
1414 # if you want to use the string provided by vcs_info() in prompts.
1415 #
1416 # Here is how to print the vcs infomation as a command:
1417 #   % alias vcsi='vcs_info command; vcs_info_lastmsg'
1418 #
1419 #   This way, you can even define different formats for output via
1420 #   vcs_info_lastmsg() in the ':vcs_info:command:*' namespace.
1421 #}}}
1422 #}}}
1423 # utilities
1424 VCS_INFO_adjust () { #{{{
1425     [[ -n ${vcs_comm[overwrite_name]} ]] && vcs=${vcs_comm[overwrite_name]}
1426     return 0
1427 }
1428 # }}}
1429 VCS_INFO_check_com () { #{{{
1430     (( ${+commands[$1]} )) && [[ -x ${commands[$1]} ]] && return 0
1431     return 1
1432 }
1433 # }}}
1434 VCS_INFO_formats () { # {{{
1435     setopt localoptions noksharrays
1436     local action=$1 branch=$2 base=$3
1437     local msg
1438     local -i i
1439
1440     if [[ -n ${action} ]] ; then
1441         zstyle -a ":vcs_info:${vcs}:${usercontext}" actionformats msgs
1442         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b|%a]-'
1443     else
1444         zstyle -a ":vcs_info:${vcs}:${usercontext}" formats msgs
1445         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b]-'
1446     fi
1447
1448     (( ${#msgs} > maxexports )) && msgs[$(( maxexports + 1 )),-1]=()
1449     for i in {1..${#msgs}} ; do
1450         zformat -f msg ${msgs[$i]}                      \
1451                         a:${action}                     \
1452                         b:${branch}                     \
1453                         r:${base:t}                     \
1454                         s:${vcs}                        \
1455                         R:${base}                       \
1456                         S:"$(VCS_INFO_reposub ${base})"
1457         msgs[$i]=${msg}
1458     done
1459     return 0
1460 }
1461 # }}}
1462 VCS_INFO_maxexports () { #{{{
1463     zstyle -s ":vcs_info:${vcs}:${usercontext}" "max-exports" maxexports || maxexports=2
1464     if [[ ${maxexports} != <-> ]] || (( maxexports < 1 )); then
1465         printf 'vcs_info(): expecting numeric arg >= 1 for max-exports (got %s).\n' ${maxexports}
1466         printf 'Defaulting to 2.\n'
1467         maxexports=2
1468     fi
1469 }
1470 # }}}
1471 VCS_INFO_nvcsformats () { #{{{
1472     setopt localoptions noksharrays
1473     local c v
1474
1475     if [[ $1 == 'preinit' ]] ; then
1476         c=default
1477         v=preinit
1478     fi
1479     zstyle -a ":vcs_info:${v:-$vcs}:${c:-$usercontext}" nvcsformats msgs
1480     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1481 }
1482 # }}}
1483 VCS_INFO_realpath () { #{{{
1484     # a portable 'readlink -f'
1485     # forcing a subshell, to ensure chpwd() is not removed
1486     # from the calling shell (if VCS_INFO_realpath() is called
1487     # manually).
1488     (
1489         (( ${+functions[chpwd]} )) && unfunction chpwd
1490         setopt chaselinks
1491         cd $1 2>/dev/null && pwd
1492     )
1493 }
1494 # }}}
1495 VCS_INFO_reposub () { #{{{
1496     setopt localoptions extendedglob
1497     local base=${1%%/##}
1498
1499     [[ ${PWD} == ${base}/* ]] || {
1500         printf '.'
1501         return 1
1502     }
1503     printf '%s' ${PWD#$base/}
1504     return 0
1505 }
1506 # }}}
1507 VCS_INFO_set () { #{{{
1508     setopt localoptions noksharrays
1509     local -i i j
1510
1511     if [[ $1 == '--clear' ]] ; then
1512         for i in {0..9} ; do
1513             unset VCS_INFO_message_${i}_
1514         done
1515     fi
1516     if [[ $1 == '--nvcs' ]] ; then
1517         [[ $2 == 'preinit' ]] && (( maxexports == 0 )) && (( maxexports = 1 ))
1518         for i in {0..$((maxexports - 1))} ; do
1519             typeset -gx VCS_INFO_message_${i}_=
1520         done
1521         VCS_INFO_nvcsformats $2
1522     fi
1523
1524     (( ${#msgs} - 1 < 0 )) && return 0
1525     for i in {0..$(( ${#msgs} - 1 ))} ; do
1526         (( j = i + 1 ))
1527         typeset -gx VCS_INFO_message_${i}_=${msgs[$j]}
1528     done
1529     return 0
1530 }
1531 # }}}
1532 # information gathering
1533 VCS_INFO_bzr_get_data () { # {{{
1534     setopt localoptions noksharrays
1535     local bzrbase bzrbr
1536     local -a bzrinfo
1537
1538     if zstyle -t ":vcs_info:${vcs}:${usercontext}" "use-simple" ; then
1539         bzrbase=${vcs_comm[basedir]}
1540         bzrinfo[2]=${bzrbase:t}
1541         if [[ -f ${bzrbase}/.bzr/branch/last-revision ]] ; then
1542             bzrinfo[1]=$(< ${bzrbase}/.bzr/branch/last-revision)
1543             bzrinfo[1]=${${bzrinfo[1]}%% *}
1544         fi
1545     else
1546         bzrbase=${${(M)${(f)"$( bzr info )"}:# ##branch\ root:*}/*: ##/}
1547         bzrinfo=( ${${${(M)${(f)"$( bzr version-info )"}:#(#s)(revno|branch-nick)*}/*: /}/*\//} )
1548         bzrbase="$(VCS_INFO_realpath ${bzrbase})"
1549     fi
1550
1551     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat bzrbr || bzrbr="%b:%r"
1552     zformat -f bzrbr "${bzrbr}" "b:${bzrinfo[2]}" "r:${bzrinfo[1]}"
1553     VCS_INFO_formats '' "${bzrbr}" "${bzrbase}"
1554     return 0
1555 }
1556 # }}}
1557 VCS_INFO_cdv_get_data () { # {{{
1558     local cdvbase
1559
1560     cdvbase=${vcs_comm[basedir]}
1561     VCS_INFO_formats '' "${cdvbase:t}" "${cdvbase}"
1562     return 0
1563 }
1564 # }}}
1565 VCS_INFO_cvs_get_data () { # {{{
1566     local cvsbranch cvsbase basename
1567
1568     cvsbase="."
1569     while [[ -d "${cvsbase}/../CVS" ]]; do
1570         cvsbase="${cvsbase}/.."
1571     done
1572     cvsbase="$(VCS_INFO_realpath ${cvsbase})"
1573     cvsbranch=$(< ./CVS/Repository)
1574     basename=${cvsbase:t}
1575     cvsbranch=${cvsbranch##${basename}/}
1576     [[ -z ${cvsbranch} ]] && cvsbranch=${basename}
1577     VCS_INFO_formats '' "${cvsbranch}" "${cvsbase}"
1578     return 0
1579 }
1580 # }}}
1581 VCS_INFO_darcs_get_data () { # {{{
1582     local darcsbase
1583
1584     darcsbase=${vcs_comm[basedir]}
1585     VCS_INFO_formats '' "${darcsbase:t}" "${darcsbase}"
1586     return 0
1587 }
1588 # }}}
1589 VCS_INFO_git_getaction () { #{{{
1590     local gitaction='' gitdir=$1
1591     local tmp
1592
1593     for tmp in "${gitdir}/rebase-apply" \
1594                "${gitdir}/rebase"       \
1595                "${gitdir}/../.dotest" ; do
1596         if [[ -d ${tmp} ]] ; then
1597             if   [[ -f "${tmp}/rebasing" ]] ; then
1598                 gitaction="rebase"
1599             elif [[ -f "${tmp}/applying" ]] ; then
1600                 gitaction="am"
1601             else
1602                 gitaction="am/rebase"
1603             fi
1604             printf '%s' ${gitaction}
1605             return 0
1606         fi
1607     done
1608
1609     for tmp in "${gitdir}/rebase-merge/interactive" \
1610                "${gitdir}/.dotest-merge/interactive" ; do
1611         if [[ -f "${tmp}" ]] ; then
1612             printf '%s' "rebase-i"
1613             return 0
1614         fi
1615     done
1616
1617     for tmp in "${gitdir}/rebase-merge" \
1618                "${gitdir}/.dotest-merge" ; do
1619         if [[ -d "${tmp}" ]] ; then
1620             printf '%s' "rebase-m"
1621             return 0
1622         fi
1623     done
1624
1625     if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1626         printf '%s' "merge"
1627         return 0
1628     fi
1629
1630     if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
1631         printf '%s' "bisect"
1632         return 0
1633     fi
1634     return 1
1635 }
1636 # }}}
1637 VCS_INFO_git_getbranch () { #{{{
1638     local gitbranch gitdir=$1
1639     local gitsymref='git symbolic-ref HEAD'
1640
1641     if    [[ -d "${gitdir}/rebase-apply" ]] \
1642        || [[ -d "${gitdir}/rebase" ]]       \
1643        || [[ -d "${gitdir}/../.dotest" ]]   \
1644        || [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1645         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1646         [[ -z ${gitbranch} ]] && [[ -r ${gitdir}/rebase-apply/head-name ]] \
1647             && gitbranch="$(< ${gitdir}/rebase-apply/head-name)"
1648
1649     elif   [[ -f "${gitdir}/rebase-merge/interactive" ]] \
1650         || [[ -d "${gitdir}/rebase-merge" ]] ; then
1651         gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
1652
1653     elif   [[ -f "${gitdir}/.dotest-merge/interactive" ]] \
1654         || [[ -d "${gitdir}/.dotest-merge" ]] ; then
1655         gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
1656
1657     else
1658         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1659
1660         if [[ $? -ne 0 ]] ; then
1661             gitbranch="$(git describe --exact-match HEAD 2>/dev/null)"
1662
1663             if [[ $? -ne 0 ]] ; then
1664                 gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
1665             fi
1666         fi
1667     fi
1668
1669     printf '%s' "${gitbranch##refs/heads/}"
1670     return 0
1671 }
1672 # }}}
1673 VCS_INFO_git_get_data () { # {{{
1674     setopt localoptions extendedglob
1675     local gitdir gitbase gitbranch gitaction
1676
1677     gitdir=${vcs_comm[gitdir]}
1678     gitbranch="$(VCS_INFO_git_getbranch ${gitdir})"
1679
1680     if [[ -z ${gitdir} ]] || [[ -z ${gitbranch} ]] ; then
1681         return 1
1682     fi
1683
1684     VCS_INFO_adjust
1685     gitaction="$(VCS_INFO_git_getaction ${gitdir})"
1686     gitbase=${PWD%/${$( git rev-parse --show-prefix )%/##}}
1687     VCS_INFO_formats "${gitaction}" "${gitbranch}" "${gitbase}"
1688     return 0
1689 }
1690 # }}}
1691 VCS_INFO_hg_get_data () { # {{{
1692     local hgbranch hgbase file
1693
1694     hgbase=${vcs_comm[basedir]}
1695
1696     file="${hgbase}/.hg/branch"
1697     if [[ -r ${file} ]] ; then
1698         hgbranch=$(< ${file})
1699     else
1700         hgbranch='default'
1701     fi
1702
1703     VCS_INFO_formats '' "${hgbranch}" "${hgbase}"
1704     return 0
1705 }
1706 # }}}
1707 VCS_INFO_mtn_get_data () { # {{{
1708     local mtnbranch mtnbase
1709
1710     mtnbase=${vcs_comm[basedir]}
1711     mtnbranch=${${(M)${(f)"$( mtn status )"}:#(#s)Current branch:*}/*: /}
1712     VCS_INFO_formats '' "${mtnbranch}" "${mtnbase}"
1713     return 0
1714 }
1715 # }}}
1716 VCS_INFO_svk_get_data () { # {{{
1717     local svkbranch svkbase
1718
1719     svkbase=${vcs_comm[basedir]}
1720     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svkbranch || svkbranch="%b:%r"
1721     zformat -f svkbranch "${svkbranch}" "b:${vcs_comm[branch]}" "r:${vcs_comm[revision]}"
1722     VCS_INFO_formats '' "${svkbranch}" "${svkbase}"
1723     return 0
1724 }
1725 # }}}
1726 VCS_INFO_svn_get_data () { # {{{
1727     setopt localoptions noksharrays
1728     local svnbase svnbranch
1729     local -a svninfo
1730
1731     svnbase="."
1732     while [[ -d "${svnbase}/../.svn" ]]; do
1733         svnbase="${svnbase}/.."
1734     done
1735     svnbase="$(VCS_INFO_realpath ${svnbase})"
1736     svninfo=( ${${${(M)${(f)"$( svn info )"}:#(#s)(URL|Revision)*}/*: /}/*\//} )
1737
1738     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svnbranch || svnbranch="%b:%r"
1739     zformat -f svnbranch "${svnbranch}" "b:${svninfo[1]}" "r:${svninfo[2]}"
1740     VCS_INFO_formats '' "${svnbranch}" "${svnbase}"
1741     return 0
1742 }
1743 # }}}
1744 VCS_INFO_tla_get_data () { # {{{
1745     local tlabase tlabranch
1746
1747     tlabase="$(VCS_INFO_realpath ${vcs_comm[basedir]})"
1748     # tree-id gives us something like 'foo@example.com/demo--1.0--patch-4', so:
1749     tlabranch=${${"$( tla tree-id )"}/*\//}
1750     VCS_INFO_formats '' "${tlabranch}" "${tlabase}"
1751     return 0
1752 }
1753 # }}}
1754 # detection
1755 VCS_INFO_detect_by_dir() { #{{{
1756     local dirname=$1
1757     local basedir="." realbasedir
1758
1759     realbasedir="$(VCS_INFO_realpath ${basedir})"
1760     while [[ ${realbasedir} != '/' ]]; do
1761         if [[ -n ${vcs_comm[detect_need_file]} ]] ; then
1762             [[ -d ${basedir}/${dirname} ]] && \
1763             [[ -e ${basedir}/${dirname}/${vcs_comm[detect_need_file]} ]] && \
1764                 break
1765         else
1766             [[ -d ${basedir}/${dirname} ]] && break
1767         fi
1768
1769         basedir=${basedir}/..
1770         realbasedir="$(VCS_INFO_realpath ${basedir})"
1771     done
1772
1773     [[ ${realbasedir} == "/" ]] && return 1
1774     vcs_comm[basedir]=${realbasedir}
1775     return 0
1776 }
1777 # }}}
1778 VCS_INFO_bzr_detect() { #{{{
1779     VCS_INFO_check_com bzr || return 1
1780     vcs_comm[detect_need_file]=branch/format
1781     VCS_INFO_detect_by_dir '.bzr'
1782     return $?
1783 }
1784 # }}}
1785 VCS_INFO_cdv_detect() { #{{{
1786     VCS_INFO_check_com cdv || return 1
1787     vcs_comm[detect_need_file]=format
1788     VCS_INFO_detect_by_dir '.cdv'
1789     return $?
1790 }
1791 # }}}
1792 VCS_INFO_cvs_detect() { #{{{
1793     VCS_INFO_check_com svn || return 1
1794     [[ -d "./CVS" ]] && [[ -r "./CVS/Repository" ]] && return 0
1795     return 1
1796 }
1797 # }}}
1798 VCS_INFO_darcs_detect() { #{{{
1799     VCS_INFO_check_com darcs || return 1
1800     vcs_comm[detect_need_file]=format
1801     VCS_INFO_detect_by_dir '_darcs'
1802     return $?
1803 }
1804 # }}}
1805 VCS_INFO_git_detect() { #{{{
1806     if VCS_INFO_check_com git && git rev-parse --is-inside-work-tree &> /dev/null ; then
1807         vcs_comm[gitdir]="$(git rev-parse --git-dir 2> /dev/null)" || return 1
1808         if   [[ -d ${vcs_comm[gitdir]}/svn ]]             ; then vcs_comm[overwrite_name]='git-svn'
1809         elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]] ; then vcs_comm[overwrite_name]='git-p4' ; fi
1810         return 0
1811     fi
1812     return 1
1813 }
1814 # }}}
1815 VCS_INFO_hg_detect() { #{{{
1816     VCS_INFO_check_com hg || return 1
1817     vcs_comm[detect_need_file]=store
1818     VCS_INFO_detect_by_dir '.hg'
1819     return $?
1820 }
1821 # }}}
1822 VCS_INFO_mtn_detect() { #{{{
1823     VCS_INFO_check_com mtn || return 1
1824     vcs_comm[detect_need_file]=revision
1825     VCS_INFO_detect_by_dir '_MTN'
1826     return $?
1827 }
1828 # }}}
1829 VCS_INFO_svk_detect() { #{{{
1830     setopt localoptions noksharrays extendedglob
1831     local -a info
1832     local -i fhash
1833     fhash=0
1834
1835     VCS_INFO_check_com svk || return 1
1836     [[ -f ~/.svk/config ]] || return 1
1837
1838     # This detection function is a bit different from the others.
1839     # We need to read svk's config file to detect a svk repository
1840     # in the first place. Therefore, we'll just proceed and read
1841     # the other information, too. This is more then any of the
1842     # other detections do but this takes only one file open for
1843     # svk at most. VCS_INFO_svk_get_data() get simpler, too. :-)
1844     while IFS= read -r line ; do
1845         if [[ -n ${vcs_comm[basedir]} ]] ; then
1846             line=${line## ##}
1847             [[ ${line} == depotpath:* ]] && vcs_comm[branch]=${line##*/}
1848             [[ ${line} == revision:* ]] && vcs_comm[revision]=${line##*[[:space:]]##}
1849             [[ -n ${vcs_comm[branch]} ]] && [[ -n ${vcs_comm[revision]} ]] && break
1850             continue
1851         fi
1852         (( fhash > 0 )) && [[ ${line} == '  '[^[:space:]]*:* ]] && break
1853         [[ ${line} == '  hash:'* ]] && fhash=1 && continue
1854         (( fhash == 0 )) && continue
1855         [[ ${PWD}/ == ${${line## ##}%:*}/* ]] && vcs_comm[basedir]=${${line## ##}%:*}
1856     done < ~/.svk/config
1857
1858     [[ -n ${vcs_comm[basedir]} ]]  && \
1859     [[ -n ${vcs_comm[branch]} ]]   && \
1860     [[ -n ${vcs_comm[revision]} ]] && return 0
1861     return 1
1862 }
1863 # }}}
1864 VCS_INFO_svn_detect() { #{{{
1865     VCS_INFO_check_com svn || return 1
1866     [[ -d ".svn" ]] && return 0
1867     return 1
1868 }
1869 # }}}
1870 VCS_INFO_tla_detect() { #{{{
1871     VCS_INFO_check_com tla || return 1
1872     vcs_comm[basedir]="$(tla tree-root 2> /dev/null)" && return 0
1873     return 1
1874 }
1875 # }}}
1876 # public API
1877 vcs_info_printsys () { # {{{
1878     vcs_info print_systems_
1879 }
1880 # }}}
1881 vcs_info_lastmsg () { # {{{
1882     local -i i
1883
1884     VCS_INFO_maxexports
1885     for i in {0..$((maxexports - 1))} ; do
1886         printf '$VCS_INFO_message_%d_: "' $i
1887         if zstyle -T ':vcs_info:formats:command' use-prompt-escapes ; then
1888             print -nP ${(P)${:-VCS_INFO_message_${i}_}}
1889         else
1890             print -n ${(P)${:-VCS_INFO_message_${i}_}}
1891         fi
1892         printf '"\n'
1893     done
1894 }
1895 # }}}
1896 vcs_info () { # {{{
1897     local pat
1898     local -i found
1899     local -a VCSs disabled dps
1900     local -x vcs usercontext
1901     local -ix maxexports
1902     local -ax msgs
1903     local -Ax vcs_comm
1904
1905     vcs="init"
1906     VCSs=(git hg bzr darcs svk mtn svn cvs cdv tla)
1907     case $1 in
1908         (print_systems_)
1909             zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1910             print -l '# list of supported version control backends:' \
1911                      '# disabled systems are prefixed by a hash sign (#)'
1912             for vcs in ${VCSs} ; do
1913                 [[ -n ${(M)disabled:#${vcs}} ]] && printf '#'
1914                 printf '%s\n' ${vcs}
1915             done
1916             print -l '# flavours (cannot be used in the disable style; they' \
1917                      '# are disabled with their master [git-svn -> git]):'   \
1918                      git-{p4,svn}
1919             return 0
1920             ;;
1921         ('')
1922             [[ -z ${usercontext} ]] && usercontext=default
1923             ;;
1924         (*) [[ -z ${usercontext} ]] && usercontext=$1
1925             ;;
1926     esac
1927
1928     zstyle -T ":vcs_info:${vcs}:${usercontext}" "enable" || {
1929         [[ -n ${VCS_INFO_message_0_} ]] && VCS_INFO_set --clear
1930         return 0
1931     }
1932     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1933
1934     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable-patterns" dps
1935     for pat in ${dps} ; do
1936         if [[ ${PWD} == ${~pat} ]] ; then
1937             [[ -n ${vcs_info_msg_0_} ]] && VCS_INFO_set --clear
1938             return 0
1939         fi
1940     done
1941
1942     VCS_INFO_maxexports
1943
1944     (( found = 0 ))
1945     for vcs in ${VCSs} ; do
1946         [[ -n ${(M)disabled:#${vcs}} ]] && continue
1947         vcs_comm=()
1948         VCS_INFO_${vcs}_detect && (( found = 1 )) && break
1949     done
1950
1951     (( found == 0 )) && {
1952         VCS_INFO_set --nvcs
1953         return 0
1954     }
1955
1956     VCS_INFO_${vcs}_get_data || {
1957         VCS_INFO_set --nvcs
1958         return 1
1959     }
1960
1961     VCS_INFO_set
1962     return 0
1963 }
1964
1965 VCS_INFO_set --nvcs preinit
1966 # }}}
1967
1968 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1969 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1970 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1971 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1972 #       to $vcs_info_msg_N_ as soon as we use the included version.
1973 if [[ "$TERM" == dumb ]] ; then
1974     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1975     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1976 else
1977     # these are the same, just with a lot of colours:
1978     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1979                                        "zsh: %r"
1980     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1981                                        "zsh: %r"
1982     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1983 fi
1984
1985 # }}}
1986
1987 # command not found handling {{{
1988
1989 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1990 function command_not_found_handler() {
1991     emulate -L zsh
1992     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1993         ${GRML_ZSH_CNF_HANDLER} $1
1994     fi
1995     return 1
1996 }
1997
1998 # }}}
1999
2000 # {{{ set prompt
2001 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2002     promptinit # people should be able to use their favourite prompt
2003 else
2004     print 'Notice: no promptinit available :('
2005 fi
2006
2007 setopt prompt_subst
2008
2009 # make sure to use right prompt only when not running a command
2010 is41 && setopt transient_rprompt
2011
2012 # TODO: revise all these NO* variables and especially their documentation
2013 #       in zsh-help() below.
2014 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
2015     [[ $NOPRECMD -gt 0 ]] && return 0
2016     # update VCS information
2017     vcs_info
2018
2019     if [[ $TERM == screen* ]] ; then
2020         if [[ -n ${VCS_INFO_message_1_} ]] ; then
2021             print -nP "\ek${VCS_INFO_message_1_}\e\\"
2022         else
2023             print -nP "\ekzsh\e\\"
2024         fi
2025     fi
2026     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
2027     if [[ $DONTSETRPROMPT -eq 0 ]] ; then
2028         if [[ $BATTERY -gt 0 ]] ; then
2029             # update battery (dropped into $PERCENT) information
2030             battery
2031             RPROMPT="%(?..:() ${PERCENT}"
2032         else
2033             RPROMPT="%(?..:() "
2034         fi
2035     fi
2036     # adjust title of xterm
2037     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2038     [[ ${NOTITLE} -gt 0 ]] && return 0
2039     case $TERM in
2040         (xterm*|rxvt*)
2041             print -Pn "\e]0;%n@%m: %~\a"
2042             ;;
2043     esac
2044 }
2045
2046 # preexec() => a function running before every command
2047 is4 && [[ $NOPRECMD -eq 0 ]] && \
2048 preexec () {
2049     [[ $NOPRECMD -gt 0 ]] && return 0
2050 # set hostname if not running on host with name 'grml'
2051     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2052        NAME="@$HOSTNAME"
2053     fi
2054 # get the name of the program currently running and hostname of local machine
2055 # set screen window title if running in a screen
2056     if [[ "$TERM" == screen* ]] ; then
2057         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
2058         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
2059         echo -ne "\ek$CMD\e\\"
2060     fi
2061 # adjust title of xterm
2062     [[ ${NOTITLE} -gt 0 ]] && return 0
2063     case $TERM in
2064         (xterm*|rxvt*)
2065             print -Pn "\e]0;%n@%m: $1\a"
2066             ;;
2067     esac
2068 }
2069
2070 EXITCODE="%(?..%?%1v )"
2071 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
2072 PS3='?# '         # selection prompt used within a select loop.
2073 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
2074
2075 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
2076 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
2077     debian_chroot=$(cat /etc/debian_chroot)
2078 fi
2079
2080 # don't use colors on dumb terminals (like emacs):
2081 if [[ "$TERM" == dumb ]] ; then
2082     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2083 else
2084     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
2085     # set variable identifying the chroot you work in (used in the prompt below)
2086     if [[ $GRMLPROMPT -gt 0 ]] ; then
2087         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
2088 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2089     else
2090         # This assembles the primary prompt string
2091         if (( EUID != 0 )); then
2092             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2093         else
2094             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2095         fi
2096     fi
2097 fi
2098
2099 # if we are inside a grml-chroot set a specific prompt theme
2100 if [[ -n "$GRML_CHROOT" ]] ; then
2101     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
2102 fi
2103 # }}}
2104
2105 # {{{ 'hash' some often used directories
2106 #d# start
2107 hash -d deb=/var/cache/apt/archives
2108 hash -d doc=/usr/share/doc
2109 hash -d linux=/lib/modules/$(command uname -r)/build/
2110 hash -d log=/var/log
2111 hash -d slog=/var/log/syslog
2112 hash -d src=/usr/src
2113 hash -d templ=/usr/share/doc/grml-templates
2114 hash -d tt=/usr/share/doc/texttools-doc
2115 hash -d www=/var/www
2116 #d# end
2117 # }}}
2118
2119 # {{{ some aliases
2120 if check_com -c screen ; then
2121     if [[ $UID -eq 0 ]] ; then
2122         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
2123     elif [[ -r $HOME/.screenrc ]] ; then
2124         alias screen="${commands[screen]} -c $HOME/.screenrc"
2125     else
2126         [[ -r /etc/grml/screenrc_grml ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2127     fi
2128 fi
2129
2130 # do we have GNU ls with color-support?
2131 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
2132     #a1# execute \kbd{@a@}:\quad ls with colors
2133     alias ls='ls -b -CF --color=auto'
2134     #a1# execute \kbd{@a@}:\quad list all files, with colors
2135     alias la='ls -la --color=auto'
2136     #a1# long colored list, without dotfiles (@a@)
2137     alias ll='ls -l --color=auto'
2138     #a1# long colored list, human readable sizes (@a@)
2139     alias lh='ls -hAl --color=auto'
2140     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2141     alias l='ls -lF --color=auto'
2142 else
2143     alias ls='ls -b -CF'
2144     alias la='ls -la'
2145     alias ll='ls -l'
2146     alias lh='ls -hAl'
2147     alias l='ls -lF'
2148 fi
2149
2150 alias mdstat='cat /proc/mdstat'
2151 alias ...='cd ../../'
2152
2153 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2154 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2155     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2156 fi
2157
2158 alias cp='nocorrect cp'         # no spelling correction on cp
2159 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
2160 alias mv='nocorrect mv'         # no spelling correction on mv
2161 alias rm='nocorrect rm'         # no spelling correction on rm
2162
2163 #a1# Execute \kbd{rmdir}
2164 alias rd='rmdir'
2165 #a1# Execute \kbd{rmdir}
2166 alias md='mkdir'
2167
2168 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2169 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2170 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2171
2172 # make sure it is not assigned yet
2173 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2174 utf2iso() {
2175     if isutfenv ; then
2176         for ENV in $(env | command grep -i '.utf') ; do
2177             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2178         done
2179     fi
2180 }
2181
2182 # make sure it is not assigned yet
2183 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2184 iso2utf() {
2185     if ! isutfenv ; then
2186         for ENV in $(env | command grep -i '\.iso') ; do
2187             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2188         done
2189     fi
2190 }
2191
2192 # set up software synthesizer via speakup
2193 swspeak() {
2194     if [ -x /usr/sbin/swspeak-setup ] ; then
2195        setopt singlelinezle
2196        unsetopt prompt_cr
2197        export PS1="%m%# "
2198        /usr/sbin/swspeak-setup $@
2199      else # old version:
2200         aumix -w 90 -v 90 -p 90 -m 90
2201         if ! [[ -r /dev/softsynth ]] ; then
2202             flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
2203             return 1
2204         else
2205            setopt singlelinezle
2206            unsetopt prompt_cr
2207            export PS1="%m%# "
2208             nice -n -20 speechd-up
2209             sleep 2
2210             flite -o play -t "Finished setting up software synthesizer"
2211         fi
2212      fi
2213 }
2214
2215 # I like clean prompt, so provide simple way to get that
2216 check_com 0 || alias 0='return 0'
2217
2218 # for really lazy people like mika:
2219 check_com S &>/dev/null || alias S='screen'
2220 check_com s &>/dev/null || alias s='ssh'
2221
2222 # get top 10 shell commands:
2223 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
2224
2225 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
2226 if check_com -c truecrypt ; then
2227     if isutfenv ; then
2228         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
2229     else
2230         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
2231     fi
2232 fi
2233
2234 #f1# Hints for the use of zsh on grml
2235 zsh-help() {
2236     print "$bg[white]$fg[black]
2237 zsh-help - hints for use of zsh on grml
2238 =======================================$reset_color"
2239
2240     print '
2241 Main configuration of zsh happens in /etc/zsh/zshrc.
2242 That file is part of the package grml-etc-core, if you want to
2243 use them on a non-grml-system just get the tar.gz from
2244 http://deb.grml.org/ or (preferably) get it from the git repository:
2245
2246   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2247
2248 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2249 The file is still there, but it is empty for backwards compatibility.
2250
2251 For your own changes use these two files:
2252     $HOME/.zshrc.pre
2253     $HOME/.zshrc.local
2254
2255 The former is sourced very early in our zshrc, the latter is sourced
2256 very lately.
2257
2258 System wide configuration without touching configuration files of grml
2259 can take place in /etc/zsh/zshrc.local.
2260
2261 Normally, the root user (EUID == 0) does not get the whole grml setup.
2262 If you want to force the whole setup for that user, too, set
2263 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
2264
2265 For information regarding zsh start at http://grml.org/zsh/
2266
2267 Take a look at grml'\''s zsh refcard:
2268 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2269
2270 Check out the main zsh refcard:
2271 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2272
2273 And of course visit the zsh-lovers:
2274 % man zsh-lovers
2275
2276 You can adjust some options through environment variables when
2277 invoking zsh without having to edit configuration files.
2278 Basically meant for bash users who are not used to the power of
2279 the zsh yet. :)
2280
2281   "NOCOR=1    zsh" => deactivate automatic correction
2282   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
2283   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2284   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2285                       preexec() and precmd() completely
2286   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2287   "COMMAND_NOT_FOUND=1 zsh"
2288                    => Enable a handler if an external command was not found
2289                       The command called in the handler can be altered by setting
2290                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2291                       "/usr/share/command-not-found/command-not-found"
2292
2293 A value greater than 0 is enables a feature; a value equal to zero
2294 disables it. If you like one or the other of these settings, you can
2295 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2296 zshrc.'
2297
2298     print "
2299 $bg[white]$fg[black]
2300 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2301 Enjoy your grml system with the zsh!$reset_color"
2302 }
2303
2304 # debian stuff
2305 if [[ -r /etc/debian_version ]] ; then
2306     #a3# Execute \kbd{apt-cache search}
2307     alias acs='apt-cache search'
2308     #a3# Execute \kbd{apt-cache show}
2309     alias acsh='apt-cache show'
2310     #a3# Execute \kbd{apt-cache policy}
2311     alias acp='apt-cache policy'
2312     #a3# Execute \kbd{apt-get dist-upgrade}
2313     salias adg="apt-get dist-upgrade"
2314     #a3# Execute \kbd{apt-get install}
2315     salias agi="apt-get install"
2316     #a3# Execute \kbd{aptitude install}
2317     salias ati="aptitude install"
2318     #a3# Execute \kbd{apt-get upgrade}
2319     salias ag="apt-get upgrade"
2320     #a3# Execute \kbd{apt-get update}
2321     salias au="apt-get update"
2322     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2323     salias -a up="aptitude update ; aptitude safe-upgrade"
2324     #a3# Execute \kbd{dpkg-buildpackage}
2325     alias dbp='dpkg-buildpackage'
2326     #a3# Execute \kbd{grep-excuses}
2327     alias ge='grep-excuses'
2328
2329     # debian upgrade
2330     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
2331     upgrade() {
2332         emulate -L zsh
2333         if [[ -z $1 ]] ; then
2334             $SUDO apt-get update
2335             $SUDO apt-get -u upgrade
2336         else
2337             ssh $1 $SUDO apt-get update
2338             # ask before the upgrade
2339             local dummy
2340             ssh $1 $SUDO apt-get --no-act upgrade
2341             echo -n 'Process the upgrade?'
2342             read -q dummy
2343             if [[ $dummy == "y" ]] ; then
2344                 ssh $1 $SUDO apt-get -u upgrade --yes
2345             fi
2346         fi
2347     }
2348
2349     # get a root shell as normal user in live-cd mode:
2350     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2351        alias su="sudo su"
2352      fi
2353
2354     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2355     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2356     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2357     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2358 fi
2359
2360 # sort installed Debian-packages by size
2361 if check_com -c grep-status ; then
2362     #a3# List installed Debian-packages sorted by size
2363     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
2364 fi
2365
2366 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2367 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
2368     if check_com -c wodim ; then
2369         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
2370 See #377109 in the BTS of Debian for more details.
2371
2372 Please use the wodim binary instead' ; return 1"
2373     fi
2374 fi
2375
2376 # get_tw_cli has been renamed into get_3ware
2377 if check_com -c get_3ware ; then
2378     get_tw_cli() {
2379         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
2380         get_3ware
2381     }
2382 fi
2383
2384 # I hate lacking backward compatibility, so provide an alternative therefore
2385 if ! check_com -c apache2-ssl-certificate ; then
2386
2387     apache2-ssl-certificate() {
2388
2389     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
2390     print 'You might want to take a look at Debian the package ssl-cert as well.'
2391     print 'To generate a certificate for use with apache2 follow the instructions:'
2392
2393     echo '
2394
2395 export RANDFILE=/dev/random
2396 mkdir /etc/apache2/ssl/
2397 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
2398 chmod 600 /etc/apache2/ssl/apache.pem
2399
2400 Run "grml-tips ssl-certificate" if you need further instructions.
2401 '
2402     }
2403 fi
2404 # }}}
2405
2406 # {{{ Use hard limits, except for a smaller stack and no core dumps
2407 unlimit
2408 is425 && limit stack 8192
2409 isgrmlcd && limit core 0 # important for a live-cd-system
2410 limit -s
2411 # }}}
2412
2413 # {{{ completion system
2414
2415 # called later (via is4 && grmlcomp)
2416 # note: use 'zstyle' for getting current settings
2417 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
2418 grmlcomp() {
2419     # TODO: This could use some additional information
2420
2421     # allow one error for every three characters typed in approximate completer
2422     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
2423
2424     # don't complete backup files as executables
2425     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
2426
2427     # start menu completion only if it could find no unambiguous initial string
2428     zstyle ':completion:*:correct:*'       insert-unambiguous true
2429     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
2430     zstyle ':completion:*:correct:*'       original true
2431
2432     # activate color-completion
2433     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
2434
2435     # format on completion
2436     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
2437
2438     # complete 'cd -<tab>' with menu
2439     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
2440
2441     # insert all expansions for expand completer
2442     zstyle ':completion:*:expand:*'        tag-order all-expansions
2443     zstyle ':completion:*:history-words'   list false
2444
2445     # activate menu
2446     zstyle ':completion:*:history-words'   menu yes
2447
2448     # ignore duplicate entries
2449     zstyle ':completion:*:history-words'   remove-all-dups yes
2450     zstyle ':completion:*:history-words'   stop yes
2451
2452     # match uppercase from lowercase
2453     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
2454
2455     # separate matches into groups
2456     zstyle ':completion:*:matches'         group 'yes'
2457     zstyle ':completion:*'                 group-name ''
2458
2459     if [[ "$NOMENU" -eq 0 ]] ; then
2460         # if there are more than 5 options allow selecting from a menu
2461         zstyle ':completion:*'               menu select=5
2462     else
2463         # don't use any menus at all
2464         setopt no_auto_menu
2465     fi
2466
2467     zstyle ':completion:*:messages'        format '%d'
2468     zstyle ':completion:*:options'         auto-description '%d'
2469
2470     # describe options in full
2471     zstyle ':completion:*:options'         description 'yes'
2472
2473     # on processes completion complete all user processes
2474     zstyle ':completion:*:processes'       command 'ps -au$USER'
2475
2476     # offer indexes before parameters in subscripts
2477     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
2478
2479     # provide verbose completion information
2480     zstyle ':completion:*'                 verbose true
2481
2482     # recent (as of Dec 2007) zsh versions are able to provide descriptions
2483     # for commands (read: 1st word in the line) that it will list for the user
2484     # to choose from. The following disables that, because it's not exactly fast.
2485     zstyle ':completion:*:-command-:*:'    verbose false
2486
2487     # set format for warnings
2488     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
2489
2490     # define files to ignore for zcompile
2491     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
2492     zstyle ':completion:correct:'          prompt 'correct to: %e'
2493
2494     # Ignore completion functions for commands you don't have:
2495     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
2496
2497     # Provide more processes in completion of programs like killall:
2498     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
2499
2500     # complete manual by their section
2501     zstyle ':completion:*:manuals'    separate-sections true
2502     zstyle ':completion:*:manuals.*'  insert-sections   true
2503     zstyle ':completion:*:man:*'      menu yes select
2504
2505     # provide .. as a completion
2506     zstyle ':completion:*' special-dirs ..
2507
2508     # run rehash on completion so new installed program are found automatically:
2509     _force_rehash() {
2510         (( CURRENT == 1 )) && rehash
2511         return 1
2512     }
2513
2514     ## correction
2515     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2516     if [[ "$NOCOR" -gt 0 ]] ; then
2517         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2518         setopt nocorrect
2519     else
2520         # try to be smart about when to use what completer...
2521         setopt correct
2522         zstyle -e ':completion:*' completer '
2523             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2524                 _last_try="$HISTNO$BUFFER$CURSOR"
2525                 reply=(_complete _match _ignored _prefix _files)
2526             else
2527                 if [[ $words[1] == (rm|mv) ]] ; then
2528                     reply=(_complete _files)
2529                 else
2530                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2531                 fi
2532             fi'
2533     fi
2534
2535     # command for process lists, the local web server details and host completion
2536     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2537
2538     # caching
2539     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2540                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2541
2542     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
2543     if is42 ; then
2544         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2545         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2546     else
2547         _ssh_hosts=()
2548         _etc_hosts=()
2549     fi
2550     hosts=(
2551         $(hostname)
2552         "$_ssh_hosts[@]"
2553         "$_etc_hosts[@]"
2554         grml.org
2555         localhost
2556     )
2557     zstyle ':completion:*:hosts' hosts $hosts
2558     # TODO: so, why is this here?
2559     #  zstyle '*' hosts $hosts
2560
2561     # use generic completion system for programs not yet defined; (_gnu_generic works
2562     # with commands that provide a --help option with "standard" gnu-like output.)
2563     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
2564                    pal stow tail uname ; do
2565         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
2566     done; unset compcom
2567
2568     # see upgrade function in this file
2569     compdef _hosts upgrade
2570 }
2571 # }}}
2572
2573 # {{{ grmlstuff
2574 grmlstuff() {
2575 # people should use 'grml-x'!
2576     startx() {
2577         if [[ -e /etc/X11/xorg.conf ]] ; then
2578             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
2579         else
2580             echo "Please use the script \"grml-x\" for starting the X Window System
2581 because there does not exist /etc/X11/xorg.conf yet.
2582 If you want to use startx anyway please call \"/usr/bin/startx\"."
2583             return -1
2584         fi
2585     }
2586
2587     xinit() {
2588         if [[ -e /etc/X11/xorg.conf ]] ; then
2589             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
2590         else
2591             echo "Please use the script \"grml-x\" for starting the X Window System.
2592 because there does not exist /etc/X11/xorg.conf yet.
2593 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
2594             return -1
2595         fi
2596     }
2597
2598     if check_com -c 915resolution ; then
2599         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
2600     fi
2601
2602     #a1# Output version of running grml
2603     alias grml-version='cat /etc/grml_version'
2604
2605     if check_com -c rebuildfstab ; then
2606         #a1# Rebuild /etc/fstab
2607         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2608     fi
2609
2610     if check_com -c grml-debootstrap ; then
2611         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
2612     fi
2613 }
2614 # }}}
2615
2616 # {{{ now run the functions
2617 isgrml && checkhome
2618 is4    && isgrml    && grmlstuff
2619 is4    && grmlcomp
2620 # }}}
2621
2622 # {{{ keephack
2623 is4 && xsource "/etc/zsh/keephack"
2624 # }}}
2625
2626 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
2627 # You use it as follows:
2628 # $ NTREF=/reference/file
2629 # $ ls -l *(e:nt:)
2630 # This lists all the files in the current directory newer than the reference file.
2631 # You can also specify the reference file inline; note quotes:
2632 # $ ls -l *(e:'nt ~/.zshenv':)
2633 is4 && nt() {
2634     if [[ -n $1 ]] ; then
2635         local NTREF=${~1}
2636     fi
2637     [[ $REPLY -nt $NTREF ]]
2638 }
2639 # }}}
2640
2641 # shell functions {{{
2642
2643 #f1# Provide csh compatibility
2644 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
2645
2646 #f1# Reload an autoloadable function
2647 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2648
2649 # TODO: Who really uses reload()? The proper way to reload a zsh setup is to
2650 # actually restart the shell via 'exec zsh'. And reload with arguments is the
2651 # same as freload() above. -ft
2652 #f1# Reload zsh setup
2653 reload() {
2654     if [[ "$#*" -eq 0 ]] ; then
2655         [[ -r ~/.zshrc ]] && . ~/.zshrc
2656     else
2657         local fn
2658         for fn in "$@"; do
2659             unfunction $fn
2660             autoload -U $fn
2661         done
2662     fi
2663 }
2664 compdef _functions reload freload
2665
2666 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2667 sll() {
2668     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2669     for file in "$@" ; do
2670         while [[ -h "$file" ]] ; do
2671             ls -l $file
2672             file=$(readlink "$file")
2673         done
2674     done
2675 }
2676
2677 # fast manual access
2678 if check_com qma ; then
2679     #f1# View the zsh manual
2680     manzsh()  { qma zshall "$1" }
2681     compdef _man qma
2682 else
2683     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
2684 fi
2685
2686 # TODO: Is it supported to use pager settings like this?
2687 #   PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2688 # with respect to wordsplitting. (ie. ${=PAGER})
2689 if check_com -c $PAGER ; then
2690     #f1# View Debian's changelog of a given package
2691     dchange() {
2692         emulate -L zsh
2693         if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
2694             $PAGER /usr/share/doc/$1/changelog.Debian.gz
2695         elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2696             $PAGER /usr/share/doc/$1/changelog.gz
2697         else
2698             if check_com -c aptitude ; then
2699                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2700                 if isgrml ; then
2701                     aptitude -t unstable changelog $1
2702                 else
2703                     aptitude changelog $1
2704                 fi
2705             else
2706                 echo "No changelog for package $1 found, sorry."
2707                 return 1
2708             fi
2709         fi
2710     }
2711     _dchange() { _files -W /usr/share/doc -/ }
2712     compdef _dchange dchange
2713
2714     #f1# View Debian's NEWS of a given package
2715     dnews() {
2716         emulate -L zsh
2717         if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2718             $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2719         else
2720             if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2721                 $PAGER /usr/share/doc/$1/NEWS.gz
2722             else
2723                 echo "No NEWS file for package $1 found, sorry."
2724                 return 1
2725             fi
2726         fi
2727     }
2728     _dnews() { _files -W /usr/share/doc -/ }
2729     compdef _dnews dnews
2730
2731     #f1# View upstream's changelog of a given package
2732     uchange() {
2733         emulate -L zsh
2734         if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2735             $PAGER /usr/share/doc/$1/changelog.gz
2736         else
2737             echo "No changelog for package $1 found, sorry."
2738             return 1
2739         fi
2740     }
2741     _uchange() { _files -W /usr/share/doc -/ }
2742     compdef _uchange uchange
2743 fi
2744
2745 # zsh profiling
2746 profile() {
2747     ZSH_PROFILE_RC=1 $SHELL "$@"
2748 }
2749
2750 #f1# Edit an alias via zle
2751 edalias() {
2752     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2753 }
2754 compdef _aliases edalias
2755
2756 #f1# Edit a function via zle
2757 edfunc() {
2758     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
2759 }
2760 compdef _functions edfunc
2761
2762 # use it e.g. via 'Restart apache2'
2763 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2764 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2765 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2766 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2767 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2768 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2769     __start_stop() {
2770         local action_="${1:l}"  # e.g Start/Stop/Restart
2771         local service_="$2"
2772         local param_="$3"
2773
2774         local service_target_="$(readlink /etc/init.d/$service_)"
2775         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2776             # runit
2777             case "${action_}" in
2778                 start) if [[ ! -e /etc/service/$service_ ]]; then
2779                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2780                        else
2781                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2782                        fi ;;
2783                 # there is no reload in runits sysv emulation
2784                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2785                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2786             esac
2787         else
2788             # sysvinit
2789             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2790         fi
2791     }
2792
2793     for i in Start Restart Stop Force-Reload Reload ; do
2794         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2795     done
2796 fi
2797
2798 #f1# Provides useful information on globbing
2799 H-Glob() {
2800     echo -e "
2801     /      directories
2802     .      plain files
2803     @      symbolic links
2804     =      sockets
2805     p      named pipes (FIFOs)
2806     *      executable plain files (0100)
2807     %      device files (character or block special)
2808     %b     block special files
2809     %c     character special files
2810     r      owner-readable files (0400)
2811     w      owner-writable files (0200)
2812     x      owner-executable files (0100)
2813     A      group-readable files (0040)
2814     I      group-writable files (0020)
2815     E      group-executable files (0010)
2816     R      world-readable files (0004)
2817     W      world-writable files (0002)
2818     X      world-executable files (0001)
2819     s      setuid files (04000)
2820     S      setgid files (02000)
2821     t      files with the sticky bit (01000)
2822
2823   print *(m-1)          # Files modified up to a day ago
2824   print *(a1)           # Files accessed a day ago
2825   print *(@)            # Just symlinks
2826   print *(Lk+50)        # Files bigger than 50 kilobytes
2827   print *(Lk-50)        # Files smaller than 50 kilobytes
2828   print **/*.c          # All *.c files recursively starting in \$PWD
2829   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2830   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2831   print *~*.*           # All Files that do not contain a dot
2832   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2833   print -l *(.c|.h)     # Lists *.c and *.h
2834   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2835   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2836 }
2837 alias help-zshglob=H-Glob
2838
2839 check_com -c qma && alias ?='qma zshall'
2840
2841 # grep for running process, like: 'any vim'
2842 any() {
2843     emulate -L zsh
2844     if [[ -z "$1" ]] ; then
2845         echo "any - grep for process(es) by keyword" >&2
2846         echo "Usage: any <keyword>" >&2 ; return 1
2847     else
2848         local STRING=$1
2849         local LENGTH=$(expr length $STRING)
2850         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
2851         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
2852         ps xauwww| grep "[$FIRSCHAR]$REST"
2853     fi
2854 }
2855
2856 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2857 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2858 [[ -r /proc/1/maps ]] && \
2859 deswap() {
2860     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2861     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2862     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2863 }
2864
2865 # print hex value of a number
2866 hex() {
2867     emulate -L zsh
2868     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2869 }
2870
2871 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2872 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2873 peval() {
2874     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2875     perl -e "print eval($CALC),\"\n\";"
2876 }
2877 functions peval &>/dev/null && alias calc=peval
2878
2879 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
2880 # certain circumstances, so work around it, no matter which environment we have
2881 brltty() {
2882     if [[ -z "$DISPLAY" ]] ; then
2883         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
2884         command brltty "$@"
2885     else
2886         command brltty "$@"
2887     fi
2888 }
2889
2890 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2891 aoeu() {
2892     echo -n 'Switching to us keyboard layout: '
2893     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2894     echo 'Done'
2895 }
2896 asdf() {
2897     echo -n 'Switching to dvorak keyboard layout: '
2898     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2899     echo 'Done'
2900 }
2901 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2902 uiae() {
2903     echo -n 'Switching to us keyboard layout: '
2904     setxkbmap us && echo 'Done' || echo 'Failed'
2905 }
2906
2907 # set up an ipv6 tunnel
2908 ipv6-tunnel() {
2909     emulate -L zsh
2910     case $1 in
2911         start)
2912             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2913                 print 'ipv6 tunnel already set up, nothing to be done.'
2914                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2915             else
2916                 [[ -n "$PUBLIC_IP" ]] || \
2917                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2918                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2919
2920                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
2921                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
2922                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
2923                 ifconfig sit0 tunnel ::192.88.99.1 up
2924                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
2925             fi
2926             ;;
2927         status)
2928             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2929                 print 'ipv6 tunnel available' ; return 0
2930             else
2931                 print 'ipv6 tunnel not available' ; return 1
2932             fi
2933             ;;
2934         stop)
2935             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2936                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
2937                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
2938             else
2939                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
2940             fi
2941             ;;
2942         *)
2943             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
2944             ;;
2945     esac
2946 }
2947
2948 # run dhclient for wireless device
2949 iwclient() {
2950     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
2951 }
2952
2953 # spawn a minimally set up ksh - useful if you want to umount /usr/.
2954 minimal-shell() {
2955     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
2956 }
2957
2958 # a wrapper for vim, that deals with title setting
2959 #   VIM_OPTIONS
2960 #       set this array to a set of options to vim you always want
2961 #       to have set when calling vim (in .zshrc.local), like:
2962 #           VIM_OPTIONS=( -p )
2963 #       This will cause vim to send every file given on the
2964 #       commandline to be send to it's own tab (needs vim7).
2965 vim() {
2966     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2967 }
2968
2969 # make a backup of a file
2970 bk() {
2971     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2972 }
2973
2974 #f1# grep for patterns in grml's zsh setup
2975 zg() {
2976 #{{{
2977     LANG=C perl -e '
2978
2979 sub usage {
2980     print "usage: zg -[anr] <pattern>\n";
2981     print " Search for patterns in grml'\''s zshrc.\n";
2982     print " zg takes no or exactly one option plus a non empty pattern.\n\n";
2983     print "   options:\n";
2984     print "     --  no options (use if your pattern starts in with a dash.\n";
2985     print "     -a  search for the pattern in all code regions\n";
2986     print "     -n  search for the pattern in non-root code only\n";
2987     print "     -r  search in code for everyone (also root) only\n\n";
2988     print "   The default is -a for non-root users and -r for root.\n\n";
2989     print " If you installed the zshrc to a non-default locations (ie *NOT*\n";
2990     print " in /etc/zsh/zshrc) do: export GRML_ZSHRC=\$HOME/.zshrc\n";
2991     print " ...in case you copied the file to that location.\n\n";
2992     exit 1;
2993 }
2994
2995 if ($ENV{GRML_ZSHRC} ne "") {
2996     $RC = $ENV{GRML_ZSHRC};
2997 } else {
2998     $RC = "/etc/zsh/zshrc";
2999 }
3000
3001 usage if ($#ARGV < 0 || $#ARGV > 1);
3002 if ($> == 0) { $mode = "allonly"; }
3003 else { $mode = "all"; }
3004
3005 $opt = $ARGV[0];
3006 if ($opt eq "--")     { shift; }
3007 elsif ($opt eq "-a")  { $mode = "all"; shift; }
3008 elsif ($opt eq "-n")  { $mode = "nonroot"; shift; }
3009 elsif ($opt eq "-r" ) { $mode = "allonly"; shift; }
3010 elsif ($opt =~ m/^-/ || $#ARGV > 0) { usage(); }
3011
3012 $pattern = $ARGV[0];
3013 usage() if ($pattern eq "");
3014
3015 open FH, "<$RC" or die "zg: Could not open $RC: $!\n";
3016 while ($line = <FH>) {
3017     chomp $line;
3018     if ($line =~ m/^#:grep:marker:for:mika:/) { $markerfound = 1; next; }
3019     next if ($mode eq "nonroot" && markerfound == 0);
3020     break if ($mode eq "allonly" && markerfound == 1);
3021     print $line, "\n" if ($line =~ /$pattern/);
3022 }
3023 close FH;
3024 exit 0;
3025
3026     ' -- "$@"
3027 #}}}
3028     return $?
3029 }
3030
3031 # }}}
3032
3033 # {{{ make sure our environment is clean regarding colors
3034 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
3035 # }}}
3036
3037 # "persistent history" {{{
3038 # just write important commands you always need to ~/.important_commands
3039 if [[ -r ~/.important_commands ]] ; then
3040     fc -R ~/.important_commands
3041 fi
3042 # }}}
3043
3044 #:grep:marker:for:mika: :-)
3045 ### non-root (EUID != 0) code below
3046 ###
3047
3048 if (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) ; then
3049     zrclocal
3050     return 0
3051 fi
3052
3053
3054 # variables {{{
3055
3056 # set terminal property (used e.g. by msgid-chooser)
3057 export COLORTERM="yes"
3058
3059 # set default browser
3060 if [[ -z "$BROWSER" ]] ; then
3061     if [[ -n "$DISPLAY" ]] ; then
3062         #v# If X11 is running
3063         check_com -c firefox && export BROWSER=firefox
3064     else
3065         #v# If no X11 is running
3066         check_com -c w3m && export BROWSER=w3m
3067     fi
3068 fi
3069
3070 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
3071 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
3072 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
3073
3074 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
3075 #v# [for non-root only]
3076 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
3077 # }}}
3078
3079 # aliases {{{
3080
3081 # Xterm resizing-fu.
3082 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
3083 alias hide='echo -en "\033]50;nil2\007"'
3084 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
3085 alias small='echo -en "\033]50;6x10\007"'
3086 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
3087 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
3088 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
3089 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
3090 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
3091 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
3092
3093 # general
3094 #a2# Execute \kbd{du -sch}
3095 alias da='du -sch'
3096 #a2# Execute \kbd{jobs -l}
3097 alias j='jobs -l'
3098
3099 # compile stuff
3100 #a2# Execute \kbd{./configure}
3101 alias CO="./configure"
3102 #a2# Execute \kbd{./configure --help}
3103 alias CH="./configure --help"
3104
3105 # arch/tla stuff
3106 if check_com -c tla ; then
3107     #a2# Execute \kbd{tla what-changed --diffs | less}
3108     alias tdi='tla what-changed --diffs | less'
3109     #a2# Execute \kbd{tla-buildpackage}
3110     alias tbp='tla-buildpackage'
3111     #a2# Execute \kbd{tla archive-mirror}
3112     alias tmi='tla archive-mirror'
3113     #a2# Execute \kbd{tla commit}
3114     alias tco='tla commit'
3115     #a2# Execute \kbd{tla star-merge}
3116     alias tme='tla star-merge'
3117 fi
3118
3119 # listing stuff
3120 #a2# Execute \kbd{ls -lSrah}
3121 alias dir="ls -lSrah"
3122 #a2# Only show dot-directories
3123 alias lad='ls -d .*(/)'                # only show dot-directories
3124 #a2# Only show dot-files
3125 alias lsa='ls -a .*(.)'                # only show dot-files
3126 #a2# Only files with setgid/setuid/sticky flag
3127 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
3128 #a2# Only show 1st ten symlinks
3129 alias lsl='ls -l *(@[1,10])'           # only symlinks
3130 #a2# Display only executables
3131 alias lsx='ls -l *(*[1,10])'           # only executables
3132 #a2# Display world-{readable,writable,executable} files
3133 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
3134 #a2# Display the ten biggest files
3135 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
3136 #a2# Only show directories
3137 alias lsd='ls -d *(/)'                 # only show directories
3138 #a2# Only show empty directories
3139 alias lse='ls -d *(/^F)'               # only show empty directories
3140 #a2# Display the ten newest files
3141 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
3142 #a2# Display the ten oldest files
3143 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
3144 #a2# Display the ten smallest files
3145 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
3146
3147 # chmod
3148 #a2# Execute \kbd{chmod 600}
3149 alias rw-='chmod 600'
3150 #a2# Execute \kbd{chmod 700}
3151 alias rwx='chmod 700'
3152 #m# a2 r-{}- Execute \kbd{chmod 644}
3153 alias r--='chmod 644'
3154 #a2# Execute \kbd{chmod 755}
3155 alias r-x='chmod 755'
3156
3157 # some useful aliases
3158 #a2# Execute \kbd{mkdir -o}
3159 alias md='mkdir -p'
3160
3161 check_com -c ipython && alias ips='ipython -p sh'
3162
3163 # console stuff
3164 #a2# Execute \kbd{mplayer -vo fbdev}
3165 alias cmplayer='mplayer -vo fbdev'
3166 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
3167 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
3168 #a2# Execute \kbd{links2 -driver fb}
3169 alias fblinks='links2 -driver fb'
3170
3171 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3172 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3173 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3174
3175 # simple webserver
3176 check_com -c python && alias http="python -m SimpleHTTPServer"
3177
3178 # Use 'g' instead of 'git':
3179 check_com g || alias g='git'
3180
3181 # check whether Debian's package management (dpkg) is running
3182 if check_com salias ; then
3183     #a2# Check whether a dpkg instance is currently running
3184     salias check_dpkg_running="dpkg_running"
3185 fi
3186
3187 # work around non utf8 capable software in utf environment via $LANG and luit
3188 if check_com isutfenv && check_com luit ; then
3189     if check_com -c mrxvt ; then
3190         isutfenv && [[ -n "$LANG" ]] && \
3191             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3192     fi
3193
3194     if check_com -c aterm ; then
3195         isutfenv && [[ -n "$LANG" ]] && \
3196             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3197     fi
3198
3199     if check_com -c centericq ; then
3200         isutfenv && [[ -n "$LANG" ]] && \
3201             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3202     fi
3203 fi
3204 # }}}
3205
3206 # useful functions {{{
3207
3208 # searching
3209 #f4# Search for newspostings from authors
3210 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
3211 #f4# Search Debian Bug Tracking System
3212 debbug()  {
3213     emulate -L zsh
3214     setopt extendedglob
3215     if [[ $# -eq 1 ]]; then
3216         case "$1" in
3217             ([0-9]##)
3218             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
3219             ;;
3220             (*@*)
3221             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
3222             ;;
3223             (*)
3224             ${=BROWSER} "http://bugs.debian.org/$*"
3225             ;;
3226         esac
3227     else
3228         print "$0 needs one argument"
3229         return 1
3230     fi
3231 }
3232 #f4# Search Debian Bug Tracking System in mbox format
3233 debbugm() {
3234     emulate -L zsh
3235     bts show --mbox $1
3236 }
3237 #f4# Search DMOZ
3238 dmoz()    {
3239     emulate -L zsh
3240     ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_}
3241 }
3242 #f4# Search German   Wiktionary
3243 dwicti()  {
3244     emulate -L zsh
3245     ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_}
3246 }
3247 #f4# Search English  Wiktionary
3248 ewicti()  {
3249     emulate -L zsh
3250     ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_}
3251 }
3252 #f4# Search Google Groups
3253 ggogle()  {
3254     emulate -L zsh
3255     ${=BROWSER} "http://groups.google.com/groups?q=$*"
3256 }
3257 #f4# Search Google
3258 google()  {
3259     emulate -L zsh
3260     ${=BROWSER} "http://www.google.com/search?&num=100&q=$*"
3261 }
3262 #f4# Search Google Groups for MsgID
3263 mggogle() {
3264     emulate -L zsh
3265     ${=BROWSER} "http://groups.google.com/groups?selm=$*"
3266 }
3267 #f4# Search Netcraft
3268 netcraft(){
3269     emulate -L zsh
3270     ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1"
3271 }
3272 #f4# Use German Wikipedia's full text search
3273 swiki()   {
3274     emulate -L zsh
3275     ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1}
3276 }
3277 #f4# search \kbd{dict.leo.org}
3278 oleo()    {
3279     emulate -L zsh
3280     ${=BROWSER} "http://dict.leo.org/?search=$*"
3281 }
3282 #f4# Search German   Wikipedia
3283 wikide()  {
3284     emulate -L zsh
3285     ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}"
3286 }
3287 #f4# Search English  Wikipedia
3288 wikien()  {
3289     emulate -L zsh
3290     ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}"
3291 }
3292 #f4# Search official debs
3293 wodeb()   {
3294     emulate -L zsh
3295     ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all"
3296 }
3297
3298 #m# f4 gex() Exact search via Google
3299 check_com google && gex () {
3300     google "\"[ $1]\" $*"
3301 }
3302
3303 # misc
3304 #f5# Backup \kbd{file {\rm to} file\_timestamp}
3305 bk() {
3306     emulate -L zsh
3307     cp -b $1 $1_`date --iso-8601=m`
3308 }
3309 #f5# Copied diff
3310 cdiff() {
3311     emulate -L zsh
3312     diff -crd "$*" | egrep -v "^Only in |^Binary files "
3313 }
3314 #f5# cd to directoy and list files
3315 cl() {
3316     emulate -L zsh
3317     cd $1 && ls -a
3318 }
3319 #f5# Cvs add
3320 cvsa() {
3321     emulate -L zsh
3322     cvs add $* && cvs com -m 'initial checkin' $*
3323 }
3324 #f5# Cvs diff
3325 cvsd() {
3326     emulate -L zsh
3327     cvs diff -N $* |& $PAGER
3328 }
3329 #f5# Cvs log
3330 cvsl() {
3331     emulate -L zsh
3332     cvs log $* |& $PAGER
3333 }
3334 #f5# Cvs update
3335 cvsq() {
3336     emulate -L zsh
3337     cvs -nq update
3338 }
3339 #f5# Rcs2log
3340 cvsr() {
3341     emulate -L zsh
3342     rcs2log $* | $PAGER
3343 }
3344 #f5# Cvs status
3345 cvss() {
3346     emulate -L zsh
3347     cvs status -v $*
3348 }
3349 #f5# Disassemble source files using gcc and as
3350 disassemble(){
3351     emulate -L zsh
3352     gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null
3353 }
3354 #f5# Firefox remote control - open given URL
3355 fir() {
3356     firefox -a firefox -remote "openURL($1)"
3357 }
3358 #f5# Create Directoy and \kbd{cd} to it
3359 mcd() {
3360     mkdir -p "$@" && cd "$@"
3361 }
3362 #f5# Unified diff to timestamped outputfile
3363 mdiff() {
3364     diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1"
3365 }
3366 #f5# Memory overview
3367 memusage() {
3368     ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc
3369 }
3370 #f5# Show contents of tar file
3371 shtar() {
3372     emulate -L zsh
3373     gunzip -c $1 | tar -tf - -- | $PAGER
3374 }
3375 #f5# Show contents of tgz file
3376 shtgz() {
3377     emulate -L zsh
3378     tar -ztf $1 | $PAGER
3379 }
3380 #f5# Show contents of zip file
3381 shzip() {
3382     emulate -L zsh
3383     unzip -l $1 | $PAGER
3384 }
3385 #f5# Greps signature from file
3386 sig() {
3387     emulate -L zsh
3388     agrep -d '^-- $' "$*" ~/.Signature
3389 }
3390 #f5# Unified diff
3391 udiff() {
3392     emulate -L zsh
3393     diff -urd $* | egrep -v "^Only in |^Binary files "
3394 }
3395 #f5# (Mis)use \kbd{vim} as \kbd{less}
3396 viless() {
3397     emulate -L zsh
3398     vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}"
3399 }
3400
3401 # Function Usage: uopen $URL/$file
3402 #f5# Download a file and display it locally
3403 uopen() {
3404     emulate -L zsh
3405     if ! [[ -n "$1" ]] ; then
3406         print "Usage: uopen \$URL/\$file">&2
3407         return 1
3408     else
3409         FILE=$1
3410         MIME=$(curl --head $FILE | grep Content-Type | cut -d ' ' -f 2 | cut -d\; -f 1)
3411         MIME=${MIME%$'\r'}
3412         curl $FILE | see ${MIME}:-
3413     fi
3414 }
3415
3416 # Function Usage: doc packagename
3417 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
3418 doc() {
3419     emulate -L zsh
3420     cd /usr/share/doc/$1 && ls
3421 }
3422 _doc() { _files -W /usr/share/doc -/ }
3423 check_com compdef && compdef _doc doc
3424
3425 #f5# Make screenshot
3426 sshot() {
3427     [[ ! -d ~/shots  ]] && mkdir ~/shots
3428     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
3429     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
3430 }
3431
3432 # list images only
3433 limg() {
3434     local -a images
3435     images=( *.{jpg,gif,png}(.N) )
3436
3437     if [[ $#images -eq 0 ]] ; then
3438         print "No image files found"
3439     else
3440         ls "$@" "$images[@]"
3441     fi
3442 }
3443
3444 #f5# Create PDF file from source code
3445 makereadable() {
3446     emulate -L zsh
3447     output=$1
3448     shift
3449     a2ps --medium A4dj -E -o $output $*
3450     ps2pdf $output
3451 }
3452
3453 # zsh with perl-regex - use it e.g. via:
3454 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
3455 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
3456 regcheck() {
3457     emulate -L zsh
3458     zmodload -i zsh/pcre
3459     pcre_compile $1 && \
3460     pcre_match $2 && echo "regex matches" || echo "regex does not match"
3461 }
3462
3463 #f5# List files which have been modified within the last {\it n} days
3464 new() {
3465     emulate -L zsh
3466     print -l *(m-$1)
3467 }
3468
3469 #f5# Grep in history
3470 greph() {
3471     emulate -L zsh
3472     history 0 | grep $1
3473 }
3474 # use colors when GNU grep with color-support
3475 #a2# Execute \kbd{grep -{}-color=auto}
3476 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
3477 #a2# Execute \kbd{grep -i -{}-color=auto}
3478 alias GREP='grep -i --color=auto'
3479
3480 #f5# Watch manpages in a stretched style
3481 man2() { PAGER='dash -c "sed G | /usr/bin/less"' command man "$@" ; }
3482
3483 # d():Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
3484 # note: option AUTO_PUSHD has to be set
3485 #f5# Jump between directories
3486 d() {
3487     emulate -L zsh
3488     autoload -U colors
3489     local color=$fg_bold[blue]
3490     integer i=0
3491     dirs -p | while read dir; do
3492         local num="${$(printf "%-4d " $i)/ /.}"
3493         printf " %s  $color%s$reset_color\n" $num $dir
3494         (( i++ ))
3495     done
3496     integer dir=-1
3497     read -r 'dir?Jump to directory: ' || return
3498     (( dir == -1 )) && return
3499     if (( dir < 0 || dir >= i )); then
3500         echo d: no such directory stack entry: $dir
3501         return 1
3502     fi
3503     cd ~$dir
3504 }
3505
3506 # usage example: 'lcheck strcpy'
3507 #f5# Find out which libs define a symbol
3508 lcheck() {
3509     if [[ -n "$1" ]] ; then
3510         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
3511     else
3512         echo "Usage: lcheck <function>" >&2
3513     fi
3514 }
3515
3516 #f5# Clean up directory - remove well known tempfiles
3517 purge() {
3518     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
3519     NBFILES=${#FILES}
3520     if [[ $NBFILES > 0 ]] ; then
3521         print $FILES
3522         local ans
3523         echo -n "Remove these files? [y/n] "
3524         read -q ans
3525         if [[ $ans == "y" ]] ; then
3526             rm ${FILES}
3527             echo ">> $PWD purged, $NBFILES files removed"
3528         else
3529             echo "Ok. .. than not.."
3530         fi
3531     fi
3532 }
3533
3534 # Translate DE<=>EN
3535 # 'translate' looks up fot a word in a file with language-to-language
3536 # translations (field separator should be " : "). A typical wordlist looks
3537 # like at follows:
3538 #  | english-word : german-transmission
3539 # It's also only possible to translate english to german but not reciprocal.
3540 # Use the following oneliner to turn back the sort order:
3541 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3542 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3543 #f5# Translates a word
3544 trans() {
3545     emulate -L zsh
3546     case "$1" in
3547         -[dD]*)
3548             translate -l de-en $2
3549             ;;
3550         -[eE]*)
3551             translate -l en-de $2
3552             ;;
3553         *)
3554             echo "Usage: $0 { -D | -E }"
3555             echo "         -D == German to English"
3556             echo "         -E == English to German"
3557     esac
3558 }
3559
3560 #f5# List all occurrences of programm in current PATH
3561 plap() {
3562     emulate -L zsh
3563     if [[ $# = 0 ]] ; then
3564         echo "Usage:    $0 program"
3565         echo "Example:  $0 zsh"
3566         echo "Lists all occurrences of program in the current PATH."
3567     else
3568         ls -l ${^path}/*$1*(*N)
3569     fi
3570 }
3571
3572 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
3573 #f5# Select items for specific command(s) from history
3574 selhist() {
3575     emulate -L zsh
3576     local TAB=$'\t';
3577     (( $# < 1 )) && {
3578         echo "Usage: $0 command"
3579         return 1
3580     };
3581     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
3582     print -l $cmd | less -F
3583     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
3584     local answer
3585     read answer
3586     print -z "${cmd[$answer]#*$TAB}"
3587 }
3588
3589 # Use vim to convert plaintext to HTML
3590 #f5# Transform files to html with highlighting
3591 2html() {
3592     emulate -L zsh
3593     vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null
3594 }
3595
3596 # Usage: simple-extract <file>
3597 #f5# Smart archive extractor
3598 simple-extract () {
3599     emulate -L zsh
3600     if [[ -f $1 ]] ; then
3601         case $1 in
3602             *.tar.bz2)  bzip2 -v -d $1      ;;
3603             *.tar.gz)   tar -xvzf $1        ;;
3604             *.rar)      unrar $1            ;;
3605             *.deb)      ar -x $1            ;;
3606             *.bz2)      bzip2 -d $1         ;;
3607             *.lzh)      lha x $1            ;;
3608             *.gz)       gunzip -d $1        ;;
3609             *.tar)      tar -xvf $1         ;;
3610             *.tgz)      gunzip -d $1        ;;
3611             *.tbz2)     tar -jxvf $1        ;;
3612             *.zip)      unzip $1            ;;
3613             *.Z)        uncompress $1       ;;
3614             *)          echo "'$1' Error. Please go away" ;;
3615         esac
3616     else
3617         echo "'$1' is not a valid file"
3618     fi
3619 }
3620
3621 # Usage: smartcompress <file> (<type>)
3622 #f5# Smart archive creator
3623 smartcompress() {
3624     emulate -L zsh
3625     if [[ -n $2 ]] ; then
3626         case $2 in
3627             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
3628             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
3629             tar.Z)          tar -Zcvf$1.$2 $1 ;;
3630             tar)            tar -cvf$1.$2  $1 ;;
3631             gz | gzip)      gzip           $1 ;;
3632             bz2 | bzip2)    bzip2          $1 ;;
3633             *)
3634                 echo "Error: $2 is not a valid compression type"
3635                 ;;
3636         esac
3637     else
3638         smartcompress $1 tar.gz
3639     fi
3640 }
3641
3642 # Usage: show-archive <archive>
3643 #f5# List an archive's content
3644 show-archive() {
3645     emulate -L zsh
3646     if [[ -f $1 ]] ; then
3647         case $1 in
3648             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
3649             *.tar)         tar -tf $1 ;;
3650             *.tgz)         tar -ztf $1 ;;
3651             *.zip)         unzip -l $1 ;;
3652             *.bz2)         bzless $1 ;;
3653             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
3654             *)             echo "'$1' Error. Please go away" ;;
3655         esac
3656     else
3657         echo "'$1' is not a valid archive"
3658     fi
3659 }
3660
3661 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
3662 #f5# Use \kbd{vim} as your manpage reader
3663 vman() {
3664     emulate -L zsh
3665     man $* | col -b | view -c 'set ft=man nomod nolist' -
3666 }
3667
3668 # function readme() { $PAGER -- (#ia3)readme* }
3669 #f5# View all README-like files in current directory in pager
3670 readme() {
3671     emulate -L zsh
3672     local files
3673     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
3674     if (($#files)) ; then
3675         $PAGER $files
3676     else
3677         print 'No README files.'
3678     fi
3679 }
3680
3681 # function ansi-colors()
3682 #f5# Display ANSI colors
3683 ansi-colors() {
3684     typeset esc="\033[" line1 line2
3685     echo " _ _ _40 _ _ _41_ _ _ _42 _ _ 43_ _ _ 44_ _ _45 _ _ _ 46_ _ _ 47_ _ _ 49_ _"
3686     for fore in 30 31 32 33 34 35 36 37; do
3687         line1="$fore "
3688         line2="   "
3689         for back in 40 41 42 43 44 45 46 47 49; do
3690             line1="${line1}${esc}${back};${fore}m Normal ${esc}0m"
3691             line2="${line2}${esc}${back};${fore};1m Bold   ${esc}0m"
3692         done
3693         echo -e "$line1\n$line2"
3694     done
3695 }
3696
3697 # suidfind() { ls -latg $path | grep '^...s' }
3698 #f5# Find all files in \$PATH with setuid bit set
3699 suidfind() { ls -latg $path/*(sN) }
3700
3701 # See above but this is /better/ ... anywise ..
3702 findsuid() {
3703     print 'Output will be written to ~/suid_* ...'
3704     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
3705     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
3706     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
3707     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
3708     print 'Finished'
3709 }
3710
3711 # TODO: So, this is the third incarnation of this function!?
3712 #f5# Reload given functions
3713 refunc() {
3714     for func in $argv ; do
3715         unfunction $func
3716         autoload $func
3717     done
3718 }
3719
3720 # a small check to see which DIR is located on which server/partition.
3721 # stolen and modified from Sven's zshrc.forall
3722 #f5# Report diskusage of a directory
3723 dirspace() {
3724     emulate -L zsh
3725     if [[ -n "$1" ]] ; then
3726         for dir in "$@" ; do
3727             if [[ -d "$dir" ]] ; then
3728                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3729             else
3730                 echo "warning: $dir does not exist" >&2
3731             fi
3732         done
3733     else
3734         for dir in $path; do
3735             if [[ -d "$dir" ]] ; then
3736                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3737             else
3738                 echo "warning: $dir does not exist" >&2
3739             fi
3740         done
3741     fi
3742 }
3743
3744 # % slow_print `cat /etc/passwd`
3745 #f5# Slowly print out parameters
3746 slow_print() {
3747     for argument in "$@" ; do
3748         for ((i = 1; i <= ${#1} ;i++)) ; do
3749             print -n "${argument[i]}"
3750             sleep 0.08
3751         done
3752         print -n " "
3753     done
3754     print ""
3755 }
3756
3757 #f5# Show some status info
3758 status() {
3759     print
3760     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")
3761     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
3762     print "Term..: $TTY ($TERM), ${BAUD:+$BAUD bauds, }$COLUMNS x $LINES chars"
3763     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
3764     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
3765     print "Uptime:$(uptime)"
3766     print
3767 }
3768
3769 # Rip an audio CD
3770 #f5# Rip an audio CD
3771 audiorip() {
3772     mkdir -p ~/ripps
3773     cd ~/ripps
3774     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
3775     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
3776     echo " * Would you like to burn the cd now? (yes/no)"
3777     read input
3778     if [[ "$input" = "yes" ]] ; then
3779         echo " ! Burning Audio CD"
3780         audioburn
3781         echo " * done."
3782     else
3783         echo " ! Invalid response."
3784     fi
3785 }
3786
3787 # and burn it
3788 #f5# Burn an audio CD (in combination with audiorip)
3789 audioburn() {
3790     cd ~/ripps
3791     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
3792     echo " * Should I remove the temporary files? (yes/no)"
3793     read input
3794     if [[ "$input" = "yes" ]] ; then
3795         echo " ! Removing Temporary Files."
3796         cd ~
3797         rm -rf ~/ripps
3798         echo " * done."
3799     else
3800         echo " ! Invalid response."
3801     fi
3802 }
3803
3804 #f5# Make an audio CD from all mp3 files
3805 mkaudiocd() {
3806     # TODO: do the renaming more zshish, possibly with zmv()
3807     emulate -L zsh
3808     cd ~/ripps
3809     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
3810     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
3811     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
3812     normalize -m *.wav
3813     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
3814 }
3815
3816 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
3817 mkiso() {
3818     emulate -L zsh
3819     echo " * Volume name "
3820     read volume
3821     echo " * ISO Name (ie. tmp.iso)"
3822     read iso
3823     echo " * Directory or File"
3824     read files
3825     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
3826 }
3827
3828 #f5# Simple thumbnails generator
3829 genthumbs() {
3830     rm -rf thumb-* index.html
3831     echo "
3832 <html>
3833   <head>
3834     <title>Images</title>
3835   </head>
3836   <body>" > index.html
3837     for f in *.(gif|jpeg|jpg|png) ; do
3838         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
3839         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
3840     done
3841     echo "
3842   </body>
3843 </html>" >> index.html
3844 }
3845
3846 #f5# Set all ulimit parameters to \kbd{unlimited}
3847 allulimit() {
3848     ulimit -c unlimited
3849     ulimit -d unlimited
3850     ulimit -f unlimited
3851     ulimit -l unlimited
3852     ulimit -n unlimited
3853     ulimit -s unlimited
3854     ulimit -t unlimited
3855 }
3856
3857 # ogg2mp3 with bitrate of 192
3858 ogg2mp3_192() {
3859     emulate -L zsh
3860     oggdec -o - $1 | lame -b 192 - ${1:r}.mp3
3861 }
3862
3863 #f5# RFC 2396 URL encoding in Z-Shell
3864 urlencode() {
3865     emulate -L zsh
3866     setopt extendedglob
3867     input=( ${(s::)1} )
3868     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%${(l:2::0:)$(([##16]#match))}}
3869 }
3870
3871 #f5# Install x-lite (VoIP software)
3872 getxlite() {
3873     emulate -L zsh
3874     setopt errreturn
3875     [[ -d ~/tmp ]] || mkdir ~/tmp
3876     cd ~/tmp
3877
3878     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
3879     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
3880         unp X-Lite_Install.tar.gz && echo done || echo failed
3881     else
3882         echo "Error while downloading." ; return 1
3883     fi
3884
3885     if [[ -x xten-xlite/xtensoftphone ]] ; then
3886         echo "Execute xten-xlite/xtensoftphone to start xlite."
3887     fi
3888 }
3889
3890 #f5# Install skype
3891 getskype() {
3892     emulate -L zsh
3893     setopt errreturn
3894     echo "Downloading debian package of skype."
3895     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
3896     wget http://www.skype.com/go/getskype-linux-deb
3897     $SUDO dpkg -i skype*.deb && echo "skype installed."
3898 }
3899
3900 #f5# Install beta-version of skype
3901 getskypebeta() {
3902     emulate -L zsh
3903     setopt errreturn
3904     echo "Downloading debian package of skype (beta version)."
3905     wget http://www.skype.com/go/getskype-linux-beta-deb
3906     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
3907 }
3908
3909 #f5# Install gizmo (VoIP software)
3910 getgizmo() {
3911     emulate -L zsh
3912     setopt errreturn
3913     echo "libgtk2.0-0, gconf2, libstdc++6, libasound2 and zlib1g have to be available. Installing."
3914     $SUDO apt-get update
3915     $SUDO apt-get install libgtk2.0-0 gconf2 libstdc++6 libasound2 zlib1g
3916     wget "$(lynx --dump http://gizmo5.com/pc/download/linux/ | awk '/libstdc\+\+6.*\.deb/ {print $2}')"
3917     $SUDO dpkg -i gizmo-project*.deb && echo "gizmo installed."
3918 }
3919
3920 #f5# Get and run AIR (Automated Image and Restore)
3921 getair() {
3922     emulate -L zsh
3923     setopt errreturn
3924     [[ -w . ]] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
3925     local VER='1.2.8'
3926     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
3927     tar zxf air-$VER.tar.gz
3928     cd air-$VER
3929     INTERACTIVE=no $SUDO ./install-air-1.2.8
3930     [[ -x /usr/local/bin/air ]] && [[ -n "$DISPLAY" ]] && $SUDO air
3931 }
3932
3933 #f5# Get specific git commitdiff
3934 git-get-diff() {
3935     emulate -L zsh
3936     if [[ -z $GITTREE ]] ; then
3937         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3938     fi
3939     if ! [[ -z $1 ]] ; then
3940         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
3941     else
3942         echo "Usage: git-get-diff <commit>"
3943     fi
3944 }
3945
3946 #f5# Get specific git commit
3947 git-get-commit() {
3948     emulate -L zsh
3949     if [[ -z $GITTREE ]] ; then
3950         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3951     fi
3952     if ! [[ -z $1 ]] ; then
3953         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
3954     else
3955         echo "Usage: git-get-commit <commit>"
3956     fi
3957 }
3958
3959 #f5# Get specific git diff
3960 git-get-plaindiff () {
3961     emulate -L zsh
3962     if [[ -z $GITTREE ]] ; then
3963        GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3964     fi
3965     if [[ -z $1 ]] ; then
3966        echo 'Usage: git-get-plaindiff '
3967     else
3968        echo -n "Downloading $1.diff ... "
3969        # avoid "generating ..." stuff from kernel.org server:
3970        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O /dev/null
3971        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff \
3972             && echo done || echo failed
3973     fi
3974 }
3975
3976
3977 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
3978 #f5# Log 'make install' output
3979 mmake() {
3980     emulate -L zsh
3981     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
3982     make -n install > ~/.errorlogs/${PWD##*/}-makelog
3983 }
3984
3985 #f5# Indent source code
3986 smart-indent() {
3987     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs "$@"
3988 }
3989
3990 # highlight important stuff in diff output, usage example: hg diff | hidiff
3991 #m# a2 hidiff \kbd{histring} oneliner for diffs
3992 check_com -c histring && \
3993     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
3994
3995 # rename pictures based on information found in exif headers
3996 #f5# Rename pictures based on information found in exif headers
3997 exirename() {
3998     emulate -L zsh
3999     if [[ $# -lt 1 ]] ; then
4000         echo 'Usage: jpgrename $FILES' >& 2
4001         return 1
4002     else
4003         echo -n 'Checking for jhead with version newer than 1.9: '
4004         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
4005         if [[ $jhead_version > '1.9' ]]; then
4006             echo 'success - now running jhead.'
4007             jhead -n%Y-%m-%d_%Hh%M_%f $*
4008         else
4009             echo 'failed - exiting.'
4010         fi
4011     fi
4012 }
4013
4014 # open file in vim and jump to line
4015 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
4016 j2v() {
4017     emulate -L zsh
4018     local -a params
4019     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
4020     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
4021     vim ${params}
4022 }
4023
4024 # get_ic() - queries imap servers for capabilities; real simple. no imaps
4025 ic_get() {
4026     emulate -L zsh
4027     local port
4028     if [[ ! -z $1 ]] ; then
4029         port=${2:-143}
4030         print "querying imap server on $1:${port}...\n";
4031         print "a1 capability\na2 logout\n" | nc $1 ${port}
4032     else
4033         print "usage:\n  $0 <imap-server> [port]"
4034     fi
4035 }
4036
4037 # creates a Maildir/ with its {new,cur,tmp} subdirs
4038 mkmaildir() {
4039     emulate -L zsh
4040     local root subdir
4041     root=${MAILDIR_ROOT:-${HOME}/Mail}
4042     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
4043     subdir=${1}
4044     mkdir -p ${root}/${subdir}/{cur,new,tmp}
4045 }
4046
4047 #f5# Change the xterm title from within GNU-screen
4048 xtrename() {
4049     emulate -L zsh
4050     if [[ $1 != "-f" ]] ; then
4051         if [[ -z ${DISPLAY} ]] ; then
4052             printf 'xtrename only makes sense in X11.\n'
4053             return 1
4054         fi
4055     else
4056         shift
4057     fi
4058     if [[ -z $1 ]] ; then
4059         printf 'usage: xtrename [-f] "title for xterm"\n'
4060         printf '  renames the title of xterm from _within_ screen.\n'
4061         printf '  also works without screen.\n'
4062         printf '  will not work if DISPLAY is unset, use -f to override.\n'
4063         return 0
4064     fi
4065     print -n "\eP\e]0;${1}\C-G\e\\"
4066     return 0
4067 }
4068
4069 # hl() highlighted less
4070 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
4071 if check_com -c highlight ; then
4072     function hl() {
4073     emulate -L zsh
4074         local theme lang
4075         theme=${HL_THEME:-""}
4076         case ${1} in
4077             (-l|--list)
4078                 ( printf 'available languages (syntax parameter):\n\n' ;
4079                     highlight --list-langs ; ) | less -SMr
4080                 ;;
4081             (-t|--themes)
4082                 ( printf 'available themes (style parameter):\n\n' ;
4083                     highlight --list-themes ; ) | less -SMr
4084                 ;;
4085             (-h|--help)
4086                 printf 'usage: hl <syntax[:theme]> <file>\n'
4087                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
4088                 printf '  Example: hl c main.c\n'
4089                 ;;
4090             (*)
4091                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
4092                     printf 'usage: hl <syntax[:theme]> <file>\n'
4093                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
4094                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
4095                     return 1
4096                 fi
4097                 lang=${1%:*}
4098                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
4099                 if [[ -n ${theme} ]] ; then
4100                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
4101                 else
4102                     highlight --ansi --syntax ${lang} ${2} | less -SMr
4103                 fi
4104                 ;;
4105         esac
4106         return 0
4107     }
4108     # ... and a proper completion for hl()
4109     # needs 'highlight' as well, so it fits fine in here.
4110     function _hl_genarg()  {
4111         local expl
4112         if [[ -prefix 1 *: ]] ; then
4113             local themes
4114             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
4115             compset -P 1 '*:'
4116             _wanted -C list themes expl theme compadd ${themes}
4117         else
4118             local langs
4119             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
4120             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
4121         fi
4122     }
4123     function _hl_complete() {
4124         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
4125     }
4126     compdef _hl_complete hl
4127 fi
4128
4129 # Create small urls via http://tinyurl.com using wget(1).
4130 function zurl() {
4131     emulate -L zsh
4132     [[ -z $1 ]] && { print "USAGE: zurl <URL>" ; return 1 }
4133
4134     local PN url tiny grabber search result preview
4135     PN=$0
4136     url=$1
4137 #   Check existence of given URL with the help of ping(1).
4138 #   N.B. ping(1) only works without an eventual given protocol.
4139     ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
4140         read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
4141
4142     if (( $? == 0 )) ; then
4143 #           Prepend 'http://' to given URL where necessary for later output.
4144             [[ ${url} != http(s|)://* ]] && url='http://'${url}
4145             tiny='http://tinyurl.com/create.php?url='
4146             if check_com -c wget ; then
4147                 grabber='wget -O- -o/dev/null'
4148             else
4149                 print "wget is not available, but mandatory for ${PN}. Aborting."
4150             fi
4151 #           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
4152             search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
4153             result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
4154 #           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
4155             preview='http://preview.'${result#http://}
4156
4157             printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
4158             printf '%s\t%s\n\n' 'Given URL:' ${url}
4159             printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
4160     else
4161         return 1
4162     fi
4163 }
4164
4165 #f2# Print a specific line of file(s).
4166 linenr () {
4167 # {{{
4168     emulate -L zsh
4169     if [ $# -lt 2 ] ; then
4170        print "Usage: linenr <number>[,<number>] <file>" ; return 1
4171     elif [ $# -eq 2 ] ; then
4172          local number=$1
4173          local file=$2
4174          command ed -s $file <<< "${number}n"
4175     else
4176          local number=$1
4177          shift
4178          for file in "$@" ; do
4179              if [ ! -d $file ] ; then
4180                 echo "${file}:"
4181                 command ed -s $file <<< "${number}n" 2> /dev/null
4182              else
4183                 continue
4184              fi
4185          done | less
4186     fi
4187 # }}}
4188 }
4189
4190 #f2# Find history events by search pattern and list them by date.
4191 whatwhen()  {
4192 # {{{
4193     emulate -L zsh
4194     local usage help ident format_l format_s first_char remain first last
4195     usage='USAGE: whatwhen [options] <searchstring> <search range>'
4196     help='Use' \`'whatwhen -h'\'' for further explanations.'
4197     ident=${(l,${#${:-Usage: }},, ,)}
4198     format_l="${ident}%s\t\t\t%s\n"
4199     format_s="${format_l//(\\t)##/\\t}"
4200     # Make the first char of the word to search for case
4201     # insensitive; e.g. [aA]
4202     first_char=[${(L)1[1]}${(U)1[1]}]
4203     remain=${1[2,-1]}
4204     # Default search range is `-100'.
4205     first=${2:-\-100}
4206     # Optional, just used for `<first> <last>' given.
4207     last=$3
4208     case $1 in
4209         ("")
4210             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
4211             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4212         ;;
4213         (-h)
4214             printf '%s\n\n' ${usage}
4215             print 'OPTIONS:'
4216             printf $format_l '-h' 'show help text'
4217             print '\f'
4218             print 'SEARCH RANGE:'
4219             printf $format_l "'0'" 'the whole history,'
4220             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
4221             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
4222             printf '\n%s\n' 'EXAMPLES:'
4223             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
4224             printf $format_l 'whatwhen zsh -250'
4225             printf $format_l 'whatwhen foo 1 99'
4226         ;;
4227         (\?)
4228             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4229         ;;
4230         (*)
4231             # -l list results on stout rather than invoking $EDITOR.
4232             # -i Print dates as in YYYY-MM-DD.
4233             # -m Search for a - quoted - pattern within the history.
4234             fc -li -m "*${first_char}${remain}*" $first $last
4235         ;;
4236     esac
4237 # }}}
4238 }
4239
4240 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
4241 fluxkey-change() {
4242     emulate -L zsh
4243     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
4244     if ! [[ -r "$FLUXKEYS" ]] ; then
4245         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
4246         return 1
4247     else
4248         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
4249             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
4250             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
4251         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
4252             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
4253             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
4254         else
4255             echo 'Sorry, do not know what to do.'
4256             return 1
4257         fi
4258     fi
4259 }
4260
4261 # retrieve weather information on the console
4262 # Usage example: 'weather LOWG'
4263 weather() {
4264     emulate -L zsh
4265     [[ -n "$1" ]] || {
4266         print 'Usage: weather <station_id>' >&2
4267         print 'List of stations: http://en.wikipedia.org/wiki/List_of_airports_by_ICAO_code'>&2
4268         return 1
4269     }
4270
4271     local PLACE="${1:u}"
4272     local FILE="$HOME/.weather/$PLACE"
4273     local LOG="$HOME/.weather/log"
4274
4275     [[ -d $HOME/.weather ]] || {
4276         print -n "Creating $HOME/.weather: "
4277         mkdir $HOME/.weather
4278         print 'done'
4279     }
4280
4281     print "Retrieving information for ${PLACE}:"
4282     print
4283     wget -T 10 --no-verbose --output-file=$LOG --output-document=$FILE --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
4284
4285     if [[ $? -eq 0 ]] ; then
4286         if [[ -n "$VERBOSE" ]] ; then
4287             cat $FILE
4288         else
4289             DATE=$(grep 'UTC' $FILE | sed 's#.* /##')
4290             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' $FILE| tr -d '(')
4291             echo "date: $DATE"
4292             echo "temp:  $TEMPERATURE"
4293         fi
4294     else
4295         print "There was an error retrieving the weather information for $PLACE" >&2
4296         cat $LOG
4297         return 1
4298     fi
4299 }
4300 # }}}
4301
4302 # mercurial related stuff {{{
4303 if check_com -c hg ; then
4304     # gnu like diff for mercurial
4305     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
4306     #f5# GNU like diff for mercurial
4307     hgdi() {
4308         emulate -L zsh
4309         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
4310     }
4311
4312     # build debian package
4313     #a2# Alias for \kbd{hg-buildpackage}
4314     alias hbp='hg-buildpackage'
4315
4316     # execute commands on the versioned patch-queue from the current repos
4317     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
4318
4319     # diffstat for specific version of a mercurial repository
4320     #   hgstat      => display diffstat between last revision and tip
4321     #   hgstat 1234 => display diffstat between revision 1234 and tip
4322     #f5# Diffstat for specific version of a mercurial repos
4323     hgstat() {
4324         emulate -L zsh
4325         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
4326     }
4327
4328     #f5# Get current mercurial tip via hg itself
4329     gethgclone() {
4330         emulate -L zsh
4331         setopt errreturn
4332         if [[ -f mercurial-tree/.hg ]] ; then
4333             cd mercurial-tree
4334             echo "Running hg pull for retreiving latest version..."
4335             hg pull
4336             echo "Finished update. Building mercurial"
4337             make local
4338             echo "Setting \$PATH to $PWD:\$PATH..."
4339             export PATH="$PWD:$PATH"
4340         else
4341             echo "Downloading mercurial via hg"
4342             hg clone http://selenic.com/repo/hg mercurial-tree
4343             cd mercurial-tree
4344             echo "Building mercurial"
4345             make local
4346             echo "Setting \$PATH to $PWD:\$PATH..."
4347             export PATH="$PWD:$PATH"
4348             echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4349             # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
4350             # export PYTHONPATH=${HOME}/lib/python
4351         fi
4352     }
4353
4354 fi # end of check whether we have the 'hg'-executable
4355
4356 # get current mercurial snapshot
4357 #f5# Get current mercurial snapshot
4358 gethgsnap() {
4359     emulate -L zsh
4360     setopt errreturn
4361     if [[ -f mercurial-snapshot.tar.gz ]] ; then
4362          echo "mercurial-snapshot.tar.gz exists already, skipping download."
4363     else
4364         echo "Downloading mercurial snapshot"
4365         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
4366     fi
4367     echo "Unpacking mercurial-snapshot.tar.gz"
4368     tar zxf mercurial-snapshot.tar.gz
4369     cd mercurial-snapshot/
4370     echo "Installing required build-dependencies"
4371     $SUDO apt-get update
4372     $SUDO apt-get install python2.4-dev
4373     echo "Building mercurial"
4374     make local
4375     echo "Setting \$PATH to $PWD:\$PATH..."
4376     export PATH="$PWD:$PATH"
4377     echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4378 }
4379 # }}}
4380
4381 # some useful commands often hard to remember - let's grep for them {{{
4382 # actually use our zg() function now. :)
4383
4384 # Work around ion/xterm resize bug.
4385 #if [[ "$SHLVL" -eq 1 ]]; then
4386 #       if check_com -c resize ; then
4387 #               eval `resize </dev/null`
4388 #       fi
4389 #fi
4390
4391 # enable jackd:
4392 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
4393 # now play audio file:
4394 #  alsaplayer -o jack foobar.mp3
4395
4396 # send files via netcat
4397 # on sending side:
4398 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
4399 #  send dir* $HOST
4400 #  alias receive='nc -vlp 51330 | tar xzvp'
4401
4402 # debian stuff:
4403 # dh_make -e foo@localhost -f $1
4404 # dpkg-buildpackage -rfakeroot
4405 # lintian *.deb
4406 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
4407 # dpkg-scansources . | gzip > Sources.gz
4408 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
4409
4410 # other stuff:
4411 # convert -geometry 200x200 -interlace LINE -verbose
4412 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
4413 # ps -ao user,pcpu,start,command
4414 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
4415 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
4416 # nc -vz $1 1-1024   # portscan via netcat
4417 # wget --mirror --no-parent --convert-links
4418 # pal -d `date +%d`
4419 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
4420 #
4421 # modify console cursor
4422 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
4423 # print $'\e[?96;0;64c'
4424 # }}}
4425
4426 # grml-small cleanups {{{
4427
4428 # The following is used to remove zsh-config-items that do not work
4429 # in grml-small by default.
4430 # If you do not want these adjustments (for whatever reason), set
4431 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
4432 # sources if it is there).
4433
4434 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
4435
4436     unset abk[V]
4437     unalias    'V'      &> /dev/null
4438     unfunction vman     &> /dev/null
4439     unfunction vimpm    &> /dev/null
4440     unfunction vimhelp  &> /dev/null
4441     unfunction viless   &> /dev/null
4442     unfunction 2html    &> /dev/null
4443
4444     # manpages are not in grmlsmall
4445     unfunction manzsh   &> /dev/null
4446     unalias    man2     &> /dev/null
4447     unalias    man      &> /dev/null
4448     unfunction man2     &> /dev/null
4449
4450 fi
4451
4452 #}}}
4453
4454 zrclocal
4455
4456 ## genrefcard.pl settings {{{
4457
4458 ### doc strings for external functions from files
4459 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
4460
4461 ### example: split functions-search 8,16,24,32
4462 #@# split functions-search 8
4463
4464 ## }}}
4465
4466 ## END OF FILE #################################################################
4467 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4