etc/zsh/zshrc

   1 # Filename:      /etc/zsh/zshrc
   2 # Purpose:       config file for zsh (z shell)
   3 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
   4 # Bug-Reports:   see http://grml.org/bugs/
   5 # License:       This file is licensed under the GPL v2.
   6 ################################################################################
   7 # This file is sourced only for interactive shells. It
   8 # should contain commands to set up aliases, functions,
   9 # options, key bindings, etc.
  10 #
  11 # Global Order: zshenv, zprofile, zshrc, zlogin
  12 ################################################################################
  13
  14 # Contributing:
  15 # If you want to help to improve grml's zsh setup, clone the grml-etc-core
  16 # repository from git.grml.org:
  17 #   git clone git://git.grml.org/grml-etc-core.git
  18 #
  19 # Make your changes, commit them; use 'git format-patch' to create a series
  20 # of patches and send those to the following address via 'git send-email':
  21 #   grml-etc-core@grml.org
  22 #
  23 # Doing so makes sure the right people get your patches for review and
  24 # possibly inclusion.
  25
  26 # zsh-refcard-tag documentation: {{{
  27 #   You may notice strange looking comments in this file.
  28 #   These are there for a purpose. grml's zsh-refcard can now be
  29 #   automatically generated from the contents of the actual configuration
  30 #   file. However, we need a little extra information on which comments
  31 #   and what lines of code to take into account (and for what purpose).
  32 #
  33 # Here is what they mean:
  34 #
  35 # List of tags (comment types) used:
  36 #   #a#     Next line contains an important alias, that should
  37 #           be included in the grml-zsh-refcard.
  38 #           (placement tag: @@INSERT-aliases@@)
  39 #   #f#     Next line contains the beginning of an important function.
  40 #           (placement tag: @@INSERT-functions@@)
  41 #   #v#     Next line contains an important variable.
  42 #           (placement tag: @@INSERT-variables@@)
  43 #   #k#     Next line contains an important keybinding.
  44 #           (placement tag: @@INSERT-keybindings@@)
  45 #   #d#     Hashed directories list generation:
  46 #               start   denotes the start of a list of 'hash -d'
  47 #                       definitions.
  48 #               end     denotes its end.
  49 #           (placement tag: @@INSERT-hasheddirs@@)
  50 #   #A#     Abbreviation expansion list generation:
  51 #               start   denotes the beginning of abbreviations.
  52 #               end     denotes their end.
  53 #           Lines within this section that end in '#d .*' provide
  54 #           extra documentation to be included in the refcard.
  55 #           (placement tag: @@INSERT-abbrev@@)
  56 #   #m#     This tag allows you to manually generate refcard entries
  57 #           for code lines that are hard/impossible to parse.
  58 #               Example:
  59 #                   #m# k ESC-h Call the run-help function
  60 #               That would add a refcard entry in the keybindings table
  61 #               for 'ESC-h' with the given comment.
  62 #           So the syntax is: #m# <section> <argument> <comment>
  63 #   #o#     This tag lets you insert entries to the 'other' hash.
  64 #           Generally, this should not be used. It is there for
  65 #           things that cannot be done easily in another way.
  66 #           (placement tag: @@INSERT-other-foobar@@)
  67 #
  68 #   All of these tags (except for m and o) take two arguments, the first
  69 #   within the tag, the other after the tag:
  70 #
  71 #   #<tag><section># <comment>
  72 #
  73 #   Where <section> is really just a number, which are defined by the
  74 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
  75 #   instead of names is, that for the reader, the tag should not differ
  76 #   much from a regular comment. For zsh, it is a regular comment indeed.
  77 #   The numbers have got the following meanings:
  78 #         0 -> "default"
  79 #         1 -> "system"
  80 #         2 -> "user"
  81 #         3 -> "debian"
  82 #         4 -> "search"
  83 #         5 -> "shortcuts"
  84 #         6 -> "services"
  85 #
  86 #   So, the following will add an entry to the 'functions' table in the
  87 #   'system' section, with a (hopefully) descriptive comment:
  88 #       #f1# Edit an alias via zle
  89 #       edalias() {
  90 #
  91 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
  92 #   that can be found in 'grml-zsh-refcard.tex.in'.
  93 #   If the section number is omitted, the 'default' section is assumed.
  94 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
  95 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
  96 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
  97 #}}}
  98
  99 # zsh profiling {{{
 100 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
 101 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
 102     zmodload zsh/zprof
 103 fi
 104 # }}}
 105
 106 # load .zshrc.pre to give the user the chance to overwrite the defaults
 107 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
 108
 109 # {{{ check for version/system
 110 # check for versions (compatibility reasons)
 111 is4(){
 112     [[ $ZSH_VERSION == <4->* ]] && return 0
 113     return 1
 114 }
 115
 116 is41(){
 117     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
 118     return 1
 119 }
 120
 121 is42(){
 122     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
 123     return 1
 124 }
 125
 126 is425(){
 127     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 128     return 1
 129 }
 130
 131 is43(){
 132     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 133     return 1
 134 }
 135
 136 is433(){
 137     [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == <5->* ]] && return 0
 138     return 1
 139 }
 140
 141 #f1# Checks whether or not you're running grml
 142 isgrml(){
 143     [[ -f /etc/grml_version ]] && return 0
 144     return 1
 145 }
 146
 147 #f1# Checks whether or not you're running a grml cd
 148 isgrmlcd(){
 149     [[ -f /etc/grml_cd ]] && return 0
 150     return 1
 151 }
 152
 153 if isgrml ; then
 154 #f1# Checks whether or not you're running grml-small
 155     isgrmlsmall() {
 156         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
 157     }
 158 else
 159     isgrmlsmall() { return 1 }
 160 fi
 161
 162 isdarwin(){
 163     [[ $OSTYPE == darwin* ]] && return 0
 164     return 1
 165 }
 166
 167 #f1# are we running within an utf environment?
 168 isutfenv() {
 169     case "$LANG $CHARSET $LANGUAGE" in
 170         *utf*) return 0 ;;
 171         *UTF*) return 0 ;;
 172         *)     return 1 ;;
 173     esac
 174 }
 175
 176 # check for user, if not running as root set $SUDO to sudo
 177 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
 178
 179 # change directory to home on first invocation of zsh
 180 # important for rungetty -> autologin
 181 # Thanks go to Bart Schaefer!
 182 isgrml && checkhome() {
 183     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
 184         export ALREADY_DID_CD_HOME=$HOME
 185         cd
 186     fi
 187 }
 188
 189 # check for zsh v3.1.7+
 190
 191 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
 192      || ${ZSH_VERSION} == 3.<2->.<->*    \
 193      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
 194
 195     printf '-!-\n'
 196     printf '-!- In this configuration we try to make use of features, that only\n'
 197     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
 198     printf '-!- used with a wide range of zsh versions, while using fairly\n'
 199     printf '-!- advanced features in all supported versions.\n'
 200     printf '-!-\n'
 201     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
 202     printf '-!-\n'
 203     printf '-!- While this *may* work, it might as well fail.\n'
 204     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
 205     printf '-!-\n'
 206     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
 207     printf '-!- If it does today, you'\''ve been lucky.\n'
 208     printf '-!-\n'
 209     printf '-!- Ye been warned!\n'
 210     printf '-!-\n'
 211
 212     function zstyle() { : }
 213 fi
 214
 215 # autoload wrapper - use this one instead of autoload directly
 216 # We need to define this function as early as this, because autoloading
 217 # 'is-at-least()' needs it.
 218 function zrcautoload() {
 219     setopt local_options extended_glob
 220     local fdir ffile
 221     local -i ffound
 222
 223     ffile=${1}
 224     (( found = 0 ))
 225     for fdir in ${fpath} ; do
 226         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
 227     done
 228
 229     (( ffound == 0 )) && return 1
 230     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
 231         autoload -U ${ffile} || return 1
 232     else
 233         autoload ${ffile} || return 1
 234     fi
 235     return 0
 236 }
 237
 238 # Load is-at-least() for more precise version checks
 239 # Note that this test will *always* fail, if the is-at-least
 240 # function could not be marked for autoloading.
 241 zrcautoload is-at-least || is-at-least() { return 1 }
 242
 243 # }}}
 244
 245 # setting some default values {{{
 246
 247 NOCOR=${NOCOR:-0}
 248 NOMENU=${NOMENU:-0}
 249 NOPRECMD=${NOPRECMD:-0}
 250 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
 251 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
 252 BATTERY=${BATTERY:-0}
 253 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
 254 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
 255
 256 if isgrmlcd ; then
 257     GRML_WARN_SKEL=${GRML_WARN_SKEL:-0}
 258 else
 259     GRML_WARN_SKEL=${GRML_WARN_SKEL:-1}
 260 fi
 261
 262 if (( GRML_WARN_SKEL != 0 )) ; then
 263
 264 function grml_warn_skel_main() {
 265     printf '
 266 Dear user,
 267
 268 You updated grml'\''s zshrc which brings a major change.
 269 The configuration is kept only in one file, being the global zshrc.
 270 In the past, the configuration was split in two files, with the
 271 second file being the .zshrc file from /etc/skel.
 272
 273 If you have a .zshrc file in your home directory that originally
 274 came from the skel directory, please remove it. This is also the case
 275 if you followed earlier instructions from the grml-zsh-refcard or
 276 from <http://grml.org/console/> on non-grml systems.
 277
 278 Please see the current grml-zsh-refcard (available at
 279 <http://grml.org/zsh/>) for updated installation information. In short,
 280 you don'\''t want a .zshrc.global file. Install the global zshrc to
 281 ~/.zshrc and be done.
 282
 283 If you need changes to the configuration, use ~/.zshrc.pre and
 284 ~/.zshrc.local.
 285
 286 '
 287 }
 288
 289 function grml_warn_skel_remove() {
 290     printf 'To remove this warning execute '\''grml_do_not_warn_skel'\''.\n\n'
 291 }
 292
 293 function grml_do_not_warn_skel() {
 294     printf '# Do not warn about old skel dot-files anymore\n' >>! ~/.zshrc.pre
 295     printf 'GRML_WARN_SKEL=0\n' >>! ~/.zshrc.pre
 296 }
 297
 298 # let's try to guess how the user uses us.
 299 if is-at-least 4.3.7 ; then
 300     # funcsourcetrace requires at least version 4.3.7 of zsh.
 301     GRML_SRC_FILE="${${funcsourcetrace[1]}%:*}"
 302
 303     grml_warn_skel_main
 304     case ${GRML_SRC_FILE} in
 305         (${HOME}/.zshrc.global)
 306             grml_warn_skel_remove
 307             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc.global'\''.\n'
 308             printf 'Nowadays you just copy the global zshrc to '\''~/.zshrc'\'' to use\n'
 309             printf 'it on a non-grml-system.\n'
 310             ;;
 311         (${HOME}/.zshrc)
 312             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc'\''.\n'
 313             printf 'We'\''ll disable this warning automatically for later sessions.\n'
 314             grml_do_not_warn_skel
 315             ;;
 316         (*)
 317             grml_do_not_warn_skel
 318             ;;
 319     esac
 320 else
 321     grml_warn_skel_main
 322     grml_warn_skel_remove
 323 fi
 324
 325 unfunction grml_warn_skel_remove grml_warn_skel_main
 326
 327 fi # GRML_WARN_SKEL
 328
 329 # }}}
 330
 331 # utility functions {{{
 332 # this function checks if a command exists and returns either true
 333 # or false. This avoids using 'which' and 'whence', which will
 334 # avoid problems with aliases for which on certain weird systems. :-)
 335 # Usage: check_com [-c|-g] word
 336 #   -c  only checks for external commands
 337 #   -g  does the usual tests and also checks for global aliases
 338 check_com() {
 339     local -i comonly gatoo
 340
 341     if [[ ${1} == '-c' ]] ; then
 342         (( comonly = 1 ))
 343         shift
 344     elif [[ ${1} == '-g' ]] ; then
 345         (( gatoo = 1 ))
 346     else
 347         (( comonly = 0 ))
 348         (( gatoo = 0 ))
 349     fi
 350
 351     if (( ${#argv} != 1 )) ; then
 352         printf 'usage: check_com [-c] <command>\n' >&2
 353         return 1
 354     fi
 355
 356     if (( comonly > 0 )) ; then
 357         [[ -n ${commands[$1]}  ]] && return 0
 358         return 1
 359     fi
 360
 361     if   [[ -n ${commands[$1]}    ]] \
 362       || [[ -n ${functions[$1]}   ]] \
 363       || [[ -n ${aliases[$1]}     ]] \
 364       || [[ -n ${reswords[(r)$1]} ]] ; then
 365
 366         return 0
 367     fi
 368
 369     if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
 370         return 0
 371     fi
 372
 373     return 1
 374 }
 375
 376 # creates an alias and precedes the command with
 377 # sudo if $EUID is not zero.
 378 salias() {
 379     local only=0 ; local multi=0
 380     while [[ ${1} == -* ]] ; do
 381         case ${1} in
 382             (-o) only=1 ;;
 383             (-a) multi=1 ;;
 384             (--) shift ; break ;;
 385             (-h)
 386                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
 387                 printf '  -h      shows this help text.\n'
 388                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
 389                 printf '          be careful using this option.\n'
 390                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
 391                 return 0
 392                 ;;
 393             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
 394         esac
 395         shift
 396     done
 397
 398     if (( ${#argv} > 1 )) ; then
 399         printf 'Too many arguments %s\n' "${#argv}"
 400         return 1
 401     fi
 402
 403     key="${1%%\=*}" ;  val="${1#*\=}"
 404     if (( EUID == 0 )) && (( only == 0 )); then
 405         alias -- "${key}=${val}"
 406     elif (( EUID > 0 )) ; then
 407         (( multi > 0 )) && val="${val// ; / ; sudo }"
 408         alias -- "${key}=sudo ${val}"
 409     fi
 410
 411     return 0
 412 }
 413
 414 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
 415 # usage: uprint foo
 416 #   Where foo is the *name* of the parameter you want printed.
 417 #   Note that foo is no typo; $foo would be wrong here!
 418 if ! is42 ; then
 419     uprint () {
 420         local -a u
 421         local w
 422         local parameter=${1}
 423
 424         if [[ -z ${parameter} ]] ; then
 425             printf 'usage: uprint <parameter>\n'
 426             return 1
 427         fi
 428
 429         for w in ${(P)parameter} ; do
 430             [[ -z ${(M)u:#${w}} ]] && u=( ${u} ${w} )
 431         done
 432
 433         builtin print -l ${u}
 434     }
 435 fi
 436
 437 # Check if we can read given files and source those we can.
 438 xsource() {
 439     if (( ${#argv} < 1 )) ; then
 440         printf 'usage: xsource FILE(s)...\n' >&2
 441         return 1
 442     fi
 443
 444     while (( ${#argv} > 0 )) ; do
 445         [[ -r ${1} ]] && source ${1}
 446         shift
 447     done
 448     return 0
 449 }
 450
 451 # Check if we can read a given file and 'cat(1)' it.
 452 xcat() {
 453     if (( ${#argv} != 1 )) ; then
 454         printf 'usage: xcat FILE\n' >&2
 455         return 1
 456     fi
 457
 458     [[ -r ${1} ]] && cat ${1}
 459     return 0
 460 }
 461
 462 # Remove these functions again, they are of use only in these
 463 # setup files. This should be called at the end of .zshrc.
 464 xunfunction() {
 465     local -a funcs
 466     funcs=(salias xcat xsource xunfunction zrcautoload)
 467
 468     for func in $funcs ; do
 469         [[ -n ${functions[$func]} ]] \
 470             && unfunction $func
 471     done
 472     return 0
 473 }
 474
 475 # this allows us to stay in sync with grml's zshrc and put own
 476 # modifications in ~/.zshrc.local
 477 zrclocal() {
 478     xsource "/etc/zsh/zshrc.local"
 479     xsource "${HOME}/.zshrc.local"
 480     return 0
 481 }
 482
 483 #}}}
 484
 485 # locale setup {{{
 486 xsource "/etc/default/locale"
 487
 488 for var in LANG LC_ALL LC_MESSAGES ; do
 489     [[ -n ${(P)var} ]] && export $var
 490 done
 491
 492 xsource "/etc/sysconfig/keyboard"
 493
 494 TZ=$(xcat /etc/timezone)
 495 # }}}
 496
 497 # check for potentially old files in 'completion.d' {{{
 498 setopt extendedglob
 499 xof=(/etc/zsh/completion.d/*~/etc/zsh/completion.d/_*(N))
 500 if (( ${#xof} > 0 )) ; then
 501     printf '\n -!- INFORMATION\n\n'
 502     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
 503     printf ' -!- /etc/zsh/completion.d/.\n\n'
 504     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
 505     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
 506     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
 507     printf ' -!- named _* to that directory.\n\n'
 508     printf ' -!- If you added functions to completion.d yourself, please consider\n'
 509     printf ' -!- moving them to /etc/zsh/functions.d/. Files in that directory, not\n'
 510     printf ' -!- starting with an underscore are marked for automatic loading\n'
 511     printf ' -!- by default (so that is quite convenient).\n\n'
 512     printf ' -!- If there are files *not* starting with an underscore from an older\n'
 513     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
 514     printf ' -!- Delete the files for example via running:\n\n'
 515     printf "      rm ${xof}\n\n"
 516     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
 517     printf ' -!- resolve the situation manually.\n\n'
 518     BROKEN_COMPLETION_DIR=1
 519 fi
 520 unset xof
 521 # }}}
 522
 523 # {{{ set some variables
 524 if check_com -c vim ; then
 525 #v#
 526     export EDITOR=${EDITOR:-vim}
 527 else
 528     export EDITOR=${EDITOR:-vi}
 529 fi
 530
 531 #v#
 532 export PAGER=${PAGER:-less}
 533
 534 #v#
 535 export MAIL=${MAIL:-/var/mail/$USER}
 536
 537 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
 538 export SHELL='/bin/zsh'
 539
 540 # color setup for ls:
 541 check_com -c dircolors && eval $(dircolors -b)
 542 # color setup for ls on OS X:
 543 isdarwin && export CLICOLOR=1
 544
 545 # do MacPorts setup on darwin
 546 if isdarwin && [[ -d /opt/local ]]; then
 547     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
 548     # zshenv.
 549     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
 550     MANPATH="/opt/local/share/man:$MANPATH"
 551 fi
 552 # do Fink setup on darwin
 553 isdarwin && xsource /sw/bin/init.sh
 554
 555 # completion functions go to /etc/zsh/completion.d
 556 # function files may be put into /etc/zsh/functions.d, from where they
 557 # will be automatically autoloaded.
 558 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
 559     print 'Warning: not setting completion directories because broken files have been found.' >&2
 560 else
 561     [[ -d /etc/zsh/completion.d ]] && fpath=( $fpath /etc/zsh/completion.d )
 562     if [[ -d /etc/zsh/functions.d ]] ; then
 563         fdir='/etc/zsh/functions.d'
 564         fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
 565         for func in ${fdir}/**/[^_]*[^~](N.) ; do
 566             zrcautoload ${func:t}
 567         done
 568         unset fdir
 569     fi
 570 fi
 571
 572 # support colors in less
 573 export LESS_TERMCAP_mb=$'\E[01;31m'
 574 export LESS_TERMCAP_md=$'\E[01;31m'
 575 export LESS_TERMCAP_me=$'\E[0m'
 576 export LESS_TERMCAP_se=$'\E[0m'
 577 export LESS_TERMCAP_so=$'\E[01;44;33m'
 578 export LESS_TERMCAP_ue=$'\E[0m'
 579 export LESS_TERMCAP_us=$'\E[01;32m'
 580
 581 # automatically remove duplicates from these arrays
 582 typeset -U path cdpath fpath manpath
 583 # }}}
 584
 585 # {{{ keybindings
 586 if [[ "$TERM" != emacs ]] ; then
 587     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
 588     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
 589     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
 590     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
 591     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
 592     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
 593     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
 594     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
 595     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
 596     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
 597     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
 598     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
 599     # ncurses stuff:
 600     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
 601     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
 602     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
 603     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
 604     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
 605     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
 606     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
 607     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
 608 fi
 609
 610 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
 611 # use emacs style per default:
 612 bindkey -e
 613 # use vi style:
 614 # bindkey -v
 615
 616 #if [[ "$TERM" == screen ]] ; then
 617 bindkey '\e[1~' beginning-of-line       # home
 618 bindkey '\e[4~' end-of-line             # end
 619 bindkey '\e[A'  up-line-or-search       # cursor up
 620 bindkey '\e[B'  down-line-or-search     # <ESC>-
 621
 622 bindkey '^xp'   history-beginning-search-backward
 623 bindkey '^xP'   history-beginning-search-forward
 624 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
 625 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
 626 # if terminal type is set to 'rxvt':
 627 bindkey '\e[7~' beginning-of-line       # home
 628 bindkey '\e[8~' end-of-line             # end
 629 #fi
 630
 631 # insert unicode character
 632 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
 633 # See for example http://unicode.org/charts/ for unicode characters code
 634 zrcautoload insert-unicode-char
 635 zle -N insert-unicode-char
 636 #k# Insert Unicode character
 637 bindkey '^Xi' insert-unicode-char
 638
 639 # just type 'cd ...' to get 'cd ../..'
 640 #  rationalise-dot() {
 641 #  if [[ $LBUFFER == *.. ]] ; then
 642 #    LBUFFER+=/..
 643 #  else
 644 #    LBUFFER+=.
 645 #  fi
 646 #  }
 647 #  zle -N rationalise-dot
 648 #  bindkey . rationalise-dot
 649
 650 #  bindkey '\eq' push-line-or-edit
 651
 652 ## toggle the ,. abbreviation feature on/off
 653 # NOABBREVIATION: default abbreviation-state
 654 #                 0 - enabled (default)
 655 #                 1 - disabled
 656 NOABBREVIATION=${NOABBREVIATION:-0}
 657
 658 grml_toggle_abbrev() {
 659     if (( ${NOABBREVIATION} > 0 )) ; then
 660         NOABBREVIATION=0
 661     else
 662         NOABBREVIATION=1
 663     fi
 664 }
 665
 666 zle -N grml_toggle_abbrev
 667 bindkey '^xA' grml_toggle_abbrev
 668
 669 # add a command line to the shells history without executing it
 670 commit-to-history() {
 671     print -s ${(z)BUFFER}
 672     zle send-break
 673 }
 674 zle -N commit-to-history
 675 bindkey "^x^h" commit-to-history
 676
 677 # }}}
 678
 679 # a generic accept-line wrapper {{{
 680
 681 # This widget can prevent unwanted autocorrections from command-name
 682 # to _command-name, rehash automatically on enter and call any number
 683 # of builtin and user-defined widgets in different contexts.
 684 #
 685 # For a broader description, see:
 686 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
 687 #
 688 # The code is imported from the file 'zsh/functions/accept-line' from
 689 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
 690 # distributed under the same terms as zsh itself.
 691
 692 # A newly added command will may not be found or will cause false
 693 # correction attempts, if you got auto-correction set. By setting the
 694 # following style, we force accept-line() to rehash, if it cannot
 695 # find the first word on the command line in the $command[] hash.
 696 zstyle ':acceptline:*' rehash true
 697
 698 function Accept-Line() {
 699     setopt localoptions noksharrays
 700     local -a subs
 701     local -xi aldone
 702     local sub
 703
 704     zstyle -a ":acceptline:${alcontext}" actions subs
 705
 706     (( ${#subs} < 1 )) && return 0
 707
 708     (( aldone = 0 ))
 709     for sub in ${subs} ; do
 710         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
 711         zle ${sub}
 712
 713         (( aldone > 0 )) && break
 714     done
 715 }
 716
 717 function Accept-Line-getdefault() {
 718     local default_action
 719
 720     zstyle -s ":acceptline:${alcontext}" default_action default_action
 721     case ${default_action} in
 722         ((accept-line|))
 723             printf ".accept-line"
 724             ;;
 725         (*)
 726             printf ${default_action}
 727             ;;
 728     esac
 729 }
 730
 731 function accept-line() {
 732     setopt localoptions noksharrays
 733     local -a cmdline
 734     local -x alcontext
 735     local buf com fname format msg default_action
 736
 737     alcontext='default'
 738     buf="${BUFFER}"
 739     cmdline=(${(z)BUFFER})
 740     com="${cmdline[1]}"
 741     fname="_${com}"
 742
 743     zstyle -t ":acceptline:${alcontext}" rehash \
 744         && [[ -z ${commands[$com]} ]]           \
 745         && rehash
 746
 747     if    [[ -n ${reswords[(r)$com]} ]] \
 748        || [[ -n ${aliases[$com]}     ]] \
 749        || [[ -n ${functions[$com]}   ]] \
 750        || [[ -n ${builtins[$com]}    ]] \
 751        || [[ -n ${commands[$com]}    ]] ; then
 752
 753         # there is something sensible to execute, just do it.
 754         alcontext='normal'
 755         zle Accept-Line
 756
 757         default_action=$(Accept-Line-getdefault)
 758         zstyle -T ":acceptline:${alcontext}" call_default \
 759             && zle ${default_action}
 760         return
 761     fi
 762
 763     if    [[ -o correct              ]] \
 764        || [[ -o correctall           ]] \
 765        && [[ -n ${functions[$fname]} ]] ; then
 766
 767         # nothing there to execute but there is a function called
 768         # _command_name; a completion widget. Makes no sense to
 769         # call it on the commandline, but the correct{,all} options
 770         # will ask for it nevertheless, so warn the user.
 771         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
 772             # Okay, we warned the user before, he called us again,
 773             # so have it his way.
 774             alcontext='force'
 775             zle Accept-Line
 776
 777             default_action=$(Accept-Line-getdefault)
 778             zstyle -T ":acceptline:${alcontext}" call_default \
 779                 && zle ${default_action}
 780             return
 781         fi
 782
 783         # prepare warning message for the user, configurable via zstyle.
 784         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
 785
 786         if [[ -z ${msg} ]] ; then
 787             msg="%c will not execute and completion %f exists."
 788         fi
 789
 790         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
 791
 792         zle -M -- "${msg}"
 793         return
 794     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
 795         # If we are here, the commandline contains something that is not
 796         # executable, which is neither subject to _command_name correction
 797         # and is not empty. might be a variable assignment
 798         alcontext='misc'
 799         zle Accept-Line
 800
 801         default_action=$(Accept-Line-getdefault)
 802         zstyle -T ":acceptline:${alcontext}" call_default \
 803             && zle ${default_action}
 804         return
 805     fi
 806
 807     # If we got this far, the commandline only contains whitespace, or is empty.
 808     alcontext='empty'
 809     zle Accept-Line
 810
 811     default_action=$(Accept-Line-getdefault)
 812     zstyle -T ":acceptline:${alcontext}" call_default \
 813         && zle ${default_action}
 814 }
 815
 816 zle -N accept-line
 817 zle -N Accept-Line
 818
 819 # }}}
 820
 821 # power completion - abbreviation expansion {{{
 822 # power completion / abbreviation expansion / buffer expansion
 823 # see http://zshwiki.org/home/examples/zleiab for details
 824 # less risky than the global aliases but powerful as well
 825 # just type the abbreviation key and afterwards ',.' to expand it
 826 declare -A abk
 827 setopt extendedglob
 828 setopt interactivecomments
 829 abk=(
 830 #   key   # value                  (#d additional doc string)
 831 #A# start
 832     '...'  '../..'
 833     '....' '../../..'
 834     'BG'   '& exit'
 835     'C'    '| wc -l'
 836     'G'    '|& grep --color=auto '
 837     'H'    '| head'
 838     'Hl'   ' --help |& less -r'    #d (Display help in pager)
 839     'L'    '| less'
 840     'LL'   '|& less -r'
 841     'M'    '| most'
 842     'N'    '&>/dev/null'           #d (No Output)
 843     'R'    '| tr A-z N-za-m'       #d (ROT13)
 844     'SL'   '| sort | less'
 845     'S'    '| sort -u'
 846     'T'    '| tail'
 847     'V'    '|& vim -'
 848 #A# end
 849     'co'   './configure && make && sudo make install'
 850 )
 851
 852 globalias() {
 853     local MATCH
 854
 855     if (( NOABBREVIATION > 0 )) ; then
 856         LBUFFER="${LBUFFER},."
 857         return 0
 858     fi
 859
 860     matched_chars='[.-|_a-zA-Z0-9]#'
 861     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
 862     LBUFFER+=${abk[$MATCH]:-$MATCH}
 863 }
 864
 865 zle -N globalias
 866 bindkey ",." globalias
 867 # }}}
 868
 869 # {{{ autoloading
 870 zrcautoload zmv    # who needs mmv or rename?
 871 zrcautoload history-search-end
 872
 873 # we don't want to quote/espace URLs on our own...
 874 # if autoload -U url-quote-magic ; then
 875 #    zle -N self-insert url-quote-magic
 876 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
 877 # else
 878 #    print 'Notice: no url-quote-magic available :('
 879 # fi
 880 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
 881
 882 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
 883 alias run-help >&/dev/null && unalias run-help
 884 zrcautoload run-help # use via 'esc-h'
 885
 886 # completion system
 887 if zrcautoload compinit ; then
 888     compinit || print 'Notice: no compinit available :('
 889 else
 890     print 'Notice: no compinit available :('
 891     function zstyle { }
 892     function compdef { }
 893 fi
 894
 895 is4 && zrcautoload zed # use ZLE editor to edit a file or function
 896
 897 is4 && \
 898 for mod in complist deltochar mathfunc ; do
 899     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
 900 done
 901
 902 # autoload zsh modules when they are referenced
 903 if is4 ; then
 904     tmpargs=(
 905         a   stat
 906         a   zpty
 907         ap  mapfile
 908     )
 909
 910     while (( ${#tmpargs} > 0 )) ; do
 911         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
 912         shift 2 tmpargs
 913     done
 914     unset tmpargs
 915 fi
 916
 917 if is4 && zrcautoload insert-files && zle -N insert-files ; then
 918     #k# Insert files
 919     bindkey "^Xf" insert-files # C-x-f
 920 fi
 921
 922 bindkey ' '   magic-space    # also do history expansion on space
 923 #k# Trigger menu-complete
 924 bindkey '\ei' menu-complete  # menu completion via esc-i
 925
 926 # press esc-e for editing command line in $EDITOR or $VISUAL
 927 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
 928     #k# Edit the current line in \kbd{\$EDITOR}
 929     bindkey '\ee' edit-command-line
 930 fi
 931
 932 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
 933     #k# menu selection: pick item but stay in the menu
 934     bindkey -M menuselect '\e^M' accept-and-menu-complete
 935
 936     # accept a completion and try to complete again by using menu
 937     # completion; very useful with completing directories
 938     # by using 'undo' one's got a simple file browser
 939     bindkey -M menuselect '^o' accept-and-infer-next-history
 940 fi
 941
 942 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
 943 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
 944 zle -N _bkdate
 945
 946 #k# Insert a timestamp on the command line (yyyy-mm-dd)
 947 bindkey '^Ed' _bkdate
 948
 949 # press esc-m for inserting last typed word again (thanks to caphuso!)
 950 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
 951 zle -N insert-last-typed-word;
 952
 953 #k# Insert last typed word
 954 bindkey "\em" insert-last-typed-word
 955
 956 #k# Shortcut for \kbd{fg<enter>}
 957 bindkey -s '^z' "fg\n"
 958
 959 # run command line as user root via sudo:
 960 sudo-command-line() {
 961     [[ -z $BUFFER ]] && zle up-history
 962     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
 963 }
 964 zle -N sudo-command-line
 965
 966 #k# Put the current command line into a \kbd{sudo} call
 967 bindkey "^Os" sudo-command-line
 968
 969 ### jump behind the first word on the cmdline.
 970 ### useful to add options.
 971 function jump_after_first_word() {
 972     local words
 973     words=(${(z)BUFFER})
 974
 975     if (( ${#words} <= 1 )) ; then
 976         CURSOR=${#BUFFER}
 977     else
 978         CURSOR=${#${words[1]}}
 979     fi
 980 }
 981 zle -N jump_after_first_word
 982
 983 bindkey '^x1' jump_after_first_word
 984
 985 # }}}
 986
 987 # {{{ set some important options
 988 # Please update these tags, if you change the umask settings below.
 989 #o# r_umask     002
 990 #o# r_umaskstr  rwxrwxr-x
 991 #o# umask       022
 992 #o# umaskstr    rwxr-xr-x
 993 (( EUID != 0 )) && umask 002 || umask 022
 994
 995 # history:
 996 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
 997 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
 998 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
 999 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
1000                             # list duplicates an older one, the older command is removed from the list
1001 setopt histignorespace      # remove command lines from the history list when
1002                             # the first character on the line is a space
1003 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
1004                             # and the command is the name of a directory, perform the cd command to that directory
1005 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
1006                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
1007                             # -> searches for word not in compressed files
1008                             # don't forget to quote '^', '~' and '#'!
1009 setopt longlistjobs         # display PID when suspending processes as well
1010 setopt notify               # report the status of backgrounds jobs immediately
1011 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
1012                             # the entire command path is hashed first.
1013 setopt completeinword       # not just at the end
1014 setopt nohup                # and don't kill them, either
1015 setopt auto_pushd           # make cd push the old directory onto the directory stack.
1016 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
1017 setopt nobeep               # avoid "beep"ing
1018 setopt pushd_ignore_dups    # don't push the same dir twice.
1019 setopt noglobdots           # * shouldn't match dotfiles. ever.
1020
1021 MAILCHECK=30       # mailchecks
1022 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
1023 watch=(notme root) # watch for everyone but me and root
1024
1025 # only slash should be considered as a word separator:
1026 slash-backward-kill-word() {
1027     local WORDCHARS="${WORDCHARS:s@/@}"
1028     # zle backward-word
1029     zle backward-kill-word
1030 }
1031 zle -N slash-backward-kill-word
1032
1033 #k# Kill everything in a word up to its last \kbd{/}
1034 bindkey '\ev' slash-backward-kill-word
1035
1036 # }}}
1037
1038 # {{{ history
1039
1040 ZSHDIR=$HOME/.zsh
1041
1042 #v#
1043 HISTFILE=$HOME/.zsh_history
1044 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1045 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1046
1047 # }}}
1048
1049 # dirstack handling {{{
1050
1051 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1052 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1053
1054 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1055     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1056     # "cd -" won't work after login by just setting $OLDPWD, so
1057     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
1058 fi
1059
1060 chpwd() {
1061     if is42 ; then
1062         builtin print -l ${(u)dirstack} >! ${DIRSTACKFILE}
1063     else
1064         uprint dirstack >! ${DIRSTACKFILE}
1065     fi
1066 }
1067
1068 # }}}
1069
1070 # directory based profiles {{{
1071
1072 if is433 ; then
1073
1074 CHPWD_PROFILE='default'
1075 function chpwd_profiles() {
1076     # Say you want certain settings to be active in certain directories.
1077     # This is what you want.
1078     #
1079     # zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)'   profile grml
1080     # zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1081     #
1082     # When that's done and you enter a directory that matches the pattern
1083     # in the third part of the context, a function called chpwd_profile_grml,
1084     # for example, is called (if it exists).
1085     #
1086     # If no pattern matches (read: no profile is detected) the profile is
1087     # set to 'default', which means chpwd_profile_default is attempted to
1088     # be called.
1089     #
1090     # A word about the context (the ':chpwd:profiles:*' stuff in the zstyle
1091     # command) which is used: The third part in the context is matched against
1092     # ${PWD}. That's why using a pattern such as /foo/bar(|/|/*) makes sense.
1093     # Because that way the profile is detected for all these values of ${PWD}:
1094     #   /foo/bar
1095     #   /foo/bar/
1096     #   /foo/bar/baz
1097     # So, if you want to make double damn sure a profile works in /foo/bar
1098     # and everywhere deeper in that tree, just use (|/|/*) and be happy.
1099     #
1100     # The name of the detected profile will be available in a variable called
1101     # 'profile' in your functions. You don't need to do anything, it'll just
1102     # be there.
1103     #
1104     # Then there is the parameter $CHPWD_PROFILE is set to the profile, that
1105     # was is currently active. That way you can avoid running code for a
1106     # profile that is already active, by running code such as the following
1107     # at the start of your function:
1108     #
1109     # function chpwd_profile_grml() {
1110     #     [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1111     #   ...
1112     # }
1113     #
1114     # The initial value for $CHPWD_PROFILE is 'default'.
1115     #
1116     # Version requirement:
1117     #   This feature requires zsh 4.3.3 or newer.
1118     #   If you use this feature and need to know whether it is active in your
1119     #   current shell, there are several ways to do that. Here are two simple
1120     #   ways:
1121     #
1122     #   a) If knowing if the profiles feature is active when zsh starts is
1123     #      good enough for you, you can put the following snippet into your
1124     #      .zshrc.local:
1125     #
1126     #   (( ${+functions[chpwd_profiles]} )) && print "directory profiles active"
1127     #
1128     #   b) If that is not good enough, and you would prefer to be notified
1129     #      whenever a profile changes, you can solve that by making sure you
1130     #      start *every* profile function you create like this:
1131     #
1132     #   function chpwd_profile_myprofilename() {
1133     #       [[ ${profile} == ${CHPWD_PROFILE} ]] && return 1
1134     #       print "chpwd(): Switching to profile: $profile"
1135     #     ...
1136     #   }
1137     #
1138     #      That makes sure you only get notified if a profile is *changed*,
1139     #      not everytime you change directory, which would probably piss
1140     #      you off fairly quickly. :-)
1141     #
1142     # There you go. Now have fun with that.
1143     local -x profile
1144
1145     zstyle -s ":chpwd:profiles:${PWD}" profile profile || profile='default'
1146     if (( ${+functions[chpwd_profile_$profile]} )) ; then
1147         chpwd_profile_${profile}
1148     fi
1149
1150     CHPWD_PROFILE="${profile}"
1151     return 0
1152 }
1153 chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1154
1155 fi # is433
1156
1157 # }}}
1158
1159 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1160 if [[ $BATTERY -gt 0 ]] ; then
1161     if ! check_com -c acpi ; then
1162         BATTERY=0
1163     fi
1164 fi
1165
1166 battery() {
1167 if [[ $BATTERY -gt 0 ]] ; then
1168     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1169     if [[ -z "$PERCENT" ]] ; then
1170         PERCENT='acpi not present'
1171     else
1172         if [[ "$PERCENT" -lt 20 ]] ; then
1173             PERCENT="warning: ${PERCENT}%%"
1174         else
1175             PERCENT="${PERCENT}%%"
1176         fi
1177     fi
1178 fi
1179 }
1180 # }}}
1181
1182 # set colors for use in prompts {{{
1183 if zrcautoload colors && colors 2>/dev/null ; then
1184     BLUE="%{${fg[blue]}%}"
1185     RED="%{${fg_bold[red]}%}"
1186     GREEN="%{${fg[green]}%}"
1187     CYAN="%{${fg[cyan]}%}"
1188     MAGENTA="%{${fg[magenta]}%}"
1189     YELLOW="%{${fg[yellow]}%}"
1190     WHITE="%{${fg[white]}%}"
1191     NO_COLOUR="%{${reset_color}%}"
1192 else
1193     BLUE=$'%{\e[1;34m%}'
1194     RED=$'%{\e[1;31m%}'
1195     GREEN=$'%{\e[1;32m%}'
1196     CYAN=$'%{\e[1;36m%}'
1197     WHITE=$'%{\e[1;37m%}'
1198     MAGENTA=$'%{\e[1;35m%}'
1199     YELLOW=$'%{\e[1;33m%}'
1200     NO_COLOUR=$'%{\e[0m%}'
1201 fi
1202
1203 # }}}
1204
1205 # gather version control information for inclusion in a prompt {{{
1206
1207 if ! is41 ; then
1208     # Be quiet about version problems in grml's zshrc as the user cannot disable
1209     # loading vcs_info() as it is *in* the zshrc - as you can see. :-)
1210     # Just unset most probable variables and disable vcs_info altogether.
1211     local -i i
1212     for i in {0..9} ; do
1213         unset VCS_INFO_message_${i}_
1214     done
1215     zstyle ':vcs_info:*' enable false
1216 fi
1217
1218 # The following code is imported from the file 'zsh/functions/vcs_info'
1219 # from <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>,
1220 # which distributed under the same terms as zsh itself.
1221
1222 # we will be using two variables, so let the code know now.
1223 zstyle ':vcs_info:*' max-exports 2
1224
1225 # vcs_info() documentation:
1226 #{{{
1227 # REQUIREMENTS:
1228 #{{{
1229 #     This functionality requires zsh version >= 4.1.*.
1230 #}}}
1231 #
1232 # LOADING:
1233 #{{{
1234 # To load vcs_info(), copy this file to your $fpath[] and do:
1235 #   % autoload -Uz vcs_info && vcs_info
1236 #
1237 # To work, vcs_info() needs 'setopt prompt_subst' in your setup.
1238 #}}}
1239 #
1240 # QUICKSTART:
1241 #{{{
1242 # To get vcs_info() working quickly (including colors), you can do the
1243 # following (assuming, you loaded vcs_info() properly - see above):
1244 #
1245 # % RED=$'%{\e[31m%}'
1246 # % GR=$'%{\e[32m%}'
1247 # % MA=$'%{\e[35m%}'
1248 # % YE=$'%{\e[33m%}'
1249 # % NC=$'%{\e[0m%}'
1250 #
1251 # % zstyle ':vcs_info:*' actionformats \
1252 #       "${MA}(${NC}%s${MA})${YE}-${MA}[${GR}%b${YE}|${RED}%a${MA}]${NC} "
1253 #
1254 # % zstyle ':vcs_info:*' formats       \
1255 #       "${MA}(${NC}%s${MA})${Y}-${MA}[${GR}%b${MA}]${NC}%} "
1256 #
1257 # % zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YE}%r"
1258 #
1259 # % precmd () { vcs_info }
1260 # % PS1='${MA}[${GR}%n${MA}] ${MA}(${RED}%!${MA}) ${YE}%3~ ${VCS_INFO_message_0_}${NC}%# '
1261 #
1262 # Obviously, the las two lines are there for demonstration: You need to
1263 # call vcs_info() from your precmd() function (see 'SPECIAL FUNCTIONS' in
1264 # 'man zshmisc'). Once that is done you need a *single* quoted
1265 # '${VCS_INFO_message_0_}' in your prompt.
1266 #
1267 # Now call the 'vcs_info_printsys' utility from the command line:
1268 #
1269 # % vcs_info_printsys
1270 # # list of supported version control backends:
1271 # # disabled systems are prefixed by a hash sign (#)
1272 # git
1273 # hg
1274 # bzr
1275 # darcs
1276 # svk
1277 # mtn
1278 # svn
1279 # cvs
1280 # cdv
1281 # tla
1282 # # flavours (cannot be used in the disable style; they
1283 # # are disabled with their master [git-svn -> git]):
1284 # git-p4
1285 # git-svn
1286 #
1287 # Ten version control backends as you can see. You may not want all
1288 # of these. Because there is no point in running the code to detect
1289 # systems you do not use. ever. So, there is a way to disable some
1290 # backends altogether:
1291 #
1292 # % zstyle ':vcs_info:*' disable bzr cdv darcs mtn svk tla
1293 #
1294 # If you rerun 'vcs_info_printsys' now, you will see the backends listed
1295 # in the 'disable' style marked as diabled by a hash sign. That means the
1296 # detection of these systems is skipped *completely*. No wasted time there.
1297 #
1298 # For more control, read the reference below.
1299 #}}}
1300 #
1301 # CONFIGURATION:
1302 #{{{
1303 # The vcs_info() feature can be configured via zstyle.
1304 #
1305 # First, the context in which we are working:
1306 #       :vcs_info:<vcs-string>:<user-context>
1307 #
1308 # ...where <vcs-string> is one of:
1309 #   - git, git-svn, git-p4, hg, darcs, bzr, cdv, mtn, svn, cvs, svk or tla.
1310 #
1311 # ...and <user-context> is a freely configurable string, assignable by the
1312 # user as the first argument to vcs_info() (see its description below).
1313 #
1314 # There is are three special values for <vcs-string>: The first is named
1315 # 'init', that is in effect as long as there was no decision what vcs
1316 # backend to use. The second is 'preinit; it is used *before* vcs_info()
1317 # is run, when initializing the data exporting variables. The third
1318 # special value is 'formats' and is used by the 'vcs_info_lastmsg' for
1319 # looking up its styles.
1320 #
1321 # There are two pre-defined values for <user-context>:
1322 #   default  - the one used if none is specified
1323 #   command  - used by vcs_info_lastmsg to lookup its styles.
1324 #
1325 # You may *not* use 'print_systems_' as a user-context string, because it
1326 # is used internally.
1327 #
1328 # You can of course use ':vcs_info:*' to match all VCSs in all
1329 # user-contexts at once.
1330 #
1331 # Another special context is 'formats', which is used by the
1332 # vcs_info_lastmsg() utility function (see below).
1333 #
1334 #
1335 # This is a description of all styles, that are looked up:
1336 #   formats             - A list of formats, used when actionformats is not
1337 #                         used (which is most of the time).
1338 #   actionformats       - A list of formats, used if a there is a special
1339 #                         action going on in your current repository;
1340 #                         (like an interactive rebase or a merge conflict)
1341 #   branchformat        - Some backends replace %b in the formats and
1342 #                         actionformats styles above, not only by a branch
1343 #                         name but also by a revision number. This style
1344 #                         let's you modify how that string should look like.
1345 #   nvcsformats         - These "formats" are exported, when we didn't detect
1346 #                         a version control system for the current directory.
1347 #                         This is useful, if you want vcs_info() to completely
1348 #                         take over the generation of your prompt.
1349 #                         You would do something like
1350 #                           PS1='${VCS_INFO_message_0_}'
1351 #                         to accomplish that.
1352 #   max-exports         - Defines the maximum number if VCS_INFO_message_*_
1353 #                         variables vcs_info() will export.
1354 #   enable              - Checked in the 'init' context. If set to false,
1355 #                         vcs_info() will do nothing.
1356 #   disable             - Provide a list of systems, you don't want
1357 #                         the vcs_info() to check for repositories
1358 #                         (checked in the 'init' context, too).
1359 #   disable-patterns    - A list of patterns that are checked against $PWD.
1360 #                         If the pattern matches, vcs_info will be disabled.
1361 #                         Say, ~/.zsh is a directory under version control,
1362 #                         in which you do not want vcs_info to be active, do:
1363 #                         zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh+(|/*)"
1364 #   use-simple          - If there are two different ways of gathering
1365 #                         information, you can select the simpler one
1366 #                         by setting this style to true; the default
1367 #                         is to use the not-that-simple code, which is
1368 #                         potentially a lot slower but might be more
1369 #                         accurate in all possible cases.
1370 #   use-prompt-escapes  - determines if we assume that the assembled
1371 #                         string from vcs_info() includes prompt escapes.
1372 #                         (Used by vcs_info_lastmsg().
1373 #
1374 # The use-simple style is only available for the bzr backend.
1375 #
1376 # The default values for these in all contexts are:
1377 #   formats             " (%s)-[%b|%a]-"
1378 #   actionformats       " (%s)-[%b]-"
1379 #   branchformat        "%b:%r" (for bzr, svn and svk)
1380 #   nvcsformats         ""
1381 #   max-exports         2
1382 #   enable              true
1383 #   disable             (empty list)
1384 #   disable-patterns    (empty list)
1385 #   use-simple          false
1386 #   use-prompt-escapes  true
1387 #
1388 #
1389 # In normal formats and actionformats, the following replacements
1390 # are done:
1391 #   %s  - The vcs in use (git, hg, svn etc.)
1392 #   %b  - Information about the current branch.
1393 #   %a  - An identifier, that describes the action.
1394 #         Only makes sense in actionformats.
1395 #   %R  - base directory of the repository.
1396 #   %r  - repository name
1397 #         If %R is '/foo/bar/repoXY', %r is 'repoXY'.
1398 #   %S  - subdirectory within a repository. if $PWD is
1399 #         '/foo/bar/reposXY/beer/tasty', %S is 'beer/tasty'.
1400 #
1401 #
1402 # In branchformat these replacements are done:
1403 #   %b  - the branch name
1404 #   %r  - the current revision number
1405 #
1406 # Not all vcs backends have to support all replacements.
1407 # nvcsformat does not perform *any* replacements. It is just a string.
1408 #}}}
1409 #
1410 # ODDITIES:
1411 #{{{
1412 # If you want to use the %b (bold off) prompt expansion in 'formats', which
1413 # expands %b itself, use %%b. That will cause the vcs_info() expansion to
1414 # replace %%b with %b. So zsh's prompt expansion mechanism can handle it.
1415 # Similarly, to hand down %b from branchformat, use %%%%b. Sorry for this
1416 # inconvenience, but it cannot be easily avoided. Luckily we do not clash
1417 # with a lot of prompt expansions and this only needs to be done for those.
1418 # See 'man zshmisc' for details about EXPANSION OF PROMPT SEQUENCES.
1419 #}}}
1420 #
1421 # FUNCTION DESCRIPTIONS (public API):
1422 #{{{
1423 #   vcs_info()
1424 #       The main function, that runs all backends and assembles
1425 #       all data into ${VCS_INFO_message_*_}. This is the function
1426 #       you want to call from precmd() if you want to include
1427 #       up-to-date information in your prompt (see VARIABLE
1428 #       DESCRIPTION below).
1429 #
1430 #   vcs_info_printsys()
1431 #       Prints a list of all supported version control systems.
1432 #       Useful to find out possible contexts (and which of them are enabled)
1433 #       or values for the 'disable' style.
1434 #
1435 #   vcs_info_lastmsg()
1436 #       Outputs the last ${VCS_INFO_message_*_} value. Takes into account
1437 #       the value of the use-prompt-escapes style in ':vcs_info:formats'.
1438 #       It also only prints max-exports values.
1439 #
1440 # All functions named VCS_INFO_* are for internal use only.
1441 #}}}
1442 #
1443 # VARIABLE DESCRIPTION:
1444 #{{{
1445 #   ${VCS_INFO_message_N_}    (Note the trailing underscore)
1446 #       Where 'N' is an integer, eg: VCS_INFO_message_0_
1447 #       These variables are the storage for the informational message the
1448 #       last vcs_info() call has assembled. These are strongly connected
1449 #       to the formats, actionformats and nvcsformats styles described
1450 #       above. Those styles are lists. the first member of that list gets
1451 #       expanded into ${VCS_INFO_message_0_}, the second into
1452 #       ${VCS_INFO_message_1_} and the Nth into ${VCS_INFO_message_N-1_}.
1453 #       These parameters are exported into the environment.
1454 #       (See the max-exports style above.)
1455 #}}}
1456 #
1457 # EXAMPLES:
1458 #{{{
1459 #   Don't use vcs_info at all (even though it's in your prompt):
1460 #   % zstyle ':vcs_info:*' enable false
1461 #
1462 #   Disable the backends for bzr and svk:
1463 #   % zstyle ':vcs_info:*' disable bzr svk
1464 #
1465 #   Provide a special formats for git:
1466 #   % zstyle ':vcs_info:git:*' formats       ' GIT, BABY! [%b]'
1467 #   % zstyle ':vcs_info:git:*' actionformats ' GIT ACTION! [%b|%a]'
1468 #
1469 #   Use the quicker bzr backend (if you do, please report if it does
1470 #   the-right-thing[tm] - thanks):
1471 #   % zstyle ':vcs_info:bzr:*' use-simple true
1472 #
1473 #   Display the revision number in yellow for bzr and svn:
1474 #   % zstyle ':vcs_info:(svn|bzr):*' branchformat '%b%{'${fg[yellow]}'%}:%r'
1475 #
1476 # If you want colors, make sure you enclose the color codes in %{...%},
1477 # if you want to use the string provided by vcs_info() in prompts.
1478 #
1479 # Here is how to print the vcs infomation as a command:
1480 #   % alias vcsi='vcs_info command; vcs_info_lastmsg'
1481 #
1482 #   This way, you can even define different formats for output via
1483 #   vcs_info_lastmsg() in the ':vcs_info:command:*' namespace.
1484 #}}}
1485 #}}}
1486 # utilities
1487 VCS_INFO_adjust () { #{{{
1488     [[ -n ${vcs_comm[overwrite_name]} ]] && vcs=${vcs_comm[overwrite_name]}
1489     return 0
1490 }
1491 # }}}
1492 VCS_INFO_check_com () { #{{{
1493     (( ${+commands[$1]} )) && [[ -x ${commands[$1]} ]] && return 0
1494     return 1
1495 }
1496 # }}}
1497 VCS_INFO_formats () { # {{{
1498     setopt localoptions noksharrays
1499     local action=$1 branch=$2 base=$3
1500     local msg
1501     local -i i
1502
1503     if [[ -n ${action} ]] ; then
1504         zstyle -a ":vcs_info:${vcs}:${usercontext}" actionformats msgs
1505         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b|%a]-'
1506     else
1507         zstyle -a ":vcs_info:${vcs}:${usercontext}" formats msgs
1508         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b]-'
1509     fi
1510
1511     (( ${#msgs} > maxexports )) && msgs[$(( maxexports + 1 )),-1]=()
1512     for i in {1..${#msgs}} ; do
1513         zformat -f msg ${msgs[$i]}                      \
1514                         a:${action}                     \
1515                         b:${branch}                     \
1516                         r:${base:t}                     \
1517                         s:${vcs}                        \
1518                         R:${base}                       \
1519                         S:"$(VCS_INFO_reposub ${base})"
1520         msgs[$i]=${msg}
1521     done
1522     return 0
1523 }
1524 # }}}
1525 VCS_INFO_maxexports () { #{{{
1526     zstyle -s ":vcs_info:${vcs}:${usercontext}" "max-exports" maxexports || maxexports=2
1527     if [[ ${maxexports} != <-> ]] || (( maxexports < 1 )); then
1528         printf 'vcs_info(): expecting numeric arg >= 1 for max-exports (got %s).\n' ${maxexports}
1529         printf 'Defaulting to 2.\n'
1530         maxexports=2
1531     fi
1532 }
1533 # }}}
1534 VCS_INFO_nvcsformats () { #{{{
1535     setopt localoptions noksharrays
1536     local c v
1537
1538     if [[ $1 == 'preinit' ]] ; then
1539         c=default
1540         v=preinit
1541     fi
1542     zstyle -a ":vcs_info:${v:-$vcs}:${c:-$usercontext}" nvcsformats msgs
1543     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1544 }
1545 # }}}
1546 VCS_INFO_realpath () { #{{{
1547     # a portable 'readlink -f'
1548     # forcing a subshell, to ensure chpwd() is not removed
1549     # from the calling shell (if VCS_INFO_realpath() is called
1550     # manually).
1551     (
1552         (( ${+functions[chpwd]} )) && unfunction chpwd
1553         setopt chaselinks
1554         cd $1 2>/dev/null && pwd
1555     )
1556 }
1557 # }}}
1558 VCS_INFO_reposub () { #{{{
1559     setopt localoptions extendedglob
1560     local base=${1%%/##}
1561
1562     [[ ${PWD} == ${base}/* ]] || {
1563         printf '.'
1564         return 1
1565     }
1566     printf '%s' ${PWD#$base/}
1567     return 0
1568 }
1569 # }}}
1570 VCS_INFO_set () { #{{{
1571     setopt localoptions noksharrays
1572     local -i i j
1573
1574     if [[ $1 == '--clear' ]] ; then
1575         for i in {0..9} ; do
1576             unset VCS_INFO_message_${i}_
1577         done
1578     fi
1579     if [[ $1 == '--nvcs' ]] ; then
1580         [[ $2 == 'preinit' ]] && (( maxexports == 0 )) && (( maxexports = 1 ))
1581         for i in {0..$((maxexports - 1))} ; do
1582             typeset -gx VCS_INFO_message_${i}_=
1583         done
1584         VCS_INFO_nvcsformats $2
1585     fi
1586
1587     (( ${#msgs} - 1 < 0 )) && return 0
1588     for i in {0..$(( ${#msgs} - 1 ))} ; do
1589         (( j = i + 1 ))
1590         typeset -gx VCS_INFO_message_${i}_=${msgs[$j]}
1591     done
1592     return 0
1593 }
1594 # }}}
1595 # information gathering
1596 VCS_INFO_bzr_get_data () { # {{{
1597     setopt localoptions noksharrays
1598     local bzrbase bzrbr
1599     local -a bzrinfo
1600
1601     if zstyle -t ":vcs_info:${vcs}:${usercontext}" "use-simple" ; then
1602         bzrbase=${vcs_comm[basedir]}
1603         bzrinfo[2]=${bzrbase:t}
1604         if [[ -f ${bzrbase}/.bzr/branch/last-revision ]] ; then
1605             bzrinfo[1]=$(< ${bzrbase}/.bzr/branch/last-revision)
1606             bzrinfo[1]=${${bzrinfo[1]}%% *}
1607         fi
1608     else
1609         bzrbase=${${(M)${(f)"$( bzr info )"}:# ##branch\ root:*}/*: ##/}
1610         bzrinfo=( ${${${(M)${(f)"$( bzr version-info )"}:#(#s)(revno|branch-nick)*}/*: /}/*\//} )
1611         bzrbase="$(VCS_INFO_realpath ${bzrbase})"
1612     fi
1613
1614     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat bzrbr || bzrbr="%b:%r"
1615     zformat -f bzrbr "${bzrbr}" "b:${bzrinfo[2]}" "r:${bzrinfo[1]}"
1616     VCS_INFO_formats '' "${bzrbr}" "${bzrbase}"
1617     return 0
1618 }
1619 # }}}
1620 VCS_INFO_cdv_get_data () { # {{{
1621     local cdvbase
1622
1623     cdvbase=${vcs_comm[basedir]}
1624     VCS_INFO_formats '' "${cdvbase:t}" "${cdvbase}"
1625     return 0
1626 }
1627 # }}}
1628 VCS_INFO_cvs_get_data () { # {{{
1629     local cvsbranch cvsbase basename
1630
1631     cvsbase="."
1632     while [[ -d "${cvsbase}/../CVS" ]]; do
1633         cvsbase="${cvsbase}/.."
1634     done
1635     cvsbase="$(VCS_INFO_realpath ${cvsbase})"
1636     cvsbranch=$(< ./CVS/Repository)
1637     basename=${cvsbase:t}
1638     cvsbranch=${cvsbranch##${basename}/}
1639     [[ -z ${cvsbranch} ]] && cvsbranch=${basename}
1640     VCS_INFO_formats '' "${cvsbranch}" "${cvsbase}"
1641     return 0
1642 }
1643 # }}}
1644 VCS_INFO_darcs_get_data () { # {{{
1645     local darcsbase
1646
1647     darcsbase=${vcs_comm[basedir]}
1648     VCS_INFO_formats '' "${darcsbase:t}" "${darcsbase}"
1649     return 0
1650 }
1651 # }}}
1652 VCS_INFO_git_getaction () { #{{{
1653     local gitaction='' gitdir=$1
1654     local tmp
1655
1656     for tmp in "${gitdir}/rebase-apply" \
1657                "${gitdir}/rebase"       \
1658                "${gitdir}/../.dotest" ; do
1659         if [[ -d ${tmp} ]] ; then
1660             if   [[ -f "${tmp}/rebasing" ]] ; then
1661                 gitaction="rebase"
1662             elif [[ -f "${tmp}/applying" ]] ; then
1663                 gitaction="am"
1664             else
1665                 gitaction="am/rebase"
1666             fi
1667             printf '%s' ${gitaction}
1668             return 0
1669         fi
1670     done
1671
1672     for tmp in "${gitdir}/rebase-merge/interactive" \
1673                "${gitdir}/.dotest-merge/interactive" ; do
1674         if [[ -f "${tmp}" ]] ; then
1675             printf '%s' "rebase-i"
1676             return 0
1677         fi
1678     done
1679
1680     for tmp in "${gitdir}/rebase-merge" \
1681                "${gitdir}/.dotest-merge" ; do
1682         if [[ -d "${tmp}" ]] ; then
1683             printf '%s' "rebase-m"
1684             return 0
1685         fi
1686     done
1687
1688     if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1689         printf '%s' "merge"
1690         return 0
1691     fi
1692
1693     if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
1694         printf '%s' "bisect"
1695         return 0
1696     fi
1697     return 1
1698 }
1699 # }}}
1700 VCS_INFO_git_getbranch () { #{{{
1701     local gitbranch gitdir=$1
1702     local gitsymref='git symbolic-ref HEAD'
1703
1704     if    [[ -d "${gitdir}/rebase-apply" ]] \
1705        || [[ -d "${gitdir}/rebase" ]]       \
1706        || [[ -d "${gitdir}/../.dotest" ]]   \
1707        || [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1708         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1709         [[ -z ${gitbranch} ]] && [[ -r ${gitdir}/rebase-apply/head-name ]] \
1710             && gitbranch="$(< ${gitdir}/rebase-apply/head-name)"
1711
1712     elif   [[ -f "${gitdir}/rebase-merge/interactive" ]] \
1713         || [[ -d "${gitdir}/rebase-merge" ]] ; then
1714         gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
1715
1716     elif   [[ -f "${gitdir}/.dotest-merge/interactive" ]] \
1717         || [[ -d "${gitdir}/.dotest-merge" ]] ; then
1718         gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
1719
1720     else
1721         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1722
1723         if [[ $? -ne 0 ]] ; then
1724             gitbranch="$(git describe --exact-match HEAD 2>/dev/null)"
1725
1726             if [[ $? -ne 0 ]] ; then
1727                 gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
1728             fi
1729         fi
1730     fi
1731
1732     printf '%s' "${gitbranch##refs/heads/}"
1733     return 0
1734 }
1735 # }}}
1736 VCS_INFO_git_get_data () { # {{{
1737     setopt localoptions extendedglob
1738     local gitdir gitbase gitbranch gitaction
1739
1740     gitdir=${vcs_comm[gitdir]}
1741     gitbranch="$(VCS_INFO_git_getbranch ${gitdir})"
1742
1743     if [[ -z ${gitdir} ]] || [[ -z ${gitbranch} ]] ; then
1744         return 1
1745     fi
1746
1747     VCS_INFO_adjust
1748     gitaction="$(VCS_INFO_git_getaction ${gitdir})"
1749     gitbase=${PWD%/${$( git rev-parse --show-prefix )%/##}}
1750     VCS_INFO_formats "${gitaction}" "${gitbranch}" "${gitbase}"
1751     return 0
1752 }
1753 # }}}
1754 VCS_INFO_hg_get_data () { # {{{
1755     local hgbranch hgbase file
1756
1757     hgbase=${vcs_comm[basedir]}
1758
1759     file="${hgbase}/.hg/branch"
1760     if [[ -r ${file} ]] ; then
1761         hgbranch=$(< ${file})
1762     else
1763         hgbranch='default'
1764     fi
1765
1766     VCS_INFO_formats '' "${hgbranch}" "${hgbase}"
1767     return 0
1768 }
1769 # }}}
1770 VCS_INFO_mtn_get_data () { # {{{
1771     local mtnbranch mtnbase
1772
1773     mtnbase=${vcs_comm[basedir]}
1774     mtnbranch=${${(M)${(f)"$( mtn status )"}:#(#s)Current branch:*}/*: /}
1775     VCS_INFO_formats '' "${mtnbranch}" "${mtnbase}"
1776     return 0
1777 }
1778 # }}}
1779 VCS_INFO_svk_get_data () { # {{{
1780     local svkbranch svkbase
1781
1782     svkbase=${vcs_comm[basedir]}
1783     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svkbranch || svkbranch="%b:%r"
1784     zformat -f svkbranch "${svkbranch}" "b:${vcs_comm[branch]}" "r:${vcs_comm[revision]}"
1785     VCS_INFO_formats '' "${svkbranch}" "${svkbase}"
1786     return 0
1787 }
1788 # }}}
1789 VCS_INFO_svn_get_data () { # {{{
1790     setopt localoptions noksharrays
1791     local svnbase svnbranch
1792     local -a svninfo
1793
1794     svnbase="."
1795     while [[ -d "${svnbase}/../.svn" ]]; do
1796         svnbase="${svnbase}/.."
1797     done
1798     svnbase="$(VCS_INFO_realpath ${svnbase})"
1799     svninfo=( ${${${(M)${(f)"$( svn info )"}:#(#s)(URL|Revision)*}/*: /}/*\//} )
1800
1801     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svnbranch || svnbranch="%b:%r"
1802     zformat -f svnbranch "${svnbranch}" "b:${svninfo[1]}" "r:${svninfo[2]}"
1803     VCS_INFO_formats '' "${svnbranch}" "${svnbase}"
1804     return 0
1805 }
1806 # }}}
1807 VCS_INFO_tla_get_data () { # {{{
1808     local tlabase tlabranch
1809
1810     tlabase="$(VCS_INFO_realpath ${vcs_comm[basedir]})"
1811     # tree-id gives us something like 'foo@example.com/demo--1.0--patch-4', so:
1812     tlabranch=${${"$( tla tree-id )"}/*\//}
1813     VCS_INFO_formats '' "${tlabranch}" "${tlabase}"
1814     return 0
1815 }
1816 # }}}
1817 # detection
1818 VCS_INFO_detect_by_dir() { #{{{
1819     local dirname=$1
1820     local basedir="." realbasedir
1821
1822     realbasedir="$(VCS_INFO_realpath ${basedir})"
1823     while [[ ${realbasedir} != '/' ]]; do
1824         if [[ -n ${vcs_comm[detect_need_file]} ]] ; then
1825             [[ -d ${basedir}/${dirname} ]] && \
1826             [[ -e ${basedir}/${dirname}/${vcs_comm[detect_need_file]} ]] && \
1827                 break
1828         else
1829             [[ -d ${basedir}/${dirname} ]] && break
1830         fi
1831
1832         basedir=${basedir}/..
1833         realbasedir="$(VCS_INFO_realpath ${basedir})"
1834     done
1835
1836     [[ ${realbasedir} == "/" ]] && return 1
1837     vcs_comm[basedir]=${realbasedir}
1838     return 0
1839 }
1840 # }}}
1841 VCS_INFO_bzr_detect() { #{{{
1842     VCS_INFO_check_com bzr || return 1
1843     vcs_comm[detect_need_file]=branch/format
1844     VCS_INFO_detect_by_dir '.bzr'
1845     return $?
1846 }
1847 # }}}
1848 VCS_INFO_cdv_detect() { #{{{
1849     VCS_INFO_check_com cdv || return 1
1850     vcs_comm[detect_need_file]=format
1851     VCS_INFO_detect_by_dir '.cdv'
1852     return $?
1853 }
1854 # }}}
1855 VCS_INFO_cvs_detect() { #{{{
1856     VCS_INFO_check_com svn || return 1
1857     [[ -d "./CVS" ]] && [[ -r "./CVS/Repository" ]] && return 0
1858     return 1
1859 }
1860 # }}}
1861 VCS_INFO_darcs_detect() { #{{{
1862     VCS_INFO_check_com darcs || return 1
1863     vcs_comm[detect_need_file]=format
1864     VCS_INFO_detect_by_dir '_darcs'
1865     return $?
1866 }
1867 # }}}
1868 VCS_INFO_git_detect() { #{{{
1869     if VCS_INFO_check_com git && git rev-parse --is-inside-work-tree &> /dev/null ; then
1870         vcs_comm[gitdir]="$(git rev-parse --git-dir 2> /dev/null)" || return 1
1871         if   [[ -d ${vcs_comm[gitdir]}/svn ]]             ; then vcs_comm[overwrite_name]='git-svn'
1872         elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]] ; then vcs_comm[overwrite_name]='git-p4' ; fi
1873         return 0
1874     fi
1875     return 1
1876 }
1877 # }}}
1878 VCS_INFO_hg_detect() { #{{{
1879     VCS_INFO_check_com hg || return 1
1880     vcs_comm[detect_need_file]=store
1881     VCS_INFO_detect_by_dir '.hg'
1882     return $?
1883 }
1884 # }}}
1885 VCS_INFO_mtn_detect() { #{{{
1886     VCS_INFO_check_com mtn || return 1
1887     vcs_comm[detect_need_file]=revision
1888     VCS_INFO_detect_by_dir '_MTN'
1889     return $?
1890 }
1891 # }}}
1892 VCS_INFO_svk_detect() { #{{{
1893     setopt localoptions noksharrays extendedglob
1894     local -a info
1895     local -i fhash
1896     fhash=0
1897
1898     VCS_INFO_check_com svk || return 1
1899     [[ -f ~/.svk/config ]] || return 1
1900
1901     # This detection function is a bit different from the others.
1902     # We need to read svk's config file to detect a svk repository
1903     # in the first place. Therefore, we'll just proceed and read
1904     # the other information, too. This is more then any of the
1905     # other detections do but this takes only one file open for
1906     # svk at most. VCS_INFO_svk_get_data() get simpler, too. :-)
1907     while IFS= read -r line ; do
1908         if [[ -n ${vcs_comm[basedir]} ]] ; then
1909             line=${line## ##}
1910             [[ ${line} == depotpath:* ]] && vcs_comm[branch]=${line##*/}
1911             [[ ${line} == revision:* ]] && vcs_comm[revision]=${line##*[[:space:]]##}
1912             [[ -n ${vcs_comm[branch]} ]] && [[ -n ${vcs_comm[revision]} ]] && break
1913             continue
1914         fi
1915         (( fhash > 0 )) && [[ ${line} == '  '[^[:space:]]*:* ]] && break
1916         [[ ${line} == '  hash:'* ]] && fhash=1 && continue
1917         (( fhash == 0 )) && continue
1918         [[ ${PWD}/ == ${${line## ##}%:*}/* ]] && vcs_comm[basedir]=${${line## ##}%:*}
1919     done < ~/.svk/config
1920
1921     [[ -n ${vcs_comm[basedir]} ]]  && \
1922     [[ -n ${vcs_comm[branch]} ]]   && \
1923     [[ -n ${vcs_comm[revision]} ]] && return 0
1924     return 1
1925 }
1926 # }}}
1927 VCS_INFO_svn_detect() { #{{{
1928     VCS_INFO_check_com svn || return 1
1929     [[ -d ".svn" ]] && return 0
1930     return 1
1931 }
1932 # }}}
1933 VCS_INFO_tla_detect() { #{{{
1934     VCS_INFO_check_com tla || return 1
1935     vcs_comm[basedir]="$(tla tree-root 2> /dev/null)" && return 0
1936     return 1
1937 }
1938 # }}}
1939 # public API
1940 vcs_info_printsys () { # {{{
1941     vcs_info print_systems_
1942 }
1943 # }}}
1944 vcs_info_lastmsg () { # {{{
1945     local -i i
1946
1947     VCS_INFO_maxexports
1948     for i in {0..$((maxexports - 1))} ; do
1949         printf '$VCS_INFO_message_%d_: "' $i
1950         if zstyle -T ':vcs_info:formats:command' use-prompt-escapes ; then
1951             print -nP ${(P)${:-VCS_INFO_message_${i}_}}
1952         else
1953             print -n ${(P)${:-VCS_INFO_message_${i}_}}
1954         fi
1955         printf '"\n'
1956     done
1957 }
1958 # }}}
1959 vcs_info () { # {{{
1960     local pat
1961     local -i found
1962     local -a VCSs disabled dps
1963     local -x vcs usercontext
1964     local -ix maxexports
1965     local -ax msgs
1966     local -Ax vcs_comm
1967
1968     vcs="init"
1969     VCSs=(git hg bzr darcs svk mtn svn cvs cdv tla)
1970     case $1 in
1971         (print_systems_)
1972             zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1973             print -l '# list of supported version control backends:' \
1974                      '# disabled systems are prefixed by a hash sign (#)'
1975             for vcs in ${VCSs} ; do
1976                 [[ -n ${(M)disabled:#${vcs}} ]] && printf '#'
1977                 printf '%s\n' ${vcs}
1978             done
1979             print -l '# flavours (cannot be used in the disable style; they' \
1980                      '# are disabled with their master [git-svn -> git]):'   \
1981                      git-{p4,svn}
1982             return 0
1983             ;;
1984         ('')
1985             [[ -z ${usercontext} ]] && usercontext=default
1986             ;;
1987         (*) [[ -z ${usercontext} ]] && usercontext=$1
1988             ;;
1989     esac
1990
1991     zstyle -T ":vcs_info:${vcs}:${usercontext}" "enable" || {
1992         [[ -n ${VCS_INFO_message_0_} ]] && VCS_INFO_set --clear
1993         return 0
1994     }
1995     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1996
1997     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable-patterns" dps
1998     for pat in ${dps} ; do
1999         if [[ ${PWD} == ${~pat} ]] ; then
2000             [[ -n ${vcs_info_msg_0_} ]] && VCS_INFO_set --clear
2001             return 0
2002         fi
2003     done
2004
2005     VCS_INFO_maxexports
2006
2007     (( found = 0 ))
2008     for vcs in ${VCSs} ; do
2009         [[ -n ${(M)disabled:#${vcs}} ]] && continue
2010         vcs_comm=()
2011         VCS_INFO_${vcs}_detect && (( found = 1 )) && break
2012     done
2013
2014     (( found == 0 )) && {
2015         VCS_INFO_set --nvcs
2016         return 0
2017     }
2018
2019     VCS_INFO_${vcs}_get_data || {
2020         VCS_INFO_set --nvcs
2021         return 1
2022     }
2023
2024     VCS_INFO_set
2025     return 0
2026 }
2027
2028 VCS_INFO_set --nvcs preinit
2029 # }}}
2030
2031 # Change vcs_info formats for the grml prompt. The 2nd format sets up
2032 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
2033 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
2034 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
2035 #       to $vcs_info_msg_N_ as soon as we use the included version.
2036 if [[ "$TERM" == dumb ]] ; then
2037     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
2038     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
2039 else
2040     # these are the same, just with a lot of colours:
2041     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
2042                                        "zsh: %r"
2043     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
2044                                        "zsh: %r"
2045     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
2046 fi
2047
2048 # }}}
2049
2050 # command not found handling {{{
2051
2052 (( ${COMMAND_NOT_FOUND} == 1 )) &&
2053 function command_not_found_handler() {
2054     setopt localoptions no_sh_wordsplit
2055     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
2056         ${GRML_ZSH_CNF_HANDLER} $1
2057     fi
2058     return 1
2059 }
2060
2061 # }}}
2062
2063 # {{{ set prompt
2064 if zrcautoload promptinit && promptinit 2>/dev/null ; then
2065     promptinit # people should be able to use their favourite prompt
2066 else
2067     print 'Notice: no promptinit available :('
2068 fi
2069
2070 setopt prompt_subst
2071
2072 # make sure to use right prompt only when not running a command
2073 is41 && setopt transient_rprompt
2074
2075 # TODO: revise all these NO* variables and especially their documentation
2076 #       in zsh-help() below.
2077 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
2078     [[ $NOPRECMD -gt 0 ]] && return 0
2079     # update VCS information
2080     vcs_info
2081
2082     if [[ $TERM == screen* ]] ; then
2083         if [[ -n ${VCS_INFO_message_1_} ]] ; then
2084             print -nP "\ek${VCS_INFO_message_1_}\e\\"
2085         else
2086             print -nP "\ekzsh\e\\"
2087         fi
2088     fi
2089     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
2090     if [[ $DONTSETRPROMPT -eq 0 ]] ; then
2091         if [[ $BATTERY -gt 0 ]] ; then
2092             # update battery (dropped into $PERCENT) information
2093             battery
2094             RPROMPT="%(?..:() ${PERCENT}"
2095         else
2096             RPROMPT="%(?..:() "
2097         fi
2098     fi
2099     # adjust title of xterm
2100     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2101     [[ ${NOTITLE} -gt 0 ]] && return 0
2102     case $TERM in
2103         (xterm*|rxvt*)
2104             print -Pn "\e]0;%n@%m: %~\a"
2105             ;;
2106     esac
2107 }
2108
2109 # preexec() => a function running before every command
2110 is4 && [[ $NOPRECMD -eq 0 ]] && \
2111 preexec () {
2112     [[ $NOPRECMD -gt 0 ]] && return 0
2113 # set hostname if not running on host with name 'grml'
2114     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2115        NAME="@$HOSTNAME"
2116     fi
2117 # get the name of the program currently running and hostname of local machine
2118 # set screen window title if running in a screen
2119     if [[ "$TERM" == screen* ]] ; then
2120         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
2121         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
2122         echo -ne "\ek$CMD\e\\"
2123     fi
2124 # adjust title of xterm
2125     [[ ${NOTITLE} -gt 0 ]] && return 0
2126     case $TERM in
2127         (xterm*|rxvt*)
2128             print -Pn "\e]0;%n@%m: $1\a"
2129             ;;
2130     esac
2131 }
2132
2133 EXITCODE="%(?..%?%1v )"
2134 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
2135 PS3='?# '         # selection prompt used within a select loop.
2136 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
2137
2138 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
2139 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
2140     debian_chroot=$(cat /etc/debian_chroot)
2141 fi
2142
2143 # don't use colors on dumb terminals (like emacs):
2144 if [[ "$TERM" == dumb ]] ; then
2145     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2146 else
2147     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
2148     # set variable identifying the chroot you work in (used in the prompt below)
2149     if [[ $GRMLPROMPT -gt 0 ]] ; then
2150         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
2151 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
2152     else
2153         # This assembles the primary prompt string
2154         if (( EUID != 0 )); then
2155             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2156         else
2157             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2158         fi
2159     fi
2160 fi
2161
2162 # if we are inside a grml-chroot set a specific prompt theme
2163 if [[ -n "$GRML_CHROOT" ]] ; then
2164     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
2165 fi
2166 # }}}
2167
2168 # {{{ 'hash' some often used directories
2169 #d# start
2170 hash -d deb=/var/cache/apt/archives
2171 hash -d doc=/usr/share/doc
2172 hash -d linux=/lib/modules/$(command uname -r)/build/
2173 hash -d log=/var/log
2174 hash -d slog=/var/log/syslog
2175 hash -d src=/usr/src
2176 hash -d templ=/usr/share/doc/grml-templates
2177 hash -d tt=/usr/share/doc/texttools-doc
2178 hash -d www=/var/www
2179 #d# end
2180 # }}}
2181
2182 # {{{ some aliases
2183 if check_com -c screen ; then
2184     if [[ $UID -eq 0 ]] ; then
2185         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
2186     elif [[ -r $HOME/.screenrc ]] ; then
2187         alias screen="${commands[screen]} -c $HOME/.screenrc"
2188     else
2189         [[ -r /etc/grml/screenrc_grml ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2190     fi
2191 fi
2192
2193 # do we have GNU ls with color-support?
2194 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
2195     #a1# execute \kbd{@a@}:\quad ls with colors
2196     alias ls='ls -b -CF --color=auto'
2197     #a1# execute \kbd{@a@}:\quad list all files, with colors
2198     alias la='ls -la --color=auto'
2199     #a1# long colored list, without dotfiles (@a@)
2200     alias ll='ls -l --color=auto'
2201     #a1# long colored list, human readable sizes (@a@)
2202     alias lh='ls -hAl --color=auto'
2203     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2204     alias l='ls -lF --color=auto'
2205 else
2206     alias ls='ls -b -CF'
2207     alias la='ls -la'
2208     alias ll='ls -l'
2209     alias lh='ls -hAl'
2210     alias l='ls -lF'
2211 fi
2212
2213 alias mdstat='cat /proc/mdstat'
2214 alias ...='cd ../../'
2215
2216 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2217 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2218     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2219 fi
2220
2221 alias cp='nocorrect cp'         # no spelling correction on cp
2222 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
2223 alias mv='nocorrect mv'         # no spelling correction on mv
2224 alias rm='nocorrect rm'         # no spelling correction on rm
2225
2226 #a1# Execute \kbd{rmdir}
2227 alias rd='rmdir'
2228 #a1# Execute \kbd{rmdir}
2229 alias md='mkdir'
2230
2231 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2232 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2233 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2234
2235 # make sure it is not assigned yet
2236 [[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2237 utf2iso() {
2238     if isutfenv ; then
2239         for ENV in $(env | command grep -i '.utf') ; do
2240             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2241         done
2242     fi
2243 }
2244
2245 # make sure it is not assigned yet
2246 [[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2247 iso2utf() {
2248     if ! isutfenv ; then
2249         for ENV in $(env | command grep -i '\.iso') ; do
2250             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2251         done
2252     fi
2253 }
2254
2255 # set up software synthesizer via speakup
2256 swspeak() {
2257     if [ -x /usr/sbin/swspeak-setup ] ; then
2258        setopt singlelinezle
2259        unsetopt prompt_cr
2260        export PS1="%m%# "
2261        /usr/sbin/swspeak-setup $@
2262      else # old version:
2263         aumix -w 90 -v 90 -p 90 -m 90
2264         if ! [[ -r /dev/softsynth ]] ; then
2265             flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
2266             return 1
2267         else
2268            setopt singlelinezle
2269            unsetopt prompt_cr
2270            export PS1="%m%# "
2271             nice -n -20 speechd-up
2272             sleep 2
2273             flite -o play -t "Finished setting up software synthesizer"
2274         fi
2275      fi
2276 }
2277
2278 # I like clean prompt, so provide simple way to get that
2279 check_com 0 || alias 0='return 0'
2280
2281 # for really lazy people like mika:
2282 check_com S &>/dev/null || alias S='screen'
2283 check_com s &>/dev/null || alias s='ssh'
2284
2285 # get top 10 shell commands:
2286 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
2287
2288 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
2289 if check_com -c truecrypt ; then
2290     if isutfenv ; then
2291         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
2292     else
2293         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
2294     fi
2295 fi
2296
2297 #f1# Hints for the use of zsh on grml
2298 zsh-help() {
2299     print "$bg[white]$fg[black]
2300 zsh-help - hints for use of zsh on grml
2301 =======================================$reset_color"
2302
2303     print '
2304 Main configuration of zsh happens in /etc/zsh/zshrc.
2305 That file is part of the package grml-etc-core, if you want to
2306 use them on a non-grml-system just get the tar.gz from
2307 http://deb.grml.org/ or (preferably) get it from the git repository:
2308
2309   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2310
2311 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2312 The file is still there, but it is empty for backwards compatibility.
2313
2314 For your own changes use these two files:
2315     $HOME/.zshrc.pre
2316     $HOME/.zshrc.local
2317
2318 The former is sourced very early in our zshrc, the latter is sourced
2319 very lately.
2320
2321 System wide configuration without touching configuration files of grml
2322 can take place in /etc/zsh/zshrc.local.
2323
2324 Normally, the root user (EUID == 0) does not get the whole grml setup.
2325 If you want to force the whole setup for that user, too, set
2326 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
2327
2328 For information regarding zsh start at http://grml.org/zsh/
2329
2330 Take a look at grml'\''s zsh refcard:
2331 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2332
2333 Check out the main zsh refcard:
2334 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2335
2336 And of course visit the zsh-lovers:
2337 % man zsh-lovers
2338
2339 You can adjust some options through environment variables when
2340 invoking zsh without having to edit configuration files.
2341 Basically meant for bash users who are not used to the power of
2342 the zsh yet. :)
2343
2344   "NOCOR=1    zsh" => deactivate automatic correction
2345   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
2346   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2347   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2348                       preexec() and precmd() completely
2349   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2350   "COMMAND_NOT_FOUND=1 zsh"
2351                    => Enable a handler if an external command was not found
2352                       The command called in the handler can be altered by setting
2353                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2354                       "/usr/share/command-not-found/command-not-found"
2355
2356 A value greater than 0 is enables a feature; a value equal to zero
2357 disables it. If you like one or the other of these settings, you can
2358 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2359 zshrc.'
2360
2361     print "
2362 $bg[white]$fg[black]
2363 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2364 Enjoy your grml system with the zsh!$reset_color"
2365 }
2366
2367 # debian stuff
2368 if [[ -r /etc/debian_version ]] ; then
2369     #a3# Execute \kbd{apt-cache search}
2370     alias acs='apt-cache search'
2371     #a3# Execute \kbd{apt-cache show}
2372     alias acsh='apt-cache show'
2373     #a3# Execute \kbd{apt-cache policy}
2374     alias acp='apt-cache policy'
2375     #a3# Execute \kbd{apt-get dist-upgrade}
2376     salias adg="apt-get dist-upgrade"
2377     #a3# Execute \kbd{apt-get install}
2378     salias agi="apt-get install"
2379     #a3# Execute \kbd{aptitude install}
2380     salias ati="aptitude install"
2381     #a3# Execute \kbd{apt-get upgrade}
2382     salias ag="apt-get upgrade"
2383     #a3# Execute \kbd{apt-get update}
2384     salias au="apt-get update"
2385     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2386     salias -a up="aptitude update ; aptitude safe-upgrade"
2387     #a3# Execute \kbd{dpkg-buildpackage}
2388     alias dbp='dpkg-buildpackage'
2389     #a3# Execute \kbd{grep-excuses}
2390     alias ge='grep-excuses'
2391
2392     # debian upgrade
2393     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
2394     upgrade() {
2395         if [[ -z "$1" ]] ; then
2396             $SUDO apt-get update
2397             $SUDO apt-get -u upgrade
2398         else
2399             ssh $1 $SUDO apt-get update
2400             # ask before the upgrade
2401             local dummy
2402             ssh $1 $SUDO apt-get --no-act upgrade
2403             echo -n 'Process the upgrade?'
2404             read -q dummy
2405             if [[ $dummy == "y" ]] ; then
2406                 ssh $1 $SUDO apt-get -u upgrade --yes
2407             fi
2408         fi
2409     }
2410
2411     # get a root shell as normal user in live-cd mode:
2412     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2413        alias su="sudo su"
2414      fi
2415
2416     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2417     salias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2418     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2419     salias tlog="tail -f /var/log/syslog"    # follow the syslog
2420 fi
2421
2422 # sort installed Debian-packages by size
2423 if check_com -c grep-status ; then
2424     #a3# List installed Debian-packages sorted by size
2425     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
2426 fi
2427
2428 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2429 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
2430     if check_com -c wodim ; then
2431         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
2432 See #377109 in the BTS of Debian for more details.
2433
2434 Please use the wodim binary instead' ; return 1"
2435     fi
2436 fi
2437
2438 # get_tw_cli has been renamed into get_3ware
2439 if check_com -c get_3ware ; then
2440     get_tw_cli() {
2441         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
2442         get_3ware
2443     }
2444 fi
2445
2446 # I hate lacking backward compatibility, so provide an alternative therefore
2447 if ! check_com -c apache2-ssl-certificate ; then
2448
2449     apache2-ssl-certificate() {
2450
2451     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
2452     print 'You might want to take a look at Debian the package ssl-cert as well.'
2453     print 'To generate a certificate for use with apache2 follow the instructions:'
2454
2455     echo '
2456
2457 export RANDFILE=/dev/random
2458 mkdir /etc/apache2/ssl/
2459 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
2460 chmod 600 /etc/apache2/ssl/apache.pem
2461
2462 Run "grml-tips ssl-certificate" if you need further instructions.
2463 '
2464     }
2465 fi
2466 # }}}
2467
2468 # {{{ Use hard limits, except for a smaller stack and no core dumps
2469 unlimit
2470 is425 && limit stack 8192
2471 isgrmlcd && limit core 0 # important for a live-cd-system
2472 limit -s
2473 # }}}
2474
2475 # {{{ completion system
2476
2477 # called later (via is4 && grmlcomp)
2478 # note: use 'zstyle' for getting current settings
2479 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
2480 grmlcomp() {
2481     # TODO: This could use some additional information
2482
2483     # allow one error for every three characters typed in approximate completer
2484     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
2485
2486     # don't complete backup files as executables
2487     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
2488
2489     # start menu completion only if it could find no unambiguous initial string
2490     zstyle ':completion:*:correct:*'       insert-unambiguous true
2491     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
2492     zstyle ':completion:*:correct:*'       original true
2493
2494     # activate color-completion
2495     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
2496
2497     # format on completion
2498     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
2499
2500     # complete 'cd -<tab>' with menu
2501     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
2502
2503     # insert all expansions for expand completer
2504     zstyle ':completion:*:expand:*'        tag-order all-expansions
2505     zstyle ':completion:*:history-words'   list false
2506
2507     # activate menu
2508     zstyle ':completion:*:history-words'   menu yes
2509
2510     # ignore duplicate entries
2511     zstyle ':completion:*:history-words'   remove-all-dups yes
2512     zstyle ':completion:*:history-words'   stop yes
2513
2514     # match uppercase from lowercase
2515     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
2516
2517     # separate matches into groups
2518     zstyle ':completion:*:matches'         group 'yes'
2519     zstyle ':completion:*'                 group-name ''
2520
2521     if [[ "$NOMENU" -eq 0 ]] ; then
2522         # if there are more than 5 options allow selecting from a menu
2523         zstyle ':completion:*'               menu select=5
2524     else
2525         # don't use any menus at all
2526         setopt no_auto_menu
2527     fi
2528
2529     zstyle ':completion:*:messages'        format '%d'
2530     zstyle ':completion:*:options'         auto-description '%d'
2531
2532     # describe options in full
2533     zstyle ':completion:*:options'         description 'yes'
2534
2535     # on processes completion complete all user processes
2536     zstyle ':completion:*:processes'       command 'ps -au$USER'
2537
2538     # offer indexes before parameters in subscripts
2539     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
2540
2541     # provide verbose completion information
2542     zstyle ':completion:*'                 verbose true
2543
2544     # recent (as of Dec 2007) zsh versions are able to provide descriptions
2545     # for commands (read: 1st word in the line) that it will list for the user
2546     # to choose from. The following disables that, because it's not exactly fast.
2547     zstyle ':completion:*:-command-:*:'    verbose false
2548
2549     # set format for warnings
2550     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
2551
2552     # define files to ignore for zcompile
2553     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
2554     zstyle ':completion:correct:'          prompt 'correct to: %e'
2555
2556     # Ignore completion functions for commands you don't have:
2557     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
2558
2559     # Provide more processes in completion of programs like killall:
2560     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
2561
2562     # complete manual by their section
2563     zstyle ':completion:*:manuals'    separate-sections true
2564     zstyle ':completion:*:manuals.*'  insert-sections   true
2565     zstyle ':completion:*:man:*'      menu yes select
2566
2567     # provide .. as a completion
2568     zstyle ':completion:*' special-dirs ..
2569
2570     # run rehash on completion so new installed program are found automatically:
2571     _force_rehash() {
2572         (( CURRENT == 1 )) && rehash
2573         return 1
2574     }
2575
2576     ## correction
2577     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2578     if [[ "$NOCOR" -gt 0 ]] ; then
2579         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2580         setopt nocorrect
2581     else
2582         # try to be smart about when to use what completer...
2583         setopt correct
2584         zstyle -e ':completion:*' completer '
2585             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2586                 _last_try="$HISTNO$BUFFER$CURSOR"
2587                 reply=(_complete _match _ignored _prefix _files)
2588             else
2589                 if [[ $words[1] == (rm|mv) ]] ; then
2590                     reply=(_complete _files)
2591                 else
2592                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2593                 fi
2594             fi'
2595     fi
2596
2597     # command for process lists, the local web server details and host completion
2598     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2599
2600     # caching
2601     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2602                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2603
2604     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
2605     if is42 ; then
2606         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2607         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2608     else
2609         _ssh_hosts=()
2610         _etc_hosts=()
2611     fi
2612     hosts=(
2613         $(hostname)
2614         "$_ssh_hosts[@]"
2615         "$_etc_hosts[@]"
2616         grml.org
2617         localhost
2618     )
2619     zstyle ':completion:*:hosts' hosts $hosts
2620     # TODO: so, why is this here?
2621     #  zstyle '*' hosts $hosts
2622
2623     # use generic completion system for programs not yet defined; (_gnu_generic works
2624     # with commands that provide a --help option with "standard" gnu-like output.)
2625     for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
2626                    pal stow tail uname ; do
2627         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
2628     done; unset compcom
2629
2630     # see upgrade function in this file
2631     compdef _hosts upgrade
2632 }
2633 # }}}
2634
2635 # {{{ grmlstuff
2636 grmlstuff() {
2637 # people should use 'grml-x'!
2638     startx() {
2639         if [[ -e /etc/X11/xorg.conf ]] ; then
2640             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
2641         else
2642             echo "Please use the script \"grml-x\" for starting the X Window System
2643 because there does not exist /etc/X11/xorg.conf yet.
2644 If you want to use startx anyway please call \"/usr/bin/startx\"."
2645             return -1
2646         fi
2647     }
2648
2649     xinit() {
2650         if [[ -e /etc/X11/xorg.conf ]] ; then
2651             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
2652         else
2653             echo "Please use the script \"grml-x\" for starting the X Window System.
2654 because there does not exist /etc/X11/xorg.conf yet.
2655 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
2656             return -1
2657         fi
2658     }
2659
2660     if check_com -c 915resolution ; then
2661         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
2662     fi
2663
2664     #a1# Output version of running grml
2665     alias grml-version='cat /etc/grml_version'
2666
2667     if check_com -c rebuildfstab ; then
2668         #a1# Rebuild /etc/fstab
2669         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2670     fi
2671
2672     if check_com -c grml-debootstrap ; then
2673         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
2674     fi
2675 }
2676 # }}}
2677
2678 # {{{ now run the functions
2679 isgrml && checkhome
2680 is4    && isgrml    && grmlstuff
2681 is4    && grmlcomp
2682 # }}}
2683
2684 # {{{ keephack
2685 is4 && xsource "/etc/zsh/keephack"
2686 # }}}
2687
2688 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
2689 # You use it as follows:
2690 # $ NTREF=/reference/file
2691 # $ ls -l *(e:nt:)
2692 # This lists all the files in the current directory newer than the reference file.
2693 # You can also specify the reference file inline; note quotes:
2694 # $ ls -l *(e:'nt ~/.zshenv':)
2695 is4 && nt() {
2696     if [[ -n $1 ]] ; then
2697         local NTREF=${~1}
2698     fi
2699     [[ $REPLY -nt $NTREF ]]
2700 }
2701 # }}}
2702
2703 # shell functions {{{
2704
2705 #f1# Provide csh compatibility
2706 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
2707
2708 #f1# Reload an autoloadable function
2709 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2710
2711 #f1# Reload zsh setup
2712 reload() {
2713     if [[ "$#*" -eq 0 ]] ; then
2714         [[ -r ~/.zshrc ]] && . ~/.zshrc
2715     else
2716         local fn
2717         for fn in "$@"; do
2718             unfunction $fn
2719             autoload -U $fn
2720         done
2721     fi
2722 }
2723 compdef _functions reload freload
2724
2725 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2726 sll() {
2727     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2728     for i in "$@" ; do
2729         file=$i
2730         while [[ -h "$file" ]] ; do
2731             ls -l $file
2732             file=$(readlink "$file")
2733         done
2734     done
2735 }
2736
2737 # fast manual access
2738 if check_com qma ; then
2739     #f1# View the zsh manual
2740     manzsh()  { qma zshall "$1" }
2741     compdef _man qma
2742 else
2743     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
2744 fi
2745
2746 if check_com -c $PAGER ; then
2747     #f1# View Debian's changelog of a given package
2748     dchange() {
2749         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
2750             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
2751         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2752             $PAGER /usr/share/doc/${1}/changelog.gz
2753         else
2754             if check_com -c aptitude ; then
2755                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2756                 if isgrml ; then
2757                     aptitude -t unstable changelog ${1}
2758                 else
2759                     aptitude changelog ${1}
2760                 fi
2761             else
2762                 echo "No changelog for package $1 found, sorry."
2763                 return 1
2764             fi
2765         fi
2766     }
2767     _dchange() { _files -W /usr/share/doc -/ }
2768     compdef _dchange dchange
2769
2770     #f1# View Debian's NEWS of a given package
2771     dnews() {
2772         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
2773             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
2774         else
2775             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
2776                 $PAGER /usr/share/doc/${1}/NEWS.gz
2777             else
2778                 echo "No NEWS file for package $1 found, sorry."
2779                 return 1
2780             fi
2781         fi
2782     }
2783     _dnews() { _files -W /usr/share/doc -/ }
2784     compdef _dnews dnews
2785
2786     #f1# View upstream's changelog of a given package
2787     uchange() {
2788         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2789             $PAGER /usr/share/doc/${1}/changelog.gz
2790         else
2791             echo "No changelog for package $1 found, sorry."
2792             return 1
2793         fi
2794     }
2795     _uchange() { _files -W /usr/share/doc -/ }
2796     compdef _uchange uchange
2797 fi
2798
2799 # zsh profiling
2800 profile() {
2801     ZSH_PROFILE_RC=1 $SHELL "$@"
2802 }
2803
2804 #f1# Edit an alias via zle
2805 edalias() {
2806     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2807 }
2808 compdef _aliases edalias
2809
2810 #f1# Edit a function via zle
2811 edfunc() {
2812     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
2813 }
2814 compdef _functions edfunc
2815
2816 # use it e.g. via 'Restart apache2'
2817 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2818 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2819 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2820 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2821 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2822 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2823     __start_stop() {
2824         local action_="${1:l}"  # e.g Start/Stop/Restart
2825         local service_="$2"
2826         local param_="$3"
2827
2828         local service_target_="$(readlink /etc/init.d/$service_)"
2829         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2830             # runit
2831             case "${action_}" in
2832                 start) if [[ ! -e /etc/service/$service_ ]]; then
2833                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2834                        else
2835                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2836                        fi ;;
2837                 # there is no reload in runits sysv emulation
2838                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2839                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2840             esac
2841         else
2842             # sysvinit
2843             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2844         fi
2845     }
2846
2847     for i in Start Restart Stop Force-Reload Reload ; do
2848         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2849     done
2850 fi
2851
2852 #f1# Provides useful information on globbing
2853 H-Glob() {
2854     echo -e "
2855     /      directories
2856     .      plain files
2857     @      symbolic links
2858     =      sockets
2859     p      named pipes (FIFOs)
2860     *      executable plain files (0100)
2861     %      device files (character or block special)
2862     %b     block special files
2863     %c     character special files
2864     r      owner-readable files (0400)
2865     w      owner-writable files (0200)
2866     x      owner-executable files (0100)
2867     A      group-readable files (0040)
2868     I      group-writable files (0020)
2869     E      group-executable files (0010)
2870     R      world-readable files (0004)
2871     W      world-writable files (0002)
2872     X      world-executable files (0001)
2873     s      setuid files (04000)
2874     S      setgid files (02000)
2875     t      files with the sticky bit (01000)
2876
2877   print *(m-1)          # Files modified up to a day ago
2878   print *(a1)           # Files accessed a day ago
2879   print *(@)            # Just symlinks
2880   print *(Lk+50)        # Files bigger than 50 kilobytes
2881   print *(Lk-50)        # Files smaller than 50 kilobytes
2882   print **/*.c          # All *.c files recursively starting in \$PWD
2883   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2884   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2885   print *~*.*           # All Files that do not contain a dot
2886   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2887   print -l *(.c|.h)     # Lists *.c and *.h
2888   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2889   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2890 }
2891 alias help-zshglob=H-Glob
2892
2893 check_com -c qma && alias ?='qma zshall'
2894
2895 # grep for running process, like: 'any vim'
2896 any() {
2897     if [[ -z "$1" ]] ; then
2898         echo "any - grep for process(es) by keyword" >&2
2899         echo "Usage: any <keyword>" >&2 ; return 1
2900     else
2901         local STRING=$1
2902         local LENGTH=$(expr length $STRING)
2903         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
2904         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
2905         ps xauwww| grep "[$FIRSCHAR]$REST"
2906     fi
2907 }
2908
2909 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2910 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2911 [[ -r /proc/1/maps ]] && \
2912 deswap() {
2913     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2914     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2915     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2916 }
2917
2918 # print hex value of a number
2919 hex() {
2920     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2921 }
2922
2923 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2924 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2925 peval() {
2926     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2927     perl -e "print eval($CALC),\"\n\";"
2928 }
2929 functions peval &>/dev/null && alias calc=peval
2930
2931 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
2932 # certain circumstances, so work around it, no matter which environment we have
2933 brltty() {
2934     if [[ -z "$DISPLAY" ]] ; then
2935         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
2936         command brltty "$@"
2937     else
2938         command brltty "$@"
2939     fi
2940 }
2941
2942 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2943 aoeu() {
2944     echo -n 'Switching to us keyboard layout: '
2945     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2946     echo 'Done'
2947 }
2948 asdf() {
2949     echo -n 'Switching to dvorak keyboard layout: '
2950     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2951     echo 'Done'
2952 }
2953 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2954 uiae() {
2955     echo -n 'Switching to us keyboard layout: '
2956     setxkbmap us && echo 'Done' || echo 'Failed'
2957 }
2958
2959 # set up an ipv6 tunnel
2960 ipv6-tunnel() {
2961     case $1 in
2962         start)
2963             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2964                 print 'ipv6 tunnel already set up, nothing to be done.'
2965                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2966             else
2967                 [[ -n "$PUBLIC_IP" ]] || \
2968                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2969                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2970
2971                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
2972                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
2973                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
2974                 ifconfig sit0 tunnel ::192.88.99.1 up
2975                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
2976             fi
2977             ;;
2978         status)
2979             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2980                 print 'ipv6 tunnel available' ; return 0
2981             else
2982                 print 'ipv6 tunnel not available' ; return 1
2983             fi
2984             ;;
2985         stop)
2986             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2987                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
2988                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
2989             else
2990                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
2991             fi
2992             ;;
2993         *)
2994             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
2995             ;;
2996     esac
2997 }
2998
2999 # run dhclient for wireless device
3000 iwclient() {
3001     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
3002 }
3003
3004 # spawn a minimally set up ksh - useful if you want to umount /usr/.
3005 minimal-shell() {
3006     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
3007 }
3008
3009 # a wrapper for vim, that deals with title setting
3010 #   VIM_OPTIONS
3011 #       set this array to a set of options to vim you always want
3012 #       to have set when calling vim (in .zshrc.local), like:
3013 #           VIM_OPTIONS=( -p )
3014 #       This will cause vim to send every file given on the
3015 #       commandline to be send to it's own tab (needs vim7).
3016 vim() {
3017     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
3018 }
3019
3020 # make a backup of a file
3021 bk() {
3022     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
3023 }
3024
3025 #f1# grep for patterns in grml's zsh setup
3026 zg() {
3027 #{{{
3028     LANG=C perl -e '
3029
3030 sub usage {
3031     print "usage: zg -[anr] <pattern>\n";
3032     print " Search for patterns in grml'\''s zshrc.\n";
3033     print " zg takes no or exactly one option plus a non empty pattern.\n\n";
3034     print "   options:\n";
3035     print "     --  no options (use if your pattern starts in with a dash.\n";
3036     print "     -a  search for the pattern in all code regions\n";
3037     print "     -n  search for the pattern in non-root code only\n";
3038     print "     -r  search in code for everyone (also root) only\n\n";
3039     print "   The default is -a for non-root users and -r for root.\n\n";
3040     print " If you installed the zshrc to a non-default locations (ie *NOT*\n";
3041     print " in /etc/zsh/zshrc) do: export GRML_ZSHRC=\$HOME/.zshrc\n";
3042     print " ...in case you copied the file to that location.\n\n";
3043     exit 1;
3044 }
3045
3046 if ($ENV{GRML_ZSHRC} ne "") {
3047     $RC = $ENV{GRML_ZSHRC};
3048 } else {
3049     $RC = "/etc/zsh/zshrc";
3050 }
3051
3052 usage if ($#ARGV < 0 || $#ARGV > 1);
3053 if ($> == 0) { $mode = "allonly"; }
3054 else { $mode = "all"; }
3055
3056 $opt = $ARGV[0];
3057 if ($opt eq "--")     { shift; }
3058 elsif ($opt eq "-a")  { $mode = "all"; shift; }
3059 elsif ($opt eq "-n")  { $mode = "nonroot"; shift; }
3060 elsif ($opt eq "-r" ) { $mode = "allonly"; shift; }
3061 elsif ($opt =~ m/^-/ || $#ARGV > 0) { usage(); }
3062
3063 $pattern = $ARGV[0];
3064 usage() if ($pattern eq "");
3065
3066 open FH, "<$RC" or die "zg: Could not open $RC: $!\n";
3067 while ($line = <FH>) {
3068     chomp $line;
3069     if ($line =~ m/^#:grep:marker:for:mika:/) { $markerfound = 1; next; }
3070     next if ($mode eq "nonroot" && markerfound == 0);
3071     break if ($mode eq "allonly" && markerfound == 1);
3072     print $line, "\n" if ($line =~ /$pattern/);
3073 }
3074 close FH;
3075 exit 0;
3076
3077     ' -- "$@"
3078 #}}}
3079     return $?
3080 }
3081
3082 # }}}
3083
3084 # {{{ make sure our environment is clean regarding colors
3085 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
3086 # }}}
3087
3088 # "persistent history" {{{
3089 # just write important commands you always need to ~/.important_commands
3090 if [[ -r ~/.important_commands ]] ; then
3091     fc -R ~/.important_commands
3092 fi
3093 # }}}
3094
3095 #:grep:marker:for:mika: :-)
3096 ### non-root (EUID != 0) code below
3097 ###
3098
3099 if (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) ; then
3100     zrclocal
3101     return 0
3102 fi
3103
3104
3105 # variables {{{
3106
3107 # set terminal property (used e.g. by msgid-chooser)
3108 export COLORTERM="yes"
3109
3110 # set default browser
3111 if [[ -z "$BROWSER" ]] ; then
3112     if [[ -n "$DISPLAY" ]] ; then
3113         #v# If X11 is running
3114         check_com -c firefox && export BROWSER=firefox
3115     else
3116         #v# If no X11 is running
3117         check_com -c w3m && export BROWSER=w3m
3118     fi
3119 fi
3120
3121 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
3122 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
3123 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
3124
3125 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
3126 #v# [for non-root only]
3127 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
3128 # }}}
3129
3130 # aliases {{{
3131
3132 # Xterm resizing-fu.
3133 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
3134 alias hide='echo -en "\033]50;nil2\007"'
3135 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
3136 alias small='echo -en "\033]50;6x10\007"'
3137 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
3138 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
3139 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
3140 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
3141 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
3142 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
3143
3144 # general
3145 #a2# Execute \kbd{du -sch}
3146 alias da='du -sch'
3147 #a2# Execute \kbd{jobs -l}
3148 alias j='jobs -l'
3149
3150 # compile stuff
3151 #a2# Execute \kbd{./configure}
3152 alias CO="./configure"
3153 #a2# Execute \kbd{./configure --help}
3154 alias CH="./configure --help"
3155
3156 # arch/tla stuff
3157 if check_com -c tla ; then
3158     #a2# Execute \kbd{tla what-changed --diffs | less}
3159     alias tdi='tla what-changed --diffs | less'
3160     #a2# Execute \kbd{tla-buildpackage}
3161     alias tbp='tla-buildpackage'
3162     #a2# Execute \kbd{tla archive-mirror}
3163     alias tmi='tla archive-mirror'
3164     #a2# Execute \kbd{tla commit}
3165     alias tco='tla commit'
3166     #a2# Execute \kbd{tla star-merge}
3167     alias tme='tla star-merge'
3168 fi
3169
3170 # listing stuff
3171 #a2# Execute \kbd{ls -lSrah}
3172 alias dir="ls -lSrah"
3173 #a2# Only show dot-directories
3174 alias lad='ls -d .*(/)'                # only show dot-directories
3175 #a2# Only show dot-files
3176 alias lsa='ls -a .*(.)'                # only show dot-files
3177 #a2# Only files with setgid/setuid/sticky flag
3178 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
3179 #a2# Only show 1st ten symlinks
3180 alias lsl='ls -l *(@[1,10])'           # only symlinks
3181 #a2# Display only executables
3182 alias lsx='ls -l *(*[1,10])'           # only executables
3183 #a2# Display world-{readable,writable,executable} files
3184 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
3185 #a2# Display the ten biggest files
3186 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
3187 #a2# Only show directories
3188 alias lsd='ls -d *(/)'                 # only show directories
3189 #a2# Only show empty directories
3190 alias lse='ls -d *(/^F)'               # only show empty directories
3191 #a2# Display the ten newest files
3192 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
3193 #a2# Display the ten oldest files
3194 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
3195 #a2# Display the ten smallest files
3196 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
3197
3198 # chmod
3199 #a2# Execute \kbd{chmod 600}
3200 alias rw-='chmod 600'
3201 #a2# Execute \kbd{chmod 700}
3202 alias rwx='chmod 700'
3203 #m# a2 r-{}- Execute \kbd{chmod 644}
3204 alias r--='chmod 644'
3205 #a2# Execute \kbd{chmod 755}
3206 alias r-x='chmod 755'
3207
3208 # some useful aliases
3209 #a2# Execute \kbd{mkdir -o}
3210 alias md='mkdir -p'
3211
3212 check_com -c ipython && alias ips='ipython -p sh'
3213
3214 # console stuff
3215 #a2# Execute \kbd{mplayer -vo fbdev}
3216 alias cmplayer='mplayer -vo fbdev'
3217 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
3218 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
3219 #a2# Execute \kbd{links2 -driver fb}
3220 alias fblinks='links2 -driver fb'
3221
3222 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3223 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3224 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3225
3226 # simple webserver
3227 check_com -c python && alias http="python -m SimpleHTTPServer"
3228
3229 # Use 'g' instead of 'git':
3230 check_com g || alias g='git'
3231
3232 # check whether Debian's package management (dpkg) is running
3233 if check_com salias ; then
3234     #a2# Check whether a dpkg instance is currently running
3235     salias check_dpkg_running="dpkg_running"
3236 fi
3237
3238 # work around non utf8 capable software in utf environment via $LANG and luit
3239 if check_com isutfenv && check_com luit ; then
3240     if check_com -c mrxvt ; then
3241         isutfenv && [[ -n "$LANG" ]] && \
3242             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3243     fi
3244
3245     if check_com -c aterm ; then
3246         isutfenv && [[ -n "$LANG" ]] && \
3247             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3248     fi
3249
3250     if check_com -c centericq ; then
3251         isutfenv && [[ -n "$LANG" ]] && \
3252             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3253     fi
3254 fi
3255 # }}}
3256
3257 # useful functions {{{
3258
3259 # searching
3260 #f4# Search for newspostings from authors
3261 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
3262 #f4# Search Debian Bug Tracking System
3263 debbug()  {
3264     setopt localoptions extendedglob
3265     if [[ $# -eq 1 ]]; then
3266         case "$1" in
3267             ([0-9]##)
3268             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
3269             ;;
3270             (*@*)
3271             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
3272             ;;
3273             (*)
3274             ${=BROWSER} "http://bugs.debian.org/$*"
3275             ;;
3276         esac
3277     else
3278         print "$0 needs one argument"
3279         return 1
3280     fi
3281 }
3282 #f4# Search Debian Bug Tracking System in mbox format
3283 debbugm() { bts show --mbox $1 } # provide bugnummer as "$1"
3284 #f4# Search DMOZ
3285 dmoz()    { ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_} }
3286 #f4# Search German   Wiktionary
3287 dwicti()  { ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_} }
3288 #f4# Search English  Wiktionary
3289 ewicti()  { ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_} }
3290 #f4# Search Google Groups
3291 ggogle()  { ${=BROWSER} "http://groups.google.com/groups?q=$*" }
3292 #f4# Search Google
3293 google()  { ${=BROWSER} "http://www.google.com/search?&num=100&q=$*" }
3294 #f4# Search Google Groups for MsgID
3295 mggogle() { ${=BROWSER} "http://groups.google.com/groups?selm=$*" }
3296 #f4# Search Netcraft
3297 netcraft(){ ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1" }
3298 #f4# Use German Wikipedia's full text search
3299 swiki()   { ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1} }
3300 #f4# search \kbd{dict.leo.org}
3301 oleo()    { ${=BROWSER} "http://dict.leo.org/?search=$*" }
3302 #f4# Search German   Wikipedia
3303 wikide()  { ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}" }
3304 #f4# Search English  Wikipedia
3305 wikien()  { ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}" }
3306 #f4# Search official debs
3307 wodeb()   { ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all" }
3308
3309 #m# f4 gex() Exact search via Google
3310 check_com google && gex () { google "\"[ $1]\" $*" } # exact search at google
3311
3312 # misc
3313 #f5# Backup \kbd{file {\rm to} file\_timestamp}
3314 bk()      { cp -b ${1} ${1}_`date --iso-8601=m` }
3315 #f5# Copied diff
3316 cdiff()   { diff -crd "$*" | egrep -v "^Only in |^Binary files " }
3317 #f5# cd to directoy and list files
3318 cl()      { cd $1 && ls -a }        # cd && ls
3319 #f5# Cvs add
3320 cvsa()    { cvs add $* && cvs com -m 'initial checkin' $* }
3321 #f5# Cvs diff
3322 cvsd()    { cvs diff -N $* |& $PAGER }
3323 #f5# Cvs log
3324 cvsl()    { cvs log $* |& $PAGER }
3325 #f5# Cvs update
3326 cvsq()    { cvs -nq update }
3327 #f5# Rcs2log
3328 cvsr()    { rcs2log $* | $PAGER }
3329 #f5# Cvs status
3330 cvss()    { cvs status -v $* }
3331 #f5# Disassemble source files using gcc and as
3332 disassemble(){ gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null }
3333 #f5# Firefox remote control - open given URL
3334 fir()     { firefox -a firefox -remote "openURL($1)" }
3335 #f5# Create Directoy and \kbd{cd} to it
3336 mcd()     { mkdir -p "$@"; cd "$@" } # mkdir && cd
3337 #f5# Unified diff to timestamped outputfile
3338 mdiff()   { diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1" }
3339 #f5# Memory overview
3340 memusage(){ ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc }
3341 #f5# Show contents of tar file
3342 shtar()   { gunzip -c $1 | tar -tf - -- | $PAGER }
3343 #f5# Show contents of tgz file
3344 shtgz()   { tar -ztf $1 | $PAGER }
3345 #f5# Show contents of zip file
3346 shzip()   { unzip -l $1 | $PAGER }
3347 #f5# Greps signature from file
3348 sig()     { agrep -d '^-- $' "$*" ~/.Signature }
3349 #f5# Unified diff
3350 udiff()   { diff -urd $* | egrep -v "^Only in |^Binary files " }
3351 #f5# (Mis)use \kbd{vim} as \kbd{less}
3352 viless()  { vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}" }
3353
3354 # download video from youtube
3355 ytdl() {
3356     if ! [[ -n "$2" ]] ; then
3357         print "Usage: ydtl http://youtube.com/watch?v=.... outputfile.flv">&2
3358         return 1
3359     else
3360         wget -O${2} "http://youtube.com/get_video?"${${${"$(wget -o/dev/null -O- "${1}" | grep -e watch_fullscreen)"}##*watch_fullscreen\?}%%\&fs=*}
3361     fi
3362 }
3363
3364 # Function Usage: uopen $URL/$file
3365 #f5# Download a file and display it locally
3366 uopen() {
3367     if ! [[ -n "$1" ]] ; then
3368         print "Usage: uopen \$URL/\$file">&2
3369         return 1
3370     else
3371         FILE=$1
3372         MIME=$(curl --head $FILE | grep Content-Type | cut -d ' ' -f 2 | cut -d\; -f 1)
3373         MIME=${MIME%$'\r'}
3374         curl $FILE | see ${MIME}:-
3375     fi
3376 }
3377
3378 # Function Usage: doc packagename
3379 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
3380 doc() { cd /usr/share/doc/$1 && ls }
3381 _doc() { _files -W /usr/share/doc -/ }
3382 check_com compdef && compdef _doc doc
3383
3384 #f5# Make screenshot
3385 sshot() {
3386     [[ ! -d ~/shots  ]] && mkdir ~/shots
3387     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
3388     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
3389 }
3390
3391 # list images only
3392 limg() {
3393     local -a images
3394     images=( *.{jpg,gif,png}(.N) )
3395
3396     if [[ $#images -eq 0 ]] ; then
3397         print "No image files found"
3398     else
3399         ls "$@" "$images[@]"
3400     fi
3401 }
3402
3403 #f5# Create PDF file from source code
3404 makereadable() {
3405     output=$1
3406     shift
3407     a2ps --medium A4dj -E -o $output $*
3408     ps2pdf $output
3409 }
3410
3411 # zsh with perl-regex - use it e.g. via:
3412 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
3413 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
3414 regcheck() {
3415     zmodload -i zsh/pcre
3416     pcre_compile $1 && \
3417     pcre_match $2 && echo "regex matches" || echo "regex does not match"
3418 }
3419
3420 #f5# List files which have been modified within the last {\it n} days
3421 new() { print -l *(m-$1) }
3422
3423 #f5# Grep in history
3424 greph() { history 0 | grep $1 }
3425 # use colors when GNU grep with color-support
3426 #a2# Execute \kbd{grep -{}-color=auto}
3427 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
3428 #a2# Execute \kbd{grep -i -{}-color=auto}
3429 alias GREP='grep -i --color=auto'
3430
3431 #f5# Watch manpages in a stretched style
3432 man2() { PAGER='dash -c "sed G | /usr/bin/less"' command man "$@" ; }
3433
3434 # d():Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
3435 # note: option AUTO_PUSHD has to be set
3436 #f5# Jump between directories
3437 d() {
3438     emulate -L zsh
3439     autoload -U colors
3440     local color=$fg_bold[blue]
3441     integer i=0
3442     dirs -p | while read dir; do
3443         local num="${$(printf "%-4d " $i)/ /.}"
3444         printf " %s  $color%s$reset_color\n" $num $dir
3445         (( i++ ))
3446     done
3447     integer dir=-1
3448     read -r 'dir?Jump to directory: ' || return
3449     (( dir == -1 )) && return
3450     if (( dir < 0 || dir >= i )); then
3451         echo d: no such directory stack entry: $dir
3452         return 1
3453     fi
3454     cd ~$dir
3455 }
3456
3457 # usage example: 'lcheck strcpy'
3458 #f5# Find out which libs define a symbol
3459 lcheck() {
3460     if [[ -n "$1" ]] ; then
3461         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
3462     else
3463         echo "Usage: lcheck <function>" >&2
3464     fi
3465 }
3466
3467 #f5# Clean up directory - remove well known tempfiles
3468 purge() {
3469     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
3470     NBFILES=${#FILES}
3471     if [[ $NBFILES > 0 ]] ; then
3472         print $FILES
3473         local ans
3474         echo -n "Remove these files? [y/n] "
3475         read -q ans
3476         if [[ $ans == "y" ]] ; then
3477             rm ${FILES}
3478             echo ">> $PWD purged, $NBFILES files removed"
3479         else
3480             echo "Ok. .. than not.."
3481         fi
3482     fi
3483 }
3484
3485 # Translate DE<=>EN
3486 # 'translate' looks up fot a word in a file with language-to-language
3487 # translations (field separator should be " : "). A typical wordlist looks
3488 # like at follows:
3489 #  | english-word : german-transmission
3490 # It's also only possible to translate english to german but not reciprocal.
3491 # Use the following oneliner to turn back the sort order:
3492 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3493 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3494 #f5# Translates a word
3495 trans() {
3496     case "$1" in
3497         -[dD]*)
3498             translate -l de-en $2
3499             ;;
3500         -[eE]*)
3501             translate -l en-de $2
3502             ;;
3503         *)
3504             echo "Usage: $0 { -D | -E }"
3505             echo "         -D == German to English"
3506             echo "         -E == English to German"
3507     esac
3508 }
3509
3510 #f5# List all occurrences of programm in current PATH
3511 plap() {
3512     if [[ $# = 0 ]] ; then
3513         echo "Usage:    $0 program"
3514         echo "Example:  $0 zsh"
3515         echo "Lists all occurrences of program in the current PATH."
3516     else
3517         ls -l ${^path}/*$1*(*N)
3518     fi
3519 }
3520
3521 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
3522 #f5# Select items for specific command(s) from history
3523 selhist() {
3524     emulate -L zsh
3525     local TAB=$'\t';
3526     (( $# < 1 )) && {
3527         echo "Usage: $0 command"
3528         return 1
3529     };
3530     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
3531     print -l $cmd | less -F
3532     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
3533     local answer
3534     read answer
3535     print -z "${cmd[$answer]#*$TAB}"
3536 }
3537
3538 # Use vim to convert plaintext to HTML
3539 #f5# Transform files to html with highlighting
3540 2html() { vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null }
3541
3542 # Usage: simple-extract <file>
3543 #f5# Smart archive extractor
3544 simple-extract () {
3545     if [[ -f $1 ]] ; then
3546         case $1 in
3547             *.tar.bz2)  bzip2 -v -d $1      ;;
3548             *.tar.gz)   tar -xvzf $1        ;;
3549             *.rar)      unrar $1            ;;
3550             *.deb)      ar -x $1            ;;
3551             *.bz2)      bzip2 -d $1         ;;
3552             *.lzh)      lha x $1            ;;
3553             *.gz)       gunzip -d $1        ;;
3554             *.tar)      tar -xvf $1         ;;
3555             *.tgz)      gunzip -d $1        ;;
3556             *.tbz2)     tar -jxvf $1        ;;
3557             *.zip)      unzip $1            ;;
3558             *.Z)        uncompress $1       ;;
3559             *)          echo "'$1' Error. Please go away" ;;
3560         esac
3561     else
3562         echo "'$1' is not a valid file"
3563     fi
3564 }
3565
3566 # Usage: smartcompress <file> (<type>)
3567 #f5# Smart archive creator
3568 smartcompress() {
3569     if [[ -n $2 ]] ; then
3570         case $2 in
3571             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
3572             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
3573             tar.Z)          tar -Zcvf$1.$2 $1 ;;
3574             tar)            tar -cvf$1.$2  $1 ;;
3575             gz | gzip)      gzip           $1 ;;
3576             bz2 | bzip2)    bzip2          $1 ;;
3577             *)
3578                 echo "Error: $2 is not a valid compression type"
3579                 ;;
3580         esac
3581     else
3582         smartcompress $1 tar.gz
3583     fi
3584 }
3585
3586 # Usage: show-archive <archive>
3587 #f5# List an archive's content
3588 show-archive() {
3589     if [[ -f $1 ]] ; then
3590         case $1 in
3591             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
3592             *.tar)         tar -tf $1 ;;
3593             *.tgz)         tar -ztf $1 ;;
3594             *.zip)         unzip -l $1 ;;
3595             *.bz2)         bzless $1 ;;
3596             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
3597             *)             echo "'$1' Error. Please go away" ;;
3598         esac
3599     else
3600         echo "'$1' is not a valid archive"
3601     fi
3602 }
3603
3604 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
3605 #f5# Use \kbd{vim} as your manpage reader
3606 vman() { man $* | col -b | view -c 'set ft=man nomod nolist' - }
3607
3608 # function readme() { $PAGER -- (#ia3)readme* }
3609 #f5# View all README-like files in current directory in pager
3610 readme() {
3611     local files
3612     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
3613     if (($#files)) ; then
3614         $PAGER $files
3615     else
3616         print 'No README files.'
3617     fi
3618 }
3619
3620 # function ansi-colors()
3621 #f5# Display ANSI colors
3622 ansi-colors() {
3623     typeset esc="\033[" line1 line2
3624     echo " _ _ _40 _ _ _41_ _ _ _42 _ _ 43_ _ _ 44_ _ _45 _ _ _ 46_ _ _ 47_ _ _ 49_ _"
3625     for fore in 30 31 32 33 34 35 36 37; do
3626         line1="$fore "
3627         line2="   "
3628         for back in 40 41 42 43 44 45 46 47 49; do
3629             line1="${line1}${esc}${back};${fore}m Normal ${esc}0m"
3630             line2="${line2}${esc}${back};${fore};1m Bold   ${esc}0m"
3631         done
3632         echo -e "$line1\n$line2"
3633     done
3634 }
3635
3636 # suidfind() { ls -latg $path | grep '^...s' }
3637 #f5# Find all files in \$PATH with setuid bit set
3638 suidfind() { ls -latg $path/*(sN) }
3639
3640 # See above but this is /better/ ... anywise ..
3641 findsuid() {
3642     print 'Output will be written to ~/suid_* ...'
3643     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
3644     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
3645     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
3646     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
3647     print 'Finished'
3648 }
3649
3650 #f5# Reload given functions
3651 refunc() {
3652     for func in $argv ; do
3653         unfunction $func
3654         autoload $func
3655     done
3656 }
3657
3658 # a small check to see which DIR is located on which server/partition.
3659 # stolen and modified from Sven's zshrc.forall
3660 #f5# Report diskusage of a directory
3661 dirspace() {
3662     if [[ -n "$1" ]] ; then
3663         for dir in $* ; do
3664             if [[ -d "$dir" ]] ; then
3665                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3666             else
3667                 echo "warning: $dir does not exist" >&2
3668             fi
3669         done
3670     else
3671         for dir in $path; do
3672             if [[ -d "$dir" ]] ; then
3673                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3674             else
3675                 echo "warning: $dir does not exist" >&2
3676             fi
3677         done
3678     fi
3679 }
3680
3681 # % slow_print `cat /etc/passwd`
3682 #f5# Slowly print out parameters
3683 slow_print() {
3684     for argument in "${@}" ; do
3685         for ((i = 1; i <= ${#1} ;i++)) ; do
3686             print -n "${argument[i]}"
3687             sleep 0.08
3688         done
3689         print -n " "
3690     done
3691     print ""
3692 }
3693
3694 #f5# Show some status info
3695 status() {
3696     print ""
3697     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
3698     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
3699     print "Term..: $TTY ($TERM), ${BAUD:+$BAUD bauds, }$COLUMNS x $LINES cars"
3700     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
3701     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
3702     print "Uptime:$(uptime)"
3703     print ""
3704 }
3705
3706 # Rip an audio CD
3707 #f5# Rip an audio CD
3708 audiorip() {
3709     mkdir -p ~/ripps
3710     cd ~/ripps
3711     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
3712     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
3713     echo " * Would you like to burn the cd now? (yes/no)"
3714     read input
3715     if [[ "$input" = "yes" ]] ; then
3716         echo " ! Burning Audio CD"
3717         audioburn
3718         echo " * done."
3719     else
3720         echo " ! Invalid response."
3721     fi
3722 }
3723
3724 # and burn it
3725 #f5# Burn an audio CD (in combination with audiorip)
3726 audioburn() {
3727     cd ~/ripps
3728     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
3729     echo " * Should I remove the temporary files? (yes/no)"
3730     read input
3731     if [[ "$input" = "yes" ]] ; then
3732         echo " ! Removing Temporary Files."
3733         cd ~
3734         rm -rf ~/ripps
3735         echo " * done."
3736     else
3737         echo " ! Invalid response."
3738     fi
3739 }
3740
3741 #f5# Make an audio CD from all mp3 files
3742 mkaudiocd() {
3743     # TODO: do the renaming more zshish, possibly with zmv()
3744     cd ~/ripps
3745     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
3746     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
3747     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
3748     normalize -m *.wav
3749     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
3750 }
3751
3752 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
3753 mkiso() {
3754     echo " * Volume name "
3755     read volume
3756     echo " * ISO Name (ie. tmp.iso)"
3757     read iso
3758     echo " * Directory or File"
3759     read files
3760     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
3761 }
3762
3763 #f5# Simple thumbnails generator
3764 genthumbs() {
3765     rm -rf thumb-* index.html
3766     echo "
3767 <html>
3768   <head>
3769     <title>Images</title>
3770   </head>
3771   <body>" > index.html
3772     for f in *.(gif|jpeg|jpg|png) ; do
3773         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
3774         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
3775     done
3776     echo "
3777   </body>
3778 </html>" >> index.html
3779 }
3780
3781 #f5# Set all ulimit parameters to \kbd{unlimited}
3782 allulimit() {
3783     ulimit -c unlimited
3784     ulimit -d unlimited
3785     ulimit -f unlimited
3786     ulimit -l unlimited
3787     ulimit -n unlimited
3788     ulimit -s unlimited
3789     ulimit -t unlimited
3790 }
3791
3792 # ogg2mp3 with bitrate of 192
3793 ogg2mp3_192() {
3794     oggdec -o - ${1} | lame -b 192 - ${1:r}.mp3
3795 }
3796
3797 #f5# RFC 2396 URL encoding in Z-Shell
3798 urlencode() {
3799     setopt localoptions extendedglob
3800     input=( ${(s::)1} )
3801     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%${(l:2::0:)$(([##16]#match))}}
3802 }
3803
3804 #f5# Install x-lite (VoIP software)
3805 getxlite() {
3806     setopt local_options
3807     setopt errreturn
3808     [[ -d ~/tmp ]] || mkdir ~/tmp
3809     cd ~/tmp
3810
3811     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
3812     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
3813         unp X-Lite_Install.tar.gz && echo done || echo failed
3814     else
3815         echo "Error while downloading." ; return 1
3816     fi
3817
3818     if [[ -x xten-xlite/xtensoftphone ]] ; then
3819         echo "Execute xten-xlite/xtensoftphone to start xlite."
3820     fi
3821 }
3822
3823 #f5# Install skype
3824 getskype() {
3825     setopt local_options
3826     setopt errreturn
3827     echo "Downloading debian package of skype."
3828     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
3829     wget http://www.skype.com/go/getskype-linux-deb
3830     $SUDO dpkg -i skype*.deb && echo "skype installed."
3831 }
3832
3833 #f5# Install beta-version of skype
3834 getskypebeta() {
3835     setopt local_options
3836     setopt errreturn
3837     echo "Downloading debian package of skype (beta version)."
3838     wget http://www.skype.com/go/getskype-linux-beta-deb
3839     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
3840 }
3841
3842 #f5# Install gizmo (VoIP software)
3843 getgizmo() {
3844     setopt local_options
3845     setopt errreturn
3846     echo "libgtk2.0-0, gconf2, libstdc++6, libasound2 and zlib1g have to be available. Installing."
3847     $SUDO apt-get update
3848     $SUDO apt-get install libgtk2.0-0 gconf2 libstdc++6 libasound2 zlib1g
3849     wget "$(lynx --dump http://gizmo5.com/pc/download/linux/ | awk '/libstdc\+\+6.*\.deb/ {print $2}')"
3850     $SUDO dpkg -i gizmo-project*.deb && echo "gizmo installed."
3851 }
3852
3853 #f5# Get and run AIR (Automated Image and Restore)
3854 getair() {
3855     setopt local_options
3856     setopt errreturn
3857     [[ -w . ]] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
3858     local VER='1.2.8'
3859     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
3860     tar zxf air-$VER.tar.gz
3861     cd air-$VER
3862     INTERACTIVE=no $SUDO ./install-air-1.2.8
3863     [[ -x /usr/local/bin/air ]] && [[ -n "$DISPLAY" ]] && $SUDO air
3864 }
3865
3866 #f5# Get specific git commitdiff
3867 git-get-diff() {
3868     if [[ -z $GITTREE ]] ; then
3869         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3870     fi
3871     if ! [[ -z $1 ]] ; then
3872         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
3873     else
3874         echo "Usage: git-get-diff <commit>"
3875     fi
3876 }
3877
3878 #f5# Get specific git commit
3879 git-get-commit() {
3880     if [[ -z $GITTREE ]] ; then
3881         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3882     fi
3883     if ! [[ -z $1 ]] ; then
3884         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
3885     else
3886         echo "Usage: git-get-commit <commit>"
3887     fi
3888 }
3889
3890 #f5# Get specific git diff
3891 git-get-plaindiff () {
3892     if [[ -z $GITTREE ]] ; then
3893        GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3894     fi
3895     if [[ -z $1 ]] ; then
3896        echo 'Usage: git-get-plaindiff '
3897     else
3898        echo -n "Downloading $1.diff ... "
3899        # avoid "generating ..." stuff from kernel.org server:
3900        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O /dev/null
3901        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff \
3902             && echo done || echo failed
3903     fi
3904 }
3905
3906
3907 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
3908 #f5# Log 'make install' output
3909 mmake() {
3910     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
3911     make -n install > ~/.errorlogs/${PWD##*/}-makelog
3912 }
3913
3914 #f5# Indent source code
3915 smart-indent() {
3916     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs $*
3917 }
3918
3919 # highlight important stuff in diff output, usage example: hg diff | hidiff
3920 #m# a2 hidiff \kbd{histring} oneliner for diffs
3921 check_com -c histring && \
3922     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
3923
3924 # rename pictures based on information found in exif headers
3925 #f5# Rename pictures based on information found in exif headers
3926 exirename() {
3927     if [[ $# -lt 1 ]] ; then
3928         echo 'Usage: jpgrename $FILES' >& 2
3929         return 1
3930     else
3931         echo -n 'Checking for jhead with version newer than 1.9: '
3932         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
3933         if [[ $jhead_version > '1.9' ]]; then
3934             echo 'success - now running jhead.'
3935             jhead -n%Y-%m-%d_%Hh%M_%f $*
3936         else
3937             echo 'failed - exiting.'
3938         fi
3939     fi
3940 }
3941
3942 # open file in vim and jump to line
3943 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
3944 j2v() {
3945     local -a params
3946     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
3947     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
3948     vim ${params}
3949 }
3950
3951 # get_ic() - queries imap servers for capabilities; real simple. no imaps
3952 ic_get() {
3953     local port
3954     if [[ ! -z $1 ]] ; then
3955         port=${2:-143}
3956         print "querying imap server on $1:${port}...\n";
3957         print "a1 capability\na2 logout\n" | nc $1 ${port}
3958     else
3959         print "usage:\n  $0 <imap-server> [port]"
3960     fi
3961 }
3962
3963 # creates a Maildir/ with its {new,cur,tmp} subdirs
3964 mkmaildir() {
3965     local root subdir
3966     root=${MAILDIR_ROOT:-${HOME}/Mail}
3967     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
3968     subdir=${1}
3969     mkdir -p ${root}/${subdir}/{cur,new,tmp}
3970 }
3971
3972 #f5# Change the xterm title from within GNU-screen
3973 xtrename() {
3974     if [[ ${1} != "-f" ]] ; then
3975         if [[ -z ${DISPLAY} ]] ; then
3976             printf 'xtrename only makes sense in X11.\n'
3977             return 1
3978         fi
3979     else
3980         shift
3981     fi
3982     if [[ -z ${1} ]] ; then
3983         printf 'usage: xtrename [-f] "title for xterm"\n'
3984         printf '  renames the title of xterm from _within_ screen.\n'
3985         printf '  also works without screen.\n'
3986         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3987         return 0
3988     fi
3989     print -n "\eP\e]0;${1}\C-G\e\\"
3990     return 0
3991 }
3992
3993 # hl() highlighted less
3994 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
3995 if check_com -c highlight ; then
3996     function hl() {
3997         local theme lang
3998         theme=${HL_THEME:-""}
3999         case ${1} in
4000             (-l|--list)
4001                 ( printf 'available languages (syntax parameter):\n\n' ;
4002                     highlight --list-langs ; ) | less -SMr
4003                 ;;
4004             (-t|--themes)
4005                 ( printf 'available themes (style parameter):\n\n' ;
4006                     highlight --list-themes ; ) | less -SMr
4007                 ;;
4008             (-h|--help)
4009                 printf 'usage: hl <syntax[:theme]> <file>\n'
4010                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
4011                 printf '  Example: hl c main.c\n'
4012                 ;;
4013             (*)
4014                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
4015                     printf 'usage: hl <syntax[:theme]> <file>\n'
4016                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
4017                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
4018                     return 1
4019                 fi
4020                 lang=${1%:*}
4021                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
4022                 if [[ -n ${theme} ]] ; then
4023                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
4024                 else
4025                     highlight --ansi --syntax ${lang} ${2} | less -SMr
4026                 fi
4027                 ;;
4028         esac
4029         return 0
4030     }
4031     # ... and a proper completion for hl()
4032     # needs 'highlight' as well, so it fits fine in here.
4033     function _hl_genarg()  {
4034         local expl
4035         if [[ -prefix 1 *: ]] ; then
4036             local themes
4037             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
4038             compset -P 1 '*:'
4039             _wanted -C list themes expl theme compadd ${themes}
4040         else
4041             local langs
4042             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
4043             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
4044         fi
4045     }
4046     function _hl_complete() {
4047         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
4048     }
4049     compdef _hl_complete hl
4050 fi
4051
4052 # Create small urls via http://tinyurl.com using wget(1).
4053 function zurl() {
4054     [[ -z ${1} ]] && { print "USAGE: zurl <URL>" ; return 1 }
4055
4056     local PN url tiny grabber search result preview
4057     PN=${0}
4058     url=${1}
4059 #   Check existence of given URL with the help of ping(1).
4060 #   N.B. ping(1) only works without an eventual given protocol.
4061     ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
4062         read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
4063
4064     if (( $? == 0 )) ; then
4065 #           Prepend 'http://' to given URL where necessary for later output.
4066             [[ ${url} != http(s|)://* ]] && url='http://'${url}
4067             tiny='http://tinyurl.com/create.php?url='
4068             if check_com -c wget ; then
4069                 grabber='wget -O- -o/dev/null'
4070             else
4071                 print "wget is not available, but mandatory for ${PN}. Aborting."
4072             fi
4073 #           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
4074             search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
4075             result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
4076 #           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
4077             preview='http://preview.'${result#http://}
4078
4079             printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
4080             printf '%s\t%s\n\n' 'Given URL:' ${url}
4081             printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
4082     else
4083         return 1
4084     fi
4085 }
4086
4087 #f2# Print a specific line of file(s).
4088 linenr () {
4089 # {{{
4090     if [ $# -lt 2 ] ; then
4091        print "Usage: linenr <number>[,<number>] <file>" ; return 1
4092     elif [ $# -eq 2 ] ; then
4093          local number=$1
4094          local file=$2
4095          command ed -s $file <<< "${number}n"
4096     else
4097          local number=$1
4098          shift
4099          for file in "$@" ; do
4100              if [ ! -d $file ] ; then
4101                 echo "${file}:"
4102                 command ed -s $file <<< "${number}n" 2> /dev/null
4103              else
4104                 continue
4105              fi
4106          done | less
4107     fi
4108 # }}}
4109 }
4110
4111 #f2# Find history events by search pattern and list them by date.
4112 whatwhen()  {
4113 # {{{
4114     local usage help ident format_l format_s first_char remain first last
4115     usage='USAGE: whatwhen [options] <searchstring> <search range>'
4116     help='Use' \`'whatwhen -h'\'' for further explanations.'
4117     ident=${(l,${#${:-Usage: }},, ,)}
4118     format_l="${ident}%s\t\t\t%s\n"
4119     format_s="${format_l//(\\t)##/\\t}"
4120     # Make the first char of the word to search for case
4121     # insensitive; e.g. [aA]
4122     first_char=[${(L)1[1]}${(U)1[1]}]
4123     remain=${1[2,-1]}
4124     # Default search range is `-100'.
4125     first=${2:-\-100}
4126     # Optional, just used for `<first> <last>' given.
4127     last=$3
4128     case $1 in
4129         ("")
4130             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
4131             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4132         ;;
4133         (-h)
4134             printf '%s\n\n' ${usage}
4135             print 'OPTIONS:'
4136             printf $format_l '-h' 'show help text'
4137             print '\f'
4138             print 'SEARCH RANGE:'
4139             printf $format_l "'0'" 'the whole history,'
4140             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
4141             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
4142             printf '\n%s\n' 'EXAMPLES:'
4143             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
4144             printf $format_l 'whatwhen zsh -250'
4145             printf $format_l 'whatwhen foo 1 99'
4146         ;;
4147         (\?)
4148             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4149         ;;
4150         (*)
4151             # -l list results on stout rather than invoking $EDITOR.
4152             # -i Print dates as in YYYY-MM-DD.
4153             # -m Search for a - quoted - pattern within the history.
4154             fc -li -m "*${first_char}${remain}*" $first $last
4155         ;;
4156     esac
4157 # }}}
4158 }
4159
4160 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
4161 fluxkey-change() {
4162     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
4163     if ! [[ -r "$FLUXKEYS" ]] ; then
4164         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
4165         return 1
4166     else
4167         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
4168             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
4169             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
4170         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
4171             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
4172             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
4173         else
4174             echo 'Sorry, do not know what to do.'
4175             return 1
4176         fi
4177     fi
4178 }
4179
4180 # retrieve weather information on the console
4181 # Usage example: 'weather LOWG'
4182 weather() {
4183     [[ -n "$1" ]] || {
4184         print 'Usage: weather <station_id>' >&2
4185         print 'List of stations: http://en.wikipedia.org/wiki/List_of_airports_by_ICAO_code'>&2
4186         return 1
4187     }
4188
4189     local PLACE="${1:u}"
4190     local FILE="$HOME/.weather/$PLACE"
4191     local LOG="$HOME/.weather/log"
4192
4193     [[ -d $HOME/.weather ]] || {
4194         print -n "Creating $HOME/.weather: "
4195         mkdir $HOME/.weather
4196         print 'done'
4197     }
4198
4199     print "Retrieving information for ${PLACE}:"
4200     print
4201     wget -T 10 --no-verbose --output-file=$LOG --output-document=$FILE --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
4202
4203     if [[ $? -eq 0 ]] ; then
4204         if [[ -n "$VERBOSE" ]] ; then
4205             cat $FILE
4206         else
4207             DATE=$(grep 'UTC' $FILE | sed 's#.* /##')
4208             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' $FILE| tr -d '(')
4209             echo "date: $DATE"
4210             echo "temp:  $TEMPERATURE"
4211         fi
4212     else
4213         print "There was an error retrieving the weather information for $PLACE" >&2
4214         cat $LOG
4215         return 1
4216     fi
4217 }
4218 # }}}
4219
4220 # mercurial related stuff {{{
4221 if check_com -c hg ; then
4222     # gnu like diff for mercurial
4223     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
4224     #f5# GNU like diff for mercurial
4225     hgdi() {
4226         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
4227     }
4228
4229     # build debian package
4230     #a2# Alias for \kbd{hg-buildpackage}
4231     alias hbp='hg-buildpackage'
4232
4233     # execute commands on the versioned patch-queue from the current repos
4234     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
4235
4236     # diffstat for specific version of a mercurial repository
4237     #   hgstat      => display diffstat between last revision and tip
4238     #   hgstat 1234 => display diffstat between revision 1234 and tip
4239     #f5# Diffstat for specific version of a mercurial repos
4240     hgstat() {
4241         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
4242     }
4243
4244     #f5# Get current mercurial tip via hg itself
4245     gethgclone() {
4246         setopt local_options
4247         setopt errreturn
4248         if [[ -f mercurial-tree/.hg ]] ; then
4249             cd mercurial-tree
4250             echo "Running hg pull for retreiving latest version..."
4251             hg pull
4252             echo "Finished update. Building mercurial"
4253             make local
4254             echo "Setting \$PATH to $PWD:\$PATH..."
4255             export PATH="$PWD:$PATH"
4256         else
4257             echo "Downloading mercurial via hg"
4258             hg clone http://selenic.com/repo/hg mercurial-tree
4259             cd mercurial-tree
4260             echo "Building mercurial"
4261             make local
4262             echo "Setting \$PATH to $PWD:\$PATH..."
4263             export PATH="$PWD:$PATH"
4264             echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4265             # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
4266             # export PYTHONPATH=${HOME}/lib/python
4267         fi
4268     }
4269
4270 fi # end of check whether we have the 'hg'-executable
4271
4272 # get current mercurial snapshot
4273 #f5# Get current mercurial snapshot
4274 gethgsnap() {
4275     setopt local_options
4276     setopt errreturn
4277     if [[ -f mercurial-snapshot.tar.gz ]] ; then
4278          echo "mercurial-snapshot.tar.gz exists already, skipping download."
4279     else
4280         echo "Downloading mercurial snapshot"
4281         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
4282     fi
4283     echo "Unpacking mercurial-snapshot.tar.gz"
4284     tar zxf mercurial-snapshot.tar.gz
4285     cd mercurial-snapshot/
4286     echo "Installing required build-dependencies"
4287     $SUDO apt-get update
4288     $SUDO apt-get install python2.4-dev
4289     echo "Building mercurial"
4290     make local
4291     echo "Setting \$PATH to $PWD:\$PATH..."
4292     export PATH="$PWD:$PATH"
4293     echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4294 }
4295 # }}}
4296
4297 # some useful commands often hard to remember - let's grep for them {{{
4298 # actually use our zg() function now. :)
4299
4300 # Work around ion/xterm resize bug.
4301 #if [[ "$SHLVL" -eq 1 ]]; then
4302 #       if check_com -c resize ; then
4303 #               eval `resize </dev/null`
4304 #       fi
4305 #fi
4306
4307 # enable jackd:
4308 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
4309 # now play audio file:
4310 #  alsaplayer -o jack foobar.mp3
4311
4312 # send files via netcat
4313 # on sending side:
4314 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
4315 #  send dir* $HOST
4316 #  alias receive='nc -vlp 51330 | tar xzvp'
4317
4318 # debian stuff:
4319 # dh_make -e foo@localhost -f $1
4320 # dpkg-buildpackage -rfakeroot
4321 # lintian *.deb
4322 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
4323 # dpkg-scansources . | gzip > Sources.gz
4324 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
4325
4326 # other stuff:
4327 # convert -geometry 200x200 -interlace LINE -verbose
4328 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
4329 # ps -ao user,pcpu,start,command
4330 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
4331 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
4332 # nc -vz $1 1-1024   # portscan via netcat
4333 # wget --mirror --no-parent --convert-links
4334 # pal -d `date +%d`
4335 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
4336 #
4337 # modify console cursor
4338 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
4339 # print $'\e[?96;0;64c'
4340 # }}}
4341
4342 # grml-small cleanups {{{
4343
4344 # The following is used to remove zsh-config-items that do not work
4345 # in grml-small by default.
4346 # If you do not want these adjustments (for whatever reason), set
4347 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
4348 # sources if it is there).
4349
4350 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
4351
4352     unset abk[V]
4353     unalias    'V'      &> /dev/null
4354     unfunction vman     &> /dev/null
4355     unfunction vimpm    &> /dev/null
4356     unfunction vimhelp  &> /dev/null
4357     unfunction viless   &> /dev/null
4358     unfunction 2html    &> /dev/null
4359
4360     # manpages are not in grmlsmall
4361     unfunction manzsh   &> /dev/null
4362     unalias    man2     &> /dev/null
4363     unalias    man      &> /dev/null
4364     unfunction man2     &> /dev/null
4365
4366 fi
4367
4368 #}}}
4369
4370 zrclocal
4371
4372 ## genrefcard.pl settings {{{
4373
4374 ### doc strings for external functions from files
4375 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
4376
4377 ### example: split functions-search 8,16,24,32
4378 #@# split functions-search 8
4379
4380 ## }}}
4381
4382 ## END OF FILE #################################################################
4383 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4